data/qcsrc/gamec/w_crylink.c

   1 void() crylink_ready_01;
   2 void() crylink_fire1_01;
   3 void() crylink_deselect_01;
   4 void() crylink_select_01;
   5
   6 .float gravity;
   7
   8 float() crylink_check =
   9 {
  10         if (self.ammo_cells >= 1)
  11                 return TRUE;
  12         return FALSE;
  13 };
  14
  15 void(float req) w_crylink =
  16 {
  17         if (req == WR_IDLE)
  18                 crylink_ready_01();
  19         else if (req == WR_FIRE1 || req == WR_FIRE2)
  20                 weapon_prepareattack(crylink_check, crylink_check, crylink_fire1_01, cvar("g_balance_crylink_refire"));
  21         else if (req == WR_RAISE)
  22                 crylink_select_01();
  23         else if (req == WR_UPDATECOUNTS)
  24                 self.currentammo = self.ammo_cells;
  25         else if (req == WR_DROP)
  26                 crylink_deselect_01();
  27         else if (req == WR_SETUP)
  28                 weapon_setup(WEP_CRYLINK, "w_crylink.zym", IT_CELLS);
  29         else if (req == WR_CHECKAMMO)
  30                 weapon_hasammo = crylink_check();
  31 };
  32
  33 .entity realowner;
  34 void W_Crylink_Touch (void)
  35 {
  36         RadiusDamage (self, self.realowner, cvar("g_balance_crylink_damage"), cvar("g_balance_crylink_edgedamage"), cvar("g_balance_crylink_radius"), world, cvar("g_balance_crylink_force"), IT_CRYLINK);
  37         //te_smallflash(self.origin);
  38         if (other.takedamage == DAMAGE_AIM)
  39         {
  40                 remove (self);
  41                 return;
  42         }
  43         self.owner = world;
  44         self.touch = SUB_Null;
  45         setmodel (self, "models/plasma.mdl");
  46         setsize (self, '0 0 0', '0 0 0');
  47         self.gravity = 1;
  48         self.glow_size = 0;
  49         self.glow_color = 0;
  50         self.think = SUB_Remove;
  51         self.movetype = MOVETYPE_NONE;
  52         self.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
  53         SUB_SetFade(self, time, 1);
  54         //remove (self);
  55 }
  56
  57 void W_Crylink_Attack (void)
  58 {
  59         local float counter, shots;
  60         local vector org;
  61         local entity proj;
  62
  63         sound (self, CHAN_WEAPON, "weapons/crylink.ogg", 1, ATTN_NORM);
  64         if (cvar("g_use_ammunition"))
  65                 self.ammo_cells = self.ammo_cells - 1;
  66         self.punchangle_x = -2;
  67         org = self.origin + self.view_ofs + v_forward * 10 + v_right * 5 + v_up * -14;
  68         te_smallflash(org);
  69
  70         shots = cvar("g_balance_crylink_shots");
  71         if (!shots)
  72                 shots = 5;
  73         while (counter < shots)
  74         {
  75                 proj = spawn ();
  76                 proj.realowner = proj.owner = self;
  77                 proj.classname = "spike";
  78
  79                 proj.movetype = MOVETYPE_BOUNCE;
  80                 proj.solid = SOLID_BBOX;
  81                 proj.gravity = 0.001;
  82
  83                 setmodel (proj, "models/plasmatrail.mdl");
  84                 setsize (proj, '0 0 0', '0 0 0');
  85                 setorigin (proj, org);
  86
  87                 if (self.button3)
  88                         proj.velocity = (v_forward + ((counter / shots) * 2 - 1) * v_right * cvar("g_balance_crylink_spread")) * cvar("g_balance_crylink_speed");
  89                 else
  90                         proj.velocity = (v_forward + randomvec() * cvar("g_balance_crylink_spread")) * cvar("g_balance_crylink_speed");
  91                 proj.touch = W_Crylink_Touch;
  92                 proj.think = SUB_Remove;
  93                 proj.nextthink = time + 9;
  94
  95                 proj.angles = vectoangles (proj.velocity);
  96
  97                 //proj.glow_size = 20;
  98
  99                 proj.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 100                 counter = counter + 1;
 101         }
 102 }
 103
 104
 105 // weapon frames
 106 void()  crylink_ready_01 =      {weapon_thinkf(WFRAME_IDLE, 0.1, crylink_ready_01); self.weaponentity.state = WS_READY;};
 107 void()  crylink_select_01 =     {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');};
 108 void()  crylink_deselect_01 =   {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);};
 109 void()  crylink_fire1_01 =
 110 {
 111         weapon_doattack(crylink_check, crylink_check, W_Crylink_Attack);
 112         weapon_thinkf(WFRAME_FIRE1, 0.15, crylink_ready_01);
 113 };
 114