data/qcsrc/menu/gamecommand.qc

   1 void GameCommand_Init()
   2 {
   3         // make gg call menu QC theCommands
   4         localcmd("alias qc_cmd \"menu_cmd $*\"\n");
   5 }
   6
   7 string _dumptree_space;
   8 void _dumptree_open(entity pass, entity me)
   9 {
  10         string s;
  11         s = me.toString(me);
  12         if(s == "")
  13                 s = me.classname;
  14         else
  15                 s = strcat(me.classname, ": ", s);
  16         print(_dumptree_space, etos(me), " (", s, ")");
  17         if(me.firstChild)
  18         {
  19                 print(" {\n");
  20                 _dumptree_space = strcat(_dumptree_space, "  ");
  21         }
  22         else
  23                 print("\n");
  24 }
  25 void _dumptree_close(entity pass, entity me)
  26 {
  27         if(me.firstChild)
  28         {
  29                 _dumptree_space = substring(_dumptree_space, 0, strlen(_dumptree_space) - 2);
  30                 print(_dumptree_space, "}\n");
  31         }
  32 }
  33
  34 void GameCommand(string theCommand)
  35 {
  36         float argc;
  37         argc = tokenize(theCommand);
  38
  39         if(argv(0) == "help" || argc == 0)
  40         {
  41                 print("Usage: menu_cmd theCommand..., where possible theCommands are:\n");
  42                 print("  sync - reloads all cvars on the current menu page\n");
  43                 print("  directmenu ITEM - select a menu item as main item\n");
  44                 GameCommand_Generic("help");
  45                 return;
  46         }
  47
  48         if(GameCommand_Generic(theCommand))
  49                 return;
  50
  51         if(argv(0) == "sync")
  52         {
  53                 loadAllCvars(main);
  54                 return;
  55         }
  56
  57         if(argv(0) == "directmenu") if(argc == 2)
  58         {
  59                 // switch to a menu item
  60                 m_goto(argv(1));
  61                 return;
  62         }
  63
  64         if(argv(0) == "dumptree")
  65         {
  66                 _dumptree_space = "";
  67                 depthfirst(main, parent, firstChild, nextSibling, _dumptree_open, _dumptree_close, NULL);
  68                 return;
  69         }
  70
  71         print("Invalid theCommand. For a list of supported theCommands, try menu_cmd help.\n");
  72 }