data/qcsrc/client/teamradar.qc

   1 float teamradar_angle; // player yaw angle
   2 vector teamradar_origin3d_in_texcoord; // player origin
   3 vector teamradar_origin2d; // 2D origin
   4 vector teamradar_size2d; // 2D size
   5 float teamradar_size; // 2D scale factor
   6 float cl_teamradar_scale; // window size = ...qu
   7
   8 float vlen_maxnorm2d(vector v)
   9 {
  10         return max4(v_x, v_y, -v_x, -v_y);
  11 }
  12
  13 float vlen_minnorm2d(vector v)
  14 {
  15         return min(max(v_x, -v_x), max(v_y, -v_y));
  16 }
  17
  18 vector teamradar_3dcoord_to_texcoord(vector in)
  19 {
  20         vector out;
  21         out_x = (in_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
  22         out_y = (in_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
  23         out_z = 0;
  24         return out;
  25 }
  26
  27 vector teamradar_texcoord_to_2dcoord(vector in)
  28 {
  29         vector out;
  30         in -= teamradar_origin3d_in_texcoord;
  31
  32         out = rotate(in, teamradar_angle * DEG2RAD);
  33         out_y = - out_y; // screen space is reversed
  34
  35         out = out * teamradar_size;
  36         out += teamradar_origin2d;
  37         return out;
  38 }
  39
  40 vector yinvert(vector v)
  41 {
  42         v_y = 1 - v_y;
  43         return v;
  44 }
  45
  46 void draw_teamradar_background(float bg, float fg)
  47 {
  48         if(bg > 0)
  49         {
  50                 R_BeginPolygon("", 0);
  51                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  52                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  53                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  54                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  55                 R_EndPolygon();
  56         }
  57
  58         if(fg > 0)
  59         {
  60                 if(csqc_flags & CSQC_FLAG_READPICTURE) // not 2.4.2
  61                         R_BeginPolygon(minimapname, DRAWFLAG_ADDITIVE | DRAWFLAG_MIPMAP);
  62                 else
  63                         R_BeginPolygon(minimapname, DRAWFLAG_ADDITIVE);
  64                 R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), '1 1 1', fg);
  65                 R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), '1 1 1', fg);
  66                 R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), '1 1 1', fg);
  67                 R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), '1 1 1', fg);
  68                 R_EndPolygon();
  69         }
  70 }
  71
  72 void(vector coord3d, vector pangles, vector rgb) draw_teamradar_player =
  73 {
  74         vector coord, rgb2;
  75
  76         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord3d));
  77
  78         makevectors(pangles - '0 1 0' * teamradar_angle);
  79         v_forward_z = 0;
  80         v_forward = normalize(v_forward);
  81         v_forward_y *= -1.0;
  82         v_right_x = -v_forward_y;
  83         v_right_y = v_forward_x;
  84
  85         if(rgb == '1 1 1')
  86                 rgb2 = '0 0 0';
  87         else
  88                 rgb2 = '1 1 1';
  89
  90         R_BeginPolygon("", 0);
  91         R_PolygonVertex(coord+v_forward*3, '0 0 0', rgb2, 1);
  92         R_PolygonVertex(coord+v_right*4-v_forward*2.5, '0 1 0', rgb2, 1);
  93         R_PolygonVertex(coord-v_forward*2, '1 0 0', rgb2, 1);
  94         R_PolygonVertex(coord-v_right*4-v_forward*2.5, '1 1 0', rgb2, 1);
  95         R_EndPolygon();
  96
  97         R_BeginPolygon("", 0);
  98         R_PolygonVertex(coord+v_forward*2, '0 0 0', rgb, 1);
  99         R_PolygonVertex(coord+v_right*3-v_forward*2, '0 1 0', rgb, 1);
 100         R_PolygonVertex(coord-v_forward, '1 0 0', rgb, 1);
 101         R_PolygonVertex(coord-v_right*3-v_forward*2, '1 1 0', rgb, 1);
 102         R_EndPolygon();
 103 };
 104
 105 void draw_teamradar_icon(vector coord, float icon, float pingtime, vector rgb, float a)
 106 {
 107         float dt;
 108         vector v;
 109
 110         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord));
 111         drawpic(coord - '4 4 0', strcat("gfx/teamradar_icon_", ftos(icon)), '8 8 0', rgb, a, 0);
 112         if(pingtime != 0)
 113         {
 114                 dt = time - pingtime;
 115                 if(dt > 1)
 116                         return;
 117                 v = '2 2 0' * teamradar_size * dt;
 118                 drawpic(coord - 0.5 * v, "gfx/teamradar_ping", v, '1 1 1', 1 - dt, DRAWFLAG_ADDITIVE);
 119         }
 120 }
 121
 122 float cl_teamradar_scale;
 123 float cl_teamradar_background_alpha;
 124 float cl_teamradar_foreground_alpha;
 125 float cl_teamradar_rotation;
 126 vector cl_teamradar_size;
 127 vector cl_teamradar_position;
 128 float cl_teamradar_zoommode;
 129
 130 void teamradar_loadcvars()
 131 {
 132         cl_teamradar_scale = cvar("cl_teamradar_scale");
 133         cl_teamradar_background_alpha = cvar("cl_teamradar_background_alpha");
 134         cl_teamradar_foreground_alpha = cvar("cl_teamradar_foreground_alpha");
 135         cl_teamradar_rotation = cvar("cl_teamradar_rotation");
 136         cl_teamradar_size = stov(cvar_string("cl_teamradar_size"));
 137         cl_teamradar_position = stov(cvar_string("cl_teamradar_position"));
 138         cl_teamradar_zoommode = cvar("cl_teamradar_zoommode");
 139
 140         // others default to 0
 141         // match this to defaultNexuiz.cfg!
 142         if(!cl_teamradar_scale) cl_teamradar_scale = 4096;
 143         if(!cl_teamradar_background_alpha) cl_teamradar_background_alpha = 0.25;
 144         if(!cl_teamradar_foreground_alpha) cl_teamradar_background_alpha = 1;
 145         if(!cl_teamradar_size_x) cl_teamradar_size_x = 128;
 146         if(!cl_teamradar_size_y) cl_teamradar_size_y = cl_teamradar_size_x;
 147
 148         cl_teamradar_size_z = 0;
 149         cl_teamradar_position_z = 0;
 150 }
 151
 152 void() teamradar_view =
 153 {
 154         local float color, color2;
 155         local vector rgb;
 156         local entity tm;
 157         float scale2d, normalsize, bigsize;
 158         float f;
 159
 160         if(minimapname == "")
 161                 return;
 162
 163         teamradar_loadcvars();
 164
 165         switch(cl_teamradar_zoommode)
 166         {
 167                 default:
 168                 case 0:
 169                         f = current_zoomfraction;
 170                         break;
 171                 case 1:
 172                         f = 1 - current_zoomfraction;
 173                         break;
 174                 case 2:
 175                         f = 0;
 176                         break;
 177                 case 3:
 178                         f = 1;
 179                         break;
 180         }
 181
 182         switch(cl_teamradar_rotation)
 183         {
 184                 case 0:
 185                         teamradar_angle = input_angles_y - 90;
 186                         break;
 187                 default:
 188                         teamradar_angle = 90 * cl_teamradar_rotation;
 189                         break;
 190         }
 191
 192         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
 193         teamradar_size2d = cl_teamradar_size;
 194         teamradar_origin2d =
 195                   '1 0 0' * (0.5 * teamradar_size2d_x + cl_teamradar_position_x * (vid_conwidth - teamradar_size2d_x))
 196                 + '0 1 0' * (0.5 * teamradar_size2d_y + cl_teamradar_position_y * (vid_conheight - teamradar_size2d_y));
 197
 198         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
 199         if(cl_teamradar_rotation == 0)
 200         {
 201                 // max-min distance must fit the radar in any rotation
 202                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen(mi_max - mi_min));
 203         }
 204         else
 205         {
 206                 vector c0, c1, c2, c3, span;
 207                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
 208                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
 209                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
 210                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
 211                 span = '0 0 0';
 212                 span_x = max4(c0_x, c1_x, c2_x, c3_x) - min4(c0_x, c1_x, c2_x, c3_x);
 213                 span_y = max4(c0_y, c1_y, c2_y, c3_y) - min4(c0_y, c1_y, c2_y, c3_y);
 214
 215                 // max-min distance must fit the radar in x=x, y=y
 216                 bigsize = min(
 217                         teamradar_size2d_x * scale2d / (1.05 * span_x),
 218                         teamradar_size2d_y * scale2d / (1.05 * span_y)
 219                 );
 220         }
 221
 222         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / cl_teamradar_scale;
 223         if(bigsize > normalsize)
 224                 normalsize = bigsize;
 225
 226         teamradar_size =
 227                   f * bigsize
 228                 + (1 - f) * normalsize;
 229         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
 230                   f * (mi_min + mi_max) * 0.5
 231                 + (1 - f) * pmove_org);
 232
 233         color = GetPlayerColor(player_localentnum-1);
 234         rgb = GetTeamRGB(color);
 235
 236         drawsetcliparea(
 237                 teamradar_origin2d_x - teamradar_size2d_x * 0.5,
 238                 teamradar_origin2d_y - teamradar_size2d_y * 0.5,
 239                 teamradar_size2d_x,
 240                 teamradar_size2d_y
 241         );
 242
 243         draw_teamradar_background(cl_teamradar_background_alpha, cl_teamradar_foreground_alpha);
 244         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
 245                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm.teamradar_time, tm.teamradar_color, tm.alpha);
 246         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
 247         {
 248                 color2 = GetPlayerColor(tm.sv_entnum);
 249                 //if(color == COLOR_SPECTATOR || color == color2)
 250                         draw_teamradar_player(tm.origin, tm.angles, GetTeamRGB(color2));
 251         }
 252         draw_teamradar_player(pmove_org, input_angles, '1 1 1');
 253
 254         drawresetcliparea();
 255 };