data/qcsrc/client/teamradar.qc

   1 float teamradar_angle; // player yaw angle
   2 vector teamradar_origin3d_in_texcoord; // player origin
   3 vector teamradar_origin2d; // 2D origin
   4 vector teamradar_size2d; // 2D size
   5 float teamradar_size; // 2D scale factor
   6 float cl_teamradar_scale; // window size = ...qu
   7 float v_flipped;
   8
   9 float vlen2d(vector v)
  10 {
  11         return sqrt(v_x * v_x + v_y * v_y);
  12 }
  13
  14 float vlen_maxnorm2d(vector v)
  15 {
  16         return max4(v_x, v_y, -v_x, -v_y);
  17 }
  18
  19 float vlen_minnorm2d(vector v)
  20 {
  21         float a, b;
  22         a = max(v_x, -v_x);
  23         b = max(v_y, -v_y);
  24         return min(a, b);
  25         // return min(max(v_x, -v_x), max(v_y, -v_y)); // fteqcc sucks
  26 }
  27
  28 vector teamradar_3dcoord_to_texcoord(vector in)
  29 {
  30         vector out;
  31         out_x = (in_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
  32         out_y = (in_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
  33         out_z = 0;
  34         return out;
  35 }
  36
  37 vector teamradar_texcoord_to_2dcoord(vector in)
  38 {
  39         vector out;
  40         in -= teamradar_origin3d_in_texcoord;
  41
  42         out = rotate(in, teamradar_angle * DEG2RAD);
  43         out_y = - out_y; // screen space is reversed
  44
  45         out = out * teamradar_size;
  46         if(v_flipped)
  47                 out_x = -out_x;
  48         out += teamradar_origin2d;
  49         return out;
  50 }
  51
  52 vector yinvert(vector v)
  53 {
  54         v_y = 1 - v_y;
  55         return v;
  56 }
  57
  58 void draw_teamradar_background(float bg, float fg)
  59 {
  60         float fga;
  61         vector fgc;
  62         if(bg > 0)
  63         {
  64                 R_BeginPolygon("", 0);
  65                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  66                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  67                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  68                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  69                 R_EndPolygon();
  70         }
  71
  72         if(fg > 0 && minimapname != "")
  73         {
  74                 fga = 1;
  75                 fgc = '1 1 1' * fg;
  76                 R_BeginPolygon(minimapname, DRAWFLAG_SCREEN | DRAWFLAG_MIPMAP);
  77                 if(v_flipped)
  78                 {
  79                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
  80                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
  81                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
  82                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
  83                 }
  84                 else
  85                 {
  86                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
  87                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
  88                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
  89                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
  90                 }
  91                 R_EndPolygon();
  92         }
  93 }
  94
  95 void(vector coord3d, vector pangles, vector rgb) draw_teamradar_player =
  96 {
  97         vector coord, rgb2;
  98
  99         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord3d));
 100
 101         makevectors(pangles - '0 1 0' * teamradar_angle);
 102         if(v_flipped)
 103         {
 104                 v_forward_x = -v_forward_x;
 105                 v_right_x = -v_right_x;
 106                 v_up_x = -v_up_x;
 107         }
 108         v_forward_z = 0;
 109         v_forward = normalize(v_forward);
 110         v_forward_y *= -1.0;
 111         v_right_x = -v_forward_y;
 112         v_right_y = v_forward_x;
 113
 114         if(rgb == '1 1 1')
 115                 rgb2 = '0 0 0';
 116         else
 117                 rgb2 = '1 1 1';
 118
 119         R_BeginPolygon("", 0);
 120         R_PolygonVertex(coord+v_forward*3, '0 0 0', rgb2, 1);
 121         R_PolygonVertex(coord+v_right*4-v_forward*2.5, '0 1 0', rgb2, 1);
 122         R_PolygonVertex(coord-v_forward*2, '1 0 0', rgb2, 1);
 123         R_PolygonVertex(coord-v_right*4-v_forward*2.5, '1 1 0', rgb2, 1);
 124         R_EndPolygon();
 125
 126         R_BeginPolygon("", 0);
 127         R_PolygonVertex(coord+v_forward*2, '0 0 0', rgb, 1);
 128         R_PolygonVertex(coord+v_right*3-v_forward*2, '0 1 0', rgb, 1);
 129         R_PolygonVertex(coord-v_forward, '1 0 0', rgb, 1);
 130         R_PolygonVertex(coord-v_right*3-v_forward*2, '1 1 0', rgb, 1);
 131         R_EndPolygon();
 132 };
 133
 134 void draw_teamradar_icon(vector coord, float icon, entity pingdata, vector rgb, float a)
 135 {
 136         float dt;
 137         vector v;
 138         float i;
 139
 140         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord));
 141         drawpic(coord - '4 4 0', strcat("gfx/teamradar_icon_", ftos(icon)), '8 8 0', rgb, a, 0);
 142
 143         if(pingdata)
 144         {
 145                 for(i = 0; i < MAX_TEAMRADAR_TIMES; ++i)
 146                 {
 147                         dt = pingdata.(teamradar_times[i]);
 148                         if(dt == 0)
 149                                 continue;
 150                         dt = time - dt;
 151                         if(dt > 1)
 152                                 continue;
 153                         v = '2 2 0' * teamradar_size * dt;
 154                         drawpic(coord - 0.5 * v, "gfx/teamradar_ping", v, '1 1 1', 1 - dt, DRAWFLAG_ADDITIVE);
 155                 }
 156         }
 157 }
 158
 159 void draw_teamradar_link(vector start, vector end, float colors)
 160 {
 161         vector c0, c1, norm;
 162
 163         start = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(start));
 164         end = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(end));
 165         norm = normalize(start - end);
 166         norm_z = norm_x;
 167         norm_x = -norm_y;
 168         norm_y = norm_z;
 169         norm_z = 0;
 170
 171         c0 = colormapPaletteColor(colors & 0x0F, FALSE);
 172         c1 = colormapPaletteColor((colors & 0xF0) / 0x10, FALSE);
 173
 174         R_BeginPolygon("", 0);
 175         R_PolygonVertex(start - norm, '0 0 0', c0, 1);
 176         R_PolygonVertex(start + norm, '0 1 0', c0, 1);
 177         R_PolygonVertex(end + norm, '1 1 0', c1, 1);
 178         R_PolygonVertex(end - norm, '1 0 0', c1, 1);
 179         R_EndPolygon();
 180 }
 181
 182 float cl_teamradar_scale;
 183 float cl_teamradar_background_alpha;
 184 float cl_teamradar_foreground_alpha;
 185 float cl_teamradar_rotation;
 186 vector cl_teamradar_size;
 187 vector cl_teamradar_position;
 188 float cl_teamradar_zoommode;
 189
 190 void teamradar_loadcvars()
 191 {
 192         v_flipped = cvar("v_flipped");
 193         if(ons_showmap)
 194         {
 195                 cl_teamradar_scale = 42; // dummy, not used (see zoommode)
 196                 cl_teamradar_background_alpha = 1;
 197                 cl_teamradar_foreground_alpha = 1;
 198                 cl_teamradar_rotation = cvar("cl_teamradar_rotation");
 199                 if(!cl_teamradar_rotation)
 200                         cl_teamradar_rotation = 4;
 201                 cl_teamradar_size = '256 256 0'; // TODO make somewhat variable?
 202                 cl_teamradar_position = '0.5 0.5 0';
 203                 cl_teamradar_zoommode = 3;
 204         }
 205         else
 206         {
 207                 cl_teamradar_scale = cvar("cl_teamradar_scale");
 208                 cl_teamradar_background_alpha = cvar("cl_teamradar_background_alpha");
 209                 cl_teamradar_foreground_alpha = cvar("cl_teamradar_foreground_alpha");
 210                 cl_teamradar_rotation = cvar("cl_teamradar_rotation");
 211                 cl_teamradar_size = stov(cvar_string("cl_teamradar_size"));
 212                 cl_teamradar_position = stov(cvar_string("cl_teamradar_position"));
 213                 cl_teamradar_zoommode = cvar("cl_teamradar_zoommode");
 214
 215                 // others default to 0
 216                 // match this to defaultNexuiz.cfg!
 217                 if(!cl_teamradar_scale) cl_teamradar_scale = 4096;
 218                 if(!cl_teamradar_background_alpha) cl_teamradar_background_alpha = 0.4;
 219                 if(!cl_teamradar_foreground_alpha) cl_teamradar_foreground_alpha = 0.8;
 220                 if(!cl_teamradar_size_x) cl_teamradar_size_x = 128;
 221                 if(!cl_teamradar_size_y) cl_teamradar_size_y = cl_teamradar_size_x;
 222
 223                 cl_teamradar_size_z = 0;
 224                 cl_teamradar_position_z = 0;
 225         }
 226 }
 227
 228 void() teamradar_view =
 229 {
 230         local float color, color2;
 231         local vector rgb;
 232         local entity tm;
 233         float scale2d, normalsize, bigsize;
 234         float f;
 235
 236         if(minimapname == "" && !ons_showmap)
 237                 return;
 238
 239         teamradar_loadcvars();
 240
 241         switch(cl_teamradar_zoommode)
 242         {
 243                 default:
 244                 case 0:
 245                         f = current_zoomfraction;
 246                         break;
 247                 case 1:
 248                         f = 1 - current_zoomfraction;
 249                         break;
 250                 case 2:
 251                         f = 0;
 252                         break;
 253                 case 3:
 254                         f = 1;
 255                         break;
 256         }
 257
 258         switch(cl_teamradar_rotation)
 259         {
 260                 case 0:
 261                         teamradar_angle = view_angles_y - 90;
 262                         break;
 263                 default:
 264                         teamradar_angle = 90 * cl_teamradar_rotation;
 265                         break;
 266         }
 267
 268         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
 269         teamradar_size2d = cl_teamradar_size;
 270         teamradar_origin2d =
 271                   '1 0 0' * (0.5 * teamradar_size2d_x + cl_teamradar_position_x * (vid_conwidth - teamradar_size2d_x))
 272                 + '0 1 0' * (0.5 * teamradar_size2d_y + cl_teamradar_position_y * (vid_conheight - teamradar_size2d_y));
 273
 274         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
 275         if(cl_teamradar_rotation == 0)
 276         {
 277                 // max-min distance must fit the radar in any rotation
 278                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_max - mi_min));
 279         }
 280         else
 281         {
 282                 vector c0, c1, c2, c3, span;
 283                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
 284                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
 285                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
 286                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
 287                 span = '0 0 0';
 288                 span_x = max4(c0_x, c1_x, c2_x, c3_x) - min4(c0_x, c1_x, c2_x, c3_x);
 289                 span_y = max4(c0_y, c1_y, c2_y, c3_y) - min4(c0_y, c1_y, c2_y, c3_y);
 290
 291                 // max-min distance must fit the radar in x=x, y=y
 292                 bigsize = min(
 293                         teamradar_size2d_x * scale2d / (1.05 * span_x),
 294                         teamradar_size2d_y * scale2d / (1.05 * span_y)
 295                 );
 296         }
 297
 298         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / cl_teamradar_scale;
 299         if(bigsize > normalsize)
 300                 normalsize = bigsize;
 301
 302         teamradar_size =
 303                   f * bigsize
 304                 + (1 - f) * normalsize;
 305         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
 306                   f * (mi_min + mi_max) * 0.5
 307                 + (1 - f) * view_origin);
 308
 309         color = GetPlayerColor(player_localentnum-1);
 310         rgb = GetTeamRGB(color);
 311
 312         drawsetcliparea(
 313                 teamradar_origin2d_x - teamradar_size2d_x * 0.5,
 314                 teamradar_origin2d_y - teamradar_size2d_y * 0.5,
 315                 teamradar_size2d_x,
 316                 teamradar_size2d_y
 317         );
 318
 319         draw_teamradar_background(cl_teamradar_background_alpha, cl_teamradar_foreground_alpha);
 320
 321         if(ons_showmap)
 322         {
 323                 drawresetcliparea();
 324
 325                 vector frame_origin, frame_size;
 326                 frame_origin = frame_size = '0 0 0';
 327
 328                 frame_origin_x = teamradar_origin2d_x - teamradar_size2d_x * 0.55859375;
 329                 frame_origin_y = teamradar_origin2d_y - teamradar_size2d_y * 0.55859375;
 330                 frame_size_x = teamradar_size2d_x * 1.1171875;
 331                 frame_size_y = teamradar_size2d_y * 1.1171875;
 332                 drawpic(frame_origin, "gfx/ons-frame.tga", frame_size, '1 1 1', 1, 0);
 333                 drawpic(frame_origin, "gfx/ons-frame-team.tga", frame_size, rgb, 1, 0);
 334
 335                 drawsetcliparea(
 336                         teamradar_origin2d_x - teamradar_size2d_x * 0.5,
 337                         teamradar_origin2d_y - teamradar_size2d_y * 0.5,
 338                         teamradar_size2d_x,
 339                         teamradar_size2d_y
 340                 );
 341         }
 342
 343         for(tm = world; (tm = find(tm, classname, "radarlink")); )
 344                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
 345         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
 346                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, tm.alpha);
 347         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
 348         {
 349                 color2 = GetPlayerColor(tm.sv_entnum);
 350                 //if(color == COLOR_SPECTATOR || color == color2)
 351                         draw_teamradar_player(tm.origin, tm.angles, GetTeamRGB(color2));
 352         }
 353         draw_teamradar_player(view_origin, view_angles, '1 1 1');
 354
 355         drawresetcliparea();
 356 };
 357
 358
 359
 360 // radar links
 361
 362 void Ent_RadarLink()
 363 {
 364         float sendflags;
 365         sendflags = ReadByte();
 366
 367         InterpolateOrigin_Undo();
 368
 369         self.iflags = IFLAG_VELOCITY;
 370         self.classname = "radarlink";
 371
 372         if(sendflags & 1)
 373         {
 374                 self.origin_x = ReadCoord();
 375                 self.origin_y = ReadCoord();
 376                 self.origin_z = ReadCoord();
 377         }
 378
 379         if(sendflags & 2)
 380         {
 381                 self.velocity_x = ReadCoord();
 382                 self.velocity_y = ReadCoord();
 383                 self.velocity_z = ReadCoord();
 384         }
 385
 386         if(sendflags & 4)
 387         {
 388                 self.team = ReadByte();
 389         }
 390
 391         InterpolateOrigin_Note();
 392 }