data/qcsrc/client/sbar.qc

   1
   2 float last_weapon;
   3 float activeweapon;
   4 float weapontime;
   5
   6 float sb_lines; // still don't know what to do with that NOTE: check dp's sbar.c to see what that should be
   7
   8 vector sbar;
   9 float sbar_alpha_fg;
  10 float sbar_hudselector;
  11 /*
  12 entity sortedPlayers;
  13 entity sortedTeams;
  14
  15 .float sb_frags;
  16 .float sb_team;
  17 .float sb_player;
  18 .float sb_caps;
  19 */
  20 float ps_primary, ps_secondary;
  21 float ts_primary, ts_secondary;
  22
  23 entity team1, team2, team3, team4, teamspec;
  24
  25 void CSQC_kh_hud();
  26 void CSQC_ctf_hud();
  27 void MapVote_Draw();
  28 void Sbar_FinaleOverlay()
  29 {
  30         /*vector pos;
  31         pos_x = (vid_conwidth - 1)/2;
  32         pos_y = 16;
  33         pos_z = 0;*/
  34
  35         //drawpic(pos, "gfx/finale", '0 0 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
  36
  37         //drawstring(pos, "END", sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
  38         MapVote_Draw();
  39 }
  40
  41 void Sbar_DrawWeapon(float nr, float fade, float active)
  42 {
  43         vector pos, vsize, color;
  44         float value;
  45
  46         value = (active) ? 1 : 0.6;
  47         color_x = color_y = color_z = value;
  48
  49         if(sbar_hudselector == 1)
  50         {
  51                 // width = 300, height = 100
  52                 const float w_width = 32, w_height = 12, w_space = 2, font_size = 8;
  53
  54                 pos_x = (vid_conwidth - w_width * 9) * 0.5 + w_width * nr;
  55                 pos_y = (vid_conheight - w_height);
  56                 pos_z = 0;
  57                 vsize_x = w_width;
  58                 vsize_y = w_height;
  59                 vsize_z = 0;
  60                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
  61                 pos_x += w_space;
  62                 pos_y += w_space;
  63                 vsize_x = font_size;
  64                 vsize_y = font_size;
  65                 vsize_z = 0;
  66                 drawstring(pos, ftos(nr+1), vsize, '1 1 0', sbar_alpha_fg, 0);
  67
  68         }
  69         else
  70         {
  71                 // width = 300, height = 100
  72                 const float w2_width = 300, w2_height = 100, w2_space = 10;
  73                 const float w2_scale = 0.4;
  74
  75                 pos_x = vid_conwidth - (w2_width + w2_space) * w2_scale;
  76                 pos_y = (w2_height + w2_space) * w2_scale * nr + w2_space;
  77                 pos_z = 0;
  78                 vsize_x = w2_width * w2_scale;
  79                 vsize_y = w2_height * w2_scale;
  80                 vsize_z = 0;
  81
  82                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
  83         }
  84 }
  85 void Sbar_DrawXNum (vector pos, float num, float digits, float lettersize, vector rgb, float a, float dflags)
  86 {
  87         float l, i;
  88         string str, tmp;
  89         float minus;
  90         vector vsize;
  91
  92         vsize_x = vsize_y = lettersize;
  93         vsize_z = 0;
  94
  95         if(num < 0)
  96         {
  97                 minus = true;
  98                 num = -num;
  99                 pos_x -= lettersize;
 100         } else
 101                 minus = false;
 102
 103         if(digits < 0)
 104         {
 105                 tmp = ftos(num);
 106                 digits = -digits;
 107                 str = strcat(substring("0000000000", 0, digits - strlen(tmp)), tmp);
 108         } else
 109                 str = ftos(num);
 110
 111         l = strlen(str);
 112
 113         if(l > digits)
 114         {
 115                 str = substring(str, l-digits, 999);
 116                 l = strlen(str);
 117         } else if(l < digits)
 118                 pos_x += (digits-l) * lettersize;
 119
 120         if(minus)
 121         {
 122                 drawpic(sbar + pos, "gfx/num_minus", vsize, rgb, a * sbar_alpha_fg, dflags);
 123                 pos_x += lettersize;
 124         }
 125
 126         for(i = 0; i < l; ++i)
 127         {
 128                 drawpic(sbar + pos, strcat("gfx/num_", substring(str, i, 1)), vsize, rgb, a * sbar_alpha_fg, dflags);
 129                 pos_x += lettersize;
 130         }
 131 }
 132
 133 void Cmd_Sbar_SetFields(float argc);
 134 void Sbar_InitScores()
 135 {
 136         float i, f, primary_prio, secondary_prio;
 137
 138         ps_primary = ps_secondary = ts_primary = ts_secondary = -1;
 139         for(i = 0; i < MAX_SCORE; ++i)
 140         {
 141                 f = (scores_flags[i] & SFL_SORT_PRIO_MASK);
 142                 if(f == SFL_SORT_PRIO_PRIMARY)
 143                         ps_primary = i;
 144                 if(f == SFL_SORT_PRIO_SECONDARY)
 145                         ps_secondary = i;
 146         }
 147         if(ps_secondary == -1)
 148                 ps_secondary = ps_primary;
 149
 150         for(i = 0; i < MAX_TEAMSCORE; ++i)
 151         {
 152                 f = (teamscores_flags[i] & SFL_SORT_PRIO_MASK);
 153                 if(f == SFL_SORT_PRIO_PRIMARY)
 154                         ts_primary = i;
 155                 if(f == SFL_SORT_PRIO_SECONDARY)
 156                         ts_secondary = i;
 157         }
 158         if(ts_secondary == -1)
 159                 ts_secondary = ts_primary;
 160
 161         Cmd_Sbar_SetFields(0);
 162 }
 163
 164 void Sbar_UpdatePlayerPos(entity pl);
 165 void Sbar_UpdatePlayerTeams()
 166 {
 167         float Team;
 168         entity pl, tmp;
 169         float num;
 170
 171         num = 0;
 172         for(pl = players.sort_next; pl; pl = pl.sort_next)
 173         {
 174                 num += 1;
 175                 Team = GetPlayerColor(pl.sv_entnum);
 176                 if(pl.team != Team)
 177                 {
 178                         tmp = GetTeam(pl.team, false);
 179                         tmp.team_size -= 1;
 180                         tmp = GetTeam(Team, true);
 181                         tmp.team_size += 1;
 182
 183                         pl.team = Team;
 184
 185                         tmp = pl.sort_prev;
 186                         Sbar_UpdatePlayerPos(pl);
 187                         if(tmp)
 188                                 pl = tmp;
 189                         else
 190                                 pl = players.sort_next;
 191                 }
 192         }
 193         //print(strcat("PNUM: ", ftos(num), "\n"));
 194 }
 195
 196 float Sbar_ComparePlayerScores(entity left, entity right)
 197 {
 198         float vl, vr;
 199         vl = GetPlayerColor(left.sv_entnum);
 200         vr = GetPlayerColor(right.sv_entnum);
 201
 202         if(vl > vr)
 203                 return true;
 204         if(vl < vr)
 205                 return false;
 206
 207         vl = left.scores[ps_primary];
 208         vr = right.scores[ps_primary];
 209         if(vl > vr)
 210                 return IS_INCREASING(scores_flags[ps_primary]);
 211         if(vl < vr)
 212                 return IS_DECREASING(scores_flags[ps_primary]);
 213
 214         vl = left.scores[ps_secondary];
 215         vr = right.scores[ps_secondary];
 216         if(vl > vr)
 217                 return IS_INCREASING(scores_flags[ps_secondary]);
 218         if(vl < vr)
 219                 return IS_DECREASING(scores_flags[ps_secondary]);
 220
 221         return false;
 222 }
 223
 224 void Sbar_UpdatePlayerPos(entity player)
 225 {
 226         for(other = player.sort_next; other && Sbar_ComparePlayerScores(player, other); other = player.sort_next)
 227         {
 228                 SORT_SWAP(player, other);
 229         }
 230         for(other = player.sort_prev; other != players && Sbar_ComparePlayerScores(other, player); other = player.sort_prev)
 231         {
 232                 SORT_SWAP(other, player);
 233         }
 234 }
 235
 236 float Sbar_CompareTeamScores(entity left, entity right)
 237 {
 238         float vl, vr;
 239
 240         if(left.team == COLOR_SPECTATOR)
 241                 return 1;
 242         if(right.team == COLOR_SPECTATOR)
 243                 return 0;
 244
 245         vl = left.teamscores[ts_primary];
 246         vr = right.teamscores[ts_primary];
 247         if(vl > vr)
 248                 return IS_INCREASING(teamscores_flags[ts_primary]);
 249         if(vl < vr)
 250                 return IS_DECREASING(teamscores_flags[ts_primary]);
 251
 252         vl = left.teamscores[ts_secondary];
 253         vr = right.teamscores[ts_secondary];
 254         if(vl > vr)
 255                 return IS_INCREASING(teamscores_flags[ts_secondary]);
 256         if(vl < vr)
 257                 return IS_DECREASING(teamscores_flags[ts_secondary]);
 258
 259         return false;
 260 }
 261
 262 void Sbar_UpdateTeamPos(entity Team)
 263 {
 264         for(other = Team.sort_next; other && Sbar_CompareTeamScores(Team, other); other = Team.sort_next)
 265         {
 266                 SORT_SWAP(Team, other);
 267         }
 268         for(other = Team.sort_prev; other != teams && Sbar_CompareTeamScores(other, Team); other = Team.sort_prev)
 269         {
 270                 SORT_SWAP(other, Team);
 271         }
 272 }
 273
 274 void Cmd_Sbar_Help(float argc)
 275 {
 276         print("You can modify the scoreboard using the\n");
 277         print("^3|---------------------------------------------------------------|\n");
 278         print("^1 TO BE DONE\n");
 279         print("Usage:\n");
 280         print("^2sbar_columns_set default\n");
 281         print("^2sbar_columns_set ^7filed1 field2 ...\n");
 282         print("The following field names are recognized (case INsensitive):\n");
 283         print("You can use a ^3|^7 to start the right-aligned fields.\n");
 284
 285         print("^3name^7 or ^3nick^7             Name of a player\n");
 286         print("^3ping^7                     Ping time\n\n");
 287         print("^3kd^7 or ^3kdr^7 or ^3kdratio^7 or ^3k/d\n");
 288         print("                         The kill-death ratio\n");
 289
 290         print("Before a field you can put a + or - sign, then a comma separated list\n");
 291         print("of game types, then a slash, to make the field show up only in these\n");
 292         print("or in all but these game types.\n");
 293
 294         local float i;
 295         print("Additional columns:\n");
 296         for(i = 0; i < MAX_SCORE; ++i)
 297         {
 298                 if(scores_label[i] != "")
 299                         print(strcat(scores_label[i], "\n"));
 300         }
 301 }
 302
 303 #define MIN_NAMELEN 24
 304 #define MAX_NAMELEN 24
 305
 306 string Sbar_DefaultColumnLayout()
 307 {
 308         return "ping name | -ctf,kh/kills -ctf,kh/deaths +lms/lives +lms/rank +kh,ctf/caps +kh/pushes +kh/destroyed -lms/score";
 309 }
 310
 311 void Cmd_Sbar_SetFields(float argc)
 312 {
 313         float i, j, slash;
 314         string str, pattern, subpattern;
 315         float digit;
 316         float have_name, have_primary, have_secondary, have_separator;
 317         float missing;
 318
 319         // TODO: re enable with gametype dependant cvars?
 320         if(argc < 2) // no arguments provided
 321                 argc = tokenizebyseparator(strcat("x ", cvar_string("sbar_columns")), " ");
 322
 323         if(argc < 2)
 324                 argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 325
 326         if(argc == 2)
 327         {
 328                 if(argv(1) == "default")
 329                         argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 330                 else if(argv(1) == "all")
 331                 {
 332                         string s;
 333                         s = "ping name |";
 334                         for(i = 0; i < MAX_SCORE; ++i)
 335                         {
 336                                 if(i != ps_primary)
 337                                 if(i != ps_secondary)
 338                                 if(scores_label[i] != "")
 339                                         s = strcat(s, " ", scores_label[i]);
 340                         }
 341                         if(ps_secondary != ps_primary)
 342                                 s = strcat(s, " ", scores_label[ps_secondary]);
 343                         s = strcat(s, " ", scores_label[ps_primary]);
 344                         argc = tokenizebyseparator(strcat("x ", s), " ");
 345                 }
 346         }
 347
 348
 349         argc = min(MAX_SBAR_FIELDS, argc);
 350         sbar_num_fields = 0;
 351
 352         drawfont = sbar_font;
 353         digit = stringwidth("0123456789", FALSE) / 10;
 354
 355         subpattern = strcat(",", GametypeNameFromType(gametype), ",");
 356
 357         argc = min(argc-1, MAX_SBAR_FIELDS-1);
 358         for(i = 0; i < argc; ++i)
 359         {
 360                 str = argv(i+1);
 361
 362                 slash = strstrofs(str, "/", 0);
 363                 if(slash >= 0)
 364                 {
 365                         pattern = substring(str, 0, slash);
 366                         str = substring(str, slash + 1, strlen(str) - (slash + 1));
 367
 368                         if(substring(pattern, 0, 1) == "-")
 369                         {
 370                                 pattern = substring(pattern, 1, strlen(pattern) - 1);
 371                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
 372                                         continue;
 373                         }
 374                         else
 375                         {
 376                                 if(substring(pattern, 0, 1) == "+")
 377                                         pattern = substring(pattern, 1, strlen(pattern) - 1);
 378                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
 379                                         continue;
 380                         }
 381                 }
 382
 383                 strunzone(sbar_title[sbar_num_fields]);
 384                 sbar_title[sbar_num_fields] = strzone(str);
 385                 sbar_size[sbar_num_fields] = stringwidth(str, FALSE);
 386                 str = strtolower(str);
 387
 388                 if(str == "ping") {
 389                         sbar_field[sbar_num_fields] = SP_PING;
 390                 } else if(str == "name" || str == "nick") {
 391                         sbar_field[sbar_num_fields] = SP_NAME;
 392                         sbar_size[sbar_num_fields] = MIN_NAMELEN; // minimum size? any use?
 393                         have_name = 1;
 394                 } else if(str == "|") {
 395                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 396                         have_separator = 1;
 397                 } else {
 398                         for(j = 0; j < MAX_SCORE; ++j)
 399                                 if(str == strtolower(scores_label[j]))
 400                                         goto found; // sorry, but otherwise fteqcc -O3 miscompiles this and warns about "unreachable code"
 401 :notfound
 402                         print(strcat("^1Error:^7 Unknown score field: '", str, "'\n"));
 403                         continue;
 404 :found
 405                         sbar_field[sbar_num_fields] = j;
 406                         if(j == ps_primary)
 407                                 have_primary = 1;
 408                         if(j == ps_secondary)
 409                                 have_secondary = 1;
 410                 }
 411                 ++sbar_num_fields;
 412         }
 413
 414         if(scores_flags[ps_primary] & SFL_ALLOW_HIDE)
 415                 have_primary = 1;
 416         if(scores_flags[ps_secondary] & SFL_ALLOW_HIDE)
 417                 have_secondary = 1;
 418         if(ps_primary == ps_secondary)
 419                 have_secondary = 1;
 420         missing = !have_primary + !have_secondary + !have_separator + !have_name;
 421
 422         if(sbar_num_fields+missing < MAX_SBAR_FIELDS)
 423         {
 424                 if(!have_name)
 425                 {
 426                         strunzone(sbar_title[sbar_num_fields]);
 427                         for(i = sbar_num_fields; i > 0; --i)
 428                         {
 429                                 sbar_title[i] = sbar_title[i-1];
 430                                 sbar_size[i] = sbar_size[i-1];
 431                                 sbar_field[i] = sbar_field[i-1];
 432                         }
 433                         sbar_title[0] = strzone("name");
 434                         sbar_field[0] = SP_NAME;
 435                         sbar_size[0] = MIN_NAMELEN; // minimum size? any use?
 436                         ++sbar_num_fields;
 437                         print("fixed missing field 'name'\n");
 438
 439                         if(!have_separator)
 440                         {
 441                                 strunzone(sbar_title[sbar_num_fields]);
 442                                 for(i = sbar_num_fields; i > 1; --i)
 443                                 {
 444                                         sbar_title[i] = sbar_title[i-1];
 445                                         sbar_size[i] = sbar_size[i-1];
 446                                         sbar_field[i] = sbar_field[i-1];
 447                                 }
 448                                 sbar_title[1] = strzone("|");
 449                                 sbar_field[1] = SP_SEPARATOR;
 450                                 sbar_size[1] = stringwidth("|", FALSE);
 451                                 ++sbar_num_fields;
 452                                 print("fixed missing field '|'\n");
 453                         }
 454                 }
 455                 else if(!have_separator)
 456                 {
 457                         strunzone(sbar_title[sbar_num_fields]);
 458                         sbar_title[sbar_num_fields] = strzone("|");
 459                         sbar_size[sbar_num_fields] = stringwidth("|", FALSE);
 460                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 461                         ++sbar_num_fields;
 462                         print("fixed missing field '|'\n");
 463                 }
 464
 465                 if(!have_secondary)
 466                 {
 467                         strunzone(sbar_title[sbar_num_fields]);
 468                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_secondary]);
 469                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 470                         sbar_field[sbar_num_fields] = ps_secondary;
 471                         ++sbar_num_fields;
 472                         print("fixed missing field '", scores_label[ps_secondary], "'\n");
 473                 }
 474
 475                 if(!have_primary)
 476                 {
 477                         strunzone(sbar_title[sbar_num_fields]);
 478                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_primary]);
 479                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 480                         sbar_field[sbar_num_fields] = ps_primary;
 481                         ++sbar_num_fields;
 482                         print("fixed missing field '", scores_label[ps_primary], "'\n");
 483                 }
 484         }
 485
 486         sbar_field[sbar_num_fields] = SP_END;
 487 }
 488
 489 // MOVEUP::
 490 vector sbar_field_rgb;
 491 string Sbar_GetField(entity pl, float field)
 492 {
 493         float tmp, num, denom, f;
 494         string str;
 495         sbar_field_rgb = '1 1 1';
 496         switch(field)
 497         {
 498                 case SP_PING:
 499                         str = bufstr_get(databuf, DATABUF_PING + pl.sv_entnum);
 500                         tmp = max(0, min(220, stof(str)-80)) / 220;
 501                         sbar_field_rgb = '1 1 1' - '0 1 1'*tmp;
 502                         return str;
 503
 504                 case SP_NAME:
 505                         return getplayerkey(pl.sv_entnum, "name");
 506
 507                 case SP_KDRATIO:
 508                         num = pl.(scores[SP_KILLS]);
 509                         denom = pl.(scores[SP_DEATHS]);
 510
 511                         if(denom == 0) {
 512                                 sbar_field_rgb = '0 1 0';
 513                                 str = ftos(num);
 514                         } else if(num <= 0) {
 515                                 sbar_field_rgb = '1 0 0';
 516                                 str = ftos(num/denom);
 517                         } else
 518                                 str = ftos(num/denom);
 519
 520                         tmp = strstrofs(str, ".", 0);
 521                         if(tmp > 0)
 522                                 str = substring(str, 0, tmp+2);
 523                         return str;
 524
 525                 default:
 526                         tmp = pl.(scores[field]);
 527                         f = scores_flags[field];
 528                         if(field == ps_primary)
 529                                 sbar_field_rgb = '1 1 0';
 530                         else if(field == ps_secondary)
 531                                 sbar_field_rgb = '0 1 1';
 532                         else
 533                                 sbar_field_rgb = '1 1 1';
 534                         if(!tmp)
 535                                 if(f & SFL_HIDE_ZERO)
 536                                         return "";
 537                         return ftos(tmp);
 538         }
 539         //return "error";
 540 }
 541
 542 // shamelessly stolen from menu QC :P <- as if I would steal YOUR code pfft ;)
 543 float textLengthUpToWidth(string theText, float maxWidth, float handleColors)
 544 {
 545         // STOP.
 546         // The following function is SLOW.
 547         // For your safety and for the protection of those around you...
 548         // DO NOT CALL THIS AT HOME.
 549         // No really, don't.
 550         if(stringwidth(theText, handleColors) <= maxWidth)
 551                 return strlen(theText); // yeah!
 552
 553         // binary search for right place to cut string
 554         float left, right, middle; // this always works
 555         left = 0;
 556         right = strlen(theText); // this always fails
 557         do
 558         {
 559                 middle = floor((left + right) / 2);
 560                 if(stringwidth(substring(theText, 0, middle), handleColors) <= maxWidth)
 561                         left = middle;
 562                 else
 563                         right = middle;
 564         }
 565         while(left < right - 1);
 566
 567         // NOTE: when color codes are involved, this binary search is,
 568         // mathematically, BROKEN. However, it is obviously guaranteed to
 569         // terminate, as the range still halves each time - but nevertheless, it is
 570         // guaranteed that it finds ONE valid cutoff place (where "left" is in
 571         // range, and "right" is outside).
 572
 573         return left;
 574 }
 575 string textShortenToWidth(string theText, float maxWidth, float handleColors)
 576 {
 577         if(stringwidth(theText, handleColors) <= maxWidth)
 578                 return theText;
 579         else
 580                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - stringwidth("...", handleColors), handleColors)), "...");
 581 }
 582
 583 float xmin, xmax, ymin, ymax, sbwidth, sbheight;
 584
 585 void Sbar_PrintScoreboardItem(vector pos, entity pl, float is_self)
 586 {
 587         vector tmp;
 588         string str;
 589         float i, field, len;
 590         float is_spec;
 591         is_spec = (GetPlayerColor(pl.sv_entnum) == COLOR_SPECTATOR);
 592
 593         // Layout:
 594         tmp_z = 0;
 595         if(is_self)
 596         {
 597                 tmp_x = sbwidth;
 598                 tmp_y = sbar_fontsize_y;
 599                 drawfill(pos - '1 1 0', tmp + '2 2 0', '1 1 1', 0.3, DRAWFLAG_NORMAL);
 600         }
 601         tmp_y = 0;
 602
 603         for(i = 0; i < sbar_num_fields; ++i)
 604         {
 605                 field = sbar_field[i];
 606                 if(field == SP_SEPARATOR)
 607                         break;
 608
 609                 if(is_spec && field != SP_NAME && field != SP_PING) {
 610                         pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 611                         continue;
 612                 }
 613                 str = Sbar_GetField(pl, field);
 614
 615                 if(field == SP_NAME)
 616                 {
 617                         float realsize;
 618                         float j;
 619                         realsize = sbar_size[i];
 620                         if(i+1 < sbar_num_fields)
 621                                 if(sbar_field[i+1] == SP_SEPARATOR)
 622                                 {
 623                                         realsize = (xmax - xmin) / sbar_fontsize_x;
 624                                         for(j = 0; j < sbar_num_fields; ++j) if(j != i) if(sbar_field[j] != SP_SEPARATOR)
 625                                                 realsize -= sbar_size[j] + 1;
 626                                         realsize += 1;
 627                                 }
 628                         str = textShortenToWidth(str, realsize, TRUE);
 629                 }
 630                 len = stringwidth(str, TRUE);
 631
 632                 if(sbar_size[i] < len)
 633                         sbar_size[i] = len;
 634
 635                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 636
 637                 if(field == SP_NAME) {
 638                         tmp_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 639                         drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 640                 } else {
 641                         tmp_x = len*sbar_fontsize_x + sbar_fontsize_x;
 642                         drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 643                 }
 644         }
 645
 646         if(sbar_field[i] == SP_SEPARATOR)
 647         {
 648                 pos_x = xmax;
 649                 for(i = sbar_num_fields-1; i > 0; --i)
 650                 {
 651                         field = sbar_field[i];
 652                         if(field == SP_SEPARATOR)
 653                                 break;
 654
 655                         if(is_spec && field != SP_NAME && field != SP_PING) {
 656                                 pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 657                                 continue;
 658                         }
 659
 660                         str = Sbar_GetField(pl, field);
 661
 662                         if(field == SP_NAME)
 663                                 str = textShortenToWidth(str, sbar_size[i], TRUE);
 664                         len = stringwidth(str, TRUE);
 665
 666                         if(sbar_size[i] < len)
 667                                 sbar_size[i] = len;
 668
 669                         if(field == SP_NAME) {
 670                                 tmp_x = sbar_fontsize_x*len; // left or right aligned? let's put it right...
 671                                 drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 672                         } else {
 673                                 tmp_x = sbar_fontsize_x*len; //strlen(str);
 674                                 drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 675                         }
 676                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 677                 }
 678         }
 679 }
 680
 681 void Sbar_DrawScoreboard()
 682 {
 683         //float xmin, ymin, xmax, ymax;
 684         vector rgb, pos, tmp, sbar_save;
 685         entity pl, tm;
 686         float specs, i;
 687         float center_x;
 688
 689         sbar_fontsize = Sbar_GetFontsize();
 690         if(sbar_fontsize_x == 0)
 691                 sbar_fontsize = '8 8 0';
 692         if(sbar_fontsize_y == 0)
 693                 sbar_fontsize_y = sbar_fontsize_x;
 694
 695         xmin = vid_conwidth / 5;
 696         ymin = 20;
 697
 698         xmax = vid_conwidth - xmin;
 699         ymax = vid_conheight - 0.2*vid_conheight;
 700
 701         sbwidth = xmax - xmin;
 702         sbheight = ymax - ymin;
 703
 704         center_x = xmin + 0.5*sbwidth;
 705
 706         //Sbar_UpdateFields();
 707
 708         // Initializes position
 709         //pos_x = xmin;
 710         pos_y = ymin;
 711         pos_z = 0;
 712
 713         // Heading
 714         drawfont = sbar_bigfont;
 715         pos_x = center_x - stringwidth("Scoreboard", TRUE)*0.5*24;
 716         drawstring(pos, "Scoreboard", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 717         pos_x = xmin;
 718         pos_y += 24 + 4;
 719
 720         // Titlebar background:
 721         tmp_x = sbwidth;
 722         tmp_y = sbar_fontsize_y;
 723         drawfill(pos - '1 1 0', tmp + '2 2 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
 724
 725         drawfont = sbar_font;
 726
 727         for(i = 0; i < sbar_num_fields; ++i)
 728         {
 729                 if(sbar_field[i] == SP_SEPARATOR)
 730                         break;
 731                 drawstring(pos, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 732                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 733         }
 734
 735         if(sbar_field[i] == SP_SEPARATOR)
 736         {
 737                 pos_x = xmax + sbar_fontsize_x;
 738                 tmp_y = tmp_z = 0;
 739                 for(i = sbar_num_fields-1; i > 0; --i)
 740                 {
 741                         if(sbar_field[i] == SP_SEPARATOR)
 742                                 break;
 743
 744                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 745                         /**
 746                          * FTEQCC BUG!
 747                          * Using the following line will fuck it all up:
 748                          **
 749                          * tmp_x = sbar_size[i] - strlen(sbar_title[i])*8;
 750                          */
 751                         tmp_x = sbar_fontsize_x*sbar_size[i];
 752                         tmp_x -= stringwidth(sbar_title[i], FALSE)*sbar_fontsize_x;
 753                         drawstring(pos + tmp, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 754                 }
 755         }
 756
 757         pos_x = xmin;
 758         pos_y += 1.5 * sbar_fontsize_y;
 759
 760         sbar_save = sbar;
 761         sbar = '0 0 0';
 762
 763         if(teamplay)
 764         {
 765                 //for(tm = sortedTeams.sort_next; tm; tm = tm.sort_next)
 766                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 767                 {
 768                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
 769                                 continue;
 770
 771                         rgb = GetTeamRGB(tm.team);
 772
 773                         pos_x = xmin;
 774
 775                         Sbar_DrawXNum(
 776                                 pos - '6.5 0 0' * sbar_fontsize_y,
 777                                 tm.(teamscores[ts_primary]),
 778                                 4, sbar_fontsize_y * 1.5, rgb, 1, DRAWFLAG_NORMAL);
 779
 780                         if(ts_primary != ts_secondary)
 781                         Sbar_DrawXNum(
 782                                 pos - '4.5 0 0' * sbar_fontsize_y + '0 1.5 0' * sbar_fontsize_y,
 783                                 tm.(teamscores[ts_secondary]),
 784                                 4, sbar_fontsize_y * 1, rgb, 1, DRAWFLAG_NORMAL);
 785
 786                         specs = tm.team_size;
 787
 788                         if(specs < 2)
 789                                 specs = 2;
 790
 791                         tmp_x = sbwidth;
 792                         tmp_y = 1.25 * sbar_fontsize_y * specs;
 793                         drawfill(pos - '1 1 0', tmp + '2 0 0', rgb, 0.2, DRAWFLAG_NORMAL);
 794
 795                         for(pl = players.sort_next; pl; pl = pl.sort_next)
 796                         {
 797                                 if(pl.team != tm.team)
 798                                         continue;
 799                                 Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 800                                 pos_y += 1.25 * sbar_fontsize_y;
 801                                 tmp_y -= 1.25 * sbar_fontsize_y;
 802                         }
 803                         pos_y += tmp_y + 1.5 * sbar_fontsize_y;
 804                 }
 805                 // rgb := tempvector :)
 806                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 807                 pos_y += 3 * sbar_fontsize_y;
 808                 specs = 0;
 809                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 810                 {
 811                         if(pl.team != COLOR_SPECTATOR)
 812                                 continue;
 813                         //drawcolorcodedstring(pos, getplayerkey(pl.sb_player, "name"), '8 8 0', 1, 0);
 814                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 815                         pos += '0 1.25 0' * sbar_fontsize_y;
 816                         ++specs;
 817                 }
 818
 819                 if(specs)
 820                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 821         } else {
 822                 pos_x = xmin;
 823                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 824                 {
 825                         if(pl.team == COLOR_SPECTATOR)
 826                                 continue;
 827                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 828                         pos_y += 1.25 * sbar_fontsize_y;
 829                         tmp_y -= 1.25 * sbar_fontsize_y;
 830                 }
 831
 832                 // rgb := tempvector :)
 833                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 834                 pos_y += 3 * sbar_fontsize_y;
 835                 specs = 0;
 836                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 837                 {
 838                         if(pl.team != COLOR_SPECTATOR)
 839                                 continue;
 840                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 841                         pos += '0 1.25 0' * sbar_fontsize_y;
 842                         ++specs;
 843                 }
 844
 845                 if(specs)
 846                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 847         }
 848
 849         string str;
 850         float tl, fl;
 851         str = strcat("playing on ^2", shortmapname, "^7");
 852         tl = getstatf(STAT_TIMELIMIT);
 853         fl = getstatf(STAT_FRAGLIMIT);
 854         if(gametype == GAME_LMS)
 855         {
 856                 if(tl > 0)
 857                         str = strcat(str, " for up to ^1", ftos(tl), " minutes^7");
 858         }
 859         else
 860         {
 861                 if(tl > 0)
 862                         str = strcat(str, " for ^1", ftos(tl), " minutes^7");
 863                 if(fl > 0)
 864                 {
 865                         if(tl > 0)
 866                                 str = strcat(str, " or");
 867                         str = strcat(str, " until ^3", ftos(fl));
 868                         if(scores_label[ps_primary] == "score")
 869                                 str = strcat(str, " points^7");
 870                         else
 871                                 str = strcat(str, " ", scores_label[ps_primary]);
 872                 }
 873         }
 874
 875         pos_y += 1.5 * sbar_fontsize_y;
 876         drawcolorcodedstring(pos + '0.5 0 0' * (sbwidth - sbar_fontsize_x * stringwidth(str, TRUE)), str, sbar_fontsize, 0.8, 0);
 877
 878         sbar = sbar_save;
 879 }
 880
 881 void Sbar_Score(float margin)
 882 {
 883         float timelimit, timeleft, minutes, seconds, distribution, myplace, score;
 884         vector sbar_save, place;
 885         entity tm, pl, me;
 886         sbar_save = sbar;
 887
 888         myteam = GetPlayerColor(player_localentnum - 1);
 889
 890         sbar_y = vid_conheight - (32+12);
 891         sbar_x -= margin;
 892
 893         place = '-48 -12 0';
 894         if(teamplay)
 895         {
 896                 // Layout:
 897                 //
 898                 //   team1 team3 team4
 899                 //
 900                 //         TEAM2
 901                 //for(i = 0; i < 4; ++i)
 902                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 903                 {
 904                         if(tm.team == COLOR_SPECTATOR || !tm.team_size) // no players? don't display
 905                                 continue;
 906                         // -32*4 = -128
 907                         score = tm.(teamscores[ts_primary]);
 908                         if(tm.team == myteam)
 909                                 Sbar_DrawXNum('-128 0 0', score, 4, 32, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
 910                         else
 911                         {
 912                                 Sbar_DrawXNum(place, score, 4, 12, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
 913                                 place_x -= 4*12;
 914                         }
 915                 }
 916         } else {
 917                 // me vector := [team/connected frags id]
 918                 myplace = 0;
 919                 for(me = players.sort_next; me; me = me.sort_next)
 920                 {
 921                         if(me.team != COLOR_SPECTATOR)
 922                                 ++myplace;
 923                         if(me.sv_entnum == player_localentnum - 1)
 924                                 break;
 925                 }
 926                 pl = players;
 927                 if(pl == me)
 928                         pl = pl.sort_next;
 929
 930                 if(pl) {
 931                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
 932                 } else
 933                         distribution = 0;
 934
 935                 if(myplace == 1)
 936                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
 937                 else if(myplace == 2)
 938                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
 939                 else
 940                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 0 0', 1, DRAWFLAG_NORMAL);
 941
 942                 score = me.(scores[ps_primary]);
 943                 if(distribution >= 0)
 944                 {
 945                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 1', 1, DRAWFLAG_NORMAL);
 946                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 1', 1, DRAWFLAG_NORMAL);
 947                 } else if(distribution >= -5)
 948                 {
 949                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 0', 1, DRAWFLAG_NORMAL);
 950                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 0', 1, DRAWFLAG_NORMAL);
 951                 } else {
 952                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 0 0', 1, DRAWFLAG_NORMAL);
 953                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 0 0', 1, DRAWFLAG_NORMAL);
 954                 }
 955         }
 956         timelimit = getstatf(STAT_TIMELIMIT);
 957         if(timelimit)
 958         {
 959                 timeleft = max(0, timelimit * 60 - time);
 960                 minutes = floor(timeleft / 60);
 961                 seconds = floor(timeleft - minutes*60);
 962                 if(minutes >= 5)
 963                 {
 964                         Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
 965                         drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 1', sbar_alpha_fg, 0);
 966                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
 967                 } else if(minutes >= 1)
 968                 {
 969                         Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
 970                         drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 0', sbar_alpha_fg, 0);
 971                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
 972                 } else {
 973                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 0 0', 1, DRAWFLAG_NORMAL);
 974                 }
 975         } else {
 976                 minutes = floor(time / 60);
 977                 seconds = floor(time - minutes*60);
 978                 Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
 979                 drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 1', sbar_alpha_fg, 0);
 980                 Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
 981         }
 982         sbar = sbar_save;
 983 }
 984
 985 void Sbar_MiniscoreItem(vector pos, entity pl, float is_self)
 986 {
 987         float x, score;
 988         pos_x += 72;
 989
 990         if(teamplay)
 991                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(pl.team)*0.5, 1, DRAWFLAG_NORMAL);
 992         else
 993                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
 994         x = pos_x;
 995         pos_x += 5*8;
 996         score = pl.(scores[ps_primary]);
 997         pos_x -= stringwidth(ftos(score), FALSE)*8;
 998         drawstring(pos, ftos(score), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 999         pos_x = x;
1000         if(is_self)
1001         {
1002                 pos_x += 48;
1003                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1004                 pos_x += 8;
1005         } else
1006                 pos_x += 56;
1007         drawcolorcodedstring(pos, getplayerkey(pl.sv_entnum, "name"), '8 8 0', 1, 0);
1008 }
1009
1010 void Sbar_MiniscoreTeamItem(vector pos, float color, float frags, float is_self)
1011 {
1012         float x;
1013         pos_x += 72;
1014
1015         if(teamplay)
1016                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(color)*0.5, 1, DRAWFLAG_NORMAL);
1017         else
1018                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
1019         x = pos_x;
1020         pos_x += 5*8;
1021         pos_x -= stringwidth(ftos(frags), FALSE)*8;
1022         drawstring(pos, ftos(frags), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1023         pos_x = x;
1024         if(is_self)
1025         {
1026                 pos_x += 48;
1027                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1028                 pos_x += 8;
1029         } else
1030                 pos_x += 56;
1031         drawstring(pos, GetTeamName(color), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1032 }
1033
1034 void Sbar_MiniDeathmatchOverlay(vector pos)
1035 {
1036         float numlines, up, down, score;
1037         entity me, tm, pl;
1038         float miniscoreboard_size;
1039         miniscoreboard_size = cvar("sbar_miniscoreboard_size");
1040
1041         if(miniscoreboard_size == 0)
1042                 return;
1043         pos_y = vid_conheight - 8;
1044
1045         if(miniscoreboard_size < 0)
1046                 numlines = (vid_conheight - sbar_y + 7) / 8;
1047         else
1048                 numlines = miniscoreboard_size;
1049
1050         // give up if there isn't enough room
1051         if(pos_x >= vid_conwidth || pos_y >= vid_conheight || numlines < 1)
1052                 return;
1053
1054         // me vector := [team/connected frags id]
1055         for(me = players.sort_next; me; me = me.sort_next)
1056         {
1057                 if(me.sv_entnum == player_localentnum - 1)
1058                         break;
1059         }
1060
1061         if(teamplay)
1062                 numlines -= numteams;
1063
1064         // figure out how many players above and below we can show
1065         up = floor(numlines/2);
1066         down = up;
1067         if((up + down) > numlines)
1068                 down = numlines - up;
1069
1070         // render bottom-up
1071         for(pl = me.sort_next; pl && down > 0; pl = pl.sort_next)
1072         {
1073                 if(pl.team == COLOR_SPECTATOR)
1074                         continue;
1075                 Sbar_MiniscoreItem(pos, pl, false);
1076                 pos_y -= 9;
1077                 --down;
1078         }
1079         Sbar_MiniscoreItem(pos, me, true);
1080         pos_y -= 9;
1081         up += down; // if there weren't enough lines below... add them
1082         for(pl = me.sort_prev; pl && up > 0; pl = pl.sort_prev)
1083         {
1084                 if(pl.team == COLOR_SPECTATOR)
1085                         continue;
1086                 Sbar_MiniscoreItem(pos, pl, false);
1087                 pos_y -= 9;
1088                 --up;
1089         }
1090
1091         if(teamplay)
1092         {
1093                 for(tm = teams.sort_next; tm.sort_next; tm = tm.sort_next);
1094                 for(; tm; tm = tm.sort_prev)
1095                 {
1096                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
1097                                 continue;
1098                         score = tm.(teamscores[ts_primary]);
1099                         Sbar_MiniscoreTeamItem(pos, tm.team, score, (tm.team == me.team));
1100                         pos_y -= 9;
1101                 }
1102         }
1103 }
1104
1105 float Sbar_WouldDrawScoreboard ()
1106 {
1107         if (sb_showscores)
1108                 return 1;
1109         else if (intermission == 1)
1110                 return 1;
1111         else if (intermission == 2)
1112                 return 1;
1113         return 0;
1114 }
1115
1116 void Sbar_Draw (void)
1117 {
1118         float i;
1119         float x, fade;
1120         float stat_items;
1121
1122         //Sbar_SortFrags();
1123         Sbar_UpdatePlayerTeams();
1124
1125         sb_lines = 24;
1126
1127         if (sb_showscores)
1128                 Sbar_DrawScoreboard();
1129         else if (intermission == 1)
1130         {
1131                 Sbar_DrawScoreboard();
1132                 return;
1133         }
1134         else if (intermission == 2)
1135                 Sbar_FinaleOverlay();
1136         else
1137         {
1138                 if (sb_showscores || (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard")))
1139                 {
1140                         sbar_x = (vid_conwidth - 640.0)*0.5;
1141                         sbar_y = vid_conheight - 47;
1142                         //Sbar_DrawAlphaPic (sbar_x, sbar_y, sb_scorebar, sbar_alpha_bg.value);
1143                         //drawpic('0 0 0', "gfx/scorebar", '0 0 0', '1 1 1', cvar("sbar_alpha_bg"), 0);
1144                         Sbar_DrawScoreboard ();
1145                 }
1146                 else
1147                 {
1148                         if (sb_lines && sbar_hudselector == 1)
1149                         {
1150                                 stat_items = getstati(STAT_ITEMS);
1151
1152                                 sbar_x = (vid_conwidth - 320.0)*0.5;
1153                                 sbar_y = vid_conheight - 24.0 - 16.0;
1154                                 sbar_z = 0;
1155
1156                                 fade = 3.2 - 2 * (time - weapontime);
1157                                 fade = bound(0.7, fade, 1);
1158
1159                                 x = 1.0;
1160                                 for(i = 0; i < 8; ++i)
1161                                 {
1162                                         if(stat_items & x)
1163                                         {
1164                                                 Sbar_DrawWeapon(i+1, fade, (i + 2 == activeweapon));
1165                                         }
1166                                         x *= 2;
1167                                 }
1168                                 x *= 2*2*2*2;
1169                                 if(stat_items & x)
1170                                 {
1171                                         Sbar_DrawWeapon(0, fade, (activeweapon == 1));
1172                                 }
1173
1174                                 // armor
1175                                 x = getstati(STAT_ARMOR);
1176                                 if (x > 0)
1177                                 {
1178                                         // "gfx/sb_armor"
1179                                         //Sbar_DrawStretchPic (72, 0, sb_armor[0], sbar_alpha_fg.value, 24, 24);
1180                                         drawpic(sbar + '72 0 0', "gfx/sb_armor", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1181                                         if(x > 200)
1182                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0 1 0', 1, 0);
1183                                         else if(x > 100)
1184                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1185                                         else if(x > 50)
1186                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1187                                         else if(x > 25)
1188                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1189                                         else
1190                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1191                                 }
1192
1193                                 // health
1194                                 x = getstati(STAT_HEALTH);
1195                                 if (x != 0)
1196                                 {
1197                                         // "gfx/sb_health"
1198                                         //Sbar_DrawStretchPic (184, 0, sb_health, sbar_alpha_fg.value, 24, 24);
1199                                         drawpic(sbar + '184 0 0', "gfx/sb_health", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1200                                         if(x > 200)
1201                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0 1 0', 1, 0);
1202                                         else if(x > 100)
1203                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1204                                         else if(x > 50)
1205                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1206                                         else if(x > 25)
1207                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1208                                         else
1209                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1210                                 }
1211
1212                                 // ammo
1213                                 x = getstati(STAT_AMMO);
1214                                 if ((stat_items & (NEX_IT_SHELLS | NEX_IT_BULLETS | NEX_IT_ROCKETS | NEX_IT_CELLS)) || x != 0)
1215                                 {
1216                                         if (stat_items & NEX_IT_SHELLS)
1217                                                 drawpic(sbar + '296 0 0', "gfx/sb_shells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1218                                         else if (stat_items & NEX_IT_BULLETS)
1219                                                 drawpic(sbar + '296 0 0', "gfx/sb_bullets", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1220                                         else if (stat_items & NEX_IT_ROCKETS)
1221                                                 drawpic(sbar + '296 0 0', "gfx/sb_rocket", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1222                                         else if (stat_items & NEX_IT_CELLS)
1223                                                 drawpic(sbar + '296 0 0', "gfx/sb_cells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1224                                         if(x > 10)
1225                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1226                                         else
1227                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1228                                 }
1229
1230                                 if (sbar_x + 320 + 160 <= vid_conwidth)
1231                                         Sbar_MiniDeathmatchOverlay(sbar + '320 0 0');
1232                                 if (sbar_x > 0)
1233                                         Sbar_Score(16);
1234                                 // The margin can be at most 8 to support 640x480 console size:
1235                                 //   320 + 2 * (144 + 16) = 640
1236                         }
1237                         else if (sb_lines)
1238                         {
1239
1240                                 stat_items = getstati(STAT_ITEMS);
1241
1242                                 sbar_x = (vid_conwidth - 640.0)*0.5;
1243                                 sbar_y = vid_conheight - 47;
1244                                 sbar_z = 0;
1245
1246                                 fade = 3 - 2 * (time - weapontime);
1247
1248                                 x = 1.0;
1249                                 for(i = 0; i < 8; ++i)
1250                                 {
1251                                         if(stat_items & x)
1252                                         {
1253                                                 Sbar_DrawWeapon(i+1, fade, (i + 2 == activeweapon));
1254                                         }
1255                                         x *= 2;
1256                                 }
1257                                 x *= 2*2*2*2;
1258                                 if(stat_items & x)
1259                                 {
1260                                         Sbar_DrawWeapon(0, fade, (activeweapon == 1));
1261                                 }
1262
1263                                 if (sb_lines > 24)
1264                                         drawpic(sbar, "gfx/sbar", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1265                                 else
1266                                         drawpic(sbar, "gfx/sbar_minimal", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1267
1268                                 // armor
1269                                 // (340-3*24) = 268
1270                                 Sbar_DrawXNum('268 12 0', getstati(STAT_ARMOR), 3, 24, '0.6 0.7 0.8', 1, 0);
1271
1272                                 // health
1273                                 // (154-3*24) = 82
1274                                 x = getstati(STAT_HEALTH);
1275                                 if(x > 100)
1276                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '1 1 1', 1, 0);
1277                                 else if(x <= 25 && time - floor(time) > 0.5)
1278                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '0.7 0 0', 1, 0);
1279                                 else
1280                                         Sbar_DrawXNum('81 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1281
1282                                 // AK dont draw ammo for the laser
1283                                 x = getstati(STAT_AMMO);
1284                                 if(activeweapon != 12)
1285                                 {
1286                                         // (519-3*24) = 447
1287                                         if (stat_items & NEX_IT_SHELLS)
1288                                                 drawpic(sbar + '519 0 0', "gfx/sb_shells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1289                                         else if (stat_items & NEX_IT_BULLETS)
1290                                                 drawpic(sbar + '519 0 0', "gfx/sb_bullets", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1291                                         else if (stat_items & NEX_IT_ROCKETS)
1292                                                 drawpic(sbar + '519 0 0', "gfx/sb_rocket", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1293                                         else if (stat_items & NEX_IT_CELLS)
1294                                                 drawpic(sbar + '519 0 0', "gfx/sb_cells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1295                                         if(x > 10)
1296                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1297                                         else
1298                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.7 0 0', 1, 0);
1299                                 }
1300
1301                                 if (sb_lines > 24)
1302                                         drawpic(sbar, "gfx/sbar_overlay", '0 0 0', '1 1 1', 1, DRAWFLAG_MODULATE);
1303
1304                                 if (sbar_x + 600 + 160 <= vid_conwidth)
1305                                         Sbar_MiniDeathmatchOverlay (sbar + '600 0 0');
1306
1307                                 if (sbar_x > 0)
1308                                         Sbar_Score(-16);
1309                                 // Because:
1310                                 //   Mini scoreboard uses 12*4 per other team, that is, 144
1311                                 //   pixels when there are four teams...
1312                                 //   Nexuiz by default sets vid_conwidth to 800... makes
1313                                 //   sbar_x == 80...
1314                                 //   so we need to shift it by 64 pixels to the right to fit
1315                                 //   BUT: then it overlaps with the image that gets drawn
1316                                 //   for viewsize 100! Therefore, just account for 3 teams,
1317                                 //   that is, 96 pixels mini scoreboard size, needing 16 pixels
1318                                 //   to the right!
1319                         }
1320
1321
1322                         if(gametype == GAME_KEYHUNT)
1323                         {
1324                                 CSQC_kh_hud();
1325                         } else if(gametype == GAME_CTF)
1326                         {
1327                                 CSQC_ctf_hud();
1328                         }
1329                 }
1330         }
1331 }
1332
1333 void CSQC_ctf_hud(void)
1334 {
1335         // cvar("sbar_flagstatus_right") move the flag icons right
1336         // cvar("sbar_flagstatus_pos") pixel position of the nexuiz flagstatus icons
1337         float redflag, blueflag;
1338         float stat_items;
1339         vector pos;
1340
1341         stat_items = getstati(STAT_ITEMS);
1342         redflag = (stat_items/32768) & 3;
1343         blueflag = (stat_items/131072) & 3;
1344
1345         /**
1346          * FTEQCC BUG!
1347          * For some reason now not even THAT works there...
1348          * Maybe the minus' precedence screws it up? The last one there, maybe I should use brackets
1349          **
1350          * pos_x = (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - sbar_x - 64 : 10 - sbar_x;
1351          ** Should try those later:
1352          * pos_x = (cvar("sbar_flagstatus_right")) ? (vid_conwidth - 10 - sbar_x - 64) : (10 - sbar_x);
1353          * pos_x = ( (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - 64 : 10 ) - sbar_x;
1354          */
1355
1356         if(cvar("sbar_flagstatus_right"))
1357                 pos_x = vid_conwidth - 10 - sbar_x - 64;
1358         else
1359                 pos_x = 10 - sbar_x;
1360
1361         pos_z = 0;
1362
1363         if(sbar_hudselector == 1)
1364                 pos_y = (vid_conheight - sbar_y) - cvar("sbar_flagstatus_pos") - 64;
1365         else
1366                 pos_y = -117;
1367
1368         pos += sbar;
1369
1370         switch(redflag)
1371         {
1372         case 1: drawpic(pos, "gfx/sb_flag_red_taken", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1373         case 2: drawpic(pos, "gfx/sb_flag_red_lost", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1374         case 3: drawpic(pos, "gfx/sb_flag_red_carrying", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1375         }
1376
1377         pos_y -= 64;
1378
1379         switch(blueflag)
1380         {
1381         case 1: drawpic(pos, "gfx/sb_flag_blue_taken", '0 0 0', '1 1 1', 1, 0); break;
1382         case 2: drawpic(pos, "gfx/sb_flag_blue_lost", '0 0 0', '1 1 1', 1, 0); break;
1383         case 3: drawpic(pos, "gfx/sb_flag_blue_carrying", '0 0 0', '1 1 1', 1, 0); break;
1384         }
1385 }