clean up the campaign cvar list
[divverent/nexuiz.git] / data / qcsrc / common / mapinfo.qc
1 // generic string stuff
2 float startsWith(string haystack, string needle)
3 {
4         return substring(haystack, 0, strlen(needle)) == needle;
5 }
6 float startsWithNocase(string haystack, string needle)
7 {
8         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
9 }
10 string extractRestOfLine(string haystack, string needle)
11 {
12         if(startsWith(haystack, needle))
13                 return substring(haystack, strlen(needle), strlen(haystack) - strlen(needle));
14         return string_null;
15 }
16 string car(string s)
17 {
18         float o;
19         o = strstrofs(s, " ", 0);
20         if(o < 0)
21                 return s;
22         return substring(s, 0, o);
23 }
24 string cdr(string s)
25 {
26         float o;
27         o = strstrofs(s, " ", 0);
28         if(o < 0)
29                 return string_null;
30         return substring(s, o + 1, strlen(s) - (o + 1));
31 }
32 float matchacl(string acl, string str)
33 {
34         string t, s;
35         float r, d;
36         r = 0;
37         while(acl)
38         {
39                 t = car(acl); acl = cdr(acl);
40                 d = 1;
41                 if(substring(t, 0, 1) == "-")
42                 {
43                         d = -1;
44                         t = substring(t, 1, strlen(t) - 1);
45                 }
46                 else if(substring(t, 0, 1) == "+")
47                         t = substring(t, 1, strlen(t) - 1);
48                 if(substring(t, -1, 1) == "*")
49                 {
50                         t = substring(t, 0, strlen(t) - 1);
51                         s = substring(s, 0, strlen(t));
52                 }
53                 else
54                         s = str;
55
56                 if(s == t)
57                 {
58                         r = d;
59                 }
60         }
61         return r;
62 }
63
64 float _MapInfo_Cache_Active;
65 float _MapInfo_Cache_DB_NameToIndex;
66 float _MapInfo_Cache_Buf_IndexToMapData;
67
68 void MapInfo_Cache_Destroy()
69 {
70         if(!_MapInfo_Cache_Active)
71                 return;
72
73         db_close(_MapInfo_Cache_DB_NameToIndex);
74         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
75         _MapInfo_Cache_Active = 0;
76 }
77
78 void MapInfo_Cache_Create()
79 {
80         MapInfo_Cache_Destroy();
81         _MapInfo_Cache_DB_NameToIndex = db_create();
82         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
83         _MapInfo_Cache_Active = 1;
84 }
85
86 void MapInfo_Cache_Invalidate()
87 {
88         if(!_MapInfo_Cache_Active)
89                 return;
90
91         MapInfo_Cache_Create();
92 }
93
94 void MapInfo_Cache_Store()
95 {
96         float i;
97         string s;
98         if(!_MapInfo_Cache_Active)
99                 return;
100
101         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
102         if(!s) // empty string is NOT valid here!
103         {
104                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
105                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
106         }
107         else
108                 i = stof(s);
109
110         // now store all the stuff
111         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
112         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
113         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
114         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
115         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
116         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
117         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
118 }
119
120 float MapInfo_Cache_Retrieve(string map)
121 {
122         float i;
123         string s;
124         if(!_MapInfo_Cache_Active)
125                 return 0;
126
127         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
128         if(!s)
129                 return 0;
130         i = stof(s);
131
132         // now retrieve all the stuff
133         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
134         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
135         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
136         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
137         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
138         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
139         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
140         return 1;
141 }
142
143 // GLOB HANDLING (for all BSP files)
144 float _MapInfo_globopen;
145 float _MapInfo_globcount; 
146 float _MapInfo_globhandle;
147 string _MapInfo_GlobItem(float i)
148 {
149         string s;
150         s = search_getfilename(_MapInfo_globhandle, i);
151         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
152 }
153
154 void MapInfo_Enumerate()
155 {
156         if(_MapInfo_globopen)
157                 search_end(_MapInfo_globhandle);
158         MapInfo_Cache_Invalidate();
159         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
160         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
161         _MapInfo_globopen = 1;
162 }
163
164 // filter the info by game type mask (updates MapInfo_count)
165 //
166 float _MapInfo_filtered;
167 float _MapInfo_filtered_allocated;
168 float MapInfo_FilterList_Lookup(float i)
169 {
170         return stof(bufstr_get(_MapInfo_filtered, i));
171 }
172
173 void _MapInfo_FilterList_swap(float i, float j, entity pass)
174 {
175         string h;
176         h = bufstr_get(_MapInfo_filtered, i);
177         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
178         bufstr_set(_MapInfo_filtered, j, h);
179 }
180
181 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
182 {
183         string a, b;
184         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
185         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
186         return strcasecmp(a, b);
187 }
188
189 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
190 {
191         float i, j;
192         if not(_MapInfo_filtered_allocated)
193         {
194                 _MapInfo_filtered_allocated = 1;
195                 _MapInfo_filtered = buf_create();
196         }
197         MapInfo_count = 0;
198         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
199         {
200                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
201                         if(pAbortOnGenerate)
202                         {
203                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
204                                 MapInfo_progress = i / _MapInfo_globcount;
205                                 return 0;
206                         }
207                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
208                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
209                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
210                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
211                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
212         }
213         MapInfo_count = j + 1;
214         MapInfo_ClearTemps();
215         
216         // sometimes the glob isn't sorted nicely, so fix it here...
217         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
218
219         return 1;
220 }
221
222 void MapInfo_Filter_Free()
223 {
224         if(_MapInfo_filtered_allocated)
225         {
226                 buf_del(_MapInfo_filtered);
227                 _MapInfo_filtered_allocated = 0;
228         }
229 }
230
231 // load info about the i-th map into the MapInfo_Map_* globals
232 string MapInfo_BSPName_ByID(float i)
233 {
234         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
235 }
236
237 string unquote(string s)
238 {
239         float i, j, l;
240         l = strlen(s);
241         j = -1;
242         for(i = 0; i < l; ++i)
243         {
244                 string ch;
245                 ch = substring(s, i, 1);
246                 if(ch != " ") if(ch != "\"")
247                 {
248                         for(j = strlen(s) - i - 1; j > 0; --j)
249                         {
250                                 ch = substring(s, i+j, 1);
251                                 if(ch != " ") if(ch != "\"")
252                                         return substring(s, i, j+1);
253                         }
254                         return substring(s, i, 1);
255                 }
256         }
257         return "";
258 }
259
260 float MapInfo_Get_ByID(float i)
261 {
262         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
263                 return 1;
264         return 0;
265 }
266
267 string _MapInfo_Map_worldspawn_music;
268
269 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
270 {
271         string fn;
272         float fh;
273         string s, k, v;
274         vector o;
275         float i;
276         float inWorldspawn;
277         float r;
278         float twoBaseModes;
279         float diameter, spawnpoints;
280         float spawnplaces;
281
282         vector mapMins, mapMaxs;
283
284         r = 1;
285         fn = strcat("maps/", pFilename, ".ent");
286         fh = fopen(fn, FILE_READ);
287         if(fh < 0)
288         {
289                 r = 2;
290                 fn = strcat("maps/", pFilename, ".bsp");
291                 fh = fopen(fn, FILE_READ);
292         }
293         if(fh < 0)
294                 return 0;
295         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
296
297         inWorldspawn = 2;
298         MapInfo_Map_flags = 0;
299         MapInfo_Map_supportedGametypes = 0;
300         spawnpoints = 0;
301         spawnplaces = 0;
302         _MapInfo_Map_worldspawn_music = "";
303
304         for(;;)
305         {
306                 if not((s = fgets(fh)))
307                         break;
308                 if(inWorldspawn == 1)
309                         if(startsWith(s, "}"))
310                                 inWorldspawn = 0;
311                 k = unquote(car(s));
312                 v = unquote(cdr(s));
313                 if(inWorldspawn)
314                 {
315                         if(k == "classname" && v == "worldspawn")
316                                 inWorldspawn = 1;
317                         else if(k == "author")
318                                 MapInfo_Map_author = v;
319                         else if(k == "_description")
320                                 MapInfo_Map_description = v;
321                         else if(k == "music")
322                                 _MapInfo_Map_worldspawn_music = v;
323                         else if(k == "noise")
324                                 _MapInfo_Map_worldspawn_music = v;
325                         else if(k == "message")
326                         {
327                                 i = strstrofs(v, " by ", 0);
328                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
329                                 {
330                                         MapInfo_Map_title = substring(v, 0, i);
331                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
332                                 }
333                                 else
334                                         MapInfo_Map_title = v;
335                         }
336                 }
337                 else
338                 {
339                         if(k == "origin")
340                         {
341                                 o = stov(strcat("'", v, "'"));
342                                 mapMins_x = min(mapMins_x, o_x);
343                                 mapMins_y = min(mapMins_y, o_y);
344                                 mapMins_z = min(mapMins_z, o_z);
345                                 mapMaxs_x = max(mapMaxs_x, o_x);
346                                 mapMaxs_y = max(mapMaxs_y, o_y);
347                                 mapMaxs_z = max(mapMaxs_z, o_z);
348                         }
349                         else if(k == "race_place")
350                         {
351                                 if(stof(v) > 0)
352                                         spawnplaces = 1;
353                         }
354                         else if(k == "classname")
355                         {
356                                 if(v == "dom_controlpoint")
357                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
358                                 else if(v == "item_flag_team2")
359                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
360                                 else if(v == "team_CTF_blueflag")
361                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
362                                 else if(v == "runematch_spawn_point")
363                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
364                                 else if(v == "target_assault_roundend")
365                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
366                                 else if(v == "onslaught_generator")
367                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
368                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
369                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
370                                 else if(v == "info_player_team1")
371                                         ++spawnpoints;
372                                 else if(v == "info_player_team2")
373                                         ++spawnpoints;
374                                 else if(v == "info_player_start")
375                                         ++spawnpoints;
376                                 else if(v == "info_player_deathmatch")
377                                         ++spawnpoints;
378                                 else if(v == "trigger_race_checkpoint")
379                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
380                                 else if(v == "weapon_nex")
381                                         { }
382                                 else if(v == "weapon_railgun")
383                                         { }
384                                 else if(startsWith(v, "weapon_"))
385                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
386                         }
387                 }
388         }
389         if(inWorldspawn)
390         {
391                 print(fn, " ended still in worldspawn, BUG\n");
392                 return 0;
393         }
394         diameter = vlen(mapMaxs - mapMins);
395
396         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
397         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
398         {
399                 // we have a CTF-only or Assault-only map. Don't add other modes then,
400                 // as the map is too symmetric for them.
401         }
402         else
403         {
404                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
405                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;       // Rune always works
406                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
407
408                 if(spawnpoints >= 8  && diameter > 4096)
409                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
410                 if(                     diameter < 4096)
411                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
412                 if(spawnpoints >= 12 && diameter > 5120)
413                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
414         }
415
416         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
417         if(!spawnplaces)
418         {
419                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
420                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
421         }
422
423         dprint("-> diameter ",    ftos(diameter));
424         dprint(";  spawnpoints ", ftos(spawnpoints));
425         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
426
427         fclose(fh);
428
429         return r;
430 }
431
432 void _MapInfo_Map_Reset()
433 {
434         MapInfo_Map_title = "<TITLE>";
435         MapInfo_Map_description = "<DESCRIPTION>";
436         MapInfo_Map_author = "<AUTHOR>";
437         MapInfo_Map_supportedGametypes = 0;
438         MapInfo_Map_supportedFeatures = 0;
439         MapInfo_Map_flags = 0;
440         MapInfo_Map_clientstuff = "";
441         MapInfo_Map_fog = "";
442         MapInfo_Map_mins = '0 0 0';
443         MapInfo_Map_maxs = '0 0 0';
444 }
445
446 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType)
447 {
448         string sa;
449         MapInfo_Map_supportedGametypes |= pThisType;
450         if(!(pThisType & pWantedType))
451                 return;
452         
453         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
454         {
455                 cvar_set("fraglimit", "0");
456         }
457         else
458         {
459                 cvar_set("fraglimit", car(s));
460                 s = cdr(s);
461         }
462
463         cvar_set("timelimit", car(s));
464         s = cdr(s);
465
466         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
467         {
468                 sa = car(s); if(sa == "") sa = "2";
469                 cvar_set("g_tdm_teams", sa);
470                 s = cdr(s);
471         }
472
473         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
474         {
475                 sa = car(s); if(sa == "") sa = "3";
476                 cvar_set("g_keyhunt_teams", sa);
477                 s = cdr(s);
478         }
479
480         if(pWantedType == MAPINFO_TYPE_CTF)
481         {
482                 sa = car(s); if(sa == "") sa = "10";
483                 if(cvar("g_ctf_win_mode") < 2)
484                         cvar_set("fraglimit", sa);
485                 s = cdr(s);
486         }
487
488         // rc = timelimit timelimit_qualification laps laps_teamplay
489         if(pWantedType == MAPINFO_TYPE_RACE)
490         {
491                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
492                 cvar_set("g_race_qualifying_timelimit", sa);
493                 s = cdr(s);
494
495                 sa = car(s); if(sa == "") sa = "10";
496                 if(cvar("g_race_teams") < 2)
497                         cvar_set("fraglimit", sa);
498                 s = cdr(s);
499
500                 sa = car(s); if(sa == "") sa = "20";
501                 if(cvar("g_race_teams") >= 2)
502                         cvar_set("fraglimit", sa);
503                 s = cdr(s);
504         }
505
506         if(pWantedType == MAPINFO_TYPE_CTS)
507         {
508                 sa = car(s); if(sa == "") sa = cvar_string("fraglimit");
509                 if(cvar("g_race_teams"))
510                         cvar_set("fraglimit", sa);
511                 s = cdr(s);
512         }
513
514         sa = car(s); if(sa == "") sa = "0";
515         cvar_set("leadlimit", sa);
516         s = cdr(s);
517 }
518
519 float MapInfo_Type_FromString(string t)
520 {
521         if     (t == "dm")      return MAPINFO_TYPE_DEATHMATCH;
522         else if(t == "tdm")     return MAPINFO_TYPE_TEAM_DEATHMATCH;
523         else if(t == "dom")     return MAPINFO_TYPE_DOMINATION;
524         else if(t == "ctf")     return MAPINFO_TYPE_CTF;
525         else if(t == "rune")    return MAPINFO_TYPE_RUNEMATCH;
526         else if(t == "lms")     return MAPINFO_TYPE_LMS;
527         else if(t == "arena")   return MAPINFO_TYPE_ARENA;
528         else if(t == "kh")      return MAPINFO_TYPE_KEYHUNT;
529         else if(t == "as")      return MAPINFO_TYPE_ASSAULT;
530         else if(t == "ons")     return MAPINFO_TYPE_ONSLAUGHT;
531         else if(t == "rc")      return MAPINFO_TYPE_RACE;
532         else if(t == "nexball") return MAPINFO_TYPE_NEXBALL;
533         else if(t == "cts")     return MAPINFO_TYPE_CTS;
534         else if(t == "all")     return MAPINFO_TYPE_ALL;
535         else                    return 0;
536 }
537
538 void _MapInfo_Parse_Settemp(string pFilename, string acl, string s, float recurse)
539 {
540         string t;
541         float fh;
542         t = car(s); s = cdr(s);
543         if(t == "#include")
544         {
545                 if(recurse > 0)
546                 {
547                         fh = fopen(s, FILE_READ);
548                         if(fh < 0)
549                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
550                         else
551                         {
552                                 for(;;)
553                                 {
554                                         if not((s = fgets(fh)))
555                                                 break;
556
557                                         // catch different sorts of comments
558                                         if(s == "")                    // empty lines
559                                                 continue;
560                                         if(substring(s, 0, 1) == "#")  // UNIX style
561                                                 continue;
562                                         if(substring(s, 0, 2) == "//") // C++ style
563                                                 continue;
564                                         if(substring(s, 0, 1) == "_")  // q3map style
565                                                 continue;
566
567                                         _MapInfo_Parse_Settemp(pFilename, acl, s, recurse - 1);
568                                 }
569                                 fclose(fh);
570                         }
571                 }
572                 else
573                         print("Map ", pFilename, " uses too many levels of inclusion\n");
574         }
575         else if not(cvar_value_issafe(t))
576                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
577         else if not (cvar_value_issafe(s))
578                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
579         else if(substring(t, 0, 10) == "g_mapinfo_")
580                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
581         else if(matchacl(acl, t) <= 0)
582                 print("Map ", pFilename, " contains a denied setting, ignored\n");
583         else
584         {
585                 dprint("Applying temporary setting ", t, " := ", s, "\n");
586                 if(cvar("g_campaign"))
587                         cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
588                 else
589                         cvar_settemp(t, s);
590         }
591 }
592
593 // load info about a map by name into the MapInfo_Map_* globals
594 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
595 {
596         string fn;
597         string s, t;
598         float fh, fh2;
599         float r, f, n, i;
600         string acl;
601
602         acl = cvar_string("g_mapinfo_settemp_acl");
603
604         if(strstrofs(pFilename, "/", 0) >= 0)
605         {
606                 print("Invalid character in map name, ignored\n");
607                 return 0;
608         }
609
610         if(pGametypeToSet == 0)
611                 if(MapInfo_Cache_Retrieve(pFilename))
612                         return 1;
613
614         r = 1;
615
616         MapInfo_Map_bspname = pFilename;
617
618         // default all generic fields so they have "good" values in case something fails
619         fn = strcat("maps/", pFilename, ".mapinfo");
620         fh = fopen(fn, FILE_READ);
621         if(fh < 0)
622         {
623                 if(!pAllowGenerate)
624                         return 0;
625                 _MapInfo_Map_Reset();
626                 r = _MapInfo_Generate(pFilename);
627                 if(!r)
628                         return 0;
629                 fh = fopen(fn, FILE_WRITE);
630                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
631                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
632                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
633                 if(_MapInfo_Map_worldspawn_music != "")
634                 {
635                         if(
636                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
637                                 ||
638                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
639                         )
640                                 fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
641                         else
642                                 fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
643                 }
644                 else
645                 {
646                         n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
647                         s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
648                         for(;;)
649                         {
650                                 i = floor(random() * n);
651                                 if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
652                                         break;
653                         }
654                         fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
655                 }
656                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
657                         fputs(fh, "has weapons\n");
658                 else
659                         fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
660                 if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
661                         fputs(fh, "frustrating\n");
662                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)      fputs(fh, "type dm 30 20\n");
663                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH) fputs(fh, "type tdm 50 20 2\n");
664                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DOMINATION)      fputs(fh, "type dom 200 20\n");
665                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTF)             fputs(fh, "type ctf 300 20 10\n");
666                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RUNEMATCH)       fputs(fh, "type rune 200 20\n");
667                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_LMS)             fputs(fh, "type lms 9 20\n");
668                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ARENA)           fputs(fh, "type arena 10 20\n");
669                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_KEYHUNT)         fputs(fh, "type kh 1000 20 3\n");
670                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ASSAULT)         fputs(fh, "type as 20\n");
671                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)            fputs(fh, "type rc 20 5 7 15\n");
672                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ONSLAUGHT)       fputs(fh, "type ons 20\n");
673                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_NEXBALL)         fputs(fh, "type nexball 5 20\n");
674                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTS)             fputs(fh, "type cts 20 -1\n");
675
676                 fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
677                 if(fh2 >= 0)
678                 {
679                         fclose(fh2);
680                         fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
681                 }
682
683                 fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
684                 fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
685                 fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
686                 fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
687                 fputs(fh, "// optional: hidden\n");
688
689                 fclose(fh);
690                 r = 2;
691                 // return r;
692                 fh = fopen(fn, FILE_READ);
693                 if(fh < 0)
694                         error("... but I just wrote it!");
695         }
696
697         _MapInfo_Map_Reset();
698         for(;;)
699         {
700                 if not((s = fgets(fh)))
701                         break;
702
703                 // catch different sorts of comments
704                 if(s == "")                    // empty lines
705                         continue;
706                 if(substring(s, 0, 1) == "#")  // UNIX style
707                         continue;
708                 if(substring(s, 0, 2) == "//") // C++ style
709                         continue;
710                 if(substring(s, 0, 1) == "_")  // q3map style
711                         continue;
712
713                 t = car(s); s = cdr(s);
714                 if(t == "title")
715                         MapInfo_Map_title = s;
716                 else if(t == "description")
717                         MapInfo_Map_description = s;
718                 else if(t == "author")
719                         MapInfo_Map_author = s;
720                 else if(t == "has")
721                 {
722                         t = car(s); s = cdr(s);
723                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
724                         else
725                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
726                 }
727                 else if(t == "hidden")
728                 {
729                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
730                 }
731                 else if(t == "forbidden")
732                 {
733                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
734                 }
735                 else if(t == "frustrating")
736                 {
737                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
738                 }
739                 else if(t == "type")
740                 {
741                         t = car(s); s = cdr(s);
742                         f = MapInfo_Type_FromString(t);
743                         if(f)
744                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f);
745                         else
746                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
747                 }
748                 else if(t == "size")
749                 {
750                         float a, b, c, d, e;
751                         t = car(s); s = cdr(s); a = stof(t);
752                         t = car(s); s = cdr(s); b = stof(t);
753                         t = car(s); s = cdr(s); c = stof(t);
754                         t = car(s); s = cdr(s); d = stof(t);
755                         t = car(s); s = cdr(s); e = stof(t);
756                         if(s == "")
757                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
758                         else
759                         {
760                                 t = car(s); s = cdr(s); f = stof(t);
761                                 if(s != "")
762                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
763                                 else
764                                 {
765                                         if(a >= d || b >= e || c >= f)
766                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
767                                         else
768                                         {
769                                                 MapInfo_Map_mins_x = a;
770                                                 MapInfo_Map_mins_y = b;
771                                                 MapInfo_Map_mins_z = c;
772                                                 MapInfo_Map_maxs_x = d;
773                                                 MapInfo_Map_maxs_y = e;
774                                                 MapInfo_Map_maxs_z = f;
775                                         }
776                                 }
777                         }
778                 }
779                 else if(t == "settemp_for_type")
780                 {
781                         t = car(s); s = cdr(s);
782                         if((f = MapInfo_Type_FromString(t)))
783                         {
784                                 if(f & pGametypeToSet)
785                                 {
786                                         _MapInfo_Parse_Settemp(pFilename, acl, s, 1);
787                                 }
788                         }
789                         else
790                         {
791                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
792                         }
793                 }
794                 else if(t == "clientsettemp_for_type")
795                 {
796                         t = car(s); s = cdr(s);
797                         if((f = MapInfo_Type_FromString(t)))
798                         {
799                                 if(f & pGametypeToSet)
800                                 {
801                                         t = car(s); s = cdr(s);
802                                         if not(cvar_value_issafe(t))
803                                                 print("Map ", pFilename, " contains a potentially harmful client setting, ignored\n");
804                                         else if not (cvar_value_issafe(s))
805                                                 print("Map ", pFilename, " contains a potentially harmful client setting, ignored\n");
806                                         else
807                                         {
808                                                 dprint("Applying temporary client setting ", t, " := ", s, "\n");
809                                                 MapInfo_Map_clientstuff = strcat(
810                                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
811                                                 );
812                                         }
813                                 }
814                         }
815                         else
816                         {
817                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
818                         }
819                 }
820                 else if(t == "fog")
821                 {
822                         if not(cvar_value_issafe(t))
823                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
824                         else
825                                 MapInfo_Map_fog = s;
826                 }
827                 else if(t == "cdtrack")
828                 {
829                         if(pGametypeToSet)
830                         {
831                                 if not(cvar_value_issafe(t))
832                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
833                                 else
834                                         MapInfo_Map_clientstuff = strcat(
835                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
836                                         );
837                         }
838                 }
839                 else
840                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
841         }
842         fclose(fh);
843
844         if(!MapInfo_Map_supportedGametypes)
845                 _MapInfo_Map_ApplyGametype("30 20", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
846
847         if(pGametypeToSet)
848                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
849                         error("Can't select the requested game type. Bailing out.");
850         MapInfo_Cache_Store();
851         if(MapInfo_Map_supportedGametypes != 0)
852                 return r;
853         dprint("Map ", pFilename, " supports no game types, ignored\n");
854         return 0;
855 }
856
857 float MapInfo_FindName(string s)
858 {
859         // if there is exactly one map of prefix s, return it
860         // if not, return the null string
861         // note that DP sorts glob results... so I can use a binary search
862         float l, r, m, cmp;
863         l = 0;
864         r = MapInfo_count;
865         // invariants: r is behind s, l-1 is equal or before
866         while(l != r)
867         {
868                 m = floor((l + r) / 2);
869                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
870                 cmp = strcasecmp(MapInfo_FindName_match, s);
871                 if(cmp == 0)
872                         return m; // found and good
873                 if(cmp < 0)
874                         l = m + 1; // l-1 is before s
875                 else
876                         r = m; // behind s
877         }
878         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
879         MapInfo_FindName_firstResult = l;
880         // r == l, so: l is behind s, l-1 is before
881         // SO: if there is any, l is the one with the right prefix
882         //     and l+1 may be one too
883         if(l == MapInfo_count)
884         {
885                 MapInfo_FindName_match = string_null;
886                 MapInfo_FindName_firstResult = -1;
887                 return -1; // no MapInfo_FindName_match, behind last item
888         }
889         if(!startsWithNocase(MapInfo_FindName_match, s))
890         {
891                 MapInfo_FindName_match = string_null;
892                 MapInfo_FindName_firstResult = -1;
893                 return -1; // wrong prefix
894         }
895         if(l == MapInfo_count - 1)
896                 return l; // last one, nothing can follow => unique
897         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
898         {
899                 MapInfo_FindName_match = string_null;
900                 return -1; // ambigous MapInfo_FindName_match
901         }
902         return l;
903 }
904
905 string MapInfo_FixName(string s)
906 {
907         MapInfo_FindName(s);
908         return MapInfo_FindName_match;
909 }
910
911 float MapInfo_CurrentFeatures()
912 {
913         float req;
914         req = 0;
915         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_minstagib") || cvar("g_nixnex") || cvar("g_rocketarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
916                 req |= MAPINFO_FEATURE_WEAPONS;
917         return req;
918 }
919
920 float MapInfo_CurrentGametype()
921 {
922         if(cvar("g_domination"))
923                 return MAPINFO_TYPE_DOMINATION;
924         else if(cvar("g_ctf"))
925                 return MAPINFO_TYPE_CTF;
926         else if(cvar("g_runematch"))
927                 return MAPINFO_TYPE_RUNEMATCH;
928         else if(cvar("g_tdm"))
929                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
930         else if(cvar("g_assault"))
931                 return MAPINFO_TYPE_ASSAULT;
932         else if(cvar("g_lms"))
933                 return MAPINFO_TYPE_LMS;
934         else if(cvar("g_arena"))
935                 return MAPINFO_TYPE_ARENA;
936         else if(cvar("g_keyhunt"))
937                 return MAPINFO_TYPE_KEYHUNT;
938         else if(cvar("g_onslaught"))
939                 return MAPINFO_TYPE_ONSLAUGHT;
940         else if(cvar("g_race"))
941                 return MAPINFO_TYPE_RACE;
942         else if(cvar("g_nexball"))
943                 return MAPINFO_TYPE_NEXBALL;
944         else if(cvar("g_cts"))
945                 return MAPINFO_TYPE_CTS;
946         else
947                 return MAPINFO_TYPE_DEATHMATCH;
948 }
949
950 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
951 {
952         if(!MapInfo_Get_ByName(s, 1, 0))
953                 return 0;
954         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
955                 return 0;
956         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
957                 return 0;
958         return 1;
959 }
960
961 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
962 {
963         float r;
964         r = _MapInfo_CheckMap(s);
965         MapInfo_ClearTemps();
966         return r;
967 }
968
969 string MapInfo_GetGameTypeCvar(float t)
970 {
971         switch(t)
972         {
973                 case MAPINFO_TYPE_DEATHMATCH: return "g_dm";
974                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "g_tdm";
975                 case MAPINFO_TYPE_DOMINATION: return "g_domination";
976                 case MAPINFO_TYPE_CTF: return "g_ctf";
977                 case MAPINFO_TYPE_RUNEMATCH: return "g_runematch";
978                 case MAPINFO_TYPE_LMS: return "g_lms";
979                 case MAPINFO_TYPE_ARENA: return "g_arena";
980                 case MAPINFO_TYPE_KEYHUNT: return "g_kh";
981                 case MAPINFO_TYPE_ASSAULT: return "g_assault";
982                 case MAPINFO_TYPE_ONSLAUGHT: return "g_onslaught";
983                 case MAPINFO_TYPE_RACE: return "g_race";
984                 case MAPINFO_TYPE_NEXBALL: return "g_nexball";
985                 case MAPINFO_TYPE_CTS: return "g_cts";
986                 default: return "";
987         }
988 }
989
990 void MapInfo_SwitchGameType(float t)
991 {
992         cvar_set("gamecfg",      "0");
993         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
994         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
995         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
996         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
997         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
998         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
999         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
1000         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
1001         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
1002         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
1003         cvar_set("g_race",       (t == MAPINFO_TYPE_RACE)            ? "1" : "0");
1004         cvar_set("g_nexball",    (t == MAPINFO_TYPE_NEXBALL)         ? "1" : "0");
1005         cvar_set("g_cts",        (t == MAPINFO_TYPE_CTS)             ? "1" : "0");
1006 }
1007
1008 void MapInfo_LoadMap(string s)
1009 {
1010         MapInfo_Map_supportedGametypes = 0;
1011         if(!MapInfo_CheckMap(s))
1012         {
1013                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1014                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1015         }
1016         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
1017 }
1018
1019 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1020 {
1021         string out;
1022         float i;
1023
1024         // to make absolutely sure:
1025         MapInfo_Enumerate();
1026         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1027
1028         out = "";
1029         for(i = 0; i < MapInfo_count; ++i)
1030                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1031         return substring(out, 1, strlen(out) - 1);
1032 }
1033
1034 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1035 {
1036         float t;
1037         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1038         {
1039                 if(MapInfo_Map_supportedGametypes <= 0)
1040                         error("Mapinfo system is not functional at all. BAILED OUT.\n");
1041
1042                 t = 1;
1043                 while(!(MapInfo_Map_supportedGametypes & 1))
1044                 {
1045                         t *= 2;
1046                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1047                 }
1048                 // t is now a supported mode!
1049                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1050                 MapInfo_SwitchGameType(t);
1051         }
1052         cvar_settemp_restore();
1053         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
1054 }
1055
1056 void MapInfo_ClearTemps()
1057 {
1058         MapInfo_Map_bspname = string_null;
1059         MapInfo_Map_title = string_null;
1060         MapInfo_Map_description = string_null;
1061         MapInfo_Map_author = string_null;
1062         MapInfo_Map_clientstuff = string_null;
1063         MapInfo_Map_supportedGametypes = 0;
1064         MapInfo_Map_supportedFeatures = 0;
1065 }
1066
1067 void MapInfo_Shutdown()
1068 {
1069         MapInfo_ClearTemps();
1070         MapInfo_Filter_Free();
1071         MapInfo_Cache_Destroy();
1072         if(_MapInfo_globopen)
1073         {
1074                 search_end(_MapInfo_globhandle);
1075                 _MapInfo_globhandle = -1;
1076                 _MapInfo_globopen = FALSE;
1077         }
1078 }
1079
1080 float MapInfo_ForbiddenFlags()
1081 {
1082         float f;
1083         f = MAPINFO_FLAG_FORBIDDEN;
1084
1085 #ifndef MENUQC
1086         if not(cvar("g_maplist_allow_hidden"))
1087 #endif
1088                 f |= MAPINFO_FLAG_HIDDEN;
1089
1090         if not(cvar("g_maplist_allow_frustrating"))
1091                 f |= MAPINFO_FLAG_FRUSTRATING;
1092
1093         return f;
1094 }
1095
1096 float MapInfo_RequiredFlags()
1097 {
1098         float f;
1099         f = 0;
1100
1101         if(cvar("g_maplist_allow_frustrating") > 1)
1102                 f |= MAPINFO_FLAG_FRUSTRATING;
1103
1104         return f;
1105 }