data/qcsrc/menu-div0test/nexuiz/maplist.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizMapList) EXTENDS(NexuizListBox)
   3         METHOD(NexuizMapList, configureNexuizMapList, void(entity))
   4         ATTRIB(NexuizMapList, rowsPerItem, float, 4)
   5         METHOD(NexuizMapList, draw, void(entity))
   6         METHOD(NexuizMapList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(NexuizMapList, clickListBoxItem, void(entity, float, vector))
   8         METHOD(NexuizMapList, resizeNotify, void(entity, vector, vector, vector, vector))
   9         METHOD(NexuizMapList, refilter, void(entity))
  10         METHOD(NexuizMapList, keyDown, float(entity, float, float, float))
  11
  12         ATTRIB(NexuizMapList, realFontSize, vector, '0 0 0')
  13         ATTRIB(NexuizMapList, columnPreviewOrigin, float, 0)
  14         ATTRIB(NexuizMapList, columnPreviewSize, float, 0)
  15         ATTRIB(NexuizMapList, columnNameOrigin, float, 0)
  16         ATTRIB(NexuizMapList, columnNameSize, float, 0)
  17         ATTRIB(NexuizMapList, checkMarkOrigin, vector, '0 0 0')
  18         ATTRIB(NexuizMapList, checkMarkSize, vector, '0 0 0')
  19         ATTRIB(NexuizMapList, realUpperMargin1, float, 0)
  20         ATTRIB(NexuizMapList, realUpperMargin2, float, 0)
  21
  22         ATTRIB(NexuizMapList, lastClickedMap, float, -1)
  23         ATTRIB(NexuizMapList, lastClickedTime, float, 0)
  24
  25         ATTRIB(NexuizMapList, lastGametype, float, 0)
  26         ATTRIB(NexuizMapList, lastFeatures, float, 0)
  27
  28         ATTRIB(NexuizMapList, origin, vector, '0 0 0')
  29         ATTRIB(NexuizMapList, itemAbsSize, vector, '0 0 0')
  30
  31         ATTRIB(NexuizMapList, g_maplistCache, string, string_null)
  32         METHOD(NexuizMapList, g_maplistCacheToggle, void(entity, float))
  33         METHOD(NexuizMapList, g_maplistCacheQuery, float(entity, float))
  34
  35         ATTRIB(NexuizMapList, startButton, entity, NULL)
  36
  37         ATTRIB(NexuizMapList, cvarName, string, "dummy")
  38         METHOD(NexuizMapList, loadCvars, void(entity))
  39 ENDCLASS(NexuizMapList)
  40 entity makeNexuizMapList();
  41 void MapList_All(entity btn, entity me);
  42 void MapList_None(entity btn, entity me);
  43 void MapList_LoadMap(entity btn, entity me);
  44 #endif
  45
  46 #ifdef IMPLEMENTATION
  47 entity makeNexuizMapList()
  48 {
  49         entity me;
  50         me = spawnNexuizMapList();
  51         me.configureNexuizMapList(me);
  52         return me;
  53 }
  54 void configureNexuizMapListNexuizMapList(entity me)
  55 {
  56         me.configureNexuizListBox(me);
  57         me.refilter(me);
  58 }
  59
  60 void loadCvarsNexuizMapList(entity me)
  61 {
  62         me.refilter(me);
  63 }
  64
  65 float g_maplistCacheQueryNexuizMapList(entity me, float i)
  66 {
  67         return stof(substring(me.g_maplistCache, i, 1));
  68 }
  69 void g_maplistCacheToggleNexuizMapList(entity me, float i)
  70 {
  71         string a, b, c, s, bspname;
  72         float n;
  73         s = me.g_maplistCache;
  74         if not(s)
  75                 return;
  76         b = substring(s, i, 1);
  77         if(b == "0")
  78                 b = "1";
  79         else if(b == "1")
  80                 b = "0";
  81         else
  82                 return; // nothing happens
  83         a = substring(s, 0, i);
  84         c = substring(s, i+1, strlen(s) - (i+1));
  85         strunzone(s);
  86         me.g_maplistCache = strzone(strcat(a, b, c));
  87         // TODO also update the actual cvar
  88         if not((bspname = MapInfo_BSPName_ByID(i)))
  89                 return;
  90         if(b == "1")
  91                 cvar_set("g_maplist", strcat(bspname, " ", cvar_string("g_maplist")));
  92         else
  93         {
  94                 s = "";
  95                 n = tokenize(cvar_string("g_maplist"));
  96                 for(i = 0; i < n; ++i)
  97                         if(argv(i) != bspname)
  98                                 s = strcat(s, " ", argv(i));
  99                 cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 100         }
 101 }
 102
 103 void drawNexuizMapList(entity me)
 104 {
 105         if(me.startButton)
 106                 me.startButton.disabled = ((me.selectedItem < 0) || (me.selectedItem >= me.nItems));
 107         drawListBox(me);
 108 }
 109
 110 void resizeNotifyNexuizMapList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 111 {
 112         me.origin = absOrigin;
 113         me.itemAbsSize = '0 0 0';
 114         resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
 115
 116         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 117         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 118         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize_y);
 119         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize_y;
 120
 121         me.columnPreviewOrigin = 0;
 122         me.columnPreviewSize = me.itemAbsSize_y / me.itemAbsSize_x * 4 / 3;
 123         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize_x;
 124         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize_x;
 125
 126         me.checkMarkSize = (eX * (me.itemAbsSize_y / me.itemAbsSize_x) + eY) * 0.5;
 127         me.checkMarkOrigin = eY + eX * (me.columnPreviewOrigin + me.columnPreviewSize) - me.checkMarkSize;
 128 }
 129 void clickListBoxItemNexuizMapList(entity me, float i, vector where)
 130 {
 131         if(where_x <= me.columnPreviewOrigin + me.columnPreviewSize)
 132         {
 133                 if(where_x >= 0)
 134                         me.g_maplistCacheToggle(me, i);
 135         }
 136         if(where_x >= me.columnNameOrigin)
 137                 if(where_x <= 1)
 138                         {
 139                                 if(i == me.lastClickedMap)
 140                                         if(time < me.lastClickedTime + 0.3)
 141                                         {
 142                                                 // DOUBLE CLICK!
 143                                                 // pop up map info screen
 144                                                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, i);
 145                                                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * i - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 146                                                 return;
 147                                         }
 148                                 me.lastClickedMap = i;
 149                                 me.lastClickedTime = time;
 150                         }
 151 }
 152 void drawListBoxItemNexuizMapList(entity me, float i, vector absSize, float isSelected)
 153 {
 154         // layout: Ping, Map name, Map name, NP, TP, MP
 155         string s;
 156         float p;
 157         float theAlpha;
 158         float included;
 159
 160         if(!MapInfo_Get_ByID(i))
 161                 return;
 162
 163         included = me.g_maplistCacheQuery(me, i);
 164         if(included)
 165                 theAlpha = SKINALPHA_MAPLIST_INCLUDEDFG;
 166         else
 167                 theAlpha = SKINALPHA_MAPLIST_NOTINCLUDEDFG;
 168
 169         if(isSelected)
 170                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 171         else if(included)
 172                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_MAPLIST_INCLUDEDBG, SKINALPHA_MAPLIST_INCLUDEDBG);
 173
 174         s = ftos(p);
 175         draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", MapInfo_Map_bspname), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 176         if(included)
 177                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 178         s = draw_TextShortenToWidth(strcat(MapInfo_Map_bspname, ": ", MapInfo_Map_title), me.columnNameSize / me.realFontSize_x, 0);
 179         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_TITLE, theAlpha, 0);
 180         s = draw_TextShortenToWidth(MapInfo_Map_author, me.columnNameSize / me.realFontSize_x, 0);
 181         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_AUTHOR, theAlpha, 0);
 182 }
 183
 184 void refilterNexuizMapList(entity me)
 185 {
 186         float i, j, n;
 187         string s;
 188         float gt, f;
 189         gt = MapInfo_CurrentGametype();
 190         f = MapInfo_CurrentFeatures();
 191         MapInfo_FilterGametype(gt, f, 0);
 192         me.nItems = MapInfo_count;
 193         for(i = 0; i < MapInfo_count; ++i)
 194                 draw_PreloadPicture(strcat("/maps/", MapInfo_BSPName_ByID(i)));
 195         if(me.g_maplistCache)
 196                 strunzone(me.g_maplistCache);
 197         s = "0";
 198         for(i = 1; i < MapInfo_count; i *= 2)
 199                 s = strcat(s, s);
 200         n = tokenize(cvar_string("g_maplist"));
 201         for(i = 0; i < n; ++i)
 202         {
 203                 j = MapInfo_FindName(argv(i));
 204                 if(j >= 0)
 205                         s = strcat(
 206                                 substring(s, 0, j),
 207                                 "1",
 208                                 substring(s, j+1, MapInfo_count - (j+1))
 209                         );
 210         }
 211         me.g_maplistCache = strzone(s);
 212         if(gt != me.lastGametype || f != me.lastFeatures)
 213         {
 214                 me.lastGametype = gt;
 215                 me.lastFeatures = f;
 216                 me.setSelected(me, 0);
 217         }
 218 }
 219 void MapList_All(entity btn, entity me)
 220 {
 221         float i;
 222         string s;
 223         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0); // all
 224         s = "";
 225         for(i = 0; i < MapInfo_count; ++i)
 226                 s = strcat(s, " ", MapInfo_BSPName_ByID(i));
 227         cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 228         me.refilter(me);
 229 }
 230 void MapList_None(entity btn, entity me)
 231 {
 232         cvar_set("g_maplist", "");
 233         me.refilter(me);
 234 }
 235 void MapList_LoadMap(entity btn, entity me)
 236 {
 237         string m;
 238         if(me.selectedItem >= me.nItems || me.selectedItem < 0)
 239                 return;
 240         m = MapInfo_BSPName_ByID(me.selectedItem);
 241         if not(m)
 242                 return;
 243         if(MapInfo_CheckMap(m))
 244         {
 245                 localcmd("\ndisconnect\nwait\nmaxplayers $menu_maxplayers\ng_maplist_shufflenow\n");
 246                 MapInfo_LoadMap(m);
 247         }
 248         else
 249         {
 250                 print("Huh? Can't play this. Refiltering so this won't happen again.\n");
 251                 me.refilter(me);
 252         }
 253 }
 254
 255 float keyDownNexuizMapList(entity me, float scan, float ascii, float shift)
 256 {
 257         if(scan == K_ENTER)
 258         {
 259                 // pop up map info screen
 260                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, me.selectedItem);
 261                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 262         }
 263         else if(scan == K_SPACE)
 264         {
 265                 me.g_maplistCacheToggle(me, me.selectedItem);
 266         }
 267         else if(ascii == 43) // +
 268         {
 269                 if not(me.g_maplistCacheQuery(me, me.selectedItem))
 270                         me.g_maplistCacheToggle(me, me.selectedItem);
 271         }
 272         else if(ascii == 45) // -
 273         {
 274                 if(me.g_maplistCacheQuery(me, me.selectedItem))
 275                         me.g_maplistCacheToggle(me, me.selectedItem);
 276         }
 277         else
 278                 return keyDownListBox(me, scan, ascii, shift);
 279         return 1;
 280 }
 281 #endif