data/qcsrc/menu/nexuiz/dialog_multiplayer_create_mutators.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizMutatorsDialog) EXTENDS(NexuizDialog)
   3         METHOD(NexuizMutatorsDialog, toString, string(entity))
   4         METHOD(NexuizMutatorsDialog, fill, void(entity))
   5         METHOD(NexuizMutatorsDialog, showNotify, void(entity))
   6         METHOD(NexuizMutatorsDialog, close, void(entity))
   7         ATTRIB(NexuizMutatorsDialog, title, string, "Mutators")
   8         ATTRIB(NexuizMutatorsDialog, color, vector, SKINCOLOR_DIALOG_MUTATORS)
   9         ATTRIB(NexuizMutatorsDialog, intendedWidth, float, 0.8)
  10         ATTRIB(NexuizMutatorsDialog, rows, float, 16)
  11         ATTRIB(NexuizMutatorsDialog, columns, float, 6)
  12         ATTRIB(NexuizMutatorsDialog, refilterEntity, entity, NULL)
  13 ENDCLASS(NexuizMutatorsDialog)
  14 #endif
  15
  16 #ifdef IMPLEMENTATION
  17 void showNotifyNexuizMutatorsDialog(entity me)
  18 {
  19         loadAllCvars(me);
  20 }
  21
  22 string weaponarenastring;
  23 string weaponarenastring_cvar;
  24 string WeaponArenaString()
  25 {
  26         string s;
  27         float n, i, j;
  28         entity e;
  29         s = cvar_string("g_weaponarena");
  30         if(s == "0")
  31                 return "";
  32         if(s == "all")
  33                 return "All Weapons Arena";
  34         if(s == "most")
  35                 return "Most Weapons Arena";
  36         if(s == weaponarenastring_cvar)
  37                 return weaponarenastring;
  38         if(weaponarenastring)
  39                 strunzone(weaponarenastring);
  40         if(weaponarenastring_cvar)
  41                 strunzone(weaponarenastring_cvar);
  42
  43         weaponarenastring_cvar = strzone(s);
  44
  45         n = tokenize_sane(s);
  46         s = "";
  47         for(i = 0; i < n; ++i)
  48         {
  49                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  50                 {
  51                         e = get_weaponinfo(j);
  52                         if(argv(i) == e.netname)
  53                                 s = strcat(s, " & ", e.message);
  54                 }
  55         }
  56         s = strcat(substring(s, 3, strlen(s) - 3), " Arena");
  57
  58         weaponarenastring = strzone(s);
  59
  60         return weaponarenastring;
  61 }
  62
  63 string toStringNexuizMutatorsDialog(entity me)
  64 {
  65         string s;
  66         s = "";
  67         if(cvar("g_minstagib"))
  68                 s = strcat(s, ", MinstaGib");
  69         if(cvar("g_nixnex"))
  70                 s = strcat(s, ", NixNex");
  71         if(cvar_string("g_weaponarena") != "0")
  72                 s = strcat(s, ", ", WeaponArenaString());
  73         if(cvar("sv_gravity") < 800)
  74                 s = strcat(s, ", Low gravity");
  75         if(cvar("g_cloaked"))
  76                 s = strcat(s, ", Cloaked");
  77         if(cvar("g_footsteps"))
  78                 s = strcat(s, ", Steps");
  79         if(cvar("g_grappling_hook"))
  80                 s = strcat(s, ", Hook");
  81         if(cvar("g_laserguided_missile"))
  82                 s = strcat(s, ", LG missiles");
  83         if(cvar("g_midair"))
  84                 s = strcat(s, ", Midair");
  85         if(cvar("g_vampire"))
  86                 s = strcat(s, ", Vampire");
  87         if(cvar("g_weapon_stay"))
  88                 s = strcat(s, ", Weapons stay");
  89         if(s == "")
  90                 return "None";
  91         else
  92                 return substring(s, 2, strlen(s) - 2);
  93 }
  94
  95
  96
  97 // WARNING: dirty hack. TODO clean this up by putting this behaviour in extra classes.
  98 void loadCvarsLaserWeaponArenaWeaponButton(entity me)
  99 {
 100         tokenize_sane(cvar_string("g_weaponarena"));
 101         me.checked = (argv(0) == me.cvarValue);
 102 }
 103
 104 void saveCvarsLaserWeaponArenaWeaponButton(entity me)
 105 {
 106         string suffix;
 107
 108         suffix = "";
 109         if(me.cvarValue != "laser")
 110                 if(cvar("menu_weaponarena_with_laser"))
 111                         suffix = " laser";
 112         if(me.checked)
 113                 cvar_set("g_weaponarena", strcat(me.cvarValue, suffix));
 114         else
 115                 cvar_set("g_weaponarena", me.cvarOffValue);
 116 }
 117
 118 .void(entity) draw_weaponarena;
 119 .void(entity) saveCvars_weaponarena;
 120 void saveCvarsLaserWeaponArenaLaserButton(entity me)
 121 {
 122         // run the old function
 123         me.saveCvars_weaponarena(me);
 124
 125         me.disabled = ((cvar_string("g_weaponarena") == "0") || (cvar_string("g_weaponarena") == "laser"));
 126
 127         if not(me.disabled)
 128         {
 129                 // check for the laser suffix
 130                 string s;
 131                 s = cvar_string("g_weaponarena");
 132                 if(me.checked && substring(s, strlen(s) - 6, 6) != " laser")
 133                         s = strcat(s, " laser");
 134                 else if(!me.checked && substring(s, strlen(s) - 6, 6) == " laser")
 135                         s = substring(s, 0, strlen(s) - 6);
 136                 cvar_set("g_weaponarena", s);
 137         }
 138 }
 139
 140 void preDrawLaserWeaponArenaLaserButton(entity me)
 141 {
 142         me.disabled = ((cvar_string("g_weaponarena") == "0") || (cvar_string("g_weaponarena") == "laser"));
 143         // run the old function
 144         me.draw_weaponarena(me);
 145 }
 146 // WARNING: end of dirty hack. Do not try this at home.
 147
 148
 149
 150 void fillNexuizMutatorsDialog(entity me)
 151 {
 152         entity e, s, w;
 153         float i, j;
 154         string str, hstr;
 155         me.TR(me);
 156                 me.TD(me, 1, 2, makeNexuizTextLabel(0, "Game mutators:"));
 157         me.TR(me);
 158                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_cloaked", "Cloaked"));
 159         me.TR(me);
 160                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_footsteps", "Footsteps"));
 161         me.TR(me);
 162                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_grappling_hook", "Grappling hook"));
 163         me.TR(me);
 164                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_laserguided_missile", "Laser guided missiles"));
 165         me.TR(me);
 166                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_midair", "Midair"));
 167         me.TR(me);
 168                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_vampire", "Vampire"));
 169         me.TR(me);
 170                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_weapon_stay", "Weapons stay"));
 171         me.TR(me);
 172                 s = makeNexuizSlider(80, 400, 8, "sv_gravity");
 173                         s.valueDigits = 0;
 174                         s.valueDisplayMultiplier = 0.125; // show gravity in percent
 175                 me.TD(me, 1, 2, e = makeNexuizSliderCheckBox(800, 1, s, "Low gravity"));
 176                         e.savedValue = 200; // good on silvercity
 177         me.TR(me);
 178                 me.TDempty(me, 0.2);
 179                 me.TD(me, 1, 1.8, s);
 180
 181         me.gotoRC(me, 0, 2); me.setFirstColumn(me, me.currentColumn);
 182                 me.TD(me, 1, 4, makeNexuizTextLabel(0, "Weapon arenas:"));
 183         me.TR(me);
 184                 me.TD(me, 1, 4, e = makeNexuizRadioButton(1, string_null, string_null, "Regular (no arena)"));
 185         for(i = WEP_FIRST, j = 0; i <= WEP_LAST; ++i, ++j)
 186         {
 187                 w = get_weaponinfo(i);
 188                 if(j & 1 == 0)
 189                         me.TR(me);
 190                 str = w.netname;
 191                 hstr = w.message;
 192                 me.TD(me, 1, 2, e = makeNexuizRadioButton(1, "g_weaponarena", strzone(str), strzone(hstr)));
 193                         e.cvarOffValue = "0";
 194                         // custom load/save logic that ignores a " laser" suffix, or adds it
 195                         e.loadCvars = loadCvarsLaserWeaponArenaWeaponButton;
 196                         e.saveCvars = saveCvarsLaserWeaponArenaWeaponButton;
 197                         e.loadCvars(e);
 198         }
 199         me.TR(me);
 200                 me.TDempty(me, 0.2);
 201                 me.TD(me, 1, 3.8, e = makeNexuizCheckBox(0, "menu_weaponarena_with_laser", "with laser"));
 202                         // hook the draw function to gray it out
 203                         e.draw_weaponarena = e.draw;
 204                         e.draw = preDrawLaserWeaponArenaLaserButton;
 205                         // hook the save function to notify about the cvar
 206                         e.saveCvars_weaponarena = e.saveCvars;
 207                         e.saveCvars = saveCvarsLaserWeaponArenaLaserButton;
 208         me.TR(me);
 209                 me.TD(me, 1, 4, makeNexuizTextLabel(0, "Special arenas:"));
 210         me.TR(me);
 211                 me.TD(me, 1, 4, e = makeNexuizRadioButton(1, "g_minstagib", string_null, "MinstaGib"));
 212         me.TR(me);
 213                 me.TD(me, 1, 4, e = makeNexuizRadioButton(1, "g_nixnex", string_null, "NixNex"));
 214         me.TR(me);
 215                 me.TDempty(me, 0.2);
 216                 me.TD(me, 1, 3.8, e = makeNexuizCheckBox(0, "g_nixnex_with_laser", "with laser"));
 217                         setDependent(e, "g_nixnex", 1, 1);
 218         me.TR(me);
 219                 me.TD(me, 1, 4, e = makeNexuizRadioButton(1, "g_weaponarena", "all", "All weapons"));
 220                         e.cvarOffValue = "0";
 221
 222         me.gotoRC(me, me.rows - 1, 0);
 223                 me.TD(me, 1, me.columns, e = makeNexuizButton("OK", '0 0 0'));
 224                         e.onClick = Dialog_Close;
 225                         e.onClickEntity = me;
 226 }
 227
 228 void closeNexuizMutatorsDialog(entity me)
 229 {
 230         if(me.refilterEntity)
 231                 me.refilterEntity.refilter(me.refilterEntity);
 232         closeDialog(me);
 233 }
 234 #endif