data/qcsrc/client/teamradar.qc

   1 float teamradar_angle; // player yaw angle
   2 vector teamradar_origin3d_in_texcoord; // player origin
   3 vector teamradar_origin2d; // 2D origin
   4 vector teamradar_size2d; // 2D size
   5 float teamradar_size; // 2D scale factor
   6 float cl_teamradar_scale; // window size = ...qu
   7 float v_flipped;
   8
   9 float vlen2d(vector v)
  10 {
  11         return sqrt(v_x * v_x + v_y * v_y);
  12 }
  13
  14 float vlen_maxnorm2d(vector v)
  15 {
  16         return max4(v_x, v_y, -v_x, -v_y);
  17 }
  18
  19 float vlen_minnorm2d(vector v)
  20 {
  21         return min(max(v_x, -v_x), max(v_y, -v_y));
  22 }
  23
  24 vector teamradar_3dcoord_to_texcoord(vector in)
  25 {
  26         vector out;
  27         out_x = (in_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
  28         out_y = (in_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
  29         out_z = 0;
  30         return out;
  31 }
  32
  33 vector teamradar_texcoord_to_2dcoord(vector in)
  34 {
  35         vector out;
  36         in -= teamradar_origin3d_in_texcoord;
  37
  38         out = rotate(in, teamradar_angle * DEG2RAD);
  39         out_y = - out_y; // screen space is reversed
  40
  41         out = out * teamradar_size;
  42         if(v_flipped)
  43                 out_x = -out_x;
  44         out += teamradar_origin2d;
  45         return out;
  46 }
  47
  48 vector yinvert(vector v)
  49 {
  50         v_y = 1 - v_y;
  51         return v;
  52 }
  53
  54 void draw_teamradar_background(float bg, float fg)
  55 {
  56         float fga;
  57         vector fgc;
  58         if(bg > 0)
  59         {
  60                 R_BeginPolygon("", 0);
  61                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  62                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  63                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  64                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  65                 R_EndPolygon();
  66         }
  67
  68         if(fg > 0 && minimapname != "")
  69         {
  70                 fga = 1;
  71                 fgc = '1 1 1' * fg;
  72                 R_BeginPolygon(minimapname, DRAWFLAG_SCREEN | DRAWFLAG_MIPMAP);
  73                 if(v_flipped)
  74                 {
  75                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
  76                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
  77                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
  78                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
  79                 }
  80                 else
  81                 {
  82                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
  83                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
  84                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
  85                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
  86                 }
  87                 R_EndPolygon();
  88         }
  89 }
  90
  91 void(vector coord3d, vector pangles, vector rgb) draw_teamradar_player =
  92 {
  93         vector coord, rgb2;
  94
  95         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord3d));
  96
  97         makevectors(pangles - '0 1 0' * teamradar_angle);
  98         if(v_flipped)
  99         {
 100                 v_forward_x = -v_forward_x;
 101                 v_right_x = -v_right_x;
 102                 v_up_x = -v_up_x;
 103         }
 104         v_forward_z = 0;
 105         v_forward = normalize(v_forward);
 106         v_forward_y *= -1.0;
 107         v_right_x = -v_forward_y;
 108         v_right_y = v_forward_x;
 109
 110         if(rgb == '1 1 1')
 111                 rgb2 = '0 0 0';
 112         else
 113                 rgb2 = '1 1 1';
 114
 115         R_BeginPolygon("", 0);
 116         R_PolygonVertex(coord+v_forward*3, '0 0 0', rgb2, 1);
 117         R_PolygonVertex(coord+v_right*4-v_forward*2.5, '0 1 0', rgb2, 1);
 118         R_PolygonVertex(coord-v_forward*2, '1 0 0', rgb2, 1);
 119         R_PolygonVertex(coord-v_right*4-v_forward*2.5, '1 1 0', rgb2, 1);
 120         R_EndPolygon();
 121
 122         R_BeginPolygon("", 0);
 123         R_PolygonVertex(coord+v_forward*2, '0 0 0', rgb, 1);
 124         R_PolygonVertex(coord+v_right*3-v_forward*2, '0 1 0', rgb, 1);
 125         R_PolygonVertex(coord-v_forward, '1 0 0', rgb, 1);
 126         R_PolygonVertex(coord-v_right*3-v_forward*2, '1 1 0', rgb, 1);
 127         R_EndPolygon();
 128 };
 129
 130 void draw_teamradar_icon(vector coord, float icon, entity pingdata, vector rgb, float a)
 131 {
 132         float dt;
 133         vector v;
 134         float i;
 135
 136         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord));
 137         drawpic(coord - '4 4 0', strcat("gfx/teamradar_icon_", ftos(icon)), '8 8 0', rgb, a, 0);
 138
 139         if(pingdata)
 140         {
 141                 for(i = 0; i < MAX_TEAMRADAR_TIMES; ++i)
 142                 {
 143                         dt = pingdata.(teamradar_times[i]);
 144                         if(dt == 0)
 145                                 continue;
 146                         dt = time - dt;
 147                         if(dt > 1)
 148                                 continue;
 149                         v = '2 2 0' * teamradar_size * dt;
 150                         drawpic(coord - 0.5 * v, "gfx/teamradar_ping", v, '1 1 1', 1 - dt, DRAWFLAG_ADDITIVE);
 151                 }
 152         }
 153 }
 154
 155 void draw_teamradar_link(vector start, vector end, float colors)
 156 {
 157         vector c0, c1, norm;
 158
 159         start = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(start));
 160         end = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(end));
 161         norm = normalize(start - end);
 162         norm_z = norm_x;
 163         norm_x = -norm_y;
 164         norm_y = norm_z;
 165         norm_z = 0;
 166
 167         c0 = colormapPaletteColor(colors & 0x0F, FALSE);
 168         c1 = colormapPaletteColor((colors & 0xF0) / 0x10, FALSE);
 169
 170         R_BeginPolygon("", 0);
 171         R_PolygonVertex(start - norm, '0 0 0', c0, 1);
 172         R_PolygonVertex(start + norm, '0 1 0', c0, 1);
 173         R_PolygonVertex(end + norm, '1 1 0', c1, 1);
 174         R_PolygonVertex(end - norm, '1 0 0', c1, 1);
 175         R_EndPolygon();
 176 }
 177
 178 float cl_teamradar_scale;
 179 float cl_teamradar_background_alpha;
 180 float cl_teamradar_foreground_alpha;
 181 float cl_teamradar_rotation;
 182 vector cl_teamradar_size;
 183 vector cl_teamradar_position;
 184 float cl_teamradar_zoommode;
 185
 186 void teamradar_loadcvars()
 187 {
 188         v_flipped = cvar("v_flipped");
 189         if(ons_showmap)
 190         {
 191                 cl_teamradar_scale = 42; // dummy, not used (see zoommode)
 192                 cl_teamradar_background_alpha = 1;
 193                 cl_teamradar_foreground_alpha = 1;
 194                 cl_teamradar_rotation = cvar("cl_teamradar_rotation");
 195                 if(!cl_teamradar_rotation)
 196                         cl_teamradar_rotation = 4;
 197                 cl_teamradar_size = '256 256 0'; // TODO make somewhat variable?
 198                 cl_teamradar_position = '0.5 0.5 0';
 199                 cl_teamradar_zoommode = 3;
 200         }
 201         else
 202         {
 203                 cl_teamradar_scale = cvar("cl_teamradar_scale");
 204                 cl_teamradar_background_alpha = cvar("cl_teamradar_background_alpha");
 205                 cl_teamradar_foreground_alpha = cvar("cl_teamradar_foreground_alpha");
 206                 cl_teamradar_rotation = cvar("cl_teamradar_rotation");
 207                 cl_teamradar_size = stov(cvar_string("cl_teamradar_size"));
 208                 cl_teamradar_position = stov(cvar_string("cl_teamradar_position"));
 209                 cl_teamradar_zoommode = cvar("cl_teamradar_zoommode");
 210
 211                 // others default to 0
 212                 // match this to defaultNexuiz.cfg!
 213                 if(!cl_teamradar_scale) cl_teamradar_scale = 4096;
 214                 if(!cl_teamradar_background_alpha) cl_teamradar_background_alpha = 0.4;
 215                 if(!cl_teamradar_foreground_alpha) cl_teamradar_foreground_alpha = 0.8;
 216                 if(!cl_teamradar_size_x) cl_teamradar_size_x = 128;
 217                 if(!cl_teamradar_size_y) cl_teamradar_size_y = cl_teamradar_size_x;
 218
 219                 cl_teamradar_size_z = 0;
 220                 cl_teamradar_position_z = 0;
 221         }
 222 }
 223
 224 void() teamradar_view =
 225 {
 226         local float color, color2;
 227         local vector rgb;
 228         local entity tm;
 229         float scale2d, normalsize, bigsize;
 230         float f;
 231
 232         if(minimapname == "" && !ons_showmap)
 233                 return;
 234
 235         teamradar_loadcvars();
 236
 237         switch(cl_teamradar_zoommode)
 238         {
 239                 default:
 240                 case 0:
 241                         f = current_zoomfraction;
 242                         break;
 243                 case 1:
 244                         f = 1 - current_zoomfraction;
 245                         break;
 246                 case 2:
 247                         f = 0;
 248                         break;
 249                 case 3:
 250                         f = 1;
 251                         break;
 252         }
 253
 254         switch(cl_teamradar_rotation)
 255         {
 256                 case 0:
 257                         teamradar_angle = view_angles_y - 90;
 258                         break;
 259                 default:
 260                         teamradar_angle = 90 * cl_teamradar_rotation;
 261                         break;
 262         }
 263
 264         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
 265         teamradar_size2d = cl_teamradar_size;
 266         teamradar_origin2d =
 267                   '1 0 0' * (0.5 * teamradar_size2d_x + cl_teamradar_position_x * (vid_conwidth - teamradar_size2d_x))
 268                 + '0 1 0' * (0.5 * teamradar_size2d_y + cl_teamradar_position_y * (vid_conheight - teamradar_size2d_y));
 269
 270         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
 271         if(cl_teamradar_rotation == 0)
 272         {
 273                 // max-min distance must fit the radar in any rotation
 274                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_max - mi_min));
 275         }
 276         else
 277         {
 278                 vector c0, c1, c2, c3, span;
 279                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
 280                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
 281                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
 282                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
 283                 span = '0 0 0';
 284                 span_x = max4(c0_x, c1_x, c2_x, c3_x) - min4(c0_x, c1_x, c2_x, c3_x);
 285                 span_y = max4(c0_y, c1_y, c2_y, c3_y) - min4(c0_y, c1_y, c2_y, c3_y);
 286
 287                 // max-min distance must fit the radar in x=x, y=y
 288                 bigsize = min(
 289                         teamradar_size2d_x * scale2d / (1.05 * span_x),
 290                         teamradar_size2d_y * scale2d / (1.05 * span_y)
 291                 );
 292         }
 293
 294         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / cl_teamradar_scale;
 295         if(bigsize > normalsize)
 296                 normalsize = bigsize;
 297
 298         teamradar_size =
 299                   f * bigsize
 300                 + (1 - f) * normalsize;
 301         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
 302                   f * (mi_min + mi_max) * 0.5
 303                 + (1 - f) * view_origin);
 304
 305         color = GetPlayerColor(player_localentnum-1);
 306         rgb = GetTeamRGB(color);
 307
 308         drawsetcliparea(
 309                 teamradar_origin2d_x - teamradar_size2d_x * 0.5,
 310                 teamradar_origin2d_y - teamradar_size2d_y * 0.5,
 311                 teamradar_size2d_x,
 312                 teamradar_size2d_y
 313         );
 314
 315         draw_teamradar_background(cl_teamradar_background_alpha, cl_teamradar_foreground_alpha);
 316
 317         if(ons_showmap)
 318         {
 319                 drawresetcliparea();
 320
 321                 vector frame_origin, frame_size;
 322                 frame_origin = frame_size = '0 0 0';
 323
 324                 frame_origin_x = teamradar_origin2d_x - teamradar_size2d_x * 0.55859375;
 325                 frame_origin_y = teamradar_origin2d_y - teamradar_size2d_y * 0.55859375;
 326                 frame_size_x = teamradar_size2d_x * 1.1171875;
 327                 frame_size_y = teamradar_size2d_y * 1.1171875;
 328                 drawpic(frame_origin, "gfx/ons-frame.tga", frame_size, '1 1 1', 1, 0);
 329                 drawpic(frame_origin, "gfx/ons-frame-team.tga", frame_size, rgb, 1, 0);
 330
 331                 drawsetcliparea(
 332                         teamradar_origin2d_x - teamradar_size2d_x * 0.5,
 333                         teamradar_origin2d_y - teamradar_size2d_y * 0.5,
 334                         teamradar_size2d_x,
 335                         teamradar_size2d_y
 336                 );
 337         }
 338
 339         for(tm = world; (tm = find(tm, classname, "radarlink")); )
 340                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
 341         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
 342                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, tm.alpha);
 343         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
 344         {
 345                 color2 = GetPlayerColor(tm.sv_entnum);
 346                 //if(color == COLOR_SPECTATOR || color == color2)
 347                         draw_teamradar_player(tm.origin, tm.angles, GetTeamRGB(color2));
 348         }
 349         draw_teamradar_player(view_origin, view_angles, '1 1 1');
 350
 351         drawresetcliparea();
 352 };
 353
 354
 355
 356 // radar links
 357
 358 void Ent_RadarLink()
 359 {
 360         float sendflags;
 361         sendflags = ReadByte();
 362
 363         InterpolateOrigin_Undo();
 364
 365         self.iflags = IFLAG_VELOCITY;
 366         self.classname = "radarlink";
 367
 368         if(sendflags & 1)
 369         {
 370                 self.origin_x = ReadCoord();
 371                 self.origin_y = ReadCoord();
 372                 self.origin_z = ReadCoord();
 373         }
 374
 375         if(sendflags & 2)
 376         {
 377                 self.velocity_x = ReadCoord();
 378                 self.velocity_y = ReadCoord();
 379                 self.velocity_z = ReadCoord();
 380         }
 381
 382         if(sendflags & 4)
 383         {
 384                 self.team = ReadByte();
 385         }
 386
 387         InterpolateOrigin_Note();
 388 }