data/qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2 float startsWith(string haystack, string needle)
   3 {
   4         return substring(haystack, 0, strlen(needle)) == needle;
   5 }
   6 float startsWithNocase(string haystack, string needle)
   7 {
   8         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
   9 }
  10 string extractRestOfLine(string haystack, string needle)
  11 {
  12         if(startsWith(haystack, needle))
  13                 return substring(haystack, strlen(needle), strlen(haystack) - strlen(needle));
  14         return string_null;
  15 }
  16 string car(string s)
  17 {
  18         float o;
  19         o = strstrofs(s, " ", 0);
  20         if(o < 0)
  21                 return s;
  22         return substring(s, 0, o);
  23 }
  24 string cdr(string s)
  25 {
  26         float o;
  27         o = strstrofs(s, " ", 0);
  28         if(o < 0)
  29                 return string_null;
  30         return substring(s, o + 1, strlen(s) - (o + 1));
  31 }
  32 float matchacl(string acl, string str)
  33 {
  34         string t, s;
  35         float r, d;
  36         r = 0;
  37         while(acl)
  38         {
  39                 t = car(acl); acl = cdr(acl);
  40                 d = 1;
  41                 if(substring(t, 0, 1) == "-")
  42                 {
  43                         d = -1;
  44                         t = substring(t, 1, strlen(t) - 1);
  45                 }
  46                 else if(substring(t, 0, 1) == "+")
  47                         t = substring(t, 1, strlen(t) - 1);
  48                 if(substring(t, -1, 1) == "*")
  49                 {
  50                         t = substring(t, 0, strlen(t) - 1);
  51                         s = substring(s, 0, strlen(t));
  52                 }
  53                 else
  54                         s = str;
  55
  56                 if(s == t)
  57                 {
  58                         r = d;
  59                 }
  60         }
  61         return r;
  62 }
  63
  64 float _MapInfo_Cache_Active;
  65 float _MapInfo_Cache_DB_NameToIndex;
  66 float _MapInfo_Cache_Buf_IndexToMapData;
  67
  68 void MapInfo_Cache_Destroy()
  69 {
  70         if(!_MapInfo_Cache_Active)
  71                 return;
  72
  73         db_close(_MapInfo_Cache_DB_NameToIndex);
  74         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  75         _MapInfo_Cache_Active = 0;
  76 }
  77
  78 void MapInfo_Cache_Create()
  79 {
  80         MapInfo_Cache_Destroy();
  81         _MapInfo_Cache_DB_NameToIndex = db_create();
  82         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  83         _MapInfo_Cache_Active = 1;
  84 }
  85
  86 void MapInfo_Cache_Invalidate()
  87 {
  88         if(!_MapInfo_Cache_Active)
  89                 return;
  90
  91         MapInfo_Cache_Create();
  92 }
  93
  94 void MapInfo_Cache_Store()
  95 {
  96         float i;
  97         string s;
  98         if(!_MapInfo_Cache_Active)
  99                 return;
 100
 101         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
 102         if(!s) // empty string is NOT valid here!
 103         {
 104                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
 105                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
 106         }
 107         else
 108                 i = stof(s);
 109
 110         // now store all the stuff
 111         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
 112         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
 113         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
 114         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
 115         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
 116         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
 117         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
 118 }
 119
 120 float MapInfo_Cache_Retrieve(string map)
 121 {
 122         float i;
 123         string s;
 124         if(!_MapInfo_Cache_Active)
 125                 return 0;
 126
 127         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
 128         if(!s)
 129                 return 0;
 130         i = stof(s);
 131
 132         // now retrieve all the stuff
 133         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
 134         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 135         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 136         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 137         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 138         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 139         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 140         return 1;
 141 }
 142
 143 // GLOB HANDLING (for all BSP files)
 144 float _MapInfo_globopen;
 145 float _MapInfo_globcount;
 146 float _MapInfo_globhandle;
 147 string _MapInfo_GlobItem(float i)
 148 {
 149         string s;
 150         s = search_getfilename(_MapInfo_globhandle, i);
 151         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 152 }
 153
 154 void MapInfo_Enumerate()
 155 {
 156         if(_MapInfo_globopen)
 157                 search_end(_MapInfo_globhandle);
 158         MapInfo_Cache_Invalidate();
 159         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 160         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 161         _MapInfo_globopen = 1;
 162 }
 163
 164 // filter the info by game type mask (updates MapInfo_count)
 165 //
 166 float _MapInfo_filtered;
 167 float _MapInfo_filtered_allocated;
 168 float MapInfo_FilterList_Lookup(float i)
 169 {
 170         return stof(bufstr_get(_MapInfo_filtered, i));
 171 }
 172
 173 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 174 {
 175         string h;
 176         h = bufstr_get(_MapInfo_filtered, i);
 177         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 178         bufstr_set(_MapInfo_filtered, j, h);
 179 }
 180
 181 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 182 {
 183         string a, b;
 184         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 185         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 186         return strcasecmp(a, b);
 187 }
 188
 189 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 190 {
 191         float i, j;
 192         if not(_MapInfo_filtered_allocated)
 193         {
 194                 _MapInfo_filtered_allocated = 1;
 195                 _MapInfo_filtered = buf_create();
 196         }
 197         MapInfo_count = 0;
 198         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 199         {
 200                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 201                         if(pAbortOnGenerate)
 202                         {
 203                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 204                                 MapInfo_progress = i / _MapInfo_globcount;
 205                                 return 0;
 206                         }
 207                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 208                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 209                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 210                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 211                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 212         }
 213         MapInfo_count = j + 1;
 214         MapInfo_ClearTemps();
 215
 216         // sometimes the glob isn't sorted nicely, so fix it here...
 217         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 218
 219         return 1;
 220 }
 221
 222 void MapInfo_Filter_Free()
 223 {
 224         if(_MapInfo_filtered_allocated)
 225         {
 226                 buf_del(_MapInfo_filtered);
 227                 _MapInfo_filtered_allocated = 0;
 228         }
 229 }
 230
 231 // load info about the i-th map into the MapInfo_Map_* globals
 232 string MapInfo_BSPName_ByID(float i)
 233 {
 234         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 235 }
 236
 237 string unquote(string s)
 238 {
 239         float i, j, l;
 240         l = strlen(s);
 241         j = -1;
 242         for(i = 0; i < l; ++i)
 243         {
 244                 string ch;
 245                 ch = substring(s, i, 1);
 246                 if(ch != " ") if(ch != "\"")
 247                 {
 248                         for(j = strlen(s) - i - 1; j > 0; --j)
 249                         {
 250                                 ch = substring(s, i+j, 1);
 251                                 if(ch != " ") if(ch != "\"")
 252                                         return substring(s, i, j+1);
 253                         }
 254                         return substring(s, i, 1);
 255                 }
 256         }
 257         return "";
 258 }
 259
 260 float MapInfo_Get_ByID(float i)
 261 {
 262         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 263                 return 1;
 264         return 0;
 265 }
 266
 267 string _MapInfo_Map_worldspawn_music;
 268
 269 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 270 {
 271         string fn;
 272         float fh;
 273         string s, k, v;
 274         vector o;
 275         float i;
 276         float inWorldspawn;
 277         float r;
 278         float twoBaseModes;
 279         float diameter, spawnpoints;
 280         float spawnplaces;
 281
 282         vector mapMins, mapMaxs;
 283
 284         r = 1;
 285         fn = strcat("maps/", pFilename, ".ent");
 286         fh = fopen(fn, FILE_READ);
 287         if(fh < 0)
 288         {
 289                 r = 2;
 290                 fn = strcat("maps/", pFilename, ".bsp");
 291                 fh = fopen(fn, FILE_READ);
 292         }
 293         if(fh < 0)
 294                 return 0;
 295         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
 296
 297         inWorldspawn = 2;
 298         MapInfo_Map_flags = 0;
 299         MapInfo_Map_supportedGametypes = 0;
 300         spawnpoints = 0;
 301         spawnplaces = 0;
 302         _MapInfo_Map_worldspawn_music = "";
 303
 304         for(;;)
 305         {
 306                 if not((s = fgets(fh)))
 307                         break;
 308                 if(inWorldspawn == 1)
 309                         if(startsWith(s, "}"))
 310                                 inWorldspawn = 0;
 311                 k = unquote(car(s));
 312                 v = unquote(cdr(s));
 313                 if(inWorldspawn)
 314                 {
 315                         if(k == "classname" && v == "worldspawn")
 316                                 inWorldspawn = 1;
 317                         else if(k == "author")
 318                                 MapInfo_Map_author = v;
 319                         else if(k == "_description")
 320                                 MapInfo_Map_description = v;
 321                         else if(k == "music")
 322                                 _MapInfo_Map_worldspawn_music = v;
 323                         else if(k == "noise")
 324                                 _MapInfo_Map_worldspawn_music = v;
 325                         else if(k == "message")
 326                         {
 327                                 i = strstrofs(v, " by ", 0);
 328                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 329                                 {
 330                                         MapInfo_Map_title = substring(v, 0, i);
 331                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 332                                 }
 333                                 else
 334                                         MapInfo_Map_title = v;
 335                         }
 336                 }
 337                 else
 338                 {
 339                         if(k == "origin")
 340                         {
 341                                 o = stov(strcat("'", v, "'"));
 342                                 mapMins_x = min(mapMins_x, o_x);
 343                                 mapMins_y = min(mapMins_y, o_y);
 344                                 mapMins_z = min(mapMins_z, o_z);
 345                                 mapMaxs_x = max(mapMaxs_x, o_x);
 346                                 mapMaxs_y = max(mapMaxs_y, o_y);
 347                                 mapMaxs_z = max(mapMaxs_z, o_z);
 348                         }
 349                         else if(k == "race_place")
 350                         {
 351                                 if(stof(v) > 0)
 352                                         spawnplaces = 1;
 353                         }
 354                         else if(k == "classname")
 355                         {
 356                                 if(v == "dom_controlpoint")
 357                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 358                                 else if(v == "item_flag_team2")
 359                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 360                                 else if(v == "team_CTF_blueflag")
 361                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 362                                 else if(v == "runematch_spawn_point")
 363                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 364                                 else if(v == "target_assault_roundend")
 365                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 366                                 else if(v == "onslaught_generator")
 367                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 368                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 369                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 370                                 else if(v == "info_player_team1")
 371                                         ++spawnpoints;
 372                                 else if(v == "info_player_team2")
 373                                         ++spawnpoints;
 374                                 else if(v == "info_player_start")
 375                                         ++spawnpoints;
 376                                 else if(v == "info_player_deathmatch")
 377                                         ++spawnpoints;
 378                                 else if(v == "trigger_race_checkpoint")
 379                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 380                                 else if(v == "target_startTimer")
 381                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 382                                 else if(v == "weapon_nex")
 383                                         { }
 384                                 else if(v == "weapon_railgun")
 385                                         { }
 386                                 else if(startsWith(v, "weapon_"))
 387                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 388                         }
 389                 }
 390         }
 391         if(inWorldspawn)
 392         {
 393                 print(fn, " ended still in worldspawn, BUG\n");
 394                 return 0;
 395         }
 396         diameter = vlen(mapMaxs - mapMins);
 397
 398         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 399         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 400         {
 401                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 402                 // as the map is too symmetric for them.
 403         }
 404         else
 405         {
 406                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 407                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;       // Rune always works
 408                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 409
 410                 if(spawnpoints >= 8  && diameter > 4096) {
 411                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 412                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 413                 }
 414                 if(                     diameter < 4096)
 415                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 416                 if(spawnpoints >= 12 && diameter > 5120)
 417                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 418         }
 419
 420         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 421         if(!spawnplaces)
 422         {
 423                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
 424                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 425         }
 426
 427         dprint("-> diameter ",    ftos(diameter));
 428         dprint(";  spawnpoints ", ftos(spawnpoints));
 429         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 430
 431         fclose(fh);
 432
 433         return r;
 434 }
 435
 436 void _MapInfo_Map_Reset()
 437 {
 438         MapInfo_Map_title = "<TITLE>";
 439         MapInfo_Map_description = "<DESCRIPTION>";
 440         MapInfo_Map_author = "<AUTHOR>";
 441         MapInfo_Map_supportedGametypes = 0;
 442         MapInfo_Map_supportedFeatures = 0;
 443         MapInfo_Map_flags = 0;
 444         MapInfo_Map_clientstuff = "";
 445         MapInfo_Map_fog = "";
 446         MapInfo_Map_mins = '0 0 0';
 447         MapInfo_Map_maxs = '0 0 0';
 448 }
 449
 450 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType)
 451 {
 452         string sa;
 453         MapInfo_Map_supportedGametypes |= pThisType;
 454         if(!(pThisType & pWantedType))
 455                 return;
 456
 457         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 458         {
 459                 cvar_set("fraglimit", "0");
 460         }
 461         else
 462         {
 463                 cvar_set("fraglimit", car(s));
 464                 s = cdr(s);
 465         }
 466
 467         cvar_set("timelimit", car(s));
 468         s = cdr(s);
 469
 470         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 471         {
 472                 sa = car(s); if(sa == "") sa = "2";
 473                 cvar_set("g_tdm_teams", sa);
 474                 s = cdr(s);
 475         }
 476
 477         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 478         {
 479                 sa = car(s); if(sa == "") sa = "3";
 480                 cvar_set("g_keyhunt_teams", sa);
 481                 s = cdr(s);
 482         }
 483
 484         if(pWantedType == MAPINFO_TYPE_CTF)
 485         {
 486                 sa = car(s); if(sa == "") sa = "10";
 487                 if(cvar("g_ctf_win_mode") < 2)
 488                         cvar_set("fraglimit", sa);
 489                 s = cdr(s);
 490         }
 491
 492         // rc = timelimit timelimit_qualification laps laps_teamplay
 493         if(pWantedType == MAPINFO_TYPE_RACE)
 494         {
 495                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 496                 cvar_set("g_race_qualifying_timelimit", sa);
 497                 s = cdr(s);
 498
 499                 sa = car(s); if(sa == "") sa = "10";
 500                 if(cvar("g_race_teams") < 2)
 501                         cvar_set("fraglimit", sa);
 502                 s = cdr(s);
 503
 504                 sa = car(s); if(sa == "") sa = "20";
 505                 if(cvar("g_race_teams") >= 2)
 506                         cvar_set("fraglimit", sa);
 507                 s = cdr(s);
 508         }
 509
 510         if(pWantedType == MAPINFO_TYPE_CTS)
 511         {
 512                 sa = car(s); if(sa == "") sa = cvar_string("fraglimit");
 513                 if(cvar("g_race_teams"))
 514                         cvar_set("fraglimit", sa);
 515                 s = cdr(s);
 516         }
 517
 518         sa = car(s); if(sa == "") sa = "0";
 519         cvar_set("leadlimit", sa);
 520         s = cdr(s);
 521 }
 522
 523 float MapInfo_Type_FromString(string t)
 524 {
 525         if     (t == "dm")      return MAPINFO_TYPE_DEATHMATCH;
 526         else if(t == "tdm")     return MAPINFO_TYPE_TEAM_DEATHMATCH;
 527         else if(t == "dom")     return MAPINFO_TYPE_DOMINATION;
 528         else if(t == "ctf")     return MAPINFO_TYPE_CTF;
 529         else if(t == "rune")    return MAPINFO_TYPE_RUNEMATCH;
 530         else if(t == "lms")     return MAPINFO_TYPE_LMS;
 531         else if(t == "arena")   return MAPINFO_TYPE_ARENA;
 532         else if(t == "ca")      return MAPINFO_TYPE_CA;
 533         else if(t == "kh")      return MAPINFO_TYPE_KEYHUNT;
 534         else if(t == "as")      return MAPINFO_TYPE_ASSAULT;
 535         else if(t == "ons")     return MAPINFO_TYPE_ONSLAUGHT;
 536         else if(t == "rc")      return MAPINFO_TYPE_RACE;
 537         else if(t == "nexball") return MAPINFO_TYPE_NEXBALL;
 538         else if(t == "cts")     return MAPINFO_TYPE_CTS;
 539         else if(t == "all")     return MAPINFO_TYPE_ALL;
 540         else                    return 0;
 541 }
 542
 543 void _MapInfo_Parse_Settemp(string pFilename, string acl, string s, float recurse)
 544 {
 545         string t;
 546         float fh, o;
 547         t = car(s); s = cdr(s);
 548
 549         // limited support of "" and comments
 550         //   remove trailing and leading " of t
 551         if(substring(t, 0, 1) == "\"")
 552         {
 553                 if(substring(t, -1, 1) == "\"")
 554                         t = substring(t, 1, -2);
 555         }
 556
 557         //   remove leading " of s
 558         if(substring(s, 0, 1) == "\"")
 559         {
 560                 s = substring(s, 1, -1);
 561         }
 562         //   remove trailing " of s, and all that follows (cvar description)
 563         o = strstrofs(s, "\"", 0);
 564         if(o >= 0)
 565                 s = substring(s, 0, o);
 566
 567         //   remove // comments
 568         o = strstrofs(s, "//", 0);
 569         if(o >= 0)
 570                 s = substring(s, 0, o);
 571
 572         //   remove trailing spaces
 573         while(substring(s, -1, 1) == " ")
 574                 s = substring(s, 0, -2);
 575
 576         if(t == "#include")
 577         {
 578                 if(recurse > 0)
 579                 {
 580                         fh = fopen(s, FILE_READ);
 581                         if(fh < 0)
 582                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 583                         else
 584                         {
 585                                 for(;;)
 586                                 {
 587                                         if not((s = fgets(fh)))
 588                                                 break;
 589
 590                                         // catch different sorts of comments
 591                                         if(s == "")                    // empty lines
 592                                                 continue;
 593                                         if(substring(s, 0, 1) == "#")  // UNIX style
 594                                                 continue;
 595                                         if(substring(s, 0, 2) == "//") // C++ style
 596                                                 continue;
 597                                         if(substring(s, 0, 1) == "_")  // q3map style
 598                                                 continue;
 599
 600                                         if(substring(s, 0, 4) == "set ")
 601                                                 s = substring(s, 4, -1);
 602                                         if(substring(s, 0, 5) == "seta ")
 603                                                 s = substring(s, 5, -1);
 604
 605                                         _MapInfo_Parse_Settemp(pFilename, acl, s, recurse - 1);
 606                                 }
 607                                 fclose(fh);
 608                         }
 609                 }
 610                 else
 611                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 612         }
 613         else if not(cvar_value_issafe(t))
 614                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 615         else if not (cvar_value_issafe(s))
 616                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 617         else if(substring(t, 0, 10) == "g_mapinfo_")
 618                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 619         else if(matchacl(acl, t) <= 0)
 620                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 621         else
 622         {
 623                 dprint("Applying temporary setting ", t, " := ", s, "\n");
 624                 if(cvar("g_campaign"))
 625                         cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 626                 else
 627                         cvar_settemp(t, s);
 628         }
 629 }
 630
 631 // load info about a map by name into the MapInfo_Map_* globals
 632 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 633 {
 634         string fn;
 635         string s, t;
 636         float fh, fh2;
 637         float r, f, n, i;
 638         string acl;
 639
 640         acl = cvar_string("g_mapinfo_settemp_acl");
 641
 642         if(strstrofs(pFilename, "/", 0) >= 0)
 643         {
 644                 print("Invalid character in map name, ignored\n");
 645                 return 0;
 646         }
 647
 648         if(pGametypeToSet == 0)
 649                 if(MapInfo_Cache_Retrieve(pFilename))
 650                         return 1;
 651
 652         r = 1;
 653
 654         MapInfo_Map_bspname = pFilename;
 655
 656         // default all generic fields so they have "good" values in case something fails
 657         fn = strcat("maps/", pFilename, ".mapinfo");
 658         fh = fopen(fn, FILE_READ);
 659         if(fh < 0)
 660         {
 661                 if(!pAllowGenerate)
 662                         return 0;
 663                 _MapInfo_Map_Reset();
 664                 r = _MapInfo_Generate(pFilename);
 665                 if(!r)
 666                         return 0;
 667                 fh = fopen(fn, FILE_WRITE);
 668                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 669                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 670                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 671                 if(_MapInfo_Map_worldspawn_music != "")
 672                 {
 673                         if(
 674                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 675                                 ||
 676                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 677                         )
 678                                 fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 679                         else
 680                                 fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 681                 }
 682                 else
 683                 {
 684                         n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 685                         s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 686                         for(;;)
 687                         {
 688                                 i = floor(random() * n);
 689                                 if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 690                                         break;
 691                         }
 692                         fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 693                 }
 694                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 695                         fputs(fh, "has weapons\n");
 696                 else
 697                         fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 698                 if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 699                         fputs(fh, "frustrating\n");
 700                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)      fputs(fh, "type dm 30 20\n");
 701                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH) fputs(fh, "type tdm 50 20 2\n");
 702                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DOMINATION)      fputs(fh, "type dom 200 20\n");
 703                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTF)             fputs(fh, "type ctf 300 20 10\n");
 704                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RUNEMATCH)       fputs(fh, "type rune 200 20\n");
 705                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_LMS)             fputs(fh, "type lms 9 20\n");
 706                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ARENA)           fputs(fh, "type arena 10 20\n");
 707                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CA)              fputs(fh, "type ca 10 20\n");
 708                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_KEYHUNT)         fputs(fh, "type kh 1000 20 3\n");
 709                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ASSAULT)         fputs(fh, "type as 20\n");
 710                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)            fputs(fh, "type rc 20 5 7 15\n");
 711                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ONSLAUGHT)       fputs(fh, "type ons 20\n");
 712                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_NEXBALL)         fputs(fh, "type nexball 5 20\n");
 713                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTS)             fputs(fh, "type cts 20 -1\n");
 714
 715                 fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
 716                 if(fh2 >= 0)
 717                 {
 718                         fclose(fh2);
 719                         fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 720                 }
 721
 722                 fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 723                 fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 724                 fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 725                 fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 726                 fputs(fh, "// optional: hidden\n");
 727
 728                 fclose(fh);
 729                 r = 2;
 730                 // return r;
 731                 fh = fopen(fn, FILE_READ);
 732                 if(fh < 0)
 733                         error("... but I just wrote it!");
 734         }
 735
 736         _MapInfo_Map_Reset();
 737         for(;;)
 738         {
 739                 if not((s = fgets(fh)))
 740                         break;
 741
 742                 // catch different sorts of comments
 743                 if(s == "")                    // empty lines
 744                         continue;
 745                 if(substring(s, 0, 1) == "#")  // UNIX style
 746                         continue;
 747                 if(substring(s, 0, 2) == "//") // C++ style
 748                         continue;
 749                 if(substring(s, 0, 1) == "_")  // q3map style
 750                         continue;
 751
 752                 t = car(s); s = cdr(s);
 753                 if(t == "title")
 754                         MapInfo_Map_title = s;
 755                 else if(t == "description")
 756                         MapInfo_Map_description = s;
 757                 else if(t == "author")
 758                         MapInfo_Map_author = s;
 759                 else if(t == "has")
 760                 {
 761                         t = car(s); s = cdr(s);
 762                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 763                         else
 764                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 765                 }
 766                 else if(t == "hidden")
 767                 {
 768                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 769                 }
 770                 else if(t == "forbidden")
 771                 {
 772                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 773                 }
 774                 else if(t == "frustrating")
 775                 {
 776                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 777                 }
 778                 else if(t == "type")
 779                 {
 780                         t = car(s); s = cdr(s);
 781                         f = MapInfo_Type_FromString(t);
 782                         if(f)
 783                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f);
 784                         else
 785                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 786                 }
 787                 else if(t == "size")
 788                 {
 789                         float a, b, c, d, e;
 790                         t = car(s); s = cdr(s); a = stof(t);
 791                         t = car(s); s = cdr(s); b = stof(t);
 792                         t = car(s); s = cdr(s); c = stof(t);
 793                         t = car(s); s = cdr(s); d = stof(t);
 794                         t = car(s); s = cdr(s); e = stof(t);
 795                         if(s == "")
 796                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 797                         else
 798                         {
 799                                 t = car(s); s = cdr(s); f = stof(t);
 800                                 if(s != "")
 801                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 802                                 else
 803                                 {
 804                                         if(a >= d || b >= e || c >= f)
 805                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
 806                                         else
 807                                         {
 808                                                 MapInfo_Map_mins_x = a;
 809                                                 MapInfo_Map_mins_y = b;
 810                                                 MapInfo_Map_mins_z = c;
 811                                                 MapInfo_Map_maxs_x = d;
 812                                                 MapInfo_Map_maxs_y = e;
 813                                                 MapInfo_Map_maxs_z = f;
 814                                         }
 815                                 }
 816                         }
 817                 }
 818                 else if(t == "settemp_for_type")
 819                 {
 820                         t = car(s); s = cdr(s);
 821                         if((f = MapInfo_Type_FromString(t)))
 822                         {
 823                                 if(f & pGametypeToSet)
 824                                 {
 825                                         _MapInfo_Parse_Settemp(pFilename, acl, s, 1);
 826                                 }
 827                         }
 828                         else
 829                         {
 830                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
 831                         }
 832                 }
 833                 else if(t == "clientsettemp_for_type")
 834                 {
 835                         t = car(s); s = cdr(s);
 836                         if((f = MapInfo_Type_FromString(t)))
 837                         {
 838                                 if(f & pGametypeToSet)
 839                                 {
 840                                         t = car(s); s = cdr(s);
 841                                         if not(cvar_value_issafe(t))
 842                                                 print("Map ", pFilename, " contains a potentially harmful client setting, ignored\n");
 843                                         else if not (cvar_value_issafe(s))
 844                                                 print("Map ", pFilename, " contains a potentially harmful client setting, ignored\n");
 845                                         else
 846                                         {
 847                                                 dprint("Applying temporary client setting ", t, " := ", s, "\n");
 848                                                 MapInfo_Map_clientstuff = strcat(
 849                                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 850                                                 );
 851                                         }
 852                                 }
 853                         }
 854                         else
 855                         {
 856                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
 857                         }
 858                 }
 859                 else if(t == "fog")
 860                 {
 861                         if not(cvar_value_issafe(t))
 862                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
 863                         else
 864                                 MapInfo_Map_fog = s;
 865                 }
 866                 else if(t == "cdtrack")
 867                 {
 868                         if(pGametypeToSet)
 869                         {
 870                                 if not(cvar_value_issafe(t))
 871                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
 872                                 else
 873                                         MapInfo_Map_clientstuff = strcat(
 874                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
 875                                         );
 876                         }
 877                 }
 878                 else
 879                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
 880         }
 881         fclose(fh);
 882
 883         if(pGametypeToSet)
 884         {
 885                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
 886                 {
 887                         print("Can't select the requested game type. Trying anyway with stupid settings.\n");
 888                         _MapInfo_Map_ApplyGametype("0 0 0", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
 889                 }
 890         }
 891
 892         MapInfo_Cache_Store();
 893         if(MapInfo_Map_supportedGametypes != 0)
 894                 return r;
 895         dprint("Map ", pFilename, " supports no game types, ignored\n");
 896         return 0;
 897 }
 898
 899 float MapInfo_FindName(string s)
 900 {
 901         // if there is exactly one map of prefix s, return it
 902         // if not, return the null string
 903         // note that DP sorts glob results... so I can use a binary search
 904         float l, r, m, cmp;
 905         l = 0;
 906         r = MapInfo_count;
 907         // invariants: r is behind s, l-1 is equal or before
 908         while(l != r)
 909         {
 910                 m = floor((l + r) / 2);
 911                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
 912                 cmp = strcasecmp(MapInfo_FindName_match, s);
 913                 if(cmp == 0)
 914                         return m; // found and good
 915                 if(cmp < 0)
 916                         l = m + 1; // l-1 is before s
 917                 else
 918                         r = m; // behind s
 919         }
 920         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
 921         MapInfo_FindName_firstResult = l;
 922         // r == l, so: l is behind s, l-1 is before
 923         // SO: if there is any, l is the one with the right prefix
 924         //     and l+1 may be one too
 925         if(l == MapInfo_count)
 926         {
 927                 MapInfo_FindName_match = string_null;
 928                 MapInfo_FindName_firstResult = -1;
 929                 return -1; // no MapInfo_FindName_match, behind last item
 930         }
 931         if(!startsWithNocase(MapInfo_FindName_match, s))
 932         {
 933                 MapInfo_FindName_match = string_null;
 934                 MapInfo_FindName_firstResult = -1;
 935                 return -1; // wrong prefix
 936         }
 937         if(l == MapInfo_count - 1)
 938                 return l; // last one, nothing can follow => unique
 939         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
 940         {
 941                 MapInfo_FindName_match = string_null;
 942                 return -1; // ambigous MapInfo_FindName_match
 943         }
 944         return l;
 945 }
 946
 947 string MapInfo_FixName(string s)
 948 {
 949         MapInfo_FindName(s);
 950         return MapInfo_FindName_match;
 951 }
 952
 953 float MapInfo_CurrentFeatures()
 954 {
 955         float req;
 956         req = 0;
 957         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nixnex") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
 958                 req |= MAPINFO_FEATURE_WEAPONS;
 959         return req;
 960 }
 961
 962 float MapInfo_CurrentGametype()
 963 {
 964         if(cvar("g_domination"))
 965                 return MAPINFO_TYPE_DOMINATION;
 966         else if(cvar("g_ctf"))
 967                 return MAPINFO_TYPE_CTF;
 968         else if(cvar("g_runematch"))
 969                 return MAPINFO_TYPE_RUNEMATCH;
 970         else if(cvar("g_tdm"))
 971                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
 972         else if(cvar("g_assault"))
 973                 return MAPINFO_TYPE_ASSAULT;
 974         else if(cvar("g_lms"))
 975                 return MAPINFO_TYPE_LMS;
 976         else if(cvar("g_arena"))
 977                 return MAPINFO_TYPE_ARENA;
 978         else if(cvar("g_ca"))
 979                 return MAPINFO_TYPE_CA;
 980         else if(cvar("g_keyhunt"))
 981                 return MAPINFO_TYPE_KEYHUNT;
 982         else if(cvar("g_onslaught"))
 983                 return MAPINFO_TYPE_ONSLAUGHT;
 984         else if(cvar("g_race"))
 985                 return MAPINFO_TYPE_RACE;
 986         else if(cvar("g_nexball"))
 987                 return MAPINFO_TYPE_NEXBALL;
 988         else if(cvar("g_cts"))
 989                 return MAPINFO_TYPE_CTS;
 990         else
 991                 return MAPINFO_TYPE_DEATHMATCH;
 992 }
 993
 994 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 995 {
 996         if(!MapInfo_Get_ByName(s, 1, 0))
 997                 return 0;
 998         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
 999                 return 0;
1000         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1001                 return 0;
1002         return 1;
1003 }
1004
1005 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1006 {
1007         float r;
1008         r = _MapInfo_CheckMap(s);
1009         MapInfo_ClearTemps();
1010         return r;
1011 }
1012
1013 string MapInfo_GetGameTypeCvar(float t)
1014 {
1015         switch(t)
1016         {
1017                 case MAPINFO_TYPE_DEATHMATCH: return "g_dm";
1018                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "g_tdm";
1019                 case MAPINFO_TYPE_DOMINATION: return "g_domination";
1020                 case MAPINFO_TYPE_CTF: return "g_ctf";
1021                 case MAPINFO_TYPE_RUNEMATCH: return "g_runematch";
1022                 case MAPINFO_TYPE_LMS: return "g_lms";
1023                 case MAPINFO_TYPE_ARENA: return "g_arena";
1024                 case MAPINFO_TYPE_CA: return "g_ca";
1025                 case MAPINFO_TYPE_KEYHUNT: return "g_kh";
1026                 case MAPINFO_TYPE_ASSAULT: return "g_assault";
1027                 case MAPINFO_TYPE_ONSLAUGHT: return "g_onslaught";
1028                 case MAPINFO_TYPE_RACE: return "g_race";
1029                 case MAPINFO_TYPE_NEXBALL: return "g_nexball";
1030                 case MAPINFO_TYPE_CTS: return "g_cts";
1031                 default: return "";
1032         }
1033 }
1034
1035 void MapInfo_SwitchGameType(float t)
1036 {
1037         cvar_set("gamecfg",      "0");
1038         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
1039         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
1040         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
1041         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
1042         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
1043         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
1044         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
1045         cvar_set("g_ca",         (t == MAPINFO_TYPE_CA)              ? "1" : "0");
1046         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
1047         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
1048         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
1049         cvar_set("g_race",       (t == MAPINFO_TYPE_RACE)            ? "1" : "0");
1050         cvar_set("g_nexball",    (t == MAPINFO_TYPE_NEXBALL)         ? "1" : "0");
1051         cvar_set("g_cts",        (t == MAPINFO_TYPE_CTS)             ? "1" : "0");
1052 }
1053
1054 void MapInfo_LoadMap(string s)
1055 {
1056         MapInfo_Map_supportedGametypes = 0;
1057         if(!MapInfo_CheckMap(s))
1058         {
1059                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1060                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1061         }
1062         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
1063 }
1064
1065 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1066 {
1067         string out;
1068         float i;
1069
1070         // to make absolutely sure:
1071         MapInfo_Enumerate();
1072         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1073
1074         out = "";
1075         for(i = 0; i < MapInfo_count; ++i)
1076                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1077         return substring(out, 1, strlen(out) - 1);
1078 }
1079
1080 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1081 {
1082         float t, t0;
1083         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1084         {
1085                 if(MapInfo_Map_supportedGametypes <= 0)
1086                         error("Mapinfo system is not functional at all. BAILED OUT.\n");
1087
1088                 t = 1;
1089                 while(!(MapInfo_Map_supportedGametypes & 1))
1090                 {
1091                         t *= 2;
1092                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1093                 }
1094                 // t is now a supported mode!
1095                 t0 = MapInfo_CurrentGametype();
1096                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1097                 {
1098                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1099                         cvar_set("timelimit", "0");
1100                         cvar_set("fraglimit", "0");
1101                         cvar_set("g_tdm_teams", "2");
1102                         cvar_set("g_keyhunt_teams", "3");
1103                         cvar_set("g_race_qualifying_timelimit", "0");
1104                         cvar_set("leadlimit", "0");
1105                 }
1106                 else
1107                 {
1108                         print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1109                         MapInfo_SwitchGameType(t);
1110                 }
1111         }
1112         cvar_settemp_restore();
1113         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
1114 }
1115
1116 void MapInfo_ClearTemps()
1117 {
1118         MapInfo_Map_bspname = string_null;
1119         MapInfo_Map_title = string_null;
1120         MapInfo_Map_description = string_null;
1121         MapInfo_Map_author = string_null;
1122         MapInfo_Map_clientstuff = string_null;
1123         MapInfo_Map_supportedGametypes = 0;
1124         MapInfo_Map_supportedFeatures = 0;
1125 }
1126
1127 void MapInfo_Shutdown()
1128 {
1129         MapInfo_ClearTemps();
1130         MapInfo_Filter_Free();
1131         MapInfo_Cache_Destroy();
1132         if(_MapInfo_globopen)
1133         {
1134                 search_end(_MapInfo_globhandle);
1135                 _MapInfo_globhandle = -1;
1136                 _MapInfo_globopen = FALSE;
1137         }
1138 }
1139
1140 float MapInfo_ForbiddenFlags()
1141 {
1142         float f;
1143         f = MAPINFO_FLAG_FORBIDDEN;
1144
1145 #ifndef MENUQC
1146         if not(cvar("g_maplist_allow_hidden"))
1147 #endif
1148                 f |= MAPINFO_FLAG_HIDDEN;
1149
1150         if not(cvar("g_maplist_allow_frustrating"))
1151                 f |= MAPINFO_FLAG_FRUSTRATING;
1152
1153         return f;
1154 }
1155
1156 float MapInfo_RequiredFlags()
1157 {
1158         float f;
1159         f = 0;
1160
1161         if(cvar("g_maplist_allow_frustrating") > 1)
1162                 f |= MAPINFO_FLAG_FRUSTRATING;
1163
1164         return f;
1165 }