data/qcsrc/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8 }
   9
  10 float spawn_goodspots, spawn_badspots;
  11 entity Spawn_ClassifyPoints(entity firstspot, entity playerlist, float mindist, float goodspotnum, float badspotnum)
  12 {
  13         local entity spot, player;
  14         local float pcount;
  15         spawn_goodspots = 0;
  16         spawn_badspots = 0;
  17         spot = firstspot;
  18         while (spot)
  19         {
  20                 pcount = 0;
  21                 player = playerlist;
  22                 while (player)
  23                 {
  24                         if (player != self)
  25                         if (vlen(player.origin - spot.origin) < 100)
  26                                 pcount = pcount + 1;
  27                         player = player.chain;
  28                 }
  29                 if (pcount)
  30                 {
  31                         if (spawn_goodspots >= badspotnum)
  32                                 return spot;
  33                         spawn_badspots = spawn_badspots + 1;
  34                 }
  35                 else
  36                 {
  37                         if (spawn_goodspots >= goodspotnum)
  38                                 return spot;
  39                         spawn_goodspots = spawn_goodspots + 1;
  40                 }
  41                 spot = find(spot, classname, "info_player_deathmatch");
  42         }
  43         return firstspot;
  44 }
  45
  46 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  47 {
  48         local entity best, spot, player;
  49         local float bestrating, rating;
  50         best = world;
  51         bestrating = -1000000;
  52         spot = firstspot;
  53         while (spot)
  54         {
  55                 rating = 1000000000;
  56                 player = playerlist;
  57                 while (player)
  58                 {
  59                         if (player != self)
  60                                 rating = min(rating, vlen(player.origin - spot.origin));
  61                         player = player.chain;
  62                 }
  63                 rating = rating + random() * 16;
  64                 if (bestrating < rating)
  65                 {
  66                         best = spot;
  67                         bestrating = rating;
  68                 }
  69                 spot = find(spot, classname, "info_player_deathmatch");
  70         }
  71         return best;
  72 }
  73
  74 /*
  75 =============
  76 SelectSpawnPoint
  77
  78 Finds a point to respawn
  79 =============
  80 */
  81 entity SelectSpawnPoint (float anypoint)
  82 {
  83         local entity spot, firstspot, playerlist;
  84         string spotname;
  85
  86         spot = find (world, classname, "testplayerstart");
  87         if (spot)
  88                 return spot;
  89
  90         spotname = "info_player_deathmatch";
  91
  92         if(!anypoint && cvar("g_ctf") )
  93         {
  94                 if(self.team == 5)//4)
  95                         spotname = "info_player_team1";
  96                 if(self.team == 14)//13)
  97                         spotname = "info_player_team2";
  98                 if(self.team == 4)//3)
  99                         spotname = "info_player_team3";
 100                 if(self.team == 13)//12)
 101                         spotname = "info_player_team4";
 102         }
 103
 104         playerlist = findchain(classname, "player");
 105         firstspot = find(world, classname, spotname);
 106         Spawn_ClassifyPoints(firstspot, playerlist, 100, 1000000, 1000000);
 107         // first check if there are ANY good spots
 108         if (spawn_goodspots > 0)
 109         {
 110                 // good spots exist, there is 50/50 chance of choosing a random good
 111                 // spot or the furthest spot
 112                 // (this means that roughly every other spawn will be furthest, so you
 113                 // usually won't get fragged at spawn twice in a row)
 114                 if (random() > 0.5)
 115                         spot = Spawn_ClassifyPoints(firstspot, playerlist, 100, min(floor(random() * spawn_goodspots), spawn_goodspots - 1), 1000000);
 116                 else
 117                         spot = Spawn_FurthestPoint(firstspot, playerlist);
 118         }
 119         else
 120         {
 121                 // no good spots exist, pick a random bad spot
 122                 spot = Spawn_ClassifyPoints(firstspot, playerlist, 100, 1000000, min(floor(random() * spawn_badspots), spawn_badspots - 1));
 123         }
 124
 125         if (!spot)
 126         {
 127                 if(anypoint)
 128                         error ("PutClientInServer: no start points on level");
 129                 else // try again with deathmatch spots
 130                         spot = SelectSpawnPoint(TRUE);
 131         }
 132
 133         return spot;
 134 }
 135
 136 /*
 137 =============
 138 CheckPlayerModel
 139
 140 Checks if the argument string can be a valid playermodel.
 141 Returns a valid one in doubt.
 142 =============
 143 */
 144 string CheckPlayerModel(string plyermodel) {
 145         if( substring(plyermodel,0,14) != "models/player/") plyermodel = "models/player/marine.zym";
 146
 147         /* Possible Fixme: Check if server can open the model?
 148            This would kill custom models, however. */
 149
 150         return plyermodel;
 151 }
 152
 153 /*
 154 =============
 155 PutObserverInServer
 156
 157 putting a client as observer in the server
 158 =============
 159 */
 160 void PutObserverInServer (void)
 161 {
 162         entity  spot;
 163         spot = SelectSpawnPoint (FALSE);
 164         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 165
 166         if(self.frags == 0)
 167                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 168         else if(self.killcount != -666)
 169                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 170
 171         self.classname = "observer";
 172         self.health = 666;
 173         self.takedamage = DAMAGE_NO;
 174         self.solid = SOLID_NOT;
 175         self.movetype = MOVETYPE_NOCLIP;
 176         self.armorvalue = 666;
 177         self.effects = 0;
 178         self.armorvalue = cvar("g_balance_armor_start");
 179         self.pauserotarmor_finished = 0;
 180         self.pauserothealth_finished = 0;
 181         self.pauseregen_finished = 0;
 182         self.damageforcescale = 0;
 183         self.death_time = 0;
 184         self.dead_time = 0;
 185         self.dead_frame = 0;
 186         self.die_frame = 0;
 187         self.alpha = 0;
 188         self.scale = 0;
 189         self.fade_time = 0;
 190         self.pain_frame = 0;
 191         self.pain_finished = 0;
 192         self.strength_finished = 0;
 193         self.invincible_finished = 0;
 194         self.pushltime = 0;
 195         self.vote_finished = 0;
 196         self.think = SUB_Null;
 197         self.nextthink = 0;
 198         self.hook_time = 0;
 199         self.runes = 0;
 200         self.deadflag = DEAD_NO;
 201         self.angles = spot.angles;
 202         self.angles_z = 0;
 203         self.fixangle = TRUE;
 204         self.crouch = FALSE;
 205         self.view_ofs = PL_VIEW_OFS;
 206         setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 207         self.oldorigin = self.origin;
 208         self.items = 0;
 209         self.model = "";
 210         self.modelindex = 0;
 211         self.weapon = 0;
 212         self.weaponmodel = "";
 213         self.weaponframe = 0;
 214         self.weaponentity = world;
 215         self.killcount = -666;
 216         if(!cvar("g_lms"))
 217                 self.frags = -666;
 218         //stuffcmd(self, "set viewsize 120 \n");
 219 //      bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 220 }
 221
 222
 223 /*
 224 =============
 225 PutClientInServer
 226
 227 Called when a client spawns in the server
 228 =============
 229 */
 230 void PutClientInServer (void)
 231 {
 232         // player is dead and becomes observer
 233         if(cvar("g_lms") && self.frags < 1)
 234                 self.classname = "observer";
 235
 236         if(self.classname == "player") {
 237                 entity  spot;
 238
 239                 spot = SelectSpawnPoint (FALSE);
 240
 241                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 242
 243                 self.classname = "player";
 244                 self.iscreature = TRUE;
 245                 self.movetype = MOVETYPE_WALK;
 246                 self.solid = SOLID_SLIDEBOX;
 247                 self.flags = FL_CLIENT;
 248                 self.takedamage = DAMAGE_AIM;
 249                 self.effects = 0;
 250                 self.health = cvar("g_balance_health_start");
 251                 self.armorvalue = cvar("g_balance_armor_start");
 252                 self.pauserotarmor_finished = time + 10;
 253                 self.pauserothealth_finished = time + 10;
 254                 self.pauseregen_finished = 0;
 255                 self.damageforcescale = 2;
 256                 self.death_time = 0;
 257                 self.dead_time = 0;
 258                 self.dead_frame = 0;
 259                 self.die_frame = 0;
 260                 self.alpha = 0;
 261                 self.scale = 0;
 262                 self.fade_time = 0;
 263                 self.pain_frame = 0;
 264                 self.pain_finished = 0;
 265                 self.strength_finished = 0;
 266                 self.invincible_finished = 0;
 267                 self.pushltime = 0;
 268                 //self.speed_finished = 0;
 269                 //self.slowmo_finished = 0;
 270                 self.vote_finished = 0;
 271                 // players have no think function
 272                 self.think = SUB_Null;
 273                 self.nextthink = 0;
 274
 275                 self.hook_time = 0;
 276
 277                 self.runes = 0;
 278
 279                 self.deadflag = DEAD_NO;
 280
 281                 self.angles = spot.angles;
 282
 283                 self.angles_z = 0; // never spawn tilted even if the spot says to
 284                 self.fixangle = TRUE; // turn this way immediately
 285                 self.velocity = '0 0 0';
 286                 self.avelocity = '0 0 0';
 287                 self.punchangle = '0 0 0';
 288                 self.punchvector = '0 0 0';
 289                 self.oldvelocity = self.velocity;
 290
 291                 self.viewzoom = 0.6;
 292
 293                 if(cvar("sv_defaultcharacter") == 1) {
 294                         local string defaultmodel;
 295                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 296
 297                         precache_model (defaultmodel);
 298                         setmodel (self, defaultmodel);
 299                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 300                 } else {
 301                         self.playermodel = CheckPlayerModel(self.playermodel);
 302
 303                         precache_model (self.playermodel);
 304                         setmodel (self, self.playermodel);
 305                         self.skin = stof(self.playerskin);
 306
 307                 }
 308
 309                 self.crouch = FALSE;
 310                 self.view_ofs = PL_VIEW_OFS;
 311                 setsize (self, PL_MIN, PL_MAX);
 312                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 313                 // don't reset back to last position, even if new position is stuck in solid
 314                 self.oldorigin = self.origin;
 315
 316                 if(cvar("g_lms"))
 317                 {
 318                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 319                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 320                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 321                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 322                 }
 323                 else if (cvar("g_use_ammunition")) {
 324                         self.ammo_shells = cvar("g_start_ammo_shells");
 325                         self.ammo_nails = cvar("g_start_ammo_nails");
 326                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 327                         self.ammo_cells = cvar("g_start_ammo_cells");
 328                 } else {
 329                         self.ammo_shells = 999;
 330                         self.ammo_nails = 999;
 331                         self.ammo_rockets = 999;
 332                         self.ammo_cells = 999;
 333                 }
 334
 335                 self.items = 0;
 336                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 337                 {
 338                         self.items = self.items | IT_LASER;
 339                         self.switchweapon = WEP_LASER;
 340                 }
 341                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 342                 {
 343                         self.items = self.items | IT_SHOTGUN;
 344                         self.switchweapon = WEP_SHOTGUN;
 345                 }
 346                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 347                 {
 348                         self.items = self.items | IT_UZI;
 349                         self.switchweapon = WEP_UZI;
 350                 }
 351                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 352                 {
 353                         self.items = self.items | IT_GRENADE_LAUNCHER;
 354                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 355                 }
 356                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 357                 {
 358                         self.items = self.items | IT_ELECTRO;
 359                         self.switchweapon = WEP_ELECTRO;
 360                 }
 361                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 362                 {
 363                         self.items = self.items | IT_CRYLINK;
 364                         self.switchweapon = WEP_CRYLINK;
 365                 }
 366                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 367                 {
 368                         self.items = self.items | IT_NEX;
 369                         self.switchweapon = WEP_NEX;
 370                 }
 371                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 372                 {
 373                         self.items = self.items | IT_HAGAR;
 374                         self.switchweapon = WEP_HAGAR;
 375                 }
 376                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 377                 {
 378                         self.items = self.items | IT_ROCKET_LAUNCHER;
 379                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 380                 }
 381
 382                 if(cvar("g_instagib"))
 383                 {
 384                         self.items = IT_NEX;
 385                         self.switchweapon = WEP_NEX;
 386                         self.ammo_cells = 999;
 387                 }
 388
 389                 if(cvar("g_rocketarena"))
 390                 {
 391                         self.items = IT_ROCKET_LAUNCHER;
 392                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 393                         self.ammo_rockets = 999;
 394                 }
 395
 396                 if(cvar("g_minstagib"))
 397                 {
 398                         self.health = 100;
 399                         self.armorvalue = 0;
 400                         self.items = IT_NEX;
 401                         self.switchweapon = WEP_NEX;
 402                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 403                         self.extralives = 0;
 404                         self.jump_interval = time;
 405                 }
 406
 407                 self.event_damage = PlayerDamage;
 408
 409                 self.statdraintime = time + 5;
 410                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 411
 412                 if(self.frags == -666 && self.killcount == -666) {
 413                         self.killcount = 0;
 414                         self.frags = 0;
 415                 }
 416
 417                 /*
 418                 W_UpdateWeapon();
 419                 W_UpdateAmmo();
 420                 */
 421                 CL_SpawnWeaponentity();
 422
 423                 //stuffcmd(self, "chase_active 0");
 424                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 425         } else if(self.classname == "observer") {
 426                 PutObserverInServer ();
 427         }
 428 }
 429
 430 /*
 431 =============
 432 SetNewParms
 433 =============
 434 */
 435 void SetNewParms (void)
 436 {
 437
 438 }
 439
 440 /*
 441 =============
 442 SetChangeParms
 443 =============
 444 */
 445 void SetChangeParms (void)
 446 {
 447
 448 }
 449
 450 /*
 451 =============
 452 ClientKill
 453
 454 Called when a client types 'kill' in the console
 455 =============
 456 */
 457 void ClientKill (void)
 458 {
 459         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 460 }
 461
 462 /*
 463 =============
 464 ClientConnect
 465
 466 Called when a client connects to the server
 467 =============
 468 */
 469 string ColoredTeamName(float t);
 470 //void dom_player_join_team(entity pl);
 471 void ClientConnect (void)
 472 {
 473         self.classname = "player_joining";
 474
 475         //if(cvar("g_domination"))
 476         //      dom_player_join_team(self);
 477
 478         //JoinBestTeam(self, FALSE);
 479         if(cvar("teamplay")) stuffcmd(self,"menu_showteamselect\n");
 480
 481
 482         if(cvar("sv_spectate") == 1 && !cvar("g_lms")) {
 483                 self.classname = "observer";
 484         } else {
 485                 self.classname = "player";
 486         }
 487
 488         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 489
 490         bprint ("^4",self.netname);
 491         bprint ("^4 connected");
 492
 493         if(cvar("g_domination") || cvar("g_ctf"))
 494         {
 495                 bprint(" and joined the ");
 496                 bprint(ColoredTeamName(self.team));
 497         }
 498
 499         bprint("\n");
 500
 501         self.welcomemessage_time = time + cvar("welcome_message_time");
 502         self.welcomemessage_time2 = 0;
 503
 504         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 505         // send prediction settings to the client
 506         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 507         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 508         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 509         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 510         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 511         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 512         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 513         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 514         // Wazat's grappling hook
 515         SetGrappleHookBindings();
 516
 517         // get autoswitch state from player
 518         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 519         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 520
 521         // get version info from player
 522         stuffcmd(self, "cmd clientversion $g_nexuizversion_major\n");
 523
 524         if(cvar("g_lms"))
 525         {
 526                 self.frags = cvar("fraglimit");
 527                 // no fraglimit was set, so player gets 999 lives
 528                 if(self.frags < 1)
 529                         self.frags = 999;
 530
 531                 // disallow player to join after the worst player has lost g_lms_last_join lives
 532                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 533                 if((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime"))
 534                 {
 535                         self.frags = -1;
 536                         lms_dead_count += 1;
 537                 }
 538                 else if(cvar("fraglimit") > lms_lowest_lives)
 539                 {
 540                         self.frags = lms_lowest_lives;
 541                 }
 542         }
 543         player_count += 1;
 544 }
 545
 546 /*
 547 =============
 548 ClientDisconnect
 549
 550 Called when a client disconnects from the server
 551 =============
 552 */
 553 .entity chatbubbleentity;
 554 void ClientDisconnect (void)
 555 {
 556         bprint ("^4",self.netname);
 557         bprint ("^4 disconnected\n");
 558
 559         if (self.chatbubbleentity)
 560         {
 561                 remove (self.chatbubbleentity);
 562                 self.chatbubbleentity = world;
 563         }
 564         DropAllRunes(self);
 565         // decrease player count for lms
 566         player_count -= 1;
 567         // player was dead, decrease dead count
 568         if(cvar("g_lms") && self.frags < 1)
 569                 lms_dead_count -= 1;
 570         //stuffcmd(self, "set viewsize $tmpviewsize \n");
 571 }
 572
 573 .float buttonchat;
 574 void() ChatBubbleThink =
 575 {
 576         self.nextthink = time;
 577         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 578         {
 579                 remove(self);
 580                 return;
 581         }
 582         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 583         if (self.owner.buttonchat && !self.owner.deadflag)
 584                 self.model = self.mdl;
 585         else
 586                 self.model = "";
 587 };
 588
 589 void() UpdateChatBubble =
 590 {
 591         if (!self.modelindex)
 592                 return;
 593         // spawn a chatbubble entity if needed
 594         if (!self.chatbubbleentity)
 595         {
 596                 self.chatbubbleentity = spawn();
 597                 self.chatbubbleentity.owner = self;
 598                 self.chatbubbleentity.exteriormodeltoclient = self;
 599                 self.chatbubbleentity.think = ChatBubbleThink;
 600                 self.chatbubbleentity.nextthink = time;
 601                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 602                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 603                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 604                 self.chatbubbleentity.model = "";
 605         }
 606 }
 607
 608 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 609 // added to the model skins
 610 /*void() UpdateColorModHack =
 611 {
 612         local float c;
 613         c = self.clientcolors & 15;
 614         // LordHavoc: only bothering to support white, green, red, yellow, blue
 615              if (teamplay == 0) self.colormod = '0 0 0';
 616         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 617         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 618         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 619         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 620         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 621         else self.colormod = '1 1 1';
 622 };*/
 623
 624 void UpdatePlayerColors () {
 625         if(self.weaponentity) {
 626                 self.weaponentity.colormap = self.colormap;
 627                 self.exteriorweaponentity.colormap = self.colormap;
 628         }
 629 }
 630 /*
 631 =============
 632 PlayerJump
 633
 634 When you press the jump key
 635 =============
 636 */
 637 void PlayerJump (void)
 638 {
 639         float mjumpheight;
 640
 641         mjumpheight = cvar("g_balance_jumpheight");
 642         if (self.waterlevel >= 2)
 643         {
 644                 if (self.watertype == CONTENT_WATER)
 645                         self.velocity_z = 200;
 646                 else if (self.watertype == CONTENT_SLIME)
 647                         self.velocity_z = 80;
 648                 else
 649                         self.velocity_z = 50;
 650
 651                 return;
 652         }
 653
 654
 655         if (!(self.flags & FL_ONGROUND))
 656                 return;
 657
 658         if (!(self.flags & FL_JUMPRELEASED))
 659                 return;
 660
 661         if(cvar("g_runematch"))
 662         {
 663                 if(self.runes & RUNE_SPEED)
 664                 {
 665                         if(self.runes & CURSE_SLOW)
 666                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 667                         else
 668                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 669                 }
 670                 else if(self.runes & CURSE_SLOW)
 671                 {
 672                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 673                 }
 674         }
 675
 676         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 677         {
 678                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 679         }
 680
 681         self.velocity_z = self.velocity_z + mjumpheight;
 682         self.oldvelocity_z = self.velocity_z;
 683
 684         self.flags = self.flags - FL_ONGROUND;
 685         self.flags = self.flags - FL_JUMPRELEASED;
 686 }
 687
 688 void() CheckWaterJump =
 689 {
 690         local vector start, end;
 691
 692 // check for a jump-out-of-water
 693         makevectors (self.angles);
 694         start = self.origin;
 695         start_z = start_z + 8;
 696         v_forward_z = 0;
 697         normalize(v_forward);
 698         end = start + v_forward*24;
 699         traceline (start, end, TRUE, self);
 700         if (trace_fraction < 1)
 701         {       // solid at waist
 702                 start_z = start_z + self.maxs_z - 8;
 703                 end = start + v_forward*24;
 704                 self.movedir = trace_plane_normal * -50;
 705                 traceline (start, end, TRUE, self);
 706                 if (trace_fraction == 1)
 707                 {       // open at eye level
 708                         self.flags = self.flags | FL_WATERJUMP;
 709                         self.velocity_z = 225;
 710                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 711                         self.teleport_time = time + 2;  // safety net
 712                         return;
 713                 }
 714         }
 715 };
 716
 717
 718 void respawn(void)
 719 {
 720         CopyBody(1);
 721         PutClientInServer();
 722 }
 723
 724 void player_powerups (void)
 725 {
 726         if (cvar("g_minstagib"))
 727         {
 728                 self.effects = EF_FULLBRIGHT;
 729                 if (self.items & IT_STRENGTH)
 730                 {
 731                         self.effects = EF_NODRAW;
 732                         if (time > self.strength_finished)
 733                         {
 734                                 self.items = self.items - (self.items & IT_STRENGTH);
 735                                 sprint(self, "^3Invisibility has worn off\n");
 736                         }
 737                 }
 738                 else
 739                 {
 740                         if (time < self.strength_finished)
 741                         {
 742                                 self.items = self.items | IT_STRENGTH;
 743                                 sprint(self, "^3You are invisible\n");
 744                         }
 745                 }
 746
 747                 if (self.items & IT_INVINCIBLE)
 748                 {
 749                         if (time > self.invincible_finished)
 750                         {
 751                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 752                                 sprint(self, "^3Speed has worn off\n");
 753                         }
 754                 }
 755                 else
 756                 {
 757                         if (time < self.invincible_finished)
 758                         {
 759                                 self.items = self.items | IT_INVINCIBLE;
 760                                 sprint(self, "^3You are on speed\n");
 761                         }
 762                 }
 763                 return;
 764         }
 765
 766         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 767         if (self.items & IT_STRENGTH)
 768         {
 769                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 770                 if (time > self.strength_finished)
 771                 {
 772                         self.items = self.items - (self.items & IT_STRENGTH);
 773                         sprint(self, "^3Strength has worn off\n");
 774                 }
 775         }
 776         else
 777         {
 778                 if (time < self.strength_finished)
 779                 {
 780                         self.items = self.items | IT_STRENGTH;
 781                         sprint(self, "^3Strength infuses your weapons with devestating power\n");
 782                 }
 783         }
 784         if (self.items & IT_INVINCIBLE)
 785         {
 786                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
 787                 if (time > self.invincible_finished)
 788                 {
 789                         self.items = self.items - (self.items & IT_INVINCIBLE);
 790                         sprint(self, "^3Shield has worn off\n");
 791                 }
 792         }
 793         else
 794         {
 795                 if (time < self.invincible_finished)
 796                 {
 797                         self.items = self.items | IT_INVINCIBLE;
 798                         sprint(self, "^3Shield surrounds you\n");
 799                 }
 800         }
 801
 802         if (cvar("g_fullbrightplayers"))
 803                 self.effects = EF_FULLBRIGHT;
 804
 805 }
 806
 807 void player_regen (void)
 808 {
 809         float maxh, maxa, max_mod, regen_mod, rot_mod;
 810         maxh = cvar("g_balance_health_stable");
 811         maxa = cvar("g_balance_armor_stable");
 812
 813         if (cvar("g_minstagib"))
 814         {
 815                 maxh = 100;
 816                 maxa = 0;
 817                 return;
 818         }
 819
 820         if(cvar("g_runematch"))
 821         {
 822                 max_mod = regen_mod = rot_mod = 1;
 823                 if (self.runes & RUNE_REGEN)
 824                 {
 825                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
 826                         {
 827                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
 828                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
 829                         }
 830                         else
 831                         {
 832                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
 833                                 max_mod = cvar("g_balance_rune_regen_hpmod");
 834                         }
 835                 }
 836                 else if (self.runes & CURSE_VENOM)
 837                 {
 838                         max_mod = cvar("g_balance_curse_venom_hpmod");
 839                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
 840                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
 841                         else
 842                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
 843                         //if (!self.runes & RUNE_REGEN)
 844                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
 845                 }
 846                 maxh = maxh * max_mod;
 847                 //maxa = maxa * max_mod;
 848
 849                 if (time > self.pauserotarmor_finished)
 850                 {
 851                         if (self.armorvalue > maxa)
 852                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 853                 }
 854                 if (time > self.pauserothealth_finished)
 855                 {
 856                         if (self.health > maxh)
 857                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
 858                 }
 859                 if (time > self.pauseregen_finished)
 860                 {
 861                         if (self.health < maxh)
 862                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime, 1000);
 863                         if (self.armorvalue < maxa)
 864                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime, 1000);
 865                 }
 866         }
 867         else
 868         {
 869                 if (time > self.pauserothealth_finished)
 870                 if (self.health > maxh)
 871                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
 872                 if (time > self.pauserotarmor_finished)
 873                 if (self.armorvalue > maxa)
 874                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 875                 if (time > self.pauseregen_finished)
 876                 {
 877                         if (self.health < maxh)
 878                                 self.health = bound(0, self.health + (maxh- self.health) * cvar("g_balance_health_regen") * frametime, 1000);
 879                         if (self.armorvalue < maxa)
 880                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime, 1000);
 881                 }
 882         }
 883 }
 884
 885 /*
 886 ======================
 887 spectate mode routines
 888 ======================
 889 */
 890 void SpectateCopy(entity spectatee) {
 891         self.armortype = spectatee.armortype;
 892         self.armorvalue = spectatee.armorvalue;
 893         self.currentammo = spectatee.currentammo;
 894         self.effects = spectatee.effects;
 895         self.health = spectatee.health;
 896         self.impulse = 0;
 897         self.items = spectatee.items;
 898         self.punchangle = spectatee.punchangle;
 899         self.view_ofs = spectatee.view_ofs;
 900         self.v_angle = spectatee.v_angle;
 901         self.viewzoom = spectatee.viewzoom;
 902         setorigin(self, spectatee.origin);
 903         setsize(self, spectatee.mins, spectatee.maxs);
 904 }
 905
 906 void SpectateUpdate() {
 907         if (self != self.enemy) {
 908                 SpectateCopy(self.enemy);
 909                 msg_entity = self;
 910                 WriteByte(MSG_ONE, SVC_SETANGLE);
 911                 WriteAngle(MSG_ONE, self.enemy.v_angle_x);
 912                 WriteAngle(MSG_ONE, self.enemy.v_angle_y);
 913                 WriteAngle(MSG_ONE, self.enemy.v_angle_z);
 914         }
 915 }
 916
 917 float SpectateNext() {
 918         other = find(self.enemy, classname, "player");
 919         if (!other) {
 920                 other = find(other, classname, "player");
 921         }
 922         if (other) {
 923                 self.enemy = other;
 924         }
 925         if(self.enemy.classname == "player") {
 926                 msg_entity = self;
 927                 WriteByte(MSG_ONE, SVC_SETVIEW);
 928                 WriteEntity(MSG_ONE, self.enemy);
 929                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 930                 SpectateUpdate();
 931                 return 1;
 932         } else {
 933                 return 0;
 934         }
 935 }
 936
 937 /*
 938 =============
 939 PlayerPreThink
 940
 941 Called every frame for each client before the physics are run
 942 =============
 943 */
 944 void PlayerPreThink (void)
 945 {
 946         if(self.classname == "player") {
 947                 local vector m1, m2;
 948
 949 //              MauveBot_AI();
 950
 951 //              if(self.netname == "Wazat")
 952 //                      bprint(strcat(self.classname, "\n"));
 953
 954                 CheckRules_Player();
 955
 956                 if (intermission_running)
 957                 {
 958                         IntermissionThink ();   // otherwise a button could be missed between
 959                         return;                                 // the think tics
 960                 }
 961
 962                 if (self.deadflag != DEAD_NO)
 963                 {
 964                         player_anim();
 965                         weapon_freeze();
 966                         if (self.deadflag == DEAD_DYING)
 967                         {
 968                                 if (time > self.dead_time)
 969                                         self.deadflag = DEAD_DEAD;
 970                         }
 971                         else if (self.deadflag == DEAD_DEAD)
 972                         {
 973                                 if (!self.button0 && !self.button2 && !self.button3)
 974                                         self.deadflag = DEAD_RESPAWNABLE;
 975                         }
 976                         else if (self.deadflag == DEAD_RESPAWNABLE)
 977                         {
 978                                 if (self.button0  ||
 979                                     self.button2  ||
 980                                     self.button3  ||
 981                                     self.button4  ||
 982                                     cvar("g_lms") ||
 983                                     cvar("g_forced_respawn"))
 984                                         respawn();
 985                         }
 986                         return;
 987                 }
 988
 989                 if (self.button5)
 990                 {
 991                         if (!self.crouch)
 992                         {
 993                                 self.crouch = TRUE;
 994                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
 995                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
 996                         }
 997                 }
 998                 else
 999                 {
1000                         if (self.crouch)
1001                         {
1002                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1003                                 if (!trace_startsolid)
1004                                 {
1005                                         self.crouch = FALSE;
1006                                         self.view_ofs = PL_VIEW_OFS;
1007                                         setsize (self, PL_MIN, PL_MAX);
1008                                 }
1009                         }
1010                 }
1011
1012                 if(cvar("sv_defaultcharacter") == 1) {
1013                         local string defaultmodel;
1014                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1015
1016                         if (defaultmodel != self.model)
1017                         {
1018                                 m1 = self.mins;
1019                                 m2 = self.maxs;
1020                                 precache_model (defaultmodel);
1021                                 setmodel (self, defaultmodel);
1022                                 setsize (self, m1, m2);
1023                         }
1024
1025                         if (self.skin != stof(cvar_string("sv_defaultplayerskin")))
1026                                 self.skin = stof(cvar_string("sv_defaultplayerskin"));
1027                 } else {
1028                         if (self.playermodel != self.model)
1029                         {
1030                                 self.playermodel = CheckPlayerModel(self.playermodel);
1031                                 m1 = self.mins;
1032                                 m2 = self.maxs;
1033                                 precache_model (self.playermodel);
1034                                 setmodel (self, self.playermodel);
1035                                 setsize (self, m1, m2);
1036                         }
1037
1038                         if (self.skin != stof(self.playerskin))
1039                                 self.skin = stof(self.playerskin);
1040                 }
1041                 // Savage: Check for nameless players
1042                 if (strlen(self.netname) < 1) {
1043                         self.netname = "Player";
1044                         stuffcmd(self, "name Player\n");
1045                 }
1046
1047                 GrapplingHookFrame();
1048
1049                 W_WeaponFrame();
1050
1051                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1052                 {
1053                         if (cvar("g_minstagib") && self.button3)
1054                         {
1055                                 if (self.jump_interval <= (time + 0.1))
1056                                 {
1057                                         self.jump_interval = time + 1;
1058                                         weapon_doattack(laser_check, laser_check, W_Laser_Attack);
1059                                 }
1060                         }
1061                         else if (self.viewzoom > 0.4)
1062                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1063                 }
1064                 else if (self.viewzoom < 1.0)
1065                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1066
1067
1068                 if (self.button2)
1069                         PlayerJump ();
1070                 else
1071                         self.flags = self.flags | FL_JUMPRELEASED;
1072
1073                 if (self.vote_finished > 0 // this player has called a vote
1074                     && time > self.vote_finished) // time is up
1075                 {
1076                         VoteCount();
1077                 }
1078
1079                 player_powerups();
1080                 player_regen();
1081                 player_anim();
1082
1083                 //self.angles_y=self.v_angle_y + 90;   // temp
1084
1085                 if (self.waterlevel == 2)
1086                         CheckWaterJump ();
1087
1088                 //if (TetrisPreFrame()) return;
1089         } else if(self.classname == "observer") {
1090
1091                 if (self.flags & FL_JUMPRELEASED) {
1092                         if (self.button2) {
1093                                 if(!cvar("teamplay")) {
1094                                         self.flags = self.flags & !FL_JUMPRELEASED;
1095                                         self.classname = "player";
1096                                         if(!cvar("g_lms"))
1097                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1098                                         PutClientInServer();
1099                                         centerprint(self,"");
1100                                         return;
1101                                 } else {
1102                                         self.flags = self.flags & !FL_JUMPRELEASED;
1103                                         stuffcmd(self,"menu_showteamselect\n");
1104                                         return;
1105                                 }
1106                         } else if(self.button0) {
1107                                 self.flags = self.flags & !FL_JUMPRELEASED;
1108                                 if(SpectateNext() == 1) {
1109                                         self.classname = "spectator";
1110                                 }
1111                         }
1112                 } else {
1113                         if (!(self.button0 || self.button2)) {
1114                                 self.flags = self.flags | FL_JUMPRELEASED;
1115                         }
1116                 }
1117                 if(cvar("g_lms") && self.frags == 0)
1118                         centerprint(self, "\n\n\n^1You have no more lives left\nwait for next round\n\n\n^7press attack to spectate other players");
1119                 else if(cvar("g_lms") && self.frags == -1)
1120                         centerprint(self, "\n\n\n^1Match has already begun\nwait for next round\n\n\n^7press attack to spectate other players");
1121                 else
1122                         PrintWelcomeMessage(self);
1123                         //centerprint(self, "\n\n\npress jump to play\npress attack to spectate other players");
1124         } else if(self.classname == "spectator") {
1125
1126                 if (self.flags & FL_JUMPRELEASED) {
1127                         if(self.button0) {
1128                                 self.flags = self.flags & !FL_JUMPRELEASED;
1129                                 if(SpectateNext() == 1) {
1130                                         self.classname = "spectator";
1131                                 } else {
1132                                         self.classname = "observer";
1133                                         msg_entity = self;
1134                                         WriteByte(MSG_ONE, SVC_SETVIEW);
1135                                         WriteEntity(MSG_ONE, self);
1136                                         PutClientInServer();
1137                                 }
1138                         } else if (self.button3) {
1139                                 self.flags = self.flags & !FL_JUMPRELEASED;
1140                                 self.classname = "observer";
1141                                 msg_entity = self;
1142                                 WriteByte(MSG_ONE, SVC_SETVIEW);
1143                                 WriteEntity(MSG_ONE, self);
1144                                 PutClientInServer();
1145                         } else {
1146                                 SpectateUpdate();
1147                         }
1148         } else {
1149                 if (!(self.button0 || self.button3)) {
1150                         self.flags = self.flags | FL_JUMPRELEASED;
1151                 }
1152                 }
1153                 centerprint(self, strcat("spectating ", self.enemy.netname, "\n\n\n^7press attack for next player\npress attack2 for free fly mode"));
1154
1155         }
1156
1157 }
1158
1159 /*
1160 =============
1161 PlayerPostThink
1162
1163 Called every frame for each client after the physics are run
1164 =============
1165 */
1166 void PlayerPostThink (void)
1167 {
1168         if(self.classname == "player") {
1169                 CheckRules_Player();
1170                 UpdateChatBubble();
1171                 UpdatePlayerColors();
1172                 if (self.deadflag == DEAD_NO)
1173                 if (self.impulse)
1174                         ImpulseCommands ();
1175                 if (intermission_running)
1176                         return;         // intermission or finale
1177
1178                 //PrintWelcomeMessage(self);
1179                 //if (TetrisPostFrame()) return;
1180         } else if (self.classname == "observer") {
1181                 //do nothing
1182         } else if (self.classname == "spectator") {
1183                 //do nothing
1184         }
1185 }