data/qcsrc/common/gamecommand.qc

   1 #define MAX_RPN_STACK 16
   2 float rpn_db;
   3 float rpn_error;
   4 float rpn_sp;
   5 string rpn_stack[MAX_RPN_STACK];
   6 string rpn_pop() {
   7         if(rpn_sp > 0) {
   8                 --rpn_sp;
   9                 return rpn_stack[rpn_sp];
  10         } else {
  11                 print("rpn: stack underflow\n");
  12                 rpn_error = TRUE;
  13                 return "";
  14         }
  15 }
  16 void rpn_push(string s) {
  17         if(rpn_sp < MAX_RPN_STACK) {
  18                 rpn_stack[rpn_sp] = s;
  19                 ++rpn_sp;
  20         } else {
  21                 print("rpn: stack overflow\n");
  22                 rpn_error = TRUE;
  23         }
  24 }
  25 string rpn_get() {
  26         if(rpn_sp > 0) {
  27                 return rpn_stack[rpn_sp - 1];
  28         } else {
  29                 print("rpn: empty stack\n");
  30                 rpn_error = TRUE;
  31                 return "";
  32         }
  33 }
  34 void rpn_set(string s) {
  35         if(rpn_sp > 0) {
  36                 rpn_stack[rpn_sp - 1] = s;
  37         } else {
  38                 print("rpn: empty stack\n");
  39                 rpn_error = TRUE;
  40         }
  41 }
  42 float rpn_getf() { return stof(rpn_get()); }
  43 float rpn_popf() { return stof(rpn_pop()); }
  44 void rpn_pushf(float f) { return rpn_push(ftos(f)); }
  45 void rpn_setf(float f) { return rpn_set(ftos(f)); }
  46
  47 float GameCommand_Generic(string command)
  48 {
  49         float argc;
  50         float i, j, f, n;
  51         vector rgb;
  52         string s, s2, c;
  53         argc = tokenize_sane(command);
  54         if(argv(0) == "help")
  55         {
  56                 print("  rpn EXPRESSION... - a RPN calculator.\n");
  57                 print("    Operator description (x: string, s: set, f: float):\n");
  58                 print("    x pop ----------------------------->     : removes the top\n");
  59                 print("    x dup -----------------------------> x x : duplicates the top\n");
  60                 print("    x x exch --------------------------> x x : swap the top two\n");
  61                 print("    /cvarname load --------------------> x   : loads a cvar\n");
  62                 print("    /cvarname x def ------------------->     : writes to a cvar\n");
  63                 print("    f f add|sub|mul|div|mod|max|min ---> f   : adds/... two numbers\n");
  64                 print("    f f eq|ne|gt|ge|lt|le -------------> f   : compares two numbers\n");
  65                 print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
  66                 print("    f f f bound -----------------------> f   : bounds the middle number\n");
  67                 print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
  68                 print("    s s union|intersection|difference -> s   : set operations\n");
  69                 print("    s shuffle -------------------------> s   : randomly arrange elements\n");
  70                 print("    x dbpush -------------------------->     : pushes the top onto the database\n");
  71                 print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
  72                 print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
  73                 print("    dbclr ----------------------------->     : clear the DB\n");
  74                 print("    s dbsave|dbload-------------------->     : save/load the DB to/from a file\n");
  75                 print("    x dbins --------------------------->     : moves the top into the DB\n");
  76                 print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
  77                 print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
  78                 print("    Set operations operate on 'such''strings'.\n");
  79                 print("    Unknown tokens insert their cvar value.\n");
  80                 print("  maplist add map\n");
  81                 print("  maplist remove map\n");
  82                 print("  maplist shuffle\n");
  83                 return TRUE;
  84         }
  85
  86         if(argv(0) == "maplist")
  87         {
  88                 if(argv(1) == "add" && argc == 3)
  89                 {
  90                         f = fopen(strcat("maps/", argv(2), ".bsp"), FILE_READ);
  91                         if(f != -1)
  92                                 fclose(f);
  93                         else {
  94                                 print("maplist: ERROR: ", argv(2), " does not exist!\n");
  95                                 return TRUE;
  96                         }
  97                         if(cvar_string("g_maplist") == "")
  98                                 cvar_set("g_maplist", argv(2));
  99                         else
 100                                 cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 101                         return TRUE;
 102                 }
 103                 else if(argv(1) == "remove" && argc == 3)
 104                 {
 105                         s = argv(2);
 106                         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 107                         s2 = "";
 108                         for(i = 0; i < n; ++i)
 109                                 if(argv(i) != s)
 110                                 {
 111                                         s2 = strcat(s2, " ", argv(i));
 112                                 }
 113                         s2 = substring(s2, 1, strlen(s2) - 1);
 114                         cvar_set("g_maplist", s2);
 115                         return TRUE;
 116                 }
 117                 else if(argv(1) == "shuffle" && argc == 2)
 118                 {
 119                         s = cvar_string("g_maplist");
 120                         for(i = 1; i < (n = tokenizebyseparator(s, " ")); ++i)
 121                         {
 122                                 // swap i-th item at a random position from 0 to i
 123                                 // proof for even distribution:
 124                                 //   n = 1: obvious
 125                                 //   n -> n+1:
 126                                 //     item n+1 gets at any position with chance 1/(n+1)
 127                                 //     all others will get their 1/n chance reduced by factor n/(n+1)
 128                                 //     to be on place n+1, their chance will be 1/(n+1)
 129                                 //     1/n * n/(n+1) = 1/(n+1)
 130                                 //     q.e.d.
 131                                 f = floor(random() * (i + 1)); // 0 to i
 132                                 if(f == i)
 133                                         continue; // no change
 134
 135                                 s2 = "";
 136                                 for(j = 0; j < n; ++j)
 137                                         s2 = strcat(s2, " ", argv((j == i) ? f : (j == f) ? i : j));
 138                                 s = substring(s2, 1, strlen(s2) - 1);
 139                         }
 140                         cvar_set("g_maplist", s);
 141                         return TRUE;
 142                 }
 143         }
 144         else if(argv(0) == "BRLOGENSHFEGLE" && argc >= 2)
 145         {
 146                 // test case for terrencehill's color codes
 147                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 148                 s2 = "";
 149                 n = strlen(s);
 150
 151                 j = random() * 0.1 + 0.05;
 152                 f = random();
 153
 154                 for(i = 0; i < n; ++i)
 155                 {
 156                         c = substring(s, i, 1);
 157                         if(c == ";")
 158                                 c = ":";
 159                         if(c != " ")
 160                         {
 161                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 162                                 c = strcat(rgb_to_hexcolor(rgb), c);
 163                         }
 164                         s2 = strcat(s2, c);
 165                 }
 166
 167                 localcmd(strcat(argv(1), " ", s2));
 168
 169                 return TRUE;
 170         }
 171         else if(argv(0) == "rpn")
 172         {
 173                 if(!rpn_db)
 174                 {
 175                         rpn_db = db_create();
 176                         db_put(rpn_db, "stack.pointer", "0");
 177                         db_put(rpn_db, "stack.pos", "-1");
 178                 }
 179                 if(argc >= 2)
 180                 {
 181                         float rpnpos;
 182                         string rpncmd;
 183                         float f2, f3;
 184                         rpn_sp = 0;
 185                         rpn_error = FALSE;
 186                         for(rpnpos = 1; rpnpos < argc; ++rpnpos)
 187                         {
 188                                 rpncmd = argv(rpnpos);
 189                                 f = strlen(rpncmd);
 190                                 if(rpncmd == "") {
 191                                 } else if(stof(substring(rpncmd, 0, 1)) > 0) {
 192                                         rpn_push(rpncmd);
 193                                 } else if(substring(rpncmd, 0, 1) == "0") {
 194                                         rpn_push(rpncmd);
 195                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
 196                                         rpn_push(rpncmd);
 197                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
 198                                         rpn_push(rpncmd);
 199                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
 200                                         rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
 201                                 } else if(rpncmd == "clear") {
 202                                         rpn_sp = 0;
 203                                 } else if(rpncmd == "def" || rpncmd == "=") {
 204                                         s = rpn_pop();
 205                                         s2 = rpn_pop();
 206 #ifdef MENUQC
 207                                         registercvar(s2, "", 0);
 208 #else
 209                                         registercvar(s2, "");
 210 #endif
 211                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 212                                                 cvar_set(s2, s);
 213                                 } else if(rpncmd == "defs" || rpncmd == "@") {
 214                                         s = "";
 215                                         i = rpn_popf();
 216                                         j = (i == 0);
 217                                         while(rpn_sp > 1 && (j || i > 0))
 218                                         {
 219                                                 s = strcat("/", rpn_pop(), " ", s);
 220                                                 --i;
 221                                         }
 222                                         s2 = rpn_pop();
 223 #ifdef MENUQC
 224                                         registercvar(s2, "", 0);
 225 #else
 226                                         registercvar(s2, "");
 227 #endif
 228                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 229                                                 cvar_set(s2, s);
 230                                 } else if(rpncmd == "load") {
 231                                         rpn_set(cvar_string(rpn_get()));
 232                                 } else if(rpncmd == "exch") {
 233                                         s = rpn_pop();
 234                                         s2 = rpn_get();
 235                                         rpn_set(s);
 236                                         rpn_push(s2);
 237                                 } else if(rpncmd == "dup") {
 238                                         rpn_push(rpn_get());
 239                                 } else if(rpncmd == "pop") {
 240                                         rpn_pop();
 241                                 } else if(rpncmd == "add" || rpncmd == "+") {
 242                                         f = rpn_popf();
 243                                         rpn_setf(rpn_getf() + f);
 244                                 } else if(rpncmd == "sub" || rpncmd == "-") {
 245                                         f = rpn_popf();
 246                                         rpn_setf(rpn_getf() - f);
 247                                 } else if(rpncmd == "mul" || rpncmd == "*") {
 248                                         f = rpn_popf();
 249                                         rpn_setf(rpn_getf() * f);
 250                                 } else if(rpncmd == "div" || rpncmd == "/") {
 251                                         f = rpn_popf();
 252                                         rpn_setf(rpn_getf() / f);
 253                                 } else if(rpncmd == "mod" || rpncmd == "%") {
 254                                         f = rpn_popf();
 255                                         f2 = rpn_getf();
 256                                         rpn_setf(f2 - f * floor(f2 / f));
 257                                 } else if(rpncmd == "abs") {
 258                                         rpn_setf(fabs(rpn_getf()));
 259                                 } else if(rpncmd == "sgn") {
 260                                         f = rpn_getf();
 261                                         if(f < 0)
 262                                                 rpn_set("-1");
 263                                         else if(f > 0)
 264                                                 rpn_set("1");
 265                                         else
 266                                                 rpn_set("0");
 267                                 } else if(rpncmd == "neg" || rpncmd == "~") {
 268                                         rpn_setf(-rpn_getf());
 269                                 } else if(rpncmd == "floor" || rpncmd == "f") {
 270                                         rpn_setf(floor(rpn_getf()));
 271                                 } else if(rpncmd == "ceil" || rpncmd == "c") {
 272                                         rpn_setf(ceil(rpn_getf()));
 273                                 } else if(rpncmd == "max") {
 274                                         f = rpn_popf();
 275                                         f2 = rpn_getf();
 276                                         rpn_setf(max(f2, f));
 277                                 } else if(rpncmd == "min") {
 278                                         f = rpn_popf();
 279                                         f2 = rpn_getf();
 280                                         rpn_setf(min(f2, f));
 281                                 } else if(rpncmd == "bound") {
 282                                         f = rpn_popf();
 283                                         f2 = rpn_popf();
 284                                         f3 = rpn_getf();
 285                                         rpn_setf(bound(f3, f2, f));
 286                                 } else if(rpncmd == "when") {
 287                                         f = rpn_popf();
 288                                         f2 = rpn_popf();
 289                                         f3 = rpn_getf();
 290                                         if(f)
 291                                                 rpn_setf(f3);
 292                                         else
 293                                                 rpn_setf(f2);
 294                                 } else if(rpncmd == ">" || rpncmd == "gt") {
 295                                         f = rpn_popf();
 296                                         rpn_setf(rpn_getf() > f);
 297                                 } else if(rpncmd == "<" || rpncmd == "lt") {
 298                                         f = rpn_popf();
 299                                         rpn_setf(rpn_getf() < f);
 300                                 } else if(rpncmd == "==" || rpncmd == "eq") {
 301                                         f = rpn_popf();
 302                                         rpn_setf(rpn_getf() == f);
 303                                 } else if(rpncmd == ">=" || rpncmd == "ge") {
 304                                         f = rpn_popf();
 305                                         rpn_setf(rpn_getf() >= f);
 306                                 } else if(rpncmd == "<=" || rpncmd == "le") {
 307                                         f = rpn_popf();
 308                                         rpn_setf(rpn_getf() <= f);
 309                                 } else if(rpncmd == "!=" || rpncmd == "ne") {
 310                                         f = rpn_popf();
 311                                         rpn_setf(rpn_getf() != f);
 312                                 } else if(rpncmd == "rand") {
 313                                         rpn_setf(ceil(random() * rpn_getf()) - 1);
 314                                 } else if(rpncmd == "dbpush") {
 315                                         s = rpn_pop();
 316                                         if(!rpn_error)
 317                                         {
 318                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 319                                                 db_put(rpn_db, "stack.pointer", ftos(i+1));
 320                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 321                                         }
 322                                         if(!i)
 323                                                 db_put(rpn_db, "stack.pos", "0");
 324                                 } else if(rpncmd == "dbpop") {
 325                                         i = stof(db_get(rpn_db, "stack.pointer"));
 326                                         if(i)
 327                                         {
 328                                                 s = ftos(i-1);
 329                                                 db_put(rpn_db, "stack.pointer", s);
 330                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 331                                                 j = stof(db_get(rpn_db, "stack.pos"));
 332                                                 if(j >= i)
 333                                                         db_put(rpn_db, "stack.pos", ftos(i-2));
 334                                         } else {
 335                                                 rpn_error = 1;
 336                                                 print("rpn: database underflow\n");
 337                                         }
 338                                 } else if(rpncmd == "dbget") {
 339
 340                                         i = stof(db_get(rpn_db, "stack.pointer"));
 341                                         if(i)
 342                                         {
 343                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 344                                         } else {
 345                                                 rpn_error = 1;
 346                                                 print("rpn: database empty\n");
 347                                         }
 348                                 } else if(rpncmd == "dblen") {
 349                                         rpn_push(db_get(rpn_db, "stack.pointer"));
 350                                 } else if(rpncmd == "dbclr") {
 351                                         db_close(rpn_db);
 352                                         rpn_db = db_create();
 353                                         db_put(rpn_db, "stack.pointer", "0");
 354                                         db_put(rpn_db, "stack.pos", "-1");
 355                                 } else if(rpncmd == "dbsave") {
 356                                         s = rpn_pop();
 357                                         if(!rpn_error)
 358                                                 db_save(rpn_db, s);
 359                                 } else if(rpncmd == "dbload") {
 360                                         s = rpn_pop();
 361                                         if(!rpn_error)
 362                                         {
 363                                                 db_close(rpn_db);
 364                                                 rpn_db = db_load(s);
 365                                         }
 366                                 } else if(rpncmd == "dbins") {
 367                                         s = rpn_pop();
 368                                         if(!rpn_error)
 369                                                 //if(rpn_sp > 0)
 370                                         {
 371                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 372                                                 i = stof(db_get(rpn_db, "stack.pos"));
 373
 374                                                 if(i < 0)
 375                                                 {
 376                                                         i = 0;
 377                                                         db_put(rpn_db, "stack.pos", "0");
 378                                                 }
 379
 380                                                 db_put(rpn_db, "stack.pointer", ftos(j+1));
 381                                                 for(--j; j >= i; --j)
 382                                                 {
 383                                                         db_put(rpn_db, strcat("stack.", ftos(j+1)),
 384                                                                db_get(rpn_db, (strcat("stack.", ftos(j))))
 385                                                                 );
 386                                                 }
 387                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 388                                         }
 389                                 } else if(rpncmd == "dbext") {
 390                                         j = stof(db_get(rpn_db, "stack.pointer"));
 391                                         i = stof(db_get(rpn_db, "stack.pos"));
 392                                         if(!j)
 393                                         {
 394                                                 rpn_error = TRUE;
 395                                                 print("rpn: empty database\n");
 396                                         } else {
 397                                                 --j;
 398                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 399                                                 db_put(rpn_db, "stack.pointer", ftos(j));
 400                                                 if(i == j)
 401                                                 {
 402                                                         db_put(rpn_db, "stack.pos", ftos(j-1));
 403                                                 } else {
 404                                                         while(i < j)
 405                                                         {
 406                                                                 db_put(rpn_db, strcat("stack.", ftos(i)),
 407                                                                        db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 408                                                                         );
 409                                                                 ++i;
 410                                                         }
 411                                                 }
 412                                         }
 413                                 } else if(rpncmd == "dbread") {
 414                                         s = db_get(rpn_db, "stack.pos");
 415                                         if(stof(s) >= 0)
 416                                         {
 417                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 418                                         } else {
 419                                                 rpn_error = 1;
 420                                                 print("rpn: empty database\n");
 421                                         }
 422                                 } else if(rpncmd == "dbat") {
 423                                         rpn_push(db_get(rpn_db, "stack.pos"));
 424                                 } else if(rpncmd == "dbmov") {
 425                                         j = stof(db_get(rpn_db, "stack.pointer"));
 426                                         i = stof(db_get(rpn_db, "stack.pos"));
 427                                         i += rpn_popf();
 428                                         if(!rpn_error)
 429                                         {
 430                                                 if(i < 0 || i >= j)
 431                                                 {
 432                                                         print("rpn: database cursor out of bounds\n");
 433                                                         rpn_error = TRUE;
 434                                                 }
 435                                                 if(!rpn_error)
 436                                                 {
 437                                                         db_put(rpn_db, "stack.pos", ftos(i));
 438                                                 }
 439                                         }
 440                                 } else if(rpncmd == "dbgoto") {
 441                                         s = rpn_pop();
 442                                         j = stof(db_get(rpn_db, "stack.pointer"));
 443                                         if(!j)
 444                                         {
 445                                                 rpn_error = TRUE;
 446                                                 print("rpn: empty database, cannot move cursor\n");
 447                                         }
 448                                         if(!rpn_error)
 449                                         {
 450                                                 if(s == "end")
 451                                                         i = stof(db_get(rpn_db, "stack.pointer"))-1;
 452                                                 else if(s == "beg")
 453                                                         i = 0;
 454                                                 else
 455                                                         i = stof(s);
 456
 457                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 458                                                 if(i < 0 || i >= j)
 459                                                 {
 460                                                         print("rpn: database cursor destination out of bounds\n");
 461                                                         rpn_error = TRUE;
 462                                                 }
 463                                                 if(!rpn_error)
 464                                                 {
 465                                                         db_put(rpn_db, "stack.pos", ftos(i));
 466                                                 }
 467                                         }
 468                                 } else if(rpncmd == "union") {
 469                                         // s s2 union
 470                                         s2 = rpn_pop();
 471                                         s = rpn_get();
 472                                         f = tokenize_sane(s);
 473                                         f2 = tokenize_sane(strcat(s, " ", s2));
 474                                         // tokens 0..(f-1) represent s
 475                                         // tokens f..f2 represent s2
 476                                         // UNION: add all tokens to s that are in s2 but not in s
 477                                         s = "";
 478                                         for(i = 0; i < f; ++i)
 479                                                 s = strcat(s, " ", argv(i));
 480                                         for(i = f; i < f2; ++i) {
 481                                                 for(j = 0; j < f; ++j)
 482                                                         if(argv(i) == argv(j))
 483                                                                 goto skip_union;
 484                                                 s = strcat(s, " ", argv(i));
 485 :skip_union
 486                                         }
 487                                         if(substring(s, 0, 1) == " ")
 488                                                 s = substring(s, 1, 99999);
 489                                         rpn_set(s);
 490                                         tokenize_sane(command);
 491                                 } else if(rpncmd == "intersection") {
 492                                         // s s2 intersection
 493                                         s2 = rpn_pop();
 494                                         s = rpn_get();
 495                                         f = tokenize_sane(s);
 496                                         f2 = tokenize_sane(strcat(s, " ", s2));
 497                                         // tokens 0..(f-1) represent s
 498                                         // tokens f..f2 represent s2
 499                                         // INTERSECTION: keep only the tokens from s that are also in s2
 500                                         s = "";
 501                                         for(i = 0; i < f; ++i) {
 502                                                 for(j = f; j < f2; ++j)
 503                                                         if(argv(i) == argv(j))
 504                                                         {
 505                                                                 s = strcat(s, " ", argv(i));
 506                                                                 break;
 507                                                         }
 508                                         }
 509                                         if(substring(s, 0, 1) == " ")
 510                                                 s = substring(s, 1, 99999);
 511                                         rpn_set(s);
 512                                         tokenize_sane(command);
 513                                 } else if(rpncmd == "difference") {
 514                                         // s s2 difference
 515                                         s2 = rpn_pop();
 516                                         s = rpn_get();
 517                                         f = tokenize_sane(s);
 518                                         f2 = tokenize_sane(strcat(s, " ", s2));
 519                                         // tokens 0..(f-1) represent s
 520                                         // tokens f..f2 represent s2
 521                                         // DIFFERENCE: keep only the tokens from s that are not in s2
 522                                         s = "";
 523                                         for(i = 0; i < f; ++i) {
 524                                                 for(j = f; j < f2; ++j)
 525                                                         if(argv(i) == argv(j))
 526                                                                 goto skip_difference;
 527                                                 s = strcat(s, " ", argv(i));
 528 :skip_difference
 529                                         }
 530                                         if(substring(s, 0, 1) == " ")
 531                                                 s = substring(s, 1, 99999);
 532                                         rpn_set(s);
 533                                         tokenize_sane(command);
 534                                 } else if(rpncmd == "shuffle") {
 535                                         // s shuffle
 536                                         s = rpn_get();
 537                                         f = tokenize_sane(s);
 538
 539                                         for(i = 0; i < f - 1; ++i) {
 540                                                 // move a random item from i..f-1 to position i
 541                                                 s = "";
 542                                                 f2 = floor(random() * (f - i) + i);
 543                                                 for(j = 0; j < i; ++j)
 544                                                         s = strcat(s, " ", argv(j));
 545                                                 s = strcat(s, " ", argv(f2));
 546                                                 for(j = i; j < f; ++j)
 547                                                         if(j != f2)
 548                                                                 s = strcat(s, " ", argv(j));
 549                                                 f = tokenize_sane(s);
 550                                         }
 551
 552                                         if(substring(s, 0, 1) == " ")
 553                                                 s = substring(s, 1, 99999);
 554                                         rpn_set(s);
 555                                         tokenize_sane(command);
 556                                         } else if(rpncmd == "fexists_assert") {
 557                                         s = rpn_pop();
 558                                         if(!rpn_error)
 559                                         {
 560                                                 f = fopen(s, FILE_READ);
 561                                                 if(f != -1)
 562                                                         fclose(f);
 563                                                 else {
 564                                                         print("rpn: ERROR: ", s, " does not exist!\n");
 565                                                         rpn_error = TRUE;
 566                                                 }
 567                                         }
 568                                 } else {
 569                                         rpn_push(cvar_string(rpncmd));
 570                                 }
 571                                 if(rpn_error)
 572                                         break;
 573                         }
 574                         while(rpn_sp > 0)
 575                         {
 576                                 s = rpn_pop();
 577                                 print("rpn: still on stack: ", s, "\n");
 578                         }
 579                         return TRUE;
 580                 }
 581 #ifdef MENUQC
 582         } else if(argv(0) == "cp") {
 583                 if(argc >= 2)
 584                 {
 585                         s = argv(1);
 586                         for(i = 2; i < argc; ++i)
 587                                 s = strcat(s, " ", argv(i));
 588                         centerprint(unescape(s));
 589                 }
 590                 return TRUE;
 591 #endif
 592         }
 593
 594         return FALSE;
 595 }