data/qcsrc/menu/nexuiz/campaign.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizCampaignList) EXTENDS(NexuizListBox)
   3         METHOD(NexuizCampaignList, configureNexuizCampaignList, void(entity))
   4         ATTRIB(NexuizCampaignList, rowsPerItem, float, 10)
   5         METHOD(NexuizCampaignList, draw, void(entity))
   6         METHOD(NexuizCampaignList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(NexuizCampaignList, clickListBoxItem, void(entity, float, vector))
   8         METHOD(NexuizCampaignList, resizeNotify, void(entity, vector, vector, vector, vector))
   9         METHOD(NexuizCampaignList, setSelected, void(entity, float))
  10         METHOD(NexuizCampaignList, keyDown, float(entity, float, float, float))
  11         METHOD(NexuizCampaignList, campaignGo, void(entity, float))
  12         METHOD(NexuizCampaignList, destroy, void(entity))
  13
  14         ATTRIB(NexuizCampaignList, campaignGlob, float, 0)
  15         ATTRIB(NexuizCampaignList, realFontSize, vector, '0 0 0')
  16         ATTRIB(NexuizCampaignList, columnPreviewOrigin, float, 0)
  17         ATTRIB(NexuizCampaignList, columnPreviewSize, float, 0)
  18         ATTRIB(NexuizCampaignList, columnNameOrigin, float, 0)
  19         ATTRIB(NexuizCampaignList, columnNameSize, float, 0)
  20         ATTRIB(NexuizCampaignList, columnCheckMarkOrigin, float, 0)
  21         ATTRIB(NexuizCampaignList, columnCheckMarkSize, float, 0)
  22         ATTRIB(NexuizCampaignList, checkMarkOrigin, vector, '0 0 0')
  23         ATTRIB(NexuizCampaignList, checkMarkSize, vector, '0 0 0')
  24         ATTRIB(NexuizCampaignList, realUpperMargin1, float, 0)
  25         ATTRIB(NexuizCampaignList, realUpperMargin2, float, 0)
  26
  27         ATTRIB(NexuizCampaignList, lastClickedMap, float, -1)
  28         ATTRIB(NexuizCampaignList, lastClickedTime, float, 0)
  29
  30         ATTRIB(NexuizCampaignList, origin, vector, '0 0 0')
  31         ATTRIB(NexuizCampaignList, itemAbsSize, vector, '0 0 0')
  32         ATTRIB(NexuizCampaignList, emptyLineHeight, float, 0.5)
  33
  34         ATTRIB(NexuizCampaignList, campaignIndex, float, 0)
  35         ATTRIB(NexuizCampaignList, cvarName, string, string_null)
  36         METHOD(NexuizCampaignList, loadCvars, void(entity))
  37         METHOD(NexuizCampaignList, saveCvars, void(entity))
  38
  39         ATTRIB(NexuizCampaignList, buttonNext, entity, NULL)
  40         ATTRIB(NexuizCampaignList, buttonPrev, entity, NULL)
  41         ATTRIB(NexuizCampaignList, labelTitle, entity, NULL)
  42 ENDCLASS(NexuizCampaignList)
  43 entity makeNexuizCampaignList();
  44 void CampaignList_LoadMap(entity btn, entity me);
  45 void MultiCampaign_Next(entity btn, entity me);
  46 void MultiCampaign_Prev(entity btn, entity me);
  47 #endif
  48
  49 #ifdef IMPLEMENTATION
  50 string campaign_longdesc_wrapped[CAMPAIGN_MAX_ENTRIES];
  51
  52 void rewrapCampaign(float w, float l0, float emptyheight)
  53 {
  54         float i, j;
  55         float n, l;
  56         string r, s;
  57         for(i = 0; i < campaign_entries; ++i)
  58         {
  59                 l = l0;
  60                 if(campaign_longdesc_wrapped[i])
  61                         strunzone(campaign_longdesc_wrapped[i]);
  62                 n = tokenizebyseparator(campaign_longdesc[i], "\n");
  63                 r = "";
  64                 for(j = 0; j < n; ++j)
  65                 {
  66                         s = argv(j);
  67                         if(s == "")
  68                         {
  69                                 l -= emptyheight;
  70                                 r = strcat(r, "\n");
  71                                 continue;
  72                         }
  73
  74                         getWrappedLine_remaining = s;
  75                         while(getWrappedLine_remaining)
  76                         {
  77                                 s = getWrappedLine(w, draw_TextWidth_WithoutColors);
  78                                 if(--l < 0) goto toolong;
  79                                 r = strcat(r, s, "\n");
  80                         }
  81                 }
  82                 goto nottoolong;
  83 :toolong
  84                 while(substring(r, strlen(r) - 1, 1) == "\n")
  85                         r = substring(r, 0, strlen(r) - 1);
  86                 r = strcat(r, "...\n");
  87 :nottoolong
  88                 campaign_longdesc_wrapped[i] = strzone(substring(r, 0, strlen(r) - 1));
  89         }
  90 }
  91
  92 entity makeNexuizCampaignList()
  93 {
  94         entity me;
  95         me = spawnNexuizCampaignList();
  96         me.configureNexuizCampaignList(me);
  97         return me;
  98 }
  99 void configureNexuizCampaignListNexuizCampaignList(entity me)
 100 {
 101         me.configureNexuizListBox(me);
 102         me.campaignGlob = search_begin("maps/campaign*.txt", TRUE, TRUE);
 103         me.loadCvars(me);
 104         me.campaignGo(me, 0); // takes care of enabling/disabling buttons too
 105 }
 106
 107 void destroyNexuizCampaignList(entity me)
 108 {
 109         if(me.campaignGlob >= 0)
 110                 search_end(me.campaignGlob);
 111 }
 112
 113 void loadCvarsNexuizCampaignList(entity me)
 114 {
 115         // read campaign cvars
 116         if(campaign_name)
 117                 strunzone(campaign_name);
 118         if(me.cvarName)
 119                 strunzone(me.cvarName);
 120         campaign_name = strzone(cvar_string("g_campaign_name"));
 121         me.cvarName = strzone(strcat("g_campaign", campaign_name, "_index"));
 122         registercvar(me.cvarName, "", 0); // saved by server QC anyway
 123         CampaignFile_Unload();
 124         CampaignFile_Load(0, CAMPAIGN_MAX_ENTRIES);
 125         me.campaignIndex = bound(0, cvar(me.cvarName), campaign_entries);
 126         cvar_set(me.cvarName, ftos(me.campaignIndex));
 127         if(me.columnNameSize)
 128                 rewrapCampaign(me.columnNameSize / me.realFontSize_x, me.rowsPerItem - 3, me.emptyLineHeight);
 129         me.nItems = min(me.campaignIndex + 2, campaign_entries);
 130         me.selectedItem = min(me.campaignIndex, me.nItems - 1);
 131         me.scrollPos = me.nItems * me.itemHeight - 1;
 132         if(me.labelTitle)
 133                 me.labelTitle.setText(me.labelTitle, campaign_title);
 134 }
 135
 136 void saveCvarsNexuizCampaignList(entity me)
 137 {
 138         // write campaign cvars
 139         // no reason to do this!
 140         // cvar_set("g_campaign_name", campaign_name);
 141         // cvar_set(me.cvarName, ftos(me.campaignIndex)); // NOTE: only server QC does that!
 142 }
 143
 144 void campaignGoNexuizCampaignList(entity me, float step)
 145 {
 146         float canNext, canPrev;
 147         string s;
 148         float i, j, n;
 149
 150         canNext = canPrev = 0;
 151
 152         if(me.campaignGlob >= 0)
 153         {
 154                 n = search_getsize(me.campaignGlob);
 155                 if(n > 0)
 156                 {
 157                         j = -1;
 158                         s = strcat("maps/campaign", campaign_name, ".txt");
 159                         for(i = 0; i < n; ++i)
 160                         {
 161                                 if(search_getfilename(me.campaignGlob, i) == s)
 162                                         j = i;
 163                         }
 164                         if(j < 0)
 165                         {
 166                                 if(step >= 0)
 167                                         j = 0;
 168                                 else
 169                                         j = n - 1;
 170                         }
 171                         else
 172                                 j = mod(j + step, n);
 173                         s = search_getfilename(me.campaignGlob, j);
 174                         s = substring(s, 13, strlen(s) - 17);
 175                         cvar_set("g_campaign_name", s);
 176                         me.loadCvars(me);
 177                         canNext = (j != n - 1);
 178                         canPrev = (j != 0);
 179                 }
 180         }
 181
 182         if(me.buttonNext)
 183                 me.buttonNext.disabled = !canNext;
 184         if(me.buttonPrev)
 185                 me.buttonPrev.disabled = !canPrev;
 186 }
 187
 188 void MultiCampaign_Next(entity btn, entity me)
 189 {
 190         me.campaignGo(me, +1);
 191 }
 192 void MultiCampaign_Prev(entity btn, entity me)
 193 {
 194         me.campaignGo(me, -1);
 195 }
 196
 197 void drawNexuizCampaignList(entity me)
 198 {
 199         if(cvar(me.cvarName) != me.campaignIndex || cvar_string("g_campaign_name") != campaign_name)
 200                 me.loadCvars(me);
 201         drawListBox(me);
 202 }
 203
 204 void resizeNotifyNexuizCampaignList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 205 {
 206         me.itemAbsSize = '0 0 0';
 207         resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
 208
 209         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 210         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 211         me.realUpperMargin1 = 0.5 * me.realFontSize_y;
 212         me.realUpperMargin2 = me.realUpperMargin1 + 2 * me.realFontSize_y;
 213
 214         me.checkMarkSize = (eX * (me.itemAbsSize_y / me.itemAbsSize_x) + eY) * 0.5;
 215
 216         me.columnPreviewOrigin = 0;
 217         me.columnPreviewSize = me.itemAbsSize_y / me.itemAbsSize_x * 4 / 3;
 218         me.columnCheckMarkSize = me.checkMarkSize_x;
 219         me.columnNameSize = 1 - me.columnPreviewSize - me.columnCheckMarkSize - 4 * me.realFontSize_x;
 220         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize_x;
 221         me.columnCheckMarkOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize_x * 2;
 222
 223         me.checkMarkOrigin = eY + eX * (me.columnCheckMarkOrigin + me.columnCheckMarkSize) - me.checkMarkSize;
 224
 225         rewrapCampaign(me.columnNameSize / me.realFontSize_x, me.rowsPerItem - 3, me.emptyLineHeight);
 226 }
 227 void clickListBoxItemNexuizCampaignList(entity me, float i, vector where)
 228 {
 229         if(i == me.lastClickedMap)
 230                 if(time < me.lastClickedTime + 0.3)
 231                 {
 232                         // DOUBLE CLICK!
 233                         // start game
 234                         CampaignList_LoadMap(me, me);
 235                         return;
 236                 }
 237         me.lastClickedMap = i;
 238         me.lastClickedTime = time;
 239 }
 240 void drawListBoxItemNexuizCampaignList(entity me, float i, vector absSize, float isSelected)
 241 {
 242         string s;
 243         float p;
 244         vector theColor;
 245         float theAlpha;
 246         float j, n;
 247         vector o;
 248
 249         if(i < me.campaignIndex)
 250         {
 251                 theAlpha = SKINALPHA_CAMPAIGN_SELECTABLE;
 252                 theColor = SKINCOLOR_CAMPAIGN_SELECTABLE;
 253         }
 254         else if(i == me.campaignIndex)
 255         {
 256                 theAlpha = SKINALPHA_CAMPAIGN_CURRENT;
 257                 theColor = SKINCOLOR_CAMPAIGN_CURRENT;
 258         }
 259         else
 260         {
 261                 theAlpha = SKINALPHA_CAMPAIGN_FUTURE;
 262                 theColor = SKINCOLOR_CAMPAIGN_FUTURE;
 263         }
 264
 265         if(isSelected)
 266                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 267
 268         s = ftos(p);
 269         draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", campaign_mapname[i]), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 270         if(i < me.campaignIndex)
 271                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 272         if(i <= me.campaignIndex)
 273                 s = campaign_shortdesc[i]; // fteqcc sucks
 274         else
 275                 s = "???";
 276         s = draw_TextShortenToWidth(strcat("Level ", ftos(i + 1), ": ", s), me.columnNameSize / me.realFontSize_x, 0);
 277         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, theColor, theAlpha, 0);
 278
 279         if(i <= me.campaignIndex)
 280         {
 281                 s = campaign_longdesc_wrapped[i];
 282                 n = tokenizebyseparator(s, "\n");
 283                 o = me.realUpperMargin2 * eY + me.columnNameOrigin * eX;
 284                 for(j = 0; j < n; ++j)
 285                         if(argv(j) != "")
 286                         {
 287                                 draw_Text(o, argv(j), me.realFontSize, theColor, theAlpha * SKINALPHA_CAMPAIGN_DESCRIPTION, 0);
 288                                 o_y += me.realFontSize_y;
 289                         }
 290                         else
 291                                 o_y += me.realFontSize_y * me.emptyLineHeight;
 292         }
 293 }
 294 void CampaignList_LoadMap(entity btn, entity me)
 295 {
 296         if(me.selectedItem >= me.nItems || me.selectedItem < 0)
 297                 return;
 298         CampaignSetup(me.selectedItem);
 299 }
 300
 301 void setSelectedNexuizCampaignList(entity me, float i)
 302 {
 303         // prevent too late items from being played
 304         setSelectedListBox(me, min(i, me.campaignIndex));
 305 }
 306
 307 float keyDownNexuizCampaignList(entity me, float scan, float ascii, float shift)
 308 {
 309         if(scan == K_ENTER || scan == K_SPACE)
 310                 CampaignList_LoadMap(me, me);
 311         else
 312                 return keyDownListBox(me, scan, ascii, shift);
 313         return 1;
 314 }
 315 #endif