data/qcsrc/menu/nexuiz/dialog_multiplayer_playersetup_weapons.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizWeaponsDialog) EXTENDS(NexuizDialog)
   3         METHOD(NexuizWeaponsDialog, toString, string(entity))
   4         METHOD(NexuizWeaponsDialog, fill, void(entity))
   5         METHOD(NexuizWeaponsDialog, showNotify, void(entity))
   6         ATTRIB(NexuizWeaponsDialog, title, string, "Weapon settings")
   7         ATTRIB(NexuizWeaponsDialog, color, vector, SKINCOLOR_DIALOG_WEAPONS)
   8         ATTRIB(NexuizWeaponsDialog, intendedWidth, float, 0.35)
   9         ATTRIB(NexuizWeaponsDialog, rows, float, 15)
  10         ATTRIB(NexuizWeaponsDialog, columns, float, 4)
  11         ATTRIB(NexuizWeaponsDialog, weaponsList, entity, NULL)
  12 ENDCLASS(NexuizWeaponsDialog)
  13 #endif
  14
  15 #ifdef IMPLEMENTATION
  16 void showNotifyNexuizWeaponsDialog(entity me)
  17 {
  18         loadAllCvars(me);
  19 }
  20 string toStringNexuizWeaponsDialog(entity me)
  21 {
  22         return me.weaponsList.toString(me.weaponsList);
  23 }
  24 void fillNexuizWeaponsDialog(entity me)
  25 {
  26         entity e;
  27         float h0, h;
  28
  29         h = me.rows - 6;
  30
  31         me.TR(me);
  32                 me.TD(me, 1, 4, makeNexuizTextLabel(0, "Weapon priority list:"));
  33         me.TR(me);
  34                 h0 = me.currentRow;
  35                 me.TD(me, h, 3, e = me.weaponsList = makeNexuizWeaponsList());
  36         me.gotoRC(me, h0 + h / 2 - 1, 3);
  37                 me.TD(me, 1, 1, e = makeNexuizButton("Up", '0 0 0'));
  38                         e.onClick = WeaponsList_MoveUp_Click;
  39                         e.onClickEntity = me.weaponsList;
  40         me.gotoRC(me, h0 + h / 2, 3);
  41                 me.TD(me, 1, 1, e = makeNexuizButton("Down", '0 0 0'));
  42                         e.onClick = WeaponsList_MoveDown_Click;
  43                         e.onClickEntity = me.weaponsList;
  44         me.gotoRC(me, h0 + h, 0);
  45                 me.TD(me, 1, 3, e = makeNexuizCheckBox(0, "cl_weaponpriority_useforcycling", "Use priority list for weapon cycling"));
  46         me.TR(me);
  47                 me.TD(me, 1, 3, e = makeNexuizCheckBox(0, "cl_autoswitch", "Auto switch weapons on pickup"));
  48         me.TR(me);
  49         me.TR(me);
  50                 me.TD(me, 1, 3, e = makeNexuizCheckBox(0, "r_drawviewmodel", "Draw 1st person weapon model"));
  51         me.TR(me);
  52                 me.TD(me, 1, me.columns, e = makeNexuizButton("OK", '0 0 0'));
  53                         e.onClick = Dialog_Close;
  54                         e.onClickEntity = me;
  55 }
  56
  57 #endif