data/qcsrc/common/mapinfo.qc

   1         // internal toy
   2 void cvar_settemp(string pKey, string pValue)
   3 {
   4         //localcmd(strcat("\nsettemp ", t, " \"", s, "\"\n"));
   5
   6         // duplicate what this alias does:
   7         // alias settemp "settemp_list \"1 $1 $settemp_var $settemp_list\"; set $settemp_var \"${$1}\"; settemp_var ${settemp_var}x; $1 \"$2\""
   8
   9         cvar_set("settemp_list", strcat("1 ", pKey, " ", cvar_string("settemp_var"), " ", cvar_string("settemp_list")));
  10 #ifdef MENUQC
  11         registercvar(cvar_string("settemp_var"), "", 0);
  12 #else
  13         registercvar(cvar_string("settemp_var"), "");
  14 #endif
  15         cvar_set(cvar_string("settemp_var"), cvar_string(pKey));
  16         cvar_set("settemp_var", strcat(cvar_string("settemp_var"), "x"));
  17         cvar_set(pKey, pValue);
  18 }
  19
  20 void cvar_settemp_restore()
  21 {
  22         // undo what cvar_settemp did
  23         float n, i;
  24         n = tokenize(cvar_string("settemp_list"));
  25         for(i = 0; i < n - 3; i += 3)
  26                 cvar_set(argv(i + 1), cvar_string(argv(i + 2)));
  27         cvar_set("settemp_list", "0");
  28 }
  29
  30 #ifdef HSOI
  31 // HUGE SET - stored in a string
  32 string HugeSetOfIntegers_empty()
  33 {
  34         return "";
  35 }
  36 float HugeSetOfIntegers_get(string pArr, float i)
  37 {
  38         return stof(substring(pArr, i * 4, 4));
  39 }
  40 float HugeSetOfIntegers_length(string pArr)
  41 {
  42         return strlen(pArr) / 4;
  43 }
  44 string HugeSetOfIntegers_concat(string a1, string a2)
  45 {
  46         return strcat(a1, a2);
  47 }
  48 string HugeSetOfIntegers_insert(string a1, float n, string a2)
  49         // special concat function to build up large lists in less time by binary concatenation
  50 {
  51         string s;
  52         s = strcat("    ", ftos(n));
  53         return strcat(a1, substring(s, strlen(s) - 4, 4), a2);
  54 }
  55 #endif
  56
  57 // generic string stuff
  58 float startsWith(string haystack, string needle)
  59 {
  60         return substring(haystack, 0, strlen(needle)) == needle;
  61 }
  62 float startsWithNocase(string haystack, string needle)
  63 {
  64         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
  65 }
  66 string extractRestOfLine(string haystack, string needle)
  67 {
  68         if(startsWith(haystack, needle))
  69                 return substring(haystack, strlen(needle), strlen(haystack) - strlen(needle));
  70         return string_null;
  71 }
  72 string car(string s)
  73 {
  74         float o;
  75         o = strstrofs(s, " ", 0);
  76         if(o < 0)
  77                 return s;
  78         return substring(s, 0, o);
  79 }
  80 string cdr(string s)
  81 {
  82         float o;
  83         o = strstrofs(s, " ", 0);
  84         if(o < 0)
  85                 return string_null;
  86         return substring(s, o + 1, strlen(s) - (o + 1));
  87 }
  88
  89 float _MapInfo_Cache_Active;
  90 float _MapInfo_Cache_DB_NameToIndex;
  91 float _MapInfo_Cache_Buf_IndexToMapData;
  92
  93 void MapInfo_Cache_Destroy()
  94 {
  95         if(!_MapInfo_Cache_Active)
  96                 return;
  97
  98         db_close(_MapInfo_Cache_DB_NameToIndex);
  99         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
 100         _MapInfo_Cache_Active = 0;
 101 }
 102
 103 void MapInfo_Cache_Create()
 104 {
 105         MapInfo_Cache_Destroy();
 106         _MapInfo_Cache_DB_NameToIndex = db_create();
 107         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
 108         _MapInfo_Cache_Active = 1;
 109 }
 110
 111 void MapInfo_Cache_Invalidate()
 112 {
 113         if(!_MapInfo_Cache_Active)
 114                 return;
 115
 116         MapInfo_Cache_Create();
 117 }
 118
 119 void MapInfo_Cache_Store()
 120 {
 121         float i;
 122         string s;
 123         if(!_MapInfo_Cache_Active)
 124                 return;
 125
 126         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
 127         if(!s) // empty string is NOT valid here!
 128         {
 129                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
 130                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
 131         }
 132         else
 133                 i = stof(s);
 134
 135         // now store all the stuff
 136         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, MapInfo_Map_bspname);
 137         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, MapInfo_Map_title);
 138         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, MapInfo_Map_description);
 139         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, MapInfo_Map_author);
 140         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, ftos(MapInfo_Map_supportedGametypes));
 141         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, ftos(MapInfo_Map_supportedFeatures));
 142         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, ftos(MapInfo_Map_diameter));
 143         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, ftos(MapInfo_Map_spawnpoints));
 144 }
 145
 146 float MapInfo_Cache_Retrieve(string map)
 147 {
 148         float i;
 149         string s;
 150         if(!_MapInfo_Cache_Active)
 151                 return 0;
 152
 153         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
 154         if(!s)
 155                 return 0;
 156         i = stof(s);
 157
 158         // now retrieve all the stuff
 159         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++);
 160         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++);
 161         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++);
 162         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++);
 163         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++));
 164         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++));
 165         MapInfo_Map_diameter = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++));
 166         MapInfo_Map_spawnpoints = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++));
 167         return 1;
 168 }
 169
 170 // GLOB HANDLING (for all BSP files)
 171 float _MapInfo_globopen;
 172 float _MapInfo_globcount;
 173 float _MapInfo_globhandle;
 174 string _MapInfo_GlobItem(float i)
 175 {
 176         string s;
 177         s = search_getfilename(_MapInfo_globhandle, i);
 178         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 179 }
 180
 181 void MapInfo_Enumerate()
 182 {
 183         if(_MapInfo_globopen)
 184                 search_end(_MapInfo_globhandle);
 185         MapInfo_Cache_Invalidate();
 186         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 187         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 188         _MapInfo_globopen = 1;
 189 }
 190
 191 // filter the info by game type mask (updates MapInfo_count)
 192 //
 193 #ifdef HSOI
 194 string _MapInfo_filtered;
 195 float MapInfo_FilterList_Lookup(float i)
 196 {
 197         return MapInfo_FilterList_Lookup(i);
 198 }
 199
 200 string MapInfo_FilterGametype_Recursive(float pGametype, float pFeatures, float pBegin, float pEnd, float pAbortOnGenerate)
 201 {
 202         float m, valid;
 203         string l, r;
 204
 205         if(pBegin == pEnd)
 206                 return HugeSetOfIntegers_empty();
 207
 208         m = floor((pBegin + pEnd) / 2);
 209
 210         l = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pBegin, m, pAbortOnGenerate);
 211         if not(l)
 212                 return string_null; // BAIL OUT
 213         if(MapInfo_Get_ByName(_MapInfo_GlobItem(m), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 214                 if(pAbortOnGenerate)
 215                 {
 216                         MapInfo_progress = m / _MapInfo_globcount;
 217                         return string_null; // BAIL OUT
 218                 }
 219         valid = (((MapInfo_Map_supportedGametypes & pGametype) != 0) && ((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures));
 220         r = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, m + 1, pEnd, pAbortOnGenerate);
 221         if not(r)
 222                 return string_null; // BAIL OUT
 223
 224         if(valid)
 225                 return HugeSetOfIntegers_insert(l, m, r);
 226         else
 227                 return HugeSetOfIntegers_concat(l, r);
 228 }
 229
 230 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pAbortOnGenerate)
 231 {
 232         if(_MapInfo_filtered)
 233                 strunzone(_MapInfo_filtered);
 234         _MapInfo_filtered = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, 0, _MapInfo_globcount, pAbortOnGenerate);
 235         if not(_MapInfo_filtered)
 236         {
 237                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 238                 return 0;
 239         }
 240         _MapInfo_filtered = strzone(_MapInfo_filtered);
 241         MapInfo_count = HugeSetOfIntegers_length(_MapInfo_filtered);
 242         MapInfo_ClearTemps();
 243         return 1;
 244 }
 245 #else
 246 float _MapInfo_filtered;
 247 float _MapInfo_filtered_allocated;
 248 float MapInfo_FilterList_Lookup(float i)
 249 {
 250         return stof(bufstr_get(_MapInfo_filtered, i));
 251 }
 252
 253 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pAbortOnGenerate)
 254 {
 255         float i, j;
 256         if not(_MapInfo_filtered_allocated)
 257         {
 258                 _MapInfo_filtered_allocated = 1;
 259                 _MapInfo_filtered = buf_create();
 260         }
 261         MapInfo_count = 0;
 262         for(i = 0, j = 0; i < _MapInfo_globcount; ++i)
 263         {
 264                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 265                         if(pAbortOnGenerate)
 266                         {
 267                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 268                                 MapInfo_progress = i / _MapInfo_globcount;
 269                                 return 0;
 270                         }
 271                 if(((MapInfo_Map_supportedGametypes & pGametype) != 0) && ((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures))
 272                         bufstr_set(_MapInfo_filtered, j++, ftos(i));
 273         }
 274         MapInfo_count = j;
 275         return 1;
 276 }
 277 #endif
 278
 279 // load info about the i-th map into the MapInfo_Map_* globals
 280 string MapInfo_BSPName_ByID(float i)
 281 {
 282         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 283 }
 284
 285 string unquote(string s)
 286 {
 287         float i, j, l;
 288         l = strlen(s);
 289         j = -1;
 290         for(i = 0; i < l; ++i)
 291         {
 292                 string ch;
 293                 ch = substring(s, i, 1);
 294                 if(ch != " ") if(ch != "\"")
 295                 {
 296                         for(j = strlen(s) - i - 1; j > 0; --j)
 297                         {
 298                                 ch = substring(s, i+j, 1);
 299                                 if(ch != " ") if(ch != "\"")
 300                                         return substring(s, i, j+1);
 301                         }
 302                         return substring(s, i, 1);
 303                 }
 304         }
 305         return "";
 306 }
 307
 308 float MapInfo_Get_ByID(float i)
 309 {
 310         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 311                 return 1;
 312         return 0;
 313 }
 314
 315 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 316 {
 317         string fn;
 318         float fh;
 319         string s, k, v;
 320         vector o;
 321         float i;
 322         float inWorldspawn;
 323         float r;
 324         float twoBaseModes;
 325
 326         vector mapMins, mapMaxs;
 327
 328         r = 1;
 329         fn = strcat("maps/", pFilename, ".ent");
 330         fh = fopen(fn, FILE_READ);
 331         if(fh < 0)
 332         {
 333                 r = 2;
 334                 fn = strcat("maps/", pFilename, ".bsp");
 335                 fh = fopen(fn, FILE_READ);
 336         }
 337         if(fh < 0)
 338                 return 0;
 339         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
 340
 341         inWorldspawn = 2;
 342         MapInfo_Map_supportedGametypes = 0;
 343
 344         for(;;)
 345         {
 346                 if not((s = fgets(fh)))
 347                         break;
 348                 if(inWorldspawn == 1)
 349                         if(startsWith(s, "}"))
 350                                 inWorldspawn = 0;
 351                 k = unquote(car(s));
 352                 v = unquote(cdr(s));
 353                 if(inWorldspawn)
 354                 {
 355                         if(k == "classname" && v == "worldspawn")
 356                                 inWorldspawn = 1;
 357                         else if(k == "author")
 358                                 MapInfo_Map_author = v;
 359                         else if(k == "message")
 360                         {
 361                                 i = strstrofs(v, " by ", 0);
 362                                 if(MapInfo_Map_author == "He-Who-Must-Not-Be-Named" && i >= 0)
 363                                 {
 364                                         MapInfo_Map_title = substring(v, 0, i);
 365                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 366                                 }
 367                                 else
 368                                         MapInfo_Map_title = v;
 369                         }
 370                 }
 371                 else
 372                 {
 373                         if(k == "origin")
 374                         {
 375                                 o = stov(strcat("'", v, "'"));
 376                                 mapMins_x = min(mapMins_x, o_x);
 377                                 mapMins_y = min(mapMins_y, o_y);
 378                                 mapMins_z = min(mapMins_z, o_z);
 379                                 mapMaxs_x = max(mapMaxs_x, o_x);
 380                                 mapMaxs_y = max(mapMaxs_y, o_y);
 381                                 mapMaxs_z = max(mapMaxs_z, o_z);
 382                         }
 383                         else if(k == "classname")
 384                         {
 385                                 if(v == "dom_controlpoint")
 386                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 387                                 else if(v == "item_flag_team2")
 388                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 389                                 else if(v == "team_CTF_blueflag")
 390                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 391                                 else if(v == "runematch_spawn_point")
 392                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 393                                 else if(v == "target_assault_roundend")
 394                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 395                                 else if(v == "onslaught_generator")
 396                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 397                                 else if(v == "info_player_team1")
 398                                         ++MapInfo_Map_spawnpoints;
 399                                 else if(v == "info_player_team2")
 400                                         ++MapInfo_Map_spawnpoints;
 401                                 else if(v == "info_player_start")
 402                                         ++MapInfo_Map_spawnpoints;
 403                                 else if(v == "info_player_deathmatch")
 404                                         ++MapInfo_Map_spawnpoints;
 405                                 else if(v == "weapon_nex")
 406                                         { }
 407                                 else if(v == "weapon_railgun")
 408                                         { }
 409                                 else if(startsWith(v, "weapon_"))
 410                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 411                         }
 412                 }
 413         }
 414         if(inWorldspawn)
 415         {
 416                 print(fn, " ended still in worldspawn, BUG\n");
 417                 return 0;
 418         }
 419         MapInfo_Map_diameter = vlen(mapMaxs - mapMins);
 420
 421         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT);
 422         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 423         {
 424                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 425                 // as the map is too symmetric for them.
 426         }
 427         else
 428         {
 429                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 430                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 431
 432                 if(MapInfo_Map_spawnpoints >= 8  && MapInfo_Map_diameter > 4096)
 433                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 434                 if(                MapInfo_Map_diameter < 4096)
 435                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 436                 if(MapInfo_Map_spawnpoints >= 12 && MapInfo_Map_diameter > 5120)
 437                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 438         }
 439
 440         fclose(fh);
 441
 442         return r;
 443 }
 444
 445 void _MapInfo_Map_Reset()
 446 {
 447         MapInfo_Map_title = "Untitled1";
 448         MapInfo_Map_description = "Bleh.";
 449         MapInfo_Map_author = "He-Who-Must-Not-Be-Named";
 450         MapInfo_Map_supportedGametypes = 0;
 451         MapInfo_Map_supportedFeatures = 0;
 452         MapInfo_Map_diameter = 0;
 453         MapInfo_Map_spawnpoints = 0;
 454 }
 455
 456 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType)
 457 {
 458         MapInfo_Map_supportedGametypes |= pThisType;
 459         if(!(pThisType & pWantedType))
 460                 return;
 461
 462         cvar_set("fraglimit", car(s));
 463         s = cdr(s);
 464
 465         cvar_set("timelimit", car(s));
 466         s = cdr(s);
 467
 468         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 469         {
 470                 cvar_set("g_tdm_teams", car(s));
 471                 s = cdr(s);
 472         }
 473
 474         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 475         {
 476                 cvar_set("g_keyhunt_teams", car(s));
 477                 s = cdr(s);
 478         }
 479 }
 480
 481 float MapInfo_Type_FromString(string t)
 482 {
 483         if     (t == "dm")    return MAPINFO_TYPE_DEATHMATCH;
 484         else if(t == "tdm")   return MAPINFO_TYPE_TEAM_DEATHMATCH;
 485         else if(t == "dom")   return MAPINFO_TYPE_DOMINATION;
 486         else if(t == "ctf")   return MAPINFO_TYPE_CTF;
 487         else if(t == "rune")  return MAPINFO_TYPE_RUNEMATCH;
 488         else if(t == "lms")   return MAPINFO_TYPE_LMS;
 489         else if(t == "arena") return MAPINFO_TYPE_ARENA;
 490         else if(t == "kh")    return MAPINFO_TYPE_KEYHUNT;
 491         else if(t == "as")    return MAPINFO_TYPE_ASSAULT;
 492         else if(t == "ons")   return MAPINFO_TYPE_ONSLAUGHT;
 493         else if(t == "all")   return MAPINFO_TYPE_ALL;
 494         else                  return 0;
 495 }
 496
 497 // load info about a map by name into the MapInfo_Map_* globals
 498 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 499 {
 500         string fn;
 501         string s, t;
 502         float fh, fh2;
 503         float r, f;
 504
 505         if(pGametypeToSet == 0)
 506                 if(MapInfo_Cache_Retrieve(pFilename))
 507                         return 1;
 508
 509         r = 1;
 510
 511         MapInfo_Map_bspname = pFilename;
 512
 513         // default all generic fields so they have "good" values in case something fails
 514         fn = strcat("maps/", pFilename, ".mapinfo");
 515         fh = fopen(fn, FILE_READ);
 516         if(fh < 0)
 517         {
 518                 if(!pAllowGenerate)
 519                         return 0;
 520                 _MapInfo_Map_Reset();
 521                 r = _MapInfo_Generate(pFilename);
 522                 if(!r)
 523                         return 0;
 524                 fh = fopen(fn, FILE_WRITE);
 525                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 526                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 527                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 528                 fputs(fh, strcat("_diameter ", ftos(MapInfo_Map_diameter), "\n"));
 529                 fputs(fh, strcat("_spawnpoints ", ftos(MapInfo_Map_spawnpoints), "\n"));
 530                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)       fputs(fh, "has weapons\n");
 531                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)      fputs(fh, "type dm 30 20\n");
 532                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH) fputs(fh, "type tdm 50 20 2\n");
 533                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DOMINATION)      fputs(fh, "type dom 200 20\n");
 534                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTF)             fputs(fh, "type ctf 300 20\n");
 535                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RUNEMATCH)       fputs(fh, "type rune 200 20\n");
 536                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_LMS)             fputs(fh, "type lms 9 20\n");
 537                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ARENA)           fputs(fh, "type arena 10 20\n");
 538                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_KEYHUNT)         fputs(fh, "type kh 1000 20 3\n");
 539                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ASSAULT)         fputs(fh, "type as 20\n");
 540                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ONSLAUGHT)       fputs(fh, "type ons 20\n");
 541
 542                 fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
 543                 if(fh2 >= 0)
 544                 {
 545                         fclose(fh2);
 546                         fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 547                 }
 548
 549                 fclose(fh);
 550                 r = 2;
 551                 // return r;
 552                 fh = fopen(fn, FILE_READ);
 553                 if(fh < 0)
 554                         error("... but I just wrote it!");
 555         }
 556
 557         _MapInfo_Map_Reset();
 558         for(;;)
 559         {
 560                 if not((s = fgets(fh)))
 561                         break;
 562                 t = car(s); s = cdr(s);
 563                 if     (t == "title")
 564                         MapInfo_Map_title = s;
 565                 else if(t == "description")
 566                         MapInfo_Map_description = s;
 567                 else if(t == "author")
 568                         MapInfo_Map_author = s;
 569                 else if(t == "_diameter")
 570                         MapInfo_Map_diameter = stof(s);
 571                 else if(t == "_spawnpoints")
 572                         MapInfo_Map_spawnpoints = stof(s);
 573                 else if(t == "has")
 574                 {
 575                         t = car(s); s = cdr(s);
 576                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 577                         else
 578                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 579                 }
 580                 else if(t == "type")
 581                 {
 582                         t = car(s); s = cdr(s);
 583                         f = MapInfo_Type_FromString(t);
 584                         if(f)
 585                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f);
 586                         else
 587                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 588                 }
 589                 else if(t == "settemp_for_type")
 590                 {
 591                         t = car(s); s = cdr(s);
 592                         if((f = MapInfo_Type_FromString(t)))
 593                         {
 594                                 if(f & pGametypeToSet)
 595                                 {
 596                                         t = car(s); s = cdr(s);
 597                                         if(strstrofs(t, "\"", 0) >= 0)
 598                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 599                                         else if(strstrofs(t, "\\", 0) >= 0)
 600                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 601                                         else if(strstrofs(t, ";", 0) >= 0)
 602                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 603                                         else if(strstrofs(s, "\"", 0) >= 0)
 604                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 605                                         else if(strstrofs(s, "\\", 0) >= 0)
 606                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 607                                         else if(strstrofs(s, ";", 0) >= 0)
 608                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 609                                         else
 610                                         {
 611                                                 dprint("Applying temporary setting ", t, " := ", s, "\n");
 612                                                 cvar_settemp(t, s);
 613                                         }
 614                                 }
 615                         }
 616                         else
 617                         {
 618                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
 619                         }
 620                 }
 621                 else
 622                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
 623         }
 624         fclose(fh);
 625         if(pGametypeToSet)
 626                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
 627                         error("Can't select the requested game type. Bailing out.");
 628         MapInfo_Cache_Store();
 629         if(MapInfo_Map_supportedGametypes != 0)
 630                 return r;
 631         dprint("Map ", pFilename, " supports no game types, ignored\n");
 632         return 0;
 633 }
 634
 635 float MapInfo_FindName(string s)
 636 {
 637         // if there is exactly one map of prefix s, return it
 638         // if not, return the null string
 639         // note that DP sorts glob results... so I can use a binary search
 640         float l, r, m, cmp;
 641         l = 0;
 642         r = MapInfo_count;
 643         // invariants: r is behind s, l-1 is equal or before
 644         while(l != r)
 645         {
 646                 m = floor((l + r) / 2);
 647                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
 648                 cmp = strcasecmp(MapInfo_FindName_match, s);
 649                 if(cmp == 0)
 650                         return m; // found and good
 651                 if(cmp < 0)
 652                         l = m + 1; // l-1 is before s
 653                 else
 654                         r = m; // behind s
 655         }
 656         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
 657         MapInfo_FindName_firstResult = l;
 658         // r == l, so: l is behind s, l-1 is before
 659         // SO: if there is any, l is the one with the right prefix
 660         //     and l+1 may be one too
 661         if(l == MapInfo_count)
 662         {
 663                 MapInfo_FindName_match = string_null;
 664                 MapInfo_FindName_firstResult = -1;
 665                 return -1; // no MapInfo_FindName_match, behind last item
 666         }
 667         if(!startsWithNocase(MapInfo_FindName_match, s))
 668         {
 669                 MapInfo_FindName_match = string_null;
 670                 MapInfo_FindName_firstResult = -1;
 671                 return -1; // wrong prefix
 672         }
 673         if(l == MapInfo_count - 1)
 674                 return l; // last one, nothing can follow => unique
 675         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
 676         {
 677                 MapInfo_FindName_match = string_null;
 678                 return -1; // ambigous MapInfo_FindName_match
 679         }
 680         return l;
 681 }
 682
 683 string MapInfo_FixName(string s)
 684 {
 685         MapInfo_FindName(s);
 686         return MapInfo_FindName_match;
 687 }
 688
 689 float MapInfo_CurrentFeatures()
 690 {
 691         float req;
 692         req = 0;
 693         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_minstagib") || cvar("g_nixnex") || cvar("g_rocketarena")))
 694                 req |= MAPINFO_FEATURE_WEAPONS;
 695         return req;
 696 }
 697
 698 float MapInfo_CurrentGametype()
 699 {
 700         if(cvar("g_domination"))
 701                 return MAPINFO_TYPE_DOMINATION;
 702         else if(cvar("g_ctf"))
 703                 return MAPINFO_TYPE_CTF;
 704         else if(cvar("g_runematch"))
 705                 return MAPINFO_TYPE_RUNEMATCH;
 706         else if(cvar("g_tdm"))
 707                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
 708         else if(cvar("g_assault"))
 709                 return MAPINFO_TYPE_ASSAULT;
 710         else if(cvar("g_lms"))
 711                 return MAPINFO_TYPE_LMS;
 712         else if(cvar("g_arena"))
 713                 return MAPINFO_TYPE_ARENA;
 714         else if(cvar("g_keyhunt"))
 715                 return MAPINFO_TYPE_KEYHUNT;
 716         else if(cvar("g_onslaught"))
 717                 return MAPINFO_TYPE_ONSLAUGHT;
 718         else
 719                 return MAPINFO_TYPE_DEATHMATCH;
 720 }
 721
 722 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 723 {
 724         if(!MapInfo_Get_ByName(s, 1, 0))
 725                 return 0;
 726         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
 727                 return 0;
 728         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
 729                 return 0;
 730         return 1;
 731 }
 732
 733 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 734 {
 735         float r;
 736         r = _MapInfo_CheckMap(s);
 737         MapInfo_ClearTemps();
 738         return r;
 739 }
 740
 741 void MapInfo_SwitchGameType(float t)
 742 {
 743         cvar_set("gamecfg",      "0");
 744         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
 745         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
 746         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
 747         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
 748         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
 749         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
 750         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
 751         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
 752         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
 753         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
 754 }
 755
 756 void MapInfo_LoadMap(string s)
 757 {
 758         MapInfo_Map_supportedGametypes = 0;
 759         if(!MapInfo_CheckMap(s))
 760         {
 761                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
 762                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
 763         }
 764         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
 765 }
 766
 767 string MapInfo_ListAllowedMaps()
 768 {
 769         string out;
 770         float i;
 771
 772         // to make absolutely sure:
 773         MapInfo_Enumerate();
 774         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 775
 776         out = "";
 777         for(i = 0; i < MapInfo_count; ++i)
 778                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
 779         return substring(out, 1, strlen(out) - 1);
 780 }
 781
 782 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
 783 {
 784         float t;
 785         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
 786         {
 787                 if(MapInfo_Map_supportedGametypes <= 0)
 788                         error("Mapinfo system is not functional at all. BAILED OUT.\n");
 789
 790                 t = 1;
 791                 while(!(MapInfo_Map_supportedGametypes & 1))
 792                 {
 793                         t *= 2;
 794                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
 795                 }
 796                 // t is now a supported mode!
 797                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
 798                 MapInfo_SwitchGameType(t);
 799         }
 800         cvar_settemp_restore();
 801         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
 802         MapInfo_ClearTemps();
 803 }
 804
 805 void MapInfo_ClearTemps()
 806 {
 807         MapInfo_Map_bspname = string_null;
 808         MapInfo_Map_title = string_null;
 809         MapInfo_Map_description = string_null;
 810         MapInfo_Map_author = string_null;
 811         MapInfo_Map_supportedGametypes = 0;
 812         MapInfo_Map_supportedFeatures = 0;
 813         MapInfo_Map_diameter = 0;
 814         MapInfo_Map_spawnpoints = 0;
 815 }