data/qcsrc/menu/nexuiz/campaign.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizCampaignList) EXTENDS(NexuizListBox)
   3         METHOD(NexuizCampaignList, configureNexuizCampaignList, void(entity))
   4         ATTRIB(NexuizCampaignList, rowsPerItem, float, 10)
   5         METHOD(NexuizCampaignList, draw, void(entity))
   6         METHOD(NexuizCampaignList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(NexuizCampaignList, clickListBoxItem, void(entity, float, vector))
   8         METHOD(NexuizCampaignList, resizeNotify, void(entity, vector, vector, vector, vector))
   9         METHOD(NexuizCampaignList, setSelected, void(entity, float))
  10         METHOD(NexuizCampaignList, keyDown, float(entity, float, float, float))
  11         METHOD(NexuizCampaignList, campaignGo, void(entity, float))
  12         METHOD(NexuizCampaignList, destroy, void(entity))
  13
  14         ATTRIB(NexuizCampaignList, campaignGlob, float, 0)
  15         ATTRIB(NexuizCampaignList, realFontSize, vector, '0 0 0')
  16         ATTRIB(NexuizCampaignList, columnPreviewOrigin, float, 0)
  17         ATTRIB(NexuizCampaignList, columnPreviewSize, float, 0)
  18         ATTRIB(NexuizCampaignList, columnNameOrigin, float, 0)
  19         ATTRIB(NexuizCampaignList, columnNameSize, float, 0)
  20         ATTRIB(NexuizCampaignList, columnCheckMarkOrigin, float, 0)
  21         ATTRIB(NexuizCampaignList, columnCheckMarkSize, float, 0)
  22         ATTRIB(NexuizCampaignList, checkMarkOrigin, vector, '0 0 0')
  23         ATTRIB(NexuizCampaignList, checkMarkSize, vector, '0 0 0')
  24         ATTRIB(NexuizCampaignList, realUpperMargin1, float, 0)
  25         ATTRIB(NexuizCampaignList, realUpperMargin2, float, 0)
  26
  27         ATTRIB(NexuizCampaignList, lastClickedMap, float, -1)
  28         ATTRIB(NexuizCampaignList, lastClickedTime, float, 0)
  29
  30         ATTRIB(NexuizCampaignList, origin, vector, '0 0 0')
  31         ATTRIB(NexuizCampaignList, itemAbsSize, vector, '0 0 0')
  32         ATTRIB(NexuizCampaignList, emptyLineHeight, float, 0.5)
  33
  34         ATTRIB(NexuizCampaignList, campaignIndex, float, 0)
  35         ATTRIB(NexuizCampaignList, cvarName, string, string_null)
  36         METHOD(NexuizCampaignList, loadCvars, void(entity))
  37         METHOD(NexuizCampaignList, saveCvars, void(entity))
  38
  39         ATTRIB(NexuizCampaignList, buttonNext, entity, NULL)
  40         ATTRIB(NexuizCampaignList, buttonPrev, entity, NULL)
  41         ATTRIB(NexuizCampaignList, labelTitle, entity, NULL)
  42 ENDCLASS(NexuizCampaignList)
  43 entity makeNexuizCampaignList();
  44 void CampaignList_LoadMap(entity btn, entity me);
  45 void MultiCampaign_Next(entity btn, entity me);
  46 void MultiCampaign_Prev(entity btn, entity me);
  47 #endif
  48
  49 #ifdef IMPLEMENTATION
  50 string campaign_longdesc_wrapped[CAMPAIGN_MAX_ENTRIES];
  51
  52 void rewrapCampaign(float w, float l0, float emptyheight)
  53 {
  54         float i, j;
  55         float n, take, cantake, l;
  56         string r, s;
  57         for(i = 0; i < campaign_entries; ++i)
  58         {
  59                 l = l0;
  60                 if(campaign_longdesc_wrapped[i])
  61                         strunzone(campaign_longdesc_wrapped[i]);
  62                 n = tokenizebyseparator(campaign_longdesc[i], "\n");
  63                 r = "";
  64                 for(j = 0; j < n; ++j)
  65                 {
  66                         s = argv(j);
  67                         if(s == "")
  68                         {
  69                                 l -= emptyheight;
  70                                 r = strcat(r, "\n");
  71                                 continue;
  72                         }
  73                         for(;;)
  74                         {
  75                                 cantake = draw_TextLengthUpToWidth(s, w, 0);
  76                                 if(cantake > 0 && cantake < strlen(s))
  77                                 {
  78                                         take = cantake - 1;
  79                                         while(take > 0 && substring(s, take, 1) != " ")
  80                                                 --take;
  81                                         if(take == 0)
  82                                         {
  83                                                 if(--l < 0) goto toolong;
  84                                                 r = strcat(r, substring(s, 0, cantake), "\n");
  85                                                 s = substring(s, cantake, strlen(s) - cantake);
  86                                         }
  87                                         else
  88                                         {
  89                                                 if(--l < 0) goto toolong;
  90                                                 r = strcat(r, substring(s, 0, take), "\n");
  91                                                 s = substring(s, take + 1, strlen(s) - take);
  92                                         }
  93                                 }
  94                                 else
  95                                 {
  96                                         if(--l < 0) goto toolong;
  97                                         r = strcat(r, s, "\n");
  98                                         break;
  99                                 }
 100                         }
 101                 }
 102                 goto nottoolong;
 103 :toolong
 104                 while(substring(r, strlen(r) - 1, 1) == "\n")
 105                         r = substring(r, 0, strlen(r) - 1);
 106                 r = strcat(r, "...\n");
 107 :nottoolong
 108                 campaign_longdesc_wrapped[i] = strzone(substring(r, 0, strlen(r) - 1));
 109         }
 110 }
 111
 112 entity makeNexuizCampaignList()
 113 {
 114         entity me;
 115         me = spawnNexuizCampaignList();
 116         me.configureNexuizCampaignList(me);
 117         return me;
 118 }
 119 void configureNexuizCampaignListNexuizCampaignList(entity me)
 120 {
 121         me.configureNexuizListBox(me);
 122         me.campaignGlob = search_begin("maps/campaign*.txt", TRUE, TRUE);
 123         me.loadCvars(me);
 124         me.campaignGo(me, 0); // takes care of enabling/disabling buttons too
 125 }
 126
 127 void destroyNexuizCampaignList(entity me)
 128 {
 129         if(me.campaignGlob >= 0)
 130                 search_end(me.campaignGlob);
 131 }
 132
 133 void loadCvarsNexuizCampaignList(entity me)
 134 {
 135         // read campaign cvars
 136         if(campaign_name)
 137                 strunzone(campaign_name);
 138         if(me.cvarName)
 139                 strunzone(me.cvarName);
 140         campaign_name = strzone(cvar_string("g_campaign_name"));
 141         me.cvarName = strzone(strcat("g_campaign", campaign_name, "_index"));
 142         registercvar(me.cvarName, "", 0); // saved by server QC anyway
 143         CampaignFile_Unload();
 144         CampaignFile_Load(0, CAMPAIGN_MAX_ENTRIES);
 145         me.campaignIndex = bound(0, cvar(me.cvarName), campaign_entries);
 146         cvar_set(me.cvarName, ftos(me.campaignIndex));
 147         if(me.columnNameSize)
 148                 rewrapCampaign(me.columnNameSize / me.realFontSize_x, me.rowsPerItem - 3, me.emptyLineHeight);
 149         me.nItems = min(me.campaignIndex + 2, campaign_entries);
 150         me.selectedItem = min(me.campaignIndex, me.nItems - 1);
 151         me.scrollPos = me.nItems * me.itemHeight - 1;
 152         if(me.labelTitle)
 153                 me.labelTitle.setText(me.labelTitle, campaign_title);
 154 }
 155
 156 void saveCvarsNexuizCampaignList(entity me)
 157 {
 158         // write campaign cvars
 159         // no reason to do this!
 160         // cvar_set("g_campaign_name", campaign_name);
 161         // cvar_set(me.cvarName, ftos(me.campaignIndex)); // NOTE: only server QC does that!
 162 }
 163
 164 void campaignGoNexuizCampaignList(entity me, float step)
 165 {
 166         float canNext, canPrev;
 167         string s;
 168         float i, j, n;
 169
 170         canNext = canPrev = 0;
 171
 172         if(me.campaignGlob >= 0)
 173         {
 174                 n = search_getsize(me.campaignGlob);
 175                 if(n > 0)
 176                 {
 177                         j = -1;
 178                         s = strcat("maps/campaign", campaign_name, ".txt");
 179                         for(i = 0; i < n; ++i)
 180                         {
 181                                 if(search_getfilename(me.campaignGlob, i) == s)
 182                                         j = i;
 183                         }
 184                         if(j < 0)
 185                         {
 186                                 if(step >= 0)
 187                                         j = 0;
 188                                 else
 189                                         j = n - 1;
 190                         }
 191                         else
 192                                 j = mod(j + step, n);
 193                         s = search_getfilename(me.campaignGlob, j);
 194                         s = substring(s, 13, strlen(s) - 17);
 195                         cvar_set("g_campaign_name", s);
 196                         me.loadCvars(me);
 197                         canNext = (j != n - 1);
 198                         canPrev = (j != 0);
 199                 }
 200         }
 201
 202         if(me.buttonNext)
 203                 me.buttonNext.disabled = !canNext;
 204         if(me.buttonPrev)
 205                 me.buttonPrev.disabled = !canPrev;
 206 }
 207
 208 void MultiCampaign_Next(entity btn, entity me)
 209 {
 210         me.campaignGo(me, +1);
 211 }
 212 void MultiCampaign_Prev(entity btn, entity me)
 213 {
 214         me.campaignGo(me, -1);
 215 }
 216
 217 void drawNexuizCampaignList(entity me)
 218 {
 219         if(cvar(me.cvarName) != me.campaignIndex || cvar_string("g_campaign_name") != campaign_name)
 220                 me.loadCvars(me);
 221         drawListBox(me);
 222 }
 223
 224 void resizeNotifyNexuizCampaignList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 225 {
 226         me.origin = absOrigin;
 227         me.itemAbsSize = '0 0 0';
 228         resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
 229
 230         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 231         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 232         me.realUpperMargin1 = 0.5 * me.realFontSize_y;
 233         me.realUpperMargin2 = me.realUpperMargin1 + 2 * me.realFontSize_y;
 234
 235         me.checkMarkSize = (eX * (me.itemAbsSize_y / me.itemAbsSize_x) + eY) * 0.5;
 236
 237         me.columnPreviewOrigin = 0;
 238         me.columnPreviewSize = me.itemAbsSize_y / me.itemAbsSize_x * 4 / 3;
 239         me.columnCheckMarkSize = me.checkMarkSize_x;
 240         me.columnNameSize = 1 - me.columnPreviewSize - me.columnCheckMarkSize - 4 * me.realFontSize_x;
 241         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize_x;
 242         me.columnCheckMarkOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize_x * 2;
 243
 244         me.checkMarkOrigin = eY + eX * (me.columnCheckMarkOrigin + me.columnCheckMarkSize) - me.checkMarkSize;
 245
 246         rewrapCampaign(me.columnNameSize / me.realFontSize_x, me.rowsPerItem - 3, me.emptyLineHeight);
 247 }
 248 void clickListBoxItemNexuizCampaignList(entity me, float i, vector where)
 249 {
 250         if(i == me.lastClickedMap)
 251                 if(time < me.lastClickedTime + 0.3)
 252                 {
 253                         // DOUBLE CLICK!
 254                         // start game
 255                         CampaignList_LoadMap(me, me);
 256                         return;
 257                 }
 258         me.lastClickedMap = i;
 259         me.lastClickedTime = time;
 260 }
 261 void drawListBoxItemNexuizCampaignList(entity me, float i, vector absSize, float isSelected)
 262 {
 263         string s;
 264         float p;
 265         vector theColor;
 266         float theAlpha;
 267         float j, n;
 268         vector o;
 269
 270         if(i < me.campaignIndex)
 271         {
 272                 theAlpha = SKINALPHA_CAMPAIGN_SELECTABLE;
 273                 theColor = SKINCOLOR_CAMPAIGN_SELECTABLE;
 274         }
 275         else if(i == me.campaignIndex)
 276         {
 277                 theAlpha = SKINALPHA_CAMPAIGN_CURRENT;
 278                 theColor = SKINCOLOR_CAMPAIGN_CURRENT;
 279         }
 280         else
 281         {
 282                 theAlpha = SKINALPHA_CAMPAIGN_FUTURE;
 283                 theColor = SKINCOLOR_CAMPAIGN_FUTURE;
 284         }
 285
 286         if(isSelected)
 287                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 288
 289         s = ftos(p);
 290         draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", campaign_mapname[i]), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 291         if(i < me.campaignIndex)
 292                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 293         if(i <= me.campaignIndex)
 294                 s = campaign_shortdesc[i]; // fteqcc sucks
 295         else
 296                 s = "???";
 297         s = draw_TextShortenToWidth(strcat("Level ", ftos(i + 1), ": ", s), me.columnNameSize / me.realFontSize_x, 0);
 298         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, theColor, theAlpha, 0);
 299
 300         if(i <= me.campaignIndex)
 301         {
 302                 s = campaign_longdesc_wrapped[i];
 303                 n = tokenizebyseparator(s, "\n");
 304                 o = me.realUpperMargin2 * eY + me.columnNameOrigin * eX;
 305                 for(j = 0; j < n; ++j)
 306                         if(argv(j) != "")
 307                         {
 308                                 draw_Text(o, argv(j), me.realFontSize, theColor, theAlpha * SKINALPHA_CAMPAIGN_DESCRIPTION, 0);
 309                                 o_y += me.realFontSize_y;
 310                         }
 311                         else
 312                                 o_y += me.realFontSize_y * me.emptyLineHeight;
 313         }
 314 }
 315 void CampaignList_LoadMap(entity btn, entity me)
 316 {
 317         if(me.selectedItem >= me.nItems || me.selectedItem < 0)
 318                 return;
 319         CampaignSetup(me.selectedItem);
 320 }
 321
 322 void setSelectedNexuizCampaignList(entity me, float i)
 323 {
 324         // prevent too late items from being played
 325         setSelectedListBox(me, min(i, me.campaignIndex));
 326 }
 327
 328 float keyDownNexuizCampaignList(entity me, float scan, float ascii, float shift)
 329 {
 330         if(scan == K_ENTER || scan == K_SPACE)
 331                 CampaignList_LoadMap(me, me);
 332         else
 333                 return keyDownListBox(me, scan, ascii, shift);
 334         return 1;
 335 }
 336 #endif