data/qcsrc/menu/menu.qc

   1 ///////////////////////////////////////////////
   2 // Menu Source File
   3 ///////////////////////
   4 // This file belongs to dpmod/darkplaces
   5 // AK contains all menu functions (especially the required ones)
   6 ///////////////////////////////////////////////
   7
   8 float mouseButtonsPressed;
   9 vector menuMousePos;
  10 float menuShiftState;
  11 float menuPrevTime;
  12 float menuAlpha;
  13 float menuLogoAlpha;
  14 float prevMenuAlpha;
  15 float menuInitialized;
  16 float menuNotTheFirstFrame;
  17
  18 void SUB_Null() { };
  19
  20 void() m_init =
  21 {
  22         dprint_load();
  23 }
  24
  25 void UpdateConWidthHeight()
  26 {
  27         float conwidth_s, conheight_s;
  28         conwidth_s = conwidth;
  29         conheight_s = conheight;
  30         conwidth = cvar("vid_conwidth");
  31         conheight = cvar("vid_conheight");
  32         if(conwidth < 800)
  33         {
  34                 conheight *= 800 / conwidth;
  35                 conwidth = 800;
  36         }
  37         if(conheight < 600)
  38         {
  39                 conwidth *= 600 / conheight;
  40                 conheight = 600;
  41         }
  42         if(main)
  43         {
  44                 if(conwidth_s != conwidth || conheight_s != conheight)
  45                 {
  46                         draw_reset();
  47                         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
  48                 }
  49         }
  50 }
  51
  52 void() m_init_delayed =
  53 {
  54         float fh, glob, n, i;
  55         string s;
  56
  57         dprint_load();
  58
  59         menuInitialized = 0;
  60         if(!preMenuInit())
  61                 return;
  62         menuInitialized = 1;
  63         GameCommand_Init();
  64
  65         fh = -1;
  66         if(cvar_string("menu_skin") != "")
  67         {
  68                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  69                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  70         }
  71         if(fh < 0)
  72         {
  73                 draw_currentSkin = "gfx/menu/default";
  74                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  75         }
  76         draw_currentSkin = strzone(draw_currentSkin);
  77         while((s = fgets(fh)))
  78                 if(tokenize(s) == 2)
  79                         Skin_ApplySetting(argv(0), argv(1));
  80         fclose(fh);
  81
  82         glob = search_begin(strcat(draw_currentSkin, "/*.tga"), TRUE, TRUE);
  83         if(glob >= 0)
  84         {
  85                 n = search_getsize(glob);
  86                 for(i = 0; i < n; ++i)
  87                         precache_pic(search_getfilename(glob, i));
  88                 search_end(glob);
  89         }
  90
  91         draw_setMousePointer(SKINGFX_CURSOR, SKINSIZE_CURSOR, SKINOFFSET_CURSOR);
  92
  93         conwidth = conheight = -1;
  94         draw_reset();
  95         UpdateConWidthHeight();
  96         main = spawnMainWindow(); main.configureMainWindow(main);
  97         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
  98         main.focused = 1;
  99         menuShiftState = 0;
 100         menuMousePos = '0.5 0.5 0';
 101
 102         if(Menu_Active)
 103                 m_display(); // delayed menu display
 104 };
 105
 106 void(float key, float ascii) m_keyup =
 107 {
 108         if(!menuInitialized)
 109                 return;
 110         if(!Menu_Active)
 111                 return;
 112         draw_reset();
 113         main.keyUp(main, key, ascii, menuShiftState);
 114         if(key >= K_MOUSE1 && key <= K_MOUSE3)
 115         {
 116                 --mouseButtonsPressed;
 117                 if(!mouseButtonsPressed)
 118                         main.mouseRelease(main, menuMousePos);
 119                 if(mouseButtonsPressed < 0)
 120                 {
 121                         mouseButtonsPressed = 0;
 122                         print("Warning: released an already released button\n");
 123                 }
 124         }
 125         if(key == K_ALT) menuShiftState -= (menuShiftState & S_ALT);
 126         if(key == K_CTRL) menuShiftState -= (menuShiftState & S_CTRL);
 127         if(key == K_SHIFT) menuShiftState -= (menuShiftState & S_SHIFT);
 128 };
 129
 130 void(float key, float ascii) m_keydown =
 131 {
 132         if(!menuInitialized)
 133                 return;
 134         if(!Menu_Active)
 135                 return;
 136         if(keyGrabber)
 137         {
 138                 entity e;
 139                 e = keyGrabber;
 140                 keyGrabber = NULL;
 141                 e.keyGrabbed(e, key, ascii);
 142         }
 143         else
 144         {
 145                 draw_reset();
 146                 if(!main.keyDown(main, key, ascii, menuShiftState))
 147                         if(key == K_ESCAPE)
 148                                 if(gamestatus & (GAME_ISSERVER | GAME_CONNECTED)) // don't back out to console only
 149                                         m_hide(); // disable menu on unhandled ESC
 150                 if(key >= K_MOUSE1 && key <= K_MOUSE3)
 151                         if(!mouseButtonsPressed)
 152                                 main.mousePress(main, menuMousePos);
 153         }
 154         if(key >= K_MOUSE1 && key <= K_MOUSE3)
 155         {
 156                 ++mouseButtonsPressed;
 157                 if(mouseButtonsPressed > 10)
 158                 {
 159                         mouseButtonsPressed = 10;
 160                         print("Warning: pressed an already pressed button\n");
 161                 }
 162         }
 163         if(key == K_ALT) menuShiftState |= S_ALT;
 164         if(key == K_CTRL) menuShiftState |= S_CTRL;
 165         if(key == K_SHIFT) menuShiftState |= S_SHIFT;
 166 };
 167
 168 void() m_draw =
 169 {
 170         float t;
 171         float realFrametime;
 172
 173         if(main)
 174                 UpdateConWidthHeight();
 175
 176         if(!menuInitialized)
 177         {
 178                 // TODO draw an info image about this situation
 179                 m_init_delayed();
 180                 return;
 181         }
 182         if(!menuNotTheFirstFrame)
 183         {
 184                 menuNotTheFirstFrame = 1;
 185                 if(Menu_Active)
 186                 if(!cvar("menu_video_played"))
 187                 {
 188                         localcmd("set menu_video_played 1; cd loop 1; play sound/announcer/male/welcome.ogg\n");
 189                         menuLogoAlpha = -0.8; // no idea why, but when I start this at zero, it jumps instead of fading
 190                 }
 191         }
 192
 193         t = gettime();
 194         realFrametime = frametime = min(0.2, t - menuPrevTime);
 195         menuPrevTime = t;
 196         time += frametime;
 197
 198         t = cvar("menu_slowmo");
 199         if(t)
 200         {
 201                 frametime *= t;
 202                 realFrametime *= t;
 203         }
 204
 205         if(Menu_Active)
 206         {
 207                 if(getmousetarget() == MT_MENU && (getkeydest() == KEY_MENU || getkeydest() == KEY_MENU_GRABBED))
 208                         setkeydest(keyGrabber ? KEY_MENU_GRABBED : KEY_MENU);
 209                 else
 210                         m_hide();
 211         }
 212
 213         if(cvar("cl_capturevideo"))
 214                 frametime = cvar("menu_slowmo") / cvar("cl_capturevideo_fps"); // make capturevideo work smoothly
 215
 216         dprint_load();
 217         gamestatus = 0;
 218         if(isserver())
 219                 gamestatus = gamestatus | GAME_ISSERVER;
 220         if(clientstate() == CS_CONNECTED)
 221                 gamestatus = gamestatus | GAME_CONNECTED;
 222         if(cvar("developer"))
 223                 gamestatus = gamestatus | GAME_DEVELOPER;
 224
 225         prevMenuAlpha = menuAlpha;
 226         if(Menu_Active)
 227         {
 228                 if(menuAlpha == 0 && menuLogoAlpha < 2)
 229                 {
 230                         menuLogoAlpha = menuLogoAlpha + frametime * 2;
 231                 }
 232                 else
 233                 {
 234                         menuAlpha = min(1, menuAlpha + frametime * 5);
 235                         menuLogoAlpha = 2;
 236                 }
 237         }
 238         else
 239         {
 240                 menuAlpha = max(0, menuAlpha - frametime * 5);
 241                 menuLogoAlpha = 2;
 242         }
 243
 244         draw_reset();
 245
 246         if(!(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)) && menuLogoAlpha > 0)
 247         {
 248                 vector sz;
 249                 vector isz;
 250                 sz = draw_PictureSize(SKINGFX_BACKGROUND);
 251                 // keep aspect of image
 252                 if(sz_x * draw_scale_y >= sz_y * draw_scale_x)
 253                 {
 254                         // that is, sz_x/sz_y >= draw_scale_x/draw_scale_y
 255                         // match up the height
 256                         isz_y = 1;
 257                         isz_x = isz_y * (sz_x / sz_y) * (draw_scale_y / draw_scale_x);
 258                 }
 259                 else
 260                 {
 261                         // that is, sz_x/sz_y <= draw_scale_x/draw_scale_y
 262                         // match up the width
 263                         isz_x = 1;
 264                         isz_y = isz_x * (sz_y / sz_x) * (draw_scale_x / draw_scale_y);
 265                 }
 266                 draw_Picture('0.5 0.5 0' - 0.5 * isz, SKINGFX_BACKGROUND, isz, '1 1 1', bound(0, menuLogoAlpha, 1));
 267                 if(menuAlpha <= 0 && SKINALPHA_CURSOR_INTRO > 0)
 268                 {
 269                         draw_alpha = SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1);
 270                         draw_drawMousePointer(menuMousePos);
 271                         draw_alpha = 1;
 272                 }
 273         }
 274
 275         draw_reset();
 276         preMenuDraw();
 277         draw_reset();
 278
 279         if(menuAlpha <= 0)
 280         {
 281                 if(prevMenuAlpha > 0)
 282                         main.initializeDialog(main, main.firstChild);
 283                 draw_reset();
 284                 postMenuDraw();
 285                 return;
 286         }
 287
 288         draw_alpha *= menuAlpha;
 289
 290         if(frametime > 0)
 291         {
 292                 vector dMouse;
 293                 dMouse = getmousepos() * (frametime / realFrametime); // for capturevideo
 294                 if(dMouse != '0 0 0')
 295                 {
 296                         dMouse = globalToBoxSize(dMouse, draw_scale);
 297                         menuMousePos += dMouse * 1; // TODO use a cvar here
 298                         menuMousePos_x = bound(0, menuMousePos_x, 1);
 299                         menuMousePos_y = bound(0, menuMousePos_y, 1);
 300                         if(mouseButtonsPressed)
 301                                 main.mouseDrag(main, menuMousePos);
 302                         else
 303                                 main.mouseMove(main, menuMousePos);
 304                 }
 305         }
 306         main.draw(main);
 307         draw_alpha = max(draw_alpha, SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1));
 308
 309         draw_drawMousePointer(menuMousePos);
 310
 311         draw_reset();
 312         postMenuDraw();
 313
 314         frametime = 0;
 315 };
 316
 317 void() m_display =
 318 {
 319         Menu_Active = true;
 320         setkeydest(KEY_MENU);
 321         setmousetarget(MT_MENU);
 322
 323         if(!menuInitialized)
 324                 return;
 325
 326         if(mouseButtonsPressed)
 327                 main.mouseRelease(main, menuMousePos);
 328         mouseButtonsPressed = 0;
 329
 330         main.focusEnter(main);
 331         main.showNotify(main);
 332 };
 333
 334 void() m_hide =
 335 {
 336         Menu_Active = false;
 337         setkeydest(KEY_GAME);
 338         setmousetarget(MT_CLIENT);
 339
 340         if(!menuInitialized)
 341                 return;
 342
 343         main.focusLeave(main);
 344         main.hideNotify(main);
 345 };
 346
 347 void() m_toggle =
 348 {
 349         if(Menu_Active)
 350                 m_hide();
 351         else
 352                 m_display();
 353 };
 354
 355 void() m_shutdown =
 356 {
 357         m_hide();
 358 };
 359
 360 void(string itemname) m_goto =
 361 {
 362         entity e;
 363         if(!menuInitialized)
 364                 return;
 365         if(itemname == "") // this can be called by GameCommand
 366         {
 367                 if(gamestatus & (GAME_ISSERVER | GAME_CONNECTED))
 368                         m_hide();
 369                 else
 370                 {
 371                         main.initializeDialog(main, main.firstChild);
 372                         m_display();
 373                 }
 374         }
 375         else
 376         {
 377                 e = findstring(NULL, name, itemname);
 378                 if(e && e.parent == main)
 379                 {
 380                         m_hide();
 381                         main.initializeDialog(main, e);
 382                         m_display();
 383                 }
 384         }
 385 }