data/qcsrc/common/mapinfo.qc

   1 #ifdef HSOI
   2 // HUGE SET - stored in a string
   3 string HugeSetOfIntegers_empty()
   4 {
   5         return "";
   6 }
   7 float HugeSetOfIntegers_get(string pArr, float i)
   8 {
   9         return stof(substring(pArr, i * 4, 4));
  10 }
  11 float HugeSetOfIntegers_length(string pArr)
  12 {
  13         return strlen(pArr) / 4;
  14 }
  15 string HugeSetOfIntegers_concat(string a1, string a2)
  16 {
  17         return strcat(a1, a2);
  18 }
  19 string HugeSetOfIntegers_insert(string a1, float n, string a2)
  20         // special concat function to build up large lists in less time by binary concatenation
  21 {
  22         string s;
  23         s = strcat("    ", ftos(n));
  24         return strcat(a1, substring(s, strlen(s) - 4, 4), a2);
  25 }
  26 #endif
  27
  28 // generic string stuff
  29 float startsWith(string haystack, string needle)
  30 {
  31         return substring(haystack, 0, strlen(needle)) == needle;
  32 }
  33 float startsWithNocase(string haystack, string needle)
  34 {
  35         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
  36 }
  37 string extractRestOfLine(string haystack, string needle)
  38 {
  39         if(startsWith(haystack, needle))
  40                 return substring(haystack, strlen(needle), strlen(haystack) - strlen(needle));
  41         return string_null;
  42 }
  43 string car(string s)
  44 {
  45         float o;
  46         o = strstrofs(s, " ", 0);
  47         if(o < 0)
  48                 return s;
  49         return substring(s, 0, o);
  50 }
  51 string cdr(string s)
  52 {
  53         float o;
  54         o = strstrofs(s, " ", 0);
  55         if(o < 0)
  56                 return string_null;
  57         return substring(s, o + 1, strlen(s) - (o + 1));
  58 }
  59
  60 float _MapInfo_Cache_Active;
  61 float _MapInfo_Cache_DB_NameToIndex;
  62 float _MapInfo_Cache_Buf_IndexToMapData;
  63
  64 void MapInfo_Cache_Destroy()
  65 {
  66         if(!_MapInfo_Cache_Active)
  67                 return;
  68
  69         db_close(_MapInfo_Cache_DB_NameToIndex);
  70         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  71         _MapInfo_Cache_Active = 0;
  72 }
  73
  74 void MapInfo_Cache_Create()
  75 {
  76         MapInfo_Cache_Destroy();
  77         _MapInfo_Cache_DB_NameToIndex = db_create();
  78         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  79         _MapInfo_Cache_Active = 1;
  80 }
  81
  82 void MapInfo_Cache_Invalidate()
  83 {
  84         if(!_MapInfo_Cache_Active)
  85                 return;
  86
  87         MapInfo_Cache_Create();
  88 }
  89
  90 void MapInfo_Cache_Store()
  91 {
  92         float i;
  93         string s;
  94         if(!_MapInfo_Cache_Active)
  95                 return;
  96
  97         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  98         if(!s) // empty string is NOT valid here!
  99         {
 100                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
 101                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
 102         }
 103         else
 104                 i = stof(s);
 105
 106         // now store all the stuff
 107         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
 108         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
 109         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
 110         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
 111         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
 112         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
 113         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
 114 }
 115
 116 float MapInfo_Cache_Retrieve(string map)
 117 {
 118         float i;
 119         string s;
 120         if(!_MapInfo_Cache_Active)
 121                 return 0;
 122
 123         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
 124         if(!s)
 125                 return 0;
 126         i = stof(s);
 127
 128         // now retrieve all the stuff
 129         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
 130         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 131         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 132         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 133         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 134         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 135         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 136         return 1;
 137 }
 138
 139 // GLOB HANDLING (for all BSP files)
 140 float _MapInfo_globopen;
 141 float _MapInfo_globcount;
 142 float _MapInfo_globhandle;
 143 string _MapInfo_GlobItem(float i)
 144 {
 145         string s;
 146         s = search_getfilename(_MapInfo_globhandle, i);
 147         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 148 }
 149
 150 void MapInfo_Enumerate()
 151 {
 152         if(_MapInfo_globopen)
 153                 search_end(_MapInfo_globhandle);
 154         MapInfo_Cache_Invalidate();
 155         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 156         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 157         _MapInfo_globopen = 1;
 158 }
 159
 160 // filter the info by game type mask (updates MapInfo_count)
 161 //
 162 #ifdef HSOI
 163 string _MapInfo_filtered;
 164 float MapInfo_FilterList_Lookup(float i)
 165 {
 166         return MapInfo_FilterList_Lookup(i);
 167 }
 168
 169 string MapInfo_FilterGametype_Recursive(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pBegin, float pEnd, float pAbortOnGenerate)
 170 {
 171         float m, valid;
 172         string l, r;
 173
 174         if(pBegin == pEnd)
 175                 return HugeSetOfIntegers_empty();
 176
 177         m = floor((pBegin + pEnd) / 2);
 178
 179         l = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pBegin, m, pAbortOnGenerate);
 180         if not(l)
 181                 return string_null; // BAIL OUT
 182         if(MapInfo_Get_ByName(_MapInfo_GlobItem(m), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 183                 if(pAbortOnGenerate)
 184                 {
 185                         MapInfo_progress = m / _MapInfo_globcount;
 186                         return string_null; // BAIL OUT
 187                 }
 188         valid = (((MapInfo_Map_supportedGametypes & pGametype) != 0);
 189         valid = valid && ((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures));
 190         valid = valid && (MapInfo_Map_flags & pFlagsForbidden == 0);
 191         valid = valid && (MapInfo_Map_flags & pFlagsRequired == pFlagsRequired);
 192         r = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pFlagsRequired, pFlagsForbidden, m + 1, pEnd, pAbortOnGenerate);
 193         if not(r)
 194                 return string_null; // BAIL OUT
 195
 196         if(valid)
 197                 return HugeSetOfIntegers_insert(l, m, r);
 198         else
 199                 return HugeSetOfIntegers_concat(l, r);
 200 }
 201
 202 float MapInfo_FilterGametype(float pGametype, float pFeatures, pFlagsRequired, pFlagsForbidden, float pAbortOnGenerate)
 203 {
 204         if(_MapInfo_filtered)
 205                 strunzone(_MapInfo_filtered);
 206         _MapInfo_filtered = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pFlagsRequired, pFlagsForbidden, 0, _MapInfo_globcount, pAbortOnGenerate);
 207         if not(_MapInfo_filtered)
 208         {
 209                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 210                 return 0;
 211         }
 212         _MapInfo_filtered = strzone(_MapInfo_filtered);
 213         MapInfo_count = HugeSetOfIntegers_length(_MapInfo_filtered);
 214         MapInfo_ClearTemps();
 215         return 1;
 216 }
 217
 218 void MapInfo_Filter_Free()
 219 {
 220         if(_MapInfo_filtered)
 221         {
 222                 strunzone(_MapInfo_filtered);
 223                 _MapInfo_filtered = string_null;
 224         }
 225 }
 226 #else
 227 float _MapInfo_filtered;
 228 float _MapInfo_filtered_allocated;
 229 float MapInfo_FilterList_Lookup(float i)
 230 {
 231         return stof(bufstr_get(_MapInfo_filtered, i));
 232 }
 233
 234 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 235 {
 236         float i, j;
 237         if not(_MapInfo_filtered_allocated)
 238         {
 239                 _MapInfo_filtered_allocated = 1;
 240                 _MapInfo_filtered = buf_create();
 241         }
 242         MapInfo_count = 0;
 243         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 244         {
 245                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 246                         if(pAbortOnGenerate)
 247                         {
 248                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 249                                 MapInfo_progress = i / _MapInfo_globcount;
 250                                 return 0;
 251                         }
 252                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 253                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 254                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 255                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 256                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 257         }
 258         MapInfo_count = j + 1;
 259         MapInfo_ClearTemps();
 260         return 1;
 261 }
 262
 263 void MapInfo_Filter_Free()
 264 {
 265         if(_MapInfo_filtered_allocated)
 266         {
 267                 buf_del(_MapInfo_filtered);
 268                 _MapInfo_filtered_allocated = 0;
 269         }
 270 }
 271 #endif
 272
 273 // load info about the i-th map into the MapInfo_Map_* globals
 274 string MapInfo_BSPName_ByID(float i)
 275 {
 276         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 277 }
 278
 279 string unquote(string s)
 280 {
 281         float i, j, l;
 282         l = strlen(s);
 283         j = -1;
 284         for(i = 0; i < l; ++i)
 285         {
 286                 string ch;
 287                 ch = substring(s, i, 1);
 288                 if(ch != " ") if(ch != "\"")
 289                 {
 290                         for(j = strlen(s) - i - 1; j > 0; --j)
 291                         {
 292                                 ch = substring(s, i+j, 1);
 293                                 if(ch != " ") if(ch != "\"")
 294                                         return substring(s, i, j+1);
 295                         }
 296                         return substring(s, i, 1);
 297                 }
 298         }
 299         return "";
 300 }
 301
 302 float MapInfo_Get_ByID(float i)
 303 {
 304         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 305                 return 1;
 306         return 0;
 307 }
 308
 309 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 310 {
 311         string fn;
 312         float fh;
 313         string s, k, v;
 314         vector o;
 315         float i;
 316         float inWorldspawn;
 317         float r;
 318         float twoBaseModes;
 319         float diameter, spawnpoints;
 320
 321         vector mapMins, mapMaxs;
 322
 323         r = 1;
 324         fn = strcat("maps/", pFilename, ".ent");
 325         fh = fopen(fn, FILE_READ);
 326         if(fh < 0)
 327         {
 328                 r = 2;
 329                 fn = strcat("maps/", pFilename, ".bsp");
 330                 fh = fopen(fn, FILE_READ);
 331         }
 332         if(fh < 0)
 333                 return 0;
 334         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
 335
 336         inWorldspawn = 2;
 337         MapInfo_Map_supportedGametypes = 0;
 338         spawnpoints = 0;
 339
 340         for(;;)
 341         {
 342                 if not((s = fgets(fh)))
 343                         break;
 344                 if(inWorldspawn == 1)
 345                         if(startsWith(s, "}"))
 346                                 inWorldspawn = 0;
 347                 k = unquote(car(s));
 348                 v = unquote(cdr(s));
 349                 if(inWorldspawn)
 350                 {
 351                         if(k == "classname" && v == "worldspawn")
 352                                 inWorldspawn = 1;
 353                         else if(k == "author")
 354                                 MapInfo_Map_author = v;
 355                         else if(k == "_description")
 356                                 MapInfo_Map_description = v;
 357                         else if(k == "message")
 358                         {
 359                                 i = strstrofs(v, " by ", 0);
 360                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 361                                 {
 362                                         MapInfo_Map_title = substring(v, 0, i);
 363                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 364                                 }
 365                                 else
 366                                         MapInfo_Map_title = v;
 367                         }
 368                 }
 369                 else
 370                 {
 371                         if(k == "origin")
 372                         {
 373                                 o = stov(strcat("'", v, "'"));
 374                                 mapMins_x = min(mapMins_x, o_x);
 375                                 mapMins_y = min(mapMins_y, o_y);
 376                                 mapMins_z = min(mapMins_z, o_z);
 377                                 mapMaxs_x = max(mapMaxs_x, o_x);
 378                                 mapMaxs_y = max(mapMaxs_y, o_y);
 379                                 mapMaxs_z = max(mapMaxs_z, o_z);
 380                         }
 381                         else if(k == "classname")
 382                         {
 383                                 if(v == "dom_controlpoint")
 384                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 385                                 else if(v == "item_flag_team2")
 386                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 387                                 else if(v == "team_CTF_blueflag")
 388                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 389                                 else if(v == "runematch_spawn_point")
 390                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 391                                 else if(v == "target_assault_roundend")
 392                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 393                                 else if(v == "onslaught_generator")
 394                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 395                                 else if(v == "info_player_team1")
 396                                         ++spawnpoints;
 397                                 else if(v == "info_player_team2")
 398                                         ++spawnpoints;
 399                                 else if(v == "info_player_start")
 400                                         ++spawnpoints;
 401                                 else if(v == "info_player_deathmatch")
 402                                         ++spawnpoints;
 403                                 else if(v == "trigger_race_checkpoint")
 404                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 405                                 else if(v == "weapon_nex")
 406                                         { }
 407                                 else if(v == "weapon_railgun")
 408                                         { }
 409                                 else if(startsWith(v, "weapon_"))
 410                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 411                         }
 412                 }
 413         }
 414         if(inWorldspawn)
 415         {
 416                 print(fn, " ended still in worldspawn, BUG\n");
 417                 return 0;
 418         }
 419         diameter = vlen(mapMaxs - mapMins);
 420
 421         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE);
 422         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 423         {
 424                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 425                 // as the map is too symmetric for them.
 426         }
 427         else
 428         {
 429                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 430                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 431
 432                 if(spawnpoints >= 8  && diameter > 4096)
 433                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 434                 if(                     diameter < 4096)
 435                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 436                 if(spawnpoints >= 12 && diameter > 5120)
 437                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 438         }
 439
 440         dprint("-> diameter ",    ftos(diameter));
 441         dprint(";  spawnpoints ", ftos(spawnpoints));
 442         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 443
 444         fclose(fh);
 445
 446         return r;
 447 }
 448
 449 void _MapInfo_Map_Reset()
 450 {
 451         MapInfo_Map_title = "<TITLE>";
 452         MapInfo_Map_description = "<DESCRIPTION>";
 453         MapInfo_Map_author = "<AUTHOR>";
 454         MapInfo_Map_supportedGametypes = 0;
 455         MapInfo_Map_supportedFeatures = 0;
 456         MapInfo_Map_flags = 0;
 457         MapInfo_Map_clientstuff = "";
 458         MapInfo_Map_fog = "";
 459         MapInfo_Map_mins = '0 0 0';
 460         MapInfo_Map_maxs = '0 0 0';
 461 }
 462
 463 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType)
 464 {
 465         string sa;
 466         MapInfo_Map_supportedGametypes |= pThisType;
 467         if(!(pThisType & pWantedType))
 468                 return;
 469
 470         cvar_set("fraglimit", car(s));
 471         s = cdr(s);
 472
 473         cvar_set("timelimit", car(s));
 474         s = cdr(s);
 475
 476         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 477         {
 478                 sa = car(s); if(sa == "") sa = "2";
 479                 cvar_set("g_tdm_teams", sa);
 480                 s = cdr(s);
 481         }
 482
 483         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 484         {
 485                 sa = car(s); if(sa == "") sa = "3";
 486                 cvar_set("g_keyhunt_teams", sa);
 487                 s = cdr(s);
 488         }
 489
 490         if(pWantedType == MAPINFO_TYPE_CTF)
 491         {
 492                 sa = car(s); if(sa == "") sa = "10";
 493                 if(cvar("g_ctf_win_mode") < 2)
 494                         cvar_set("fraglimit", sa);
 495                 s = cdr(s);
 496         }
 497
 498         if(pWantedType == MAPINFO_TYPE_RACE)
 499         {
 500                 sa = car(s); if(sa == "") sa = cvar_string("fraglimit");
 501                 if(cvar("g_race_teams"))
 502                         cvar_set("fraglimit", sa);
 503                 s = cdr(s);
 504         }
 505 }
 506
 507 float MapInfo_Type_FromString(string t)
 508 {
 509         if     (t == "dm")    return MAPINFO_TYPE_DEATHMATCH;
 510         else if(t == "tdm")   return MAPINFO_TYPE_TEAM_DEATHMATCH;
 511         else if(t == "dom")   return MAPINFO_TYPE_DOMINATION;
 512         else if(t == "ctf")   return MAPINFO_TYPE_CTF;
 513         else if(t == "rune")  return MAPINFO_TYPE_RUNEMATCH;
 514         else if(t == "lms")   return MAPINFO_TYPE_LMS;
 515         else if(t == "arena") return MAPINFO_TYPE_ARENA;
 516         else if(t == "kh")    return MAPINFO_TYPE_KEYHUNT;
 517         else if(t == "as")    return MAPINFO_TYPE_ASSAULT;
 518         else if(t == "ons")   return MAPINFO_TYPE_ONSLAUGHT;
 519         else if(t == "race")  return MAPINFO_TYPE_RACE;
 520         else if(t == "all")   return MAPINFO_TYPE_ALL;
 521         else                  return 0;
 522 }
 523
 524 // load info about a map by name into the MapInfo_Map_* globals
 525 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 526 {
 527         string fn;
 528         string s, t;
 529         float fh, fh2;
 530         float r, f;
 531
 532         if(pGametypeToSet == 0)
 533                 if(MapInfo_Cache_Retrieve(pFilename))
 534                         return 1;
 535
 536         r = 1;
 537
 538         MapInfo_Map_bspname = pFilename;
 539
 540         // default all generic fields so they have "good" values in case something fails
 541         fn = strcat("maps/", pFilename, ".mapinfo");
 542         fh = fopen(fn, FILE_READ);
 543         if(fh < 0)
 544         {
 545                 if(!pAllowGenerate)
 546                         return 0;
 547                 _MapInfo_Map_Reset();
 548                 r = _MapInfo_Generate(pFilename);
 549                 if(!r)
 550                         return 0;
 551                 fh = fopen(fn, FILE_WRITE);
 552                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 553                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 554                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 555                 fputs(fh, strcat("cdtrack ", ftos(floor(random() * 9 + 2)), "\n")); // track from 2 to 10
 556                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)       fputs(fh, "has weapons\n");
 557                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)      fputs(fh, "type dm 30 20\n");
 558                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH) fputs(fh, "type tdm 50 20 2\n");
 559                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DOMINATION)      fputs(fh, "type dom 200 20\n");
 560                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTF)             fputs(fh, "type ctf 300 20 10\n");
 561                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RUNEMATCH)       fputs(fh, "type rune 200 20\n");
 562                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_LMS)             fputs(fh, "type lms 9 20\n");
 563                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ARENA)           fputs(fh, "type arena 10 20\n");
 564                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_KEYHUNT)         fputs(fh, "type kh 1000 20 3\n");
 565                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ASSAULT)         fputs(fh, "type as 20\n");
 566                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)            fputs(fh, "type race 5 20 15\n");
 567                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ONSLAUGHT)       fputs(fh, "type ons 20\n");
 568
 569                 fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
 570                 if(fh2 >= 0)
 571                 {
 572                         fclose(fh2);
 573                         fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 574                 }
 575
 576                 fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 577                 fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 578                 fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 579                 fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 580                 fputs(fh, "// optional: hidden\n");
 581
 582                 fclose(fh);
 583                 r = 2;
 584                 // return r;
 585                 fh = fopen(fn, FILE_READ);
 586                 if(fh < 0)
 587                         error("... but I just wrote it!");
 588         }
 589
 590         _MapInfo_Map_Reset();
 591         for(;;)
 592         {
 593                 if not((s = fgets(fh)))
 594                         break;
 595
 596                 // catch different sorts of comments
 597                 if(s == "")                    // empty lines
 598                         continue;
 599                 if(substring(s, 0, 1) == "#")  // UNIX style
 600                         continue;
 601                 if(substring(s, 0, 2) == "//") // C++ style
 602                         continue;
 603                 if(substring(s, 0, 1) == "_")  // q3map style
 604                         continue;
 605
 606                 t = car(s); s = cdr(s);
 607                 if(t == "title")
 608                         MapInfo_Map_title = s;
 609                 else if(t == "description")
 610                         MapInfo_Map_description = s;
 611                 else if(t == "author")
 612                         MapInfo_Map_author = s;
 613                 else if(t == "has")
 614                 {
 615                         t = car(s); s = cdr(s);
 616                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 617                         else
 618                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 619                 }
 620                 else if(t == "hidden")
 621                 {
 622                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 623                 }
 624                 else if(t == "type")
 625                 {
 626                         t = car(s); s = cdr(s);
 627                         f = MapInfo_Type_FromString(t);
 628                         if(f)
 629                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f);
 630                         else
 631                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 632                 }
 633                 else if(t == "size")
 634                 {
 635                         float a, b, c, d, e;
 636                         t = car(s); s = cdr(s); a = stof(t);
 637                         t = car(s); s = cdr(s); b = stof(t);
 638                         t = car(s); s = cdr(s); c = stof(t);
 639                         t = car(s); s = cdr(s); d = stof(t);
 640                         t = car(s); s = cdr(s); e = stof(t);
 641                         if(s == "")
 642                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 643                         else
 644                         {
 645                                 t = car(s); s = cdr(s); f = stof(t);
 646                                 if(s != "")
 647                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 648                                 else
 649                                 {
 650                                         if(a >= d || b >= e || c >= f)
 651                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
 652                                         else
 653                                         {
 654                                                 MapInfo_Map_mins_x = a;
 655                                                 MapInfo_Map_mins_y = b;
 656                                                 MapInfo_Map_mins_z = c;
 657                                                 MapInfo_Map_maxs_x = d;
 658                                                 MapInfo_Map_maxs_y = e;
 659                                                 MapInfo_Map_maxs_z = f;
 660                                         }
 661                                 }
 662                         }
 663                 }
 664                 else if(t == "settemp_for_type")
 665                 {
 666                         t = car(s); s = cdr(s);
 667                         if((f = MapInfo_Type_FromString(t)))
 668                         {
 669                                 if(f & pGametypeToSet)
 670                                 {
 671                                         t = car(s); s = cdr(s);
 672                                         if not(cvar_value_issafe(t))
 673                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 674                                         else if not (cvar_value_issafe(s))
 675                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 676                                         else
 677                                         {
 678                                                 dprint("Applying temporary setting ", t, " := ", s, "\n");
 679                                                 cvar_settemp(t, s);
 680                                         }
 681                                 }
 682                         }
 683                         else
 684                         {
 685                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
 686                         }
 687                 }
 688                 else if(t == "clientsettemp_for_type")
 689                 {
 690                         t = car(s); s = cdr(s);
 691                         if((f = MapInfo_Type_FromString(t)))
 692                         {
 693                                 if(f & pGametypeToSet)
 694                                 {
 695                                         t = car(s); s = cdr(s);
 696                                         if not(cvar_value_issafe(t))
 697                                                 print("Map ", pFilename, " contains a potentially harmful client setting, ignored\n");
 698                                         else if not (cvar_value_issafe(s))
 699                                                 print("Map ", pFilename, " contains a potentially harmful client setting, ignored\n");
 700                                         else
 701                                         {
 702                                                 dprint("Applying temporary client setting ", t, " := ", s, "\n");
 703                                                 MapInfo_Map_clientstuff = strcat(
 704                                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 705                                                 );
 706                                         }
 707                                 }
 708                         }
 709                         else
 710                         {
 711                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
 712                         }
 713                 }
 714                 else if(t == "fog")
 715                 {
 716                         if not(cvar_value_issafe(t))
 717                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
 718                         else
 719                                 MapInfo_Map_fog = s;
 720                 }
 721                 else if(t == "cdtrack")
 722                 {
 723                         if(pGametypeToSet)
 724                         {
 725                                 if not(cvar_value_issafe(t))
 726                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
 727                                 else
 728                                         MapInfo_Map_clientstuff = strcat(
 729                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
 730                                         );
 731                         }
 732                 }
 733                 else
 734                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
 735         }
 736         fclose(fh);
 737         if(pGametypeToSet)
 738                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
 739                         error("Can't select the requested game type. Bailing out.");
 740         MapInfo_Cache_Store();
 741         if(MapInfo_Map_supportedGametypes != 0)
 742                 return r;
 743         dprint("Map ", pFilename, " supports no game types, ignored\n");
 744         return 0;
 745 }
 746
 747 float MapInfo_FindName(string s)
 748 {
 749         // if there is exactly one map of prefix s, return it
 750         // if not, return the null string
 751         // note that DP sorts glob results... so I can use a binary search
 752         float l, r, m, cmp;
 753         l = 0;
 754         r = MapInfo_count;
 755         // invariants: r is behind s, l-1 is equal or before
 756         while(l != r)
 757         {
 758                 m = floor((l + r) / 2);
 759                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
 760                 cmp = strcasecmp(MapInfo_FindName_match, s);
 761                 if(cmp == 0)
 762                         return m; // found and good
 763                 if(cmp < 0)
 764                         l = m + 1; // l-1 is before s
 765                 else
 766                         r = m; // behind s
 767         }
 768         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
 769         MapInfo_FindName_firstResult = l;
 770         // r == l, so: l is behind s, l-1 is before
 771         // SO: if there is any, l is the one with the right prefix
 772         //     and l+1 may be one too
 773         if(l == MapInfo_count)
 774         {
 775                 MapInfo_FindName_match = string_null;
 776                 MapInfo_FindName_firstResult = -1;
 777                 return -1; // no MapInfo_FindName_match, behind last item
 778         }
 779         if(!startsWithNocase(MapInfo_FindName_match, s))
 780         {
 781                 MapInfo_FindName_match = string_null;
 782                 MapInfo_FindName_firstResult = -1;
 783                 return -1; // wrong prefix
 784         }
 785         if(l == MapInfo_count - 1)
 786                 return l; // last one, nothing can follow => unique
 787         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
 788         {
 789                 MapInfo_FindName_match = string_null;
 790                 return -1; // ambigous MapInfo_FindName_match
 791         }
 792         return l;
 793 }
 794
 795 string MapInfo_FixName(string s)
 796 {
 797         MapInfo_FindName(s);
 798         return MapInfo_FindName_match;
 799 }
 800
 801 float MapInfo_CurrentFeatures()
 802 {
 803         float req;
 804         req = 0;
 805         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_minstagib") || cvar("g_nixnex") || cvar("g_rocketarena") || !cvar("g_pickup_items") || cvar("g_race")))
 806                 req |= MAPINFO_FEATURE_WEAPONS;
 807         return req;
 808 }
 809
 810 float MapInfo_CurrentGametype()
 811 {
 812         if(cvar("g_domination"))
 813                 return MAPINFO_TYPE_DOMINATION;
 814         else if(cvar("g_ctf"))
 815                 return MAPINFO_TYPE_CTF;
 816         else if(cvar("g_runematch"))
 817                 return MAPINFO_TYPE_RUNEMATCH;
 818         else if(cvar("g_tdm"))
 819                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
 820         else if(cvar("g_assault"))
 821                 return MAPINFO_TYPE_ASSAULT;
 822         else if(cvar("g_lms"))
 823                 return MAPINFO_TYPE_LMS;
 824         else if(cvar("g_arena"))
 825                 return MAPINFO_TYPE_ARENA;
 826         else if(cvar("g_keyhunt"))
 827                 return MAPINFO_TYPE_KEYHUNT;
 828         else if(cvar("g_onslaught"))
 829                 return MAPINFO_TYPE_ONSLAUGHT;
 830         else if(cvar("g_race"))
 831                 return MAPINFO_TYPE_RACE;
 832         else
 833                 return MAPINFO_TYPE_DEATHMATCH;
 834 }
 835
 836 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 837 {
 838         if(!MapInfo_Get_ByName(s, 1, 0))
 839                 return 0;
 840         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
 841                 return 0;
 842         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
 843                 return 0;
 844         return 1;
 845 }
 846
 847 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 848 {
 849         float r;
 850         r = _MapInfo_CheckMap(s);
 851         MapInfo_ClearTemps();
 852         return r;
 853 }
 854
 855 void MapInfo_SwitchGameType(float t)
 856 {
 857         cvar_set("gamecfg",      "0");
 858         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
 859         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
 860         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
 861         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
 862         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
 863         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
 864         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
 865         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
 866         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
 867         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
 868         cvar_set("g_race",       (t == MAPINFO_TYPE_RACE)            ? "1" : "0");
 869 }
 870
 871 void MapInfo_LoadMap(string s)
 872 {
 873         MapInfo_Map_supportedGametypes = 0;
 874         if(!MapInfo_CheckMap(s))
 875         {
 876                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
 877                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
 878         }
 879         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
 880 }
 881
 882 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
 883 {
 884         string out;
 885         float i;
 886
 887         // to make absolutely sure:
 888         MapInfo_Enumerate();
 889         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
 890
 891         out = "";
 892         for(i = 0; i < MapInfo_count; ++i)
 893                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
 894         return substring(out, 1, strlen(out) - 1);
 895 }
 896
 897 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
 898 {
 899         float t;
 900         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
 901         {
 902                 if(MapInfo_Map_supportedGametypes <= 0)
 903                         error("Mapinfo system is not functional at all. BAILED OUT.\n");
 904
 905                 t = 1;
 906                 while(!(MapInfo_Map_supportedGametypes & 1))
 907                 {
 908                         t *= 2;
 909                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
 910                 }
 911                 // t is now a supported mode!
 912                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
 913                 MapInfo_SwitchGameType(t);
 914         }
 915         cvar_settemp_restore();
 916         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
 917 }
 918
 919 void MapInfo_ClearTemps()
 920 {
 921         MapInfo_Map_bspname = string_null;
 922         MapInfo_Map_title = string_null;
 923         MapInfo_Map_description = string_null;
 924         MapInfo_Map_author = string_null;
 925         MapInfo_Map_clientstuff = string_null;
 926         MapInfo_Map_supportedGametypes = 0;
 927         MapInfo_Map_supportedFeatures = 0;
 928 }
 929
 930 void MapInfo_Shutdown()
 931 {
 932         MapInfo_ClearTemps();
 933         MapInfo_Filter_Free();
 934         MapInfo_Cache_Destroy();
 935         if(_MapInfo_globopen)
 936         {
 937                 search_end(_MapInfo_globhandle);
 938                 _MapInfo_globhandle = -1;
 939                 _MapInfo_globopen = FALSE;
 940         }
 941 }