data/qcsrc/client/sbar.qc

   1
   2 float last_weapon;
   3 float activeweapon;
   4 float weapontime;
   5
   6 float sb_lines; // still don't know what to do with that NOTE: check dp's sbar.c to see what that should be
   7
   8 vector sbar;
   9 float sbar_alpha_fg;
  10 float sbar_hudselector;
  11
  12 float ps_primary, ps_secondary;
  13 float ts_primary, ts_secondary;
  14
  15 void CSQC_kh_hud();
  16 void CSQC_ctf_hud();
  17 void MapVote_Draw();
  18 void Sbar_FinaleOverlay()
  19 {
  20         /*vector pos;
  21         pos_x = (vid_conwidth - 1)/2;
  22         pos_y = 16;
  23         pos_z = 0;*/
  24
  25         //drawpic(pos, "gfx/finale", '0 0 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
  26
  27         //drawstring(pos, "END", sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
  28         MapVote_Draw();
  29 }
  30
  31 void Sbar_DrawWeapon(float nr, float fade, float active)
  32 {
  33         vector pos, vsize, color;
  34         float value;
  35
  36         value = (active) ? 1 : 0.6;
  37         color_x = color_y = color_z = value;
  38
  39         if(sbar_hudselector == 1)
  40         {
  41                 // width = 300, height = 100
  42                 const float w_width = 32, w_height = 12, w_space = 2, font_size = 8;
  43
  44                 pos_x = (vid_conwidth - w_width * 9) * 0.5 + w_width * nr;
  45                 pos_y = (vid_conheight - w_height);
  46                 pos_z = 0;
  47                 vsize_x = w_width;
  48                 vsize_y = w_height;
  49                 vsize_z = 0;
  50                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
  51                 pos_x += w_space;
  52                 pos_y += w_space;
  53                 vsize_x = font_size;
  54                 vsize_y = font_size;
  55                 vsize_z = 0;
  56                 drawstring(pos, ftos(nr+1), vsize, '1 1 0', sbar_alpha_fg, 0);
  57
  58         }
  59         else
  60         {
  61                 // width = 300, height = 100
  62                 const float w2_width = 300, w2_height = 100, w2_space = 10;
  63                 const float w2_scale = 0.4;
  64
  65                 pos_x = vid_conwidth - (w2_width + w2_space) * w2_scale;
  66                 pos_y = (w2_height + w2_space) * w2_scale * nr + w2_space;
  67                 pos_z = 0;
  68                 vsize_x = w2_width * w2_scale;
  69                 vsize_y = w2_height * w2_scale;
  70                 vsize_z = 0;
  71
  72                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
  73         }
  74 }
  75 void Sbar_DrawXNum (vector pos, float num, float digits, float lettersize, vector rgb, float a, float dflags)
  76 {
  77         float l, i;
  78         string str, tmp;
  79         float minus;
  80         vector vsize;
  81
  82         vsize_x = vsize_y = lettersize;
  83         vsize_z = 0;
  84
  85         if(num < 0)
  86         {
  87                 minus = true;
  88                 num = -num;
  89                 pos_x -= lettersize;
  90         } else
  91                 minus = false;
  92
  93         if(digits < 0)
  94         {
  95                 tmp = ftos(num);
  96                 digits = -digits;
  97                 str = strcat(substring("0000000000", 0, digits - strlen(tmp)), tmp);
  98         } else
  99                 str = ftos(num);
 100
 101         l = strlen(str);
 102
 103         if(l > digits)
 104         {
 105                 str = substring(str, l-digits, 999);
 106                 l = strlen(str);
 107         } else if(l < digits)
 108                 pos_x += (digits-l) * lettersize;
 109
 110         if(minus)
 111         {
 112                 drawpic(sbar + pos, "gfx/num_minus", vsize, rgb, a * sbar_alpha_fg, dflags);
 113                 pos_x += lettersize;
 114         }
 115
 116         for(i = 0; i < l; ++i)
 117         {
 118                 drawpic(sbar + pos, strcat("gfx/num_", substring(str, i, 1)), vsize, rgb, a * sbar_alpha_fg, dflags);
 119                 pos_x += lettersize;
 120         }
 121 }
 122
 123 void Cmd_Sbar_SetFields(float argc);
 124 void Sbar_InitScores()
 125 {
 126         float i, f;
 127
 128         ps_primary = ps_secondary = ts_primary = ts_secondary = -1;
 129         for(i = 0; i < MAX_SCORE; ++i)
 130         {
 131                 f = (scores_flags[i] & SFL_SORT_PRIO_MASK);
 132                 if(f == SFL_SORT_PRIO_PRIMARY)
 133                         ps_primary = i;
 134                 if(f == SFL_SORT_PRIO_SECONDARY)
 135                         ps_secondary = i;
 136         }
 137         if(ps_secondary == -1)
 138                 ps_secondary = ps_primary;
 139
 140         for(i = 0; i < MAX_TEAMSCORE; ++i)
 141         {
 142                 f = (teamscores_flags[i] & SFL_SORT_PRIO_MASK);
 143                 if(f == SFL_SORT_PRIO_PRIMARY)
 144                         ts_primary = i;
 145                 if(f == SFL_SORT_PRIO_SECONDARY)
 146                         ts_secondary = i;
 147         }
 148         if(ts_secondary == -1)
 149                 ts_secondary = ts_primary;
 150
 151         Cmd_Sbar_SetFields(0);
 152 }
 153
 154 void Sbar_UpdatePlayerPos(entity pl);
 155 float SetTeam(entity pl, float Team);
 156 //float lastpnum;
 157 void Sbar_UpdatePlayerTeams()
 158 {
 159         float Team;
 160         entity pl, tmp;
 161         float num;
 162
 163         num = 0;
 164         for(pl = players.sort_next; pl; pl = pl.sort_next)
 165         {
 166                 num += 1;
 167                 Team = GetPlayerColor(pl.sv_entnum);
 168                 if(SetTeam(pl, Team))
 169                 {
 170                         tmp = pl.sort_prev;
 171                         Sbar_UpdatePlayerPos(pl);
 172                         if(tmp)
 173                                 pl = tmp;
 174                         else
 175                                 pl = players.sort_next;
 176                 }
 177         }
 178         /*
 179         if(num != lastpnum)
 180                 print(strcat("PNUM: ", ftos(num), "\n"));
 181         lastpnum = num;
 182         */
 183 }
 184
 185 float Sbar_ComparePlayerScores(entity left, entity right)
 186 {
 187         float vl, vr;
 188         vl = GetPlayerColor(left.sv_entnum);
 189         vr = GetPlayerColor(right.sv_entnum);
 190
 191         if(vl > vr)
 192                 return true;
 193         if(vl < vr)
 194                 return false;
 195
 196         if(vl == COLOR_SPECTATOR)
 197         {
 198                 // FIRST the one with scores (spectators), THEN the ones without (downloaders)
 199                 // no other sorting
 200                 if(!left.gotscores && right.gotscores)
 201                         return true;
 202                 return false;
 203         }
 204
 205         vl = left.scores[ps_primary];
 206         vr = right.scores[ps_primary];
 207         if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
 208         {
 209                 if(vl == 0 && vr != 0)
 210                         return 1;
 211                 if(vl != 0 && vr == 0)
 212                         return 0;
 213         }
 214         if(vl > vr)
 215                 return IS_INCREASING(scores_flags[ps_primary]);
 216         if(vl < vr)
 217                 return IS_DECREASING(scores_flags[ps_primary]);
 218
 219         vl = left.scores[ps_secondary];
 220         vr = right.scores[ps_secondary];
 221         if(scores_flags[ps_secondary] & SFL_ZERO_IS_WORST)
 222         {
 223                 if(vl == 0 && vr != 0)
 224                         return 1;
 225                 if(vl != 0 && vr == 0)
 226                         return 0;
 227         }
 228         if(vl > vr)
 229                 return IS_INCREASING(scores_flags[ps_secondary]);
 230         if(vl < vr)
 231                 return IS_DECREASING(scores_flags[ps_secondary]);
 232
 233         return false;
 234 }
 235
 236 void Sbar_UpdatePlayerPos(entity player)
 237 {
 238         for(other = player.sort_next; other && Sbar_ComparePlayerScores(player, other); other = player.sort_next)
 239         {
 240                 SORT_SWAP(player, other);
 241         }
 242         for(other = player.sort_prev; other != players && Sbar_ComparePlayerScores(other, player); other = player.sort_prev)
 243         {
 244                 SORT_SWAP(other, player);
 245         }
 246 }
 247
 248 float Sbar_CompareTeamScores(entity left, entity right)
 249 {
 250         float vl, vr;
 251
 252         if(left.team == COLOR_SPECTATOR)
 253                 return 1;
 254         if(right.team == COLOR_SPECTATOR)
 255                 return 0;
 256
 257         vl = left.teamscores[ts_primary];
 258         vr = right.teamscores[ts_primary];
 259         if(vl > vr)
 260                 return IS_INCREASING(teamscores_flags[ts_primary]);
 261         if(vl < vr)
 262                 return IS_DECREASING(teamscores_flags[ts_primary]);
 263
 264         vl = left.teamscores[ts_secondary];
 265         vr = right.teamscores[ts_secondary];
 266         if(vl > vr)
 267                 return IS_INCREASING(teamscores_flags[ts_secondary]);
 268         if(vl < vr)
 269                 return IS_DECREASING(teamscores_flags[ts_secondary]);
 270
 271         return false;
 272 }
 273
 274 void Sbar_UpdateTeamPos(entity Team)
 275 {
 276         for(other = Team.sort_next; other && Sbar_CompareTeamScores(Team, other); other = Team.sort_next)
 277         {
 278                 SORT_SWAP(Team, other);
 279         }
 280         for(other = Team.sort_prev; other != teams && Sbar_CompareTeamScores(other, Team); other = Team.sort_prev)
 281         {
 282                 SORT_SWAP(other, Team);
 283         }
 284 }
 285
 286 void Cmd_Sbar_Help(float argc)
 287 {
 288         print("You can modify the scoreboard using the\n");
 289         print("^3|---------------------------------------------------------------|\n");
 290         print("^1 TO BE DONE\n");
 291         print("Usage:\n");
 292         print("^2sbar_columns_set default\n");
 293         print("^2sbar_columns_set ^7filed1 field2 ...\n");
 294         print("The following field names are recognized (case INsensitive):\n");
 295         print("You can use a ^3|^7 to start the right-aligned fields.\n");
 296
 297         print("^3name^7 or ^3nick^7             Name of a player\n");
 298         print("^3ping^7                     Ping time\n\n");
 299         print("^3kd^7 or ^3kdr^7 or ^3kdratio^7 or ^3k/d\n");
 300         print("                         The kill-death ratio\n");
 301
 302         print("Before a field you can put a + or - sign, then a comma separated list\n");
 303         print("of game types, then a slash, to make the field show up only in these\n");
 304         print("or in all but these game types.\n");
 305
 306         local float i;
 307         print("Additional columns:\n");
 308         for(i = 0; i < MAX_SCORE; ++i)
 309         {
 310                 if(scores_label[i] != "")
 311                         print(strcat(scores_label[i], "\n"));
 312         }
 313 }
 314
 315 #define MIN_NAMELEN 24
 316 #define MAX_NAMELEN 24
 317
 318 string Sbar_DefaultColumnLayout()
 319 {
 320         return "ping pl name | -ctf,kh/kills -ctf,kh/deaths +lms/lives +lms/rank +kh,ctf/caps +kh/pushes +kh/destroyed -lms/score";
 321 }
 322
 323 void Cmd_Sbar_SetFields(float argc)
 324 {
 325         float i, j, slash;
 326         string str, pattern, subpattern;
 327         float digit;
 328         float have_name, have_primary, have_secondary, have_separator;
 329         float missing;
 330
 331         // TODO: re enable with gametype dependant cvars?
 332         if(argc < 2) // no arguments provided
 333                 argc = tokenizebyseparator(strcat("x ", cvar_string("sbar_columns")), " ");
 334
 335         if(argc < 2)
 336                 argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 337
 338         if(argc == 2)
 339         {
 340                 if(argv(1) == "default")
 341                         argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 342                 else if(argv(1) == "all")
 343                 {
 344                         string s;
 345                         s = "ping name |";
 346                         for(i = 0; i < MAX_SCORE; ++i)
 347                         {
 348                                 if(i != ps_primary)
 349                                 if(i != ps_secondary)
 350                                 if(scores_label[i] != "")
 351                                         s = strcat(s, " ", scores_label[i]);
 352                         }
 353                         if(ps_secondary != ps_primary)
 354                                 s = strcat(s, " ", scores_label[ps_secondary]);
 355                         s = strcat(s, " ", scores_label[ps_primary]);
 356                         argc = tokenizebyseparator(strcat("x ", s), " ");
 357                 }
 358         }
 359
 360
 361         argc = min(MAX_SBAR_FIELDS, argc);
 362         sbar_num_fields = 0;
 363
 364         drawfont = sbar_font;
 365         digit = stringwidth("0123456789", FALSE) / 10;
 366
 367         subpattern = strcat(",", GametypeNameFromType(gametype), ",");
 368
 369         argc = min(argc-1, MAX_SBAR_FIELDS-1);
 370         for(i = 0; i < argc; ++i)
 371         {
 372                 str = argv(i+1);
 373
 374                 slash = strstrofs(str, "/", 0);
 375                 if(slash >= 0)
 376                 {
 377                         pattern = substring(str, 0, slash);
 378                         str = substring(str, slash + 1, strlen(str) - (slash + 1));
 379
 380                         if(substring(pattern, 0, 1) == "-")
 381                         {
 382                                 pattern = substring(pattern, 1, strlen(pattern) - 1);
 383                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
 384                                         continue;
 385                         }
 386                         else
 387                         {
 388                                 if(substring(pattern, 0, 1) == "+")
 389                                         pattern = substring(pattern, 1, strlen(pattern) - 1);
 390                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
 391                                         continue;
 392                         }
 393                 }
 394
 395                 strunzone(sbar_title[sbar_num_fields]);
 396                 sbar_title[sbar_num_fields] = strzone(str);
 397                 sbar_size[sbar_num_fields] = stringwidth(str, FALSE);
 398                 str = strtolower(str);
 399
 400                 if(str == "ping") {
 401                         sbar_field[sbar_num_fields] = SP_PING;
 402                 } else if(str == "pl") {
 403                         sbar_field[sbar_num_fields] = SP_PL;
 404                 } else if(str == "kd" || str == "kdr" || str == "kdratio" || str == "k/d") {
 405                         sbar_field[sbar_num_fields] = SP_KDRATIO;
 406                 } else if(str == "name" || str == "nick") {
 407                         sbar_field[sbar_num_fields] = SP_NAME;
 408                         sbar_size[sbar_num_fields] = MIN_NAMELEN; // minimum size? any use?
 409                         have_name = 1;
 410                 } else if(str == "|") {
 411                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 412                         have_separator = 1;
 413                 } else {
 414                         for(j = 0; j < MAX_SCORE; ++j)
 415                                 if(str == strtolower(scores_label[j]))
 416                                         goto found; // sorry, but otherwise fteqcc -O3 miscompiles this and warns about "unreachable code"
 417 :notfound
 418                         print(strcat("^1Error:^7 Unknown score field: '", str, "'\n"));
 419                         continue;
 420 :found
 421                         sbar_field[sbar_num_fields] = j;
 422                         if(j == ps_primary)
 423                                 have_primary = 1;
 424                         if(j == ps_secondary)
 425                                 have_secondary = 1;
 426                 }
 427                 ++sbar_num_fields;
 428         }
 429
 430         if(scores_flags[ps_primary] & SFL_ALLOW_HIDE)
 431                 have_primary = 1;
 432         if(scores_flags[ps_secondary] & SFL_ALLOW_HIDE)
 433                 have_secondary = 1;
 434         if(ps_primary == ps_secondary)
 435                 have_secondary = 1;
 436         missing = !have_primary + !have_secondary + !have_separator + !have_name;
 437
 438         if(sbar_num_fields+missing < MAX_SBAR_FIELDS)
 439         {
 440                 if(!have_name)
 441                 {
 442                         strunzone(sbar_title[sbar_num_fields]);
 443                         for(i = sbar_num_fields; i > 0; --i)
 444                         {
 445                                 sbar_title[i] = sbar_title[i-1];
 446                                 sbar_size[i] = sbar_size[i-1];
 447                                 sbar_field[i] = sbar_field[i-1];
 448                         }
 449                         sbar_title[0] = strzone("name");
 450                         sbar_field[0] = SP_NAME;
 451                         sbar_size[0] = MIN_NAMELEN; // minimum size? any use?
 452                         ++sbar_num_fields;
 453                         print("fixed missing field 'name'\n");
 454
 455                         if(!have_separator)
 456                         {
 457                                 strunzone(sbar_title[sbar_num_fields]);
 458                                 for(i = sbar_num_fields; i > 1; --i)
 459                                 {
 460                                         sbar_title[i] = sbar_title[i-1];
 461                                         sbar_size[i] = sbar_size[i-1];
 462                                         sbar_field[i] = sbar_field[i-1];
 463                                 }
 464                                 sbar_title[1] = strzone("|");
 465                                 sbar_field[1] = SP_SEPARATOR;
 466                                 sbar_size[1] = stringwidth("|", FALSE);
 467                                 ++sbar_num_fields;
 468                                 print("fixed missing field '|'\n");
 469                         }
 470                 }
 471                 else if(!have_separator)
 472                 {
 473                         strunzone(sbar_title[sbar_num_fields]);
 474                         sbar_title[sbar_num_fields] = strzone("|");
 475                         sbar_size[sbar_num_fields] = stringwidth("|", FALSE);
 476                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 477                         ++sbar_num_fields;
 478                         print("fixed missing field '|'\n");
 479                 }
 480
 481                 if(!have_secondary)
 482                 {
 483                         strunzone(sbar_title[sbar_num_fields]);
 484                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_secondary]);
 485                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 486                         sbar_field[sbar_num_fields] = ps_secondary;
 487                         ++sbar_num_fields;
 488                         print("fixed missing field '", scores_label[ps_secondary], "'\n");
 489                 }
 490
 491                 if(!have_primary)
 492                 {
 493                         strunzone(sbar_title[sbar_num_fields]);
 494                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_primary]);
 495                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 496                         sbar_field[sbar_num_fields] = ps_primary;
 497                         ++sbar_num_fields;
 498                         print("fixed missing field '", scores_label[ps_primary], "'\n");
 499                 }
 500         }
 501
 502         sbar_field[sbar_num_fields] = SP_END;
 503 }
 504
 505 // MOVEUP::
 506 vector sbar_field_rgb;
 507 string Sbar_GetField(entity pl, float field)
 508 {
 509         float tmp, num, denom, f;
 510         string str;
 511         sbar_field_rgb = '1 1 1';
 512         switch(field)
 513         {
 514                 case SP_PING:
 515                         if not(pl.gotscores)
 516                                 return "\x8D\x8D\x8D"; // >>> sign
 517                         str = getplayerkey(pl.sv_entnum, "ping");
 518                         if(str == "0")
 519                                 return "N/A";
 520                         tmp = max(0, min(220, stof(str)-80)) / 220;
 521                         sbar_field_rgb = '1 1 1' - '0 1 1'*tmp;
 522                         return str;
 523
 524                 case SP_PL:
 525                         if not(pl.gotscores)
 526                                 return "N/A";
 527                         str = getplayerkey(pl.sv_entnum, "pl");
 528                         if(str == "0")
 529                                 return "";
 530                         tmp = bound(0, stof(str), 20) / 20; // 20% is REALLY BAD pl
 531                         sbar_field_rgb = '1 0.5 0.5' - '0 0.5 0.5'*tmp;
 532                         return str;
 533
 534                 case SP_NAME:
 535                         return getplayerkey(pl.sv_entnum, "name");
 536
 537                 case SP_KDRATIO:
 538                         num = pl.(scores[SP_KILLS]);
 539                         denom = pl.(scores[SP_DEATHS]);
 540
 541                         if(denom == 0) {
 542                                 sbar_field_rgb = '0 1 0';
 543                                 str = ftos(num);
 544                         } else if(num <= 0) {
 545                                 sbar_field_rgb = '1 0 0';
 546                                 str = ftos(num/denom);
 547                         } else
 548                                 str = ftos(num/denom);
 549
 550                         tmp = strstrofs(str, ".", 0);
 551                         if(tmp > 0)
 552                                 str = substring(str, 0, tmp+2);
 553                         return str;
 554
 555                 default:
 556                         tmp = pl.(scores[field]);
 557                         f = scores_flags[field];
 558                         if(field == ps_primary)
 559                                 sbar_field_rgb = '1 1 0';
 560                         else if(field == ps_secondary)
 561                                 sbar_field_rgb = '0 1 1';
 562                         else
 563                                 sbar_field_rgb = '1 1 1';
 564                         if(!tmp)
 565                                 if(f & (SFL_HIDE_ZERO | SFL_RANK | SFL_TIME))
 566                                         return "";
 567                         if(f & SFL_RANK)
 568                         {
 569                                 str = ftos(floor(tmp + 0.5));
 570                                 num = strlen(str);
 571                                 if((num >= 2) && (substring(str, num - 2, 1) == "1"))
 572                                         return strcat(str, "th");
 573                                 else if(substring(str, num - 1, 1) == "1")
 574                                         return strcat(str, "st");
 575                                 else if(substring(str, num - 1, 1) == "2")
 576                                         return strcat(str, "nd");
 577                                 else if(substring(str, num - 1, 1) == "3")
 578                                         return strcat(str, "rd");
 579                                 else
 580                                         return strcat(str, "th");
 581                         }
 582                         else if(f & SFL_TIME)
 583                         {
 584                                 return mmsss(tmp);
 585                         }
 586                         return ftos(tmp);
 587         }
 588         //return "error";
 589 }
 590
 591 // shamelessly stolen from menu QC :P <- as if I would steal YOUR code pfft ;)
 592 float textLengthUpToWidth(string theText, float maxWidth, float handleColors)
 593 {
 594         // STOP.
 595         // The following function is SLOW.
 596         // For your safety and for the protection of those around you...
 597         // DO NOT CALL THIS AT HOME.
 598         // No really, don't.
 599         if(stringwidth(theText, handleColors) <= maxWidth)
 600                 return strlen(theText); // yeah!
 601
 602         // binary search for right place to cut string
 603         float left, right, middle; // this always works
 604         left = 0;
 605         right = strlen(theText); // this always fails
 606         do
 607         {
 608                 middle = floor((left + right) / 2);
 609                 if(stringwidth(substring(theText, 0, middle), handleColors) <= maxWidth)
 610                         left = middle;
 611                 else
 612                         right = middle;
 613         }
 614         while(left < right - 1);
 615
 616         // NOTE: when color codes are involved, this binary search is,
 617         // mathematically, BROKEN. However, it is obviously guaranteed to
 618         // terminate, as the range still halves each time - but nevertheless, it is
 619         // guaranteed that it finds ONE valid cutoff place (where "left" is in
 620         // range, and "right" is outside).
 621
 622         return left;
 623 }
 624 string textShortenToWidth(string theText, float maxWidth, float handleColors)
 625 {
 626         if(stringwidth(theText, handleColors) <= maxWidth)
 627                 return theText;
 628         else
 629                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - stringwidth("...", handleColors), handleColors)), "...");
 630 }
 631
 632 float xmin, xmax, ymin, ymax, sbwidth, sbheight;
 633
 634 void Sbar_PrintScoreboardItem(vector pos, entity pl, float is_self)
 635 {
 636         vector tmp;
 637         string str;
 638         float i, field, len;
 639         float is_spec;
 640         is_spec = (GetPlayerColor(pl.sv_entnum) == COLOR_SPECTATOR);
 641
 642         // Layout:
 643         tmp_z = 0;
 644         if(is_self)
 645         {
 646                 tmp_x = sbwidth;
 647                 tmp_y = sbar_fontsize_y;
 648                 drawfill(pos - '1 1 0', tmp + '2 2 0', '1 1 1', 0.3, DRAWFLAG_NORMAL);
 649         }
 650         tmp_y = 0;
 651
 652         for(i = 0; i < sbar_num_fields; ++i)
 653         {
 654                 field = sbar_field[i];
 655                 if(field == SP_SEPARATOR)
 656                         break;
 657
 658                 if(is_spec && field != SP_NAME && field != SP_PING) {
 659                         pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 660                         continue;
 661                 }
 662                 str = Sbar_GetField(pl, field);
 663
 664                 if(field == SP_NAME)
 665                 {
 666                         float realsize;
 667                         float j;
 668                         realsize = sbar_size[i];
 669                         if(i+1 < sbar_num_fields)
 670                                 if(sbar_field[i+1] == SP_SEPARATOR)
 671                                 {
 672                                         realsize = (xmax - xmin) / sbar_fontsize_x;
 673                                         for(j = 0; j < sbar_num_fields; ++j) if(j != i) if(sbar_field[j] != SP_SEPARATOR)
 674                                                 realsize -= sbar_size[j] + 1;
 675                                         realsize += 1;
 676                                 }
 677                         str = textShortenToWidth(str, realsize, TRUE);
 678                 }
 679                 len = stringwidth(str, TRUE);
 680
 681                 if(sbar_size[i] < len)
 682                         sbar_size[i] = len;
 683
 684                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 685
 686                 if(field == SP_NAME) {
 687                         tmp_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 688                         drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 689                 } else {
 690                         tmp_x = len*sbar_fontsize_x + sbar_fontsize_x;
 691                         drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 692                 }
 693         }
 694
 695         if(sbar_field[i] == SP_SEPARATOR)
 696         {
 697                 pos_x = xmax;
 698                 for(i = sbar_num_fields-1; i > 0; --i)
 699                 {
 700                         field = sbar_field[i];
 701                         if(field == SP_SEPARATOR)
 702                                 break;
 703
 704                         if(is_spec && field != SP_NAME && field != SP_PING) {
 705                                 pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 706                                 continue;
 707                         }
 708
 709                         str = Sbar_GetField(pl, field);
 710
 711                         if(field == SP_NAME)
 712                                 str = textShortenToWidth(str, sbar_size[i], TRUE);
 713                         len = stringwidth(str, TRUE);
 714
 715                         if(sbar_size[i] < len)
 716                                 sbar_size[i] = len;
 717
 718                         if(field == SP_NAME) {
 719                                 tmp_x = sbar_fontsize_x*len; // left or right aligned? let's put it right...
 720                                 drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 721                         } else {
 722                                 tmp_x = sbar_fontsize_x*len; //strlen(str);
 723                                 drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 724                         }
 725                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 726                 }
 727         }
 728 }
 729
 730 float lastpingstime;
 731 void Sbar_DrawScoreboard()
 732 {
 733         //float xmin, ymin, xmax, ymax;
 734         vector rgb, pos, tmp, sbar_save;
 735         entity pl, tm;
 736         float specs, i;
 737         float center_x;
 738
 739         if(time > lastpingstime + 10)
 740         {
 741                 localcmd("pings\n");
 742                 lastpingstime = time;
 743         }
 744
 745         sbar_fontsize = Sbar_GetFontsize();
 746         if(sbar_fontsize_x == 0)
 747                 sbar_fontsize = '8 8 0';
 748         if(sbar_fontsize_y == 0)
 749                 sbar_fontsize_y = sbar_fontsize_x;
 750
 751         xmin = vid_conwidth / 5;
 752         ymin = 20;
 753
 754         xmax = vid_conwidth - xmin;
 755         ymax = vid_conheight - 0.2*vid_conheight;
 756
 757         sbwidth = xmax - xmin;
 758         sbheight = ymax - ymin;
 759
 760         center_x = xmin + 0.5*sbwidth;
 761
 762         //Sbar_UpdateFields();
 763
 764         // Initializes position
 765         //pos_x = xmin;
 766         pos_y = ymin;
 767         pos_z = 0;
 768
 769         // Heading
 770         drawfont = sbar_bigfont;
 771         pos_x = center_x - stringwidth("Scoreboard", TRUE)*0.5*24;
 772         drawstring(pos, "Scoreboard", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 773         pos_x = xmin;
 774         pos_y += 24 + 4;
 775
 776         // Titlebar background:
 777         tmp_x = sbwidth;
 778         tmp_y = sbar_fontsize_y;
 779         drawfill(pos - '1 1 0', tmp + '2 2 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
 780
 781         drawfont = sbar_font;
 782
 783         for(i = 0; i < sbar_num_fields; ++i)
 784         {
 785                 if(sbar_field[i] == SP_SEPARATOR)
 786                         break;
 787                 drawstring(pos, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 788                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 789         }
 790
 791         if(sbar_field[i] == SP_SEPARATOR)
 792         {
 793                 pos_x = xmax + sbar_fontsize_x;
 794                 tmp_y = tmp_z = 0;
 795                 for(i = sbar_num_fields-1; i > 0; --i)
 796                 {
 797                         if(sbar_field[i] == SP_SEPARATOR)
 798                                 break;
 799
 800                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 801                         /**
 802                          * FTEQCC BUG!
 803                          * Using the following line will fuck it all up:
 804                          **
 805                          * tmp_x = sbar_size[i] - strlen(sbar_title[i])*8;
 806                          */
 807                         tmp_x = sbar_fontsize_x*sbar_size[i];
 808                         tmp_x -= stringwidth(sbar_title[i], FALSE)*sbar_fontsize_x;
 809                         drawstring(pos + tmp, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 810                 }
 811         }
 812
 813         pos_x = xmin;
 814         pos_y += 1.5 * sbar_fontsize_y;
 815
 816         sbar_save = sbar;
 817         sbar = '0 0 0';
 818
 819         if(teamplay)
 820         {
 821                 //for(tm = sortedTeams.sort_next; tm; tm = tm.sort_next)
 822                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 823                 {
 824                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
 825                                 continue;
 826
 827                         rgb = GetTeamRGB(tm.team);
 828
 829                         pos_x = xmin;
 830
 831                         Sbar_DrawXNum(
 832                                 pos - '6.5 0 0' * sbar_fontsize_y,
 833                                 tm.(teamscores[ts_primary]),
 834                                 4, sbar_fontsize_y * 1.5, rgb, 1, DRAWFLAG_NORMAL);
 835
 836                         if(ts_primary != ts_secondary)
 837                         Sbar_DrawXNum(
 838                                 pos - '4.5 0 0' * sbar_fontsize_y + '0 1.5 0' * sbar_fontsize_y,
 839                                 tm.(teamscores[ts_secondary]),
 840                                 4, sbar_fontsize_y * 1, rgb, 1, DRAWFLAG_NORMAL);
 841
 842                         specs = tm.team_size;
 843
 844                         if(specs < 2)
 845                                 specs = 2;
 846
 847                         tmp_x = sbwidth;
 848                         tmp_y = 1.25 * sbar_fontsize_y * specs;
 849                         drawfill(pos - '1 1 0', tmp + '2 0 0', rgb, 0.2, DRAWFLAG_NORMAL);
 850
 851                         for(pl = players.sort_next; pl; pl = pl.sort_next)
 852                         {
 853                                 if(pl.team != tm.team)
 854                                         continue;
 855                                 Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 856                                 pos_y += 1.25 * sbar_fontsize_y;
 857                                 tmp_y -= 1.25 * sbar_fontsize_y;
 858                         }
 859                         pos_y += tmp_y + 1.5 * sbar_fontsize_y;
 860                 }
 861                 // rgb := tempvector :)
 862                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 863                 pos_y += 3 * sbar_fontsize_y;
 864                 specs = 0;
 865                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 866                 {
 867                         if(pl.team != COLOR_SPECTATOR)
 868                                 continue;
 869                         //drawcolorcodedstring(pos, getplayerkey(pl.sb_player, "name"), '8 8 0', 1, 0);
 870                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 871                         pos += '0 1.25 0' * sbar_fontsize_y;
 872                         ++specs;
 873                 }
 874
 875                 if(specs)
 876                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 877         } else {
 878                 pos_x = xmin;
 879                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 880                 {
 881                         if(pl.team == COLOR_SPECTATOR)
 882                                 continue;
 883                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 884                         pos_y += 1.25 * sbar_fontsize_y;
 885                         tmp_y -= 1.25 * sbar_fontsize_y;
 886                 }
 887
 888                 // rgb := tempvector :)
 889                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 890                 pos_y += 3 * sbar_fontsize_y;
 891                 specs = 0;
 892                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 893                 {
 894                         if(pl.team != COLOR_SPECTATOR)
 895                                 continue;
 896                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 897                         pos += '0 1.25 0' * sbar_fontsize_y;
 898                         ++specs;
 899                 }
 900
 901                 if(specs)
 902                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 903         }
 904
 905         string str;
 906         float tl, fl;
 907         str = strcat("playing on ^2", shortmapname, "^7");
 908         tl = getstatf(STAT_TIMELIMIT);
 909         fl = getstatf(STAT_FRAGLIMIT);
 910         if(gametype == GAME_LMS)
 911         {
 912                 if(tl > 0)
 913                         str = strcat(str, " for up to ^1", ftos(tl), " minutes^7");
 914         }
 915         else
 916         {
 917                 if(tl > 0)
 918                         str = strcat(str, " for ^1", ftos(tl), " minutes^7");
 919                 if(fl > 0)
 920                 {
 921                         if(tl > 0)
 922                                 str = strcat(str, " or");
 923                         str = strcat(str, " until ^3", ftos(fl));
 924                         if(scores_label[ps_primary] == "score")
 925                                 str = strcat(str, " points^7");
 926                         else
 927                                 str = strcat(str, " ", scores_label[ps_primary]);
 928                 }
 929         }
 930
 931         pos_y += 1.5 * sbar_fontsize_y;
 932         drawcolorcodedstring(pos + '0.5 0 0' * (sbwidth - sbar_fontsize_x * stringwidth(str, TRUE)), str, sbar_fontsize, 0.8, 0);
 933
 934         sbar = sbar_save;
 935 }
 936
 937 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 938 {
 939         string col;
 940         string timestr;
 941         string cpname;
 942         string lapstr;
 943         lapstr = "";
 944
 945         if(histime == 0) // goal hit
 946         {
 947                 if(mytime > 0)
 948                 {
 949                         timestr = strcat("+", ftos_decimals(+mytime, 1));
 950                         col = "^1";
 951                 }
 952                 else if(mytime == 0)
 953                 {
 954                         timestr = "+0.0";
 955                         col = "^3";
 956                 }
 957                 else
 958                 {
 959                         timestr = strcat("-", ftos_decimals(-mytime, 1));
 960                         col = "^2";
 961                 }
 962
 963                 if(lapdelta > 0)
 964                 {
 965                         lapstr = strcat(" (-", ftos(lapdelta), "L)");
 966                         col = "^2";
 967                 }
 968                 else if(lapdelta < 0)
 969                 {
 970                         lapstr = strcat(" (+", ftos(-lapdelta), "L)");
 971                         col = "^1";
 972                 }
 973         }
 974         else if(histime > 0) // anticipation
 975         {
 976                 if(mytime >= histime)
 977                         timestr = strcat("+", ftos_decimals(mytime - histime, 1));
 978                 else
 979                         timestr = mmsss(histime * 10);
 980                 col = "^3";
 981         }
 982         else
 983                 col = "^7";
 984
 985         if(cp)
 986                 cpname = strcat("Intermediate ", ftos(cp));
 987         else
 988                 cpname = "Finish line";
 989
 990         if(histime < 0)
 991                 return strcat(col, cpname);
 992         else if(hisname == "")
 993                 return strcat(col, cpname, " (", timestr, ")");
 994         else
 995                 return strcat(col, cpname, " (", timestr, " ", strcat(hisname, col, lapstr), ")");
 996 }
 997
 998 void dummyfunction(float a1, float a2, float a3, float a4, float a5, float a6, float a7, float a8)
 999 {
1000 }
1001
1002 void Sbar_Score(float margin)
1003 {
1004         float timelimit, timeleft, minutes, seconds, distribution, myplace, score;
1005         vector sbar_save, place;
1006         entity tm, pl, me;
1007         sbar_save = sbar;
1008
1009         myteam = GetPlayerColor(player_localentnum - 1);
1010
1011         sbar_y = vid_conheight - (32+12);
1012         sbar_x -= margin;
1013
1014         place = '-48 -12 0';
1015         if(teamplay)
1016         {
1017                 // Layout:
1018                 //
1019                 //   team1 team3 team4
1020                 //
1021                 //         TEAM2
1022                 //for(i = 0; i < 4; ++i)
1023                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
1024                 {
1025                         if(tm.team == COLOR_SPECTATOR || !tm.team_size) // no players? don't display
1026                                 continue;
1027                         // -32*4 = -128
1028                         score = tm.(teamscores[ts_primary]);
1029                         if(tm.team == myteam)
1030                                 Sbar_DrawXNum('-128 0 0', score, 4, 32, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
1031                         else
1032                         {
1033                                 Sbar_DrawXNum(place, score, 4, 12, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
1034                                 place_x -= 4*12;
1035                         }
1036                 }
1037         } else {
1038                 // me vector := [team/connected frags id]
1039                 myplace = 0;
1040                 for(me = players.sort_next; me; me = me.sort_next)
1041                 {
1042                         if(me.team != COLOR_SPECTATOR)
1043                                 ++myplace;
1044                         if(me.sv_entnum == player_localentnum - 1)
1045                                 break;
1046                 }
1047                 pl = players;
1048                 if(pl == me)
1049                         pl = pl.sort_next;
1050
1051                 if(pl) {
1052                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
1053                 } else
1054                         distribution = 0;
1055
1056                 if(myplace == 1)
1057                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1058                 else if(myplace == 2)
1059                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
1060                 else
1061                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 0 0', 1, DRAWFLAG_NORMAL);
1062
1063                 score = me.(scores[ps_primary]);
1064                 if(distribution >= 0)
1065                 {
1066                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 1', 1, DRAWFLAG_NORMAL);
1067                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 1', 1, DRAWFLAG_NORMAL);
1068                 } else if(distribution >= -5)
1069                 {
1070                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 0', 1, DRAWFLAG_NORMAL);
1071                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 0', 1, DRAWFLAG_NORMAL);
1072                 } else {
1073                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 0 0', 1, DRAWFLAG_NORMAL);
1074                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 0 0', 1, DRAWFLAG_NORMAL);
1075                 }
1076         }
1077         timelimit = getstatf(STAT_TIMELIMIT);
1078         if(timelimit)
1079         {
1080                 timeleft = max(0, timelimit * 60 - time);
1081                 minutes = floor(timeleft / 60);
1082                 seconds = floor(timeleft - minutes*60);
1083                 if(minutes >= 5)
1084                 {
1085                         Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1086                         drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 1', sbar_alpha_fg, 0);
1087                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1088                 } else if(minutes >= 1)
1089                 {
1090                         Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
1091                         drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 0', sbar_alpha_fg, 0);
1092                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
1093                 } else {
1094                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 0 0', 1, DRAWFLAG_NORMAL);
1095                 }
1096         } else {
1097                 minutes = floor(time / 60);
1098                 seconds = floor(time - minutes*60);
1099                 Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1100                 drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 1', sbar_alpha_fg, 0);
1101                 Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1102         }
1103
1104         if(gametype == GAME_RACE)
1105         {
1106                 drawfont = sbar_bigfont;
1107                 float a;
1108                 vector m;
1109                 string s;
1110
1111                 m = '0.5 0 0' * vid_conwidth + '0 0.25 0' * vid_conheight;
1112
1113                 if(race_checkpointtime)
1114                 {
1115
1116                         a = bound(0, 2 - (time - race_checkpointtime), 1);
1117                         s = "";
1118                         if(a > 0) // just hit a checkpoint?
1119                         {
1120                                 if(race_time && race_previousbesttime)
1121                                         s = MakeRaceString(race_checkpoint, race_time / 10 - race_previousbesttime / 10, 0, 0, race_previousbestname);
1122                                 else
1123                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
1124                         }
1125                         else
1126                         {
1127                                 if(race_laptime && race_nextbesttime)
1128                                 {
1129                                         a = bound(0, 2 - ((race_laptime + race_nextbesttime/10) - time), 1);
1130                                         if(a > 0) // next one?
1131                                         {
1132                                                 s = MakeRaceString(race_nextcheckpoint, time - race_laptime, race_nextbesttime / 10, 0, race_nextbestname);
1133                                         }
1134                                 }
1135                         }
1136
1137                         if(s != "")
1138                         if(a > 0)
1139                         {
1140                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1141                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1142                         }
1143
1144                         if(race_laptime)
1145                         {
1146                                 s = mmsss(10*(time - race_laptime));
1147                                 drawstring(m - '0 0 0' - '16 0 0' * stringwidth(s, FALSE), s, '32 32 0', '1 1 1', sbar_alpha_fg, 0);
1148                         }
1149                 }
1150                 else
1151                 {
1152                         if(race_mycheckpointtime)
1153                         {
1154                                 a = bound(0, 2 - (time - race_mycheckpointtime), 1);
1155                                 s = MakeRaceString(race_mycheckpoint, race_mycheckpointdelta / 10, -!race_mycheckpointenemy, race_mycheckpointlapsdelta, race_mycheckpointenemy);
1156                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1157                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1158                         }
1159                         if(race_othercheckpointtime && race_othercheckpointenemy != "")
1160                         {
1161                                 a = bound(0, 2 - (time - race_othercheckpointtime), 1);
1162                                 s = MakeRaceString(race_othercheckpoint, -race_othercheckpointdelta / 10, -!race_othercheckpointenemy, race_othercheckpointlapsdelta, race_othercheckpointenemy);
1163                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1164                                 drawcolorcodedstring(m - '0 0 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1165                         }
1166                 }
1167
1168                 drawfont = sbar_font;
1169         }
1170
1171         sbar = sbar_save;
1172 }
1173
1174 void Sbar_MiniscoreItem(vector pos, entity pl, float is_self)
1175 {
1176         float x, score;
1177         pos_x += 72;
1178
1179         if(teamplay)
1180                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(pl.team)*0.5, 1, DRAWFLAG_NORMAL);
1181         else
1182                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
1183         x = pos_x;
1184         pos_x += 5*8;
1185         score = pl.(scores[ps_primary]);
1186         pos_x -= stringwidth(ftos(score), FALSE)*8;
1187         drawstring(pos, ftos(score), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1188         pos_x = x;
1189         if(is_self)
1190         {
1191                 pos_x += 48;
1192                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1193                 pos_x += 8;
1194         } else
1195                 pos_x += 56;
1196         drawcolorcodedstring(pos, getplayerkey(pl.sv_entnum, "name"), '8 8 0', 1, 0);
1197 }
1198
1199 void Sbar_MiniscoreTeamItem(vector pos, float color, float frags, float is_self)
1200 {
1201         float x;
1202         pos_x += 72;
1203
1204         if(teamplay)
1205                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(color)*0.5, 1, DRAWFLAG_NORMAL);
1206         else
1207                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
1208         x = pos_x;
1209         pos_x += 5*8;
1210         pos_x -= stringwidth(ftos(frags), FALSE)*8;
1211         drawstring(pos, ftos(frags), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1212         pos_x = x;
1213         if(is_self)
1214         {
1215                 pos_x += 48;
1216                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1217                 pos_x += 8;
1218         } else
1219                 pos_x += 56;
1220         drawstring(pos, GetTeamName(color), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1221 }
1222
1223 void Sbar_MiniDeathmatchOverlay(vector pos)
1224 {
1225         float numlines, up, down, score;
1226         entity me, tm, pl;
1227         float miniscoreboard_size;
1228         miniscoreboard_size = cvar("sbar_miniscoreboard_size");
1229
1230         if(miniscoreboard_size == 0)
1231                 return;
1232         pos_y = vid_conheight - 8;
1233
1234         if(miniscoreboard_size < 0)
1235                 numlines = (vid_conheight - sbar_y + 7) / 8;
1236         else
1237                 numlines = miniscoreboard_size;
1238
1239         // give up if there isn't enough room
1240         if(pos_x >= vid_conwidth || pos_y >= vid_conheight || numlines < 1)
1241                 return;
1242
1243         // me vector := [team/connected frags id]
1244         for(me = players.sort_next; me; me = me.sort_next)
1245         {
1246                 if(me.sv_entnum == player_localentnum - 1)
1247                         break;
1248         }
1249
1250         if(teamplay)
1251                 numlines -= numteams;
1252
1253         // figure out how many players above and below we can show
1254         up = floor(numlines/2);
1255         down = up;
1256         if((up + down) > numlines)
1257                 down = numlines - up;
1258
1259         // render bottom-up
1260         for(pl = me.sort_next; pl && down > 0; pl = pl.sort_next)
1261         {
1262                 if(pl.team == COLOR_SPECTATOR)
1263                         continue;
1264                 Sbar_MiniscoreItem(pos, pl, false);
1265                 pos_y -= 9;
1266                 --down;
1267         }
1268         Sbar_MiniscoreItem(pos, me, true);
1269         pos_y -= 9;
1270         up += down; // if there weren't enough lines below... add them
1271         for(pl = me.sort_prev; pl && up > 0; pl = pl.sort_prev)
1272         {
1273                 if(pl.team == COLOR_SPECTATOR)
1274                         continue;
1275                 Sbar_MiniscoreItem(pos, pl, false);
1276                 pos_y -= 9;
1277                 --up;
1278         }
1279
1280         if(teamplay)
1281         {
1282                 for(tm = teams.sort_next; tm.sort_next; tm = tm.sort_next);
1283                 for(; tm; tm = tm.sort_prev)
1284                 {
1285                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
1286                                 continue;
1287                         score = tm.(teamscores[ts_primary]);
1288                         Sbar_MiniscoreTeamItem(pos, tm.team, score, (tm.team == me.team));
1289                         pos_y -= 9;
1290                 }
1291         }
1292 }
1293
1294 float Sbar_WouldDrawScoreboard ()
1295 {
1296         if (sb_showscores)
1297                 return 1;
1298         else if (intermission == 1)
1299                 return 1;
1300         else if (intermission == 2)
1301                 return 1;
1302         else if (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard"))
1303                 return 1;
1304         else if(sb_showscores_force)
1305                 return 1;
1306         return 0;
1307 }
1308
1309 void Sbar_Draw (void)
1310 {
1311         float i;
1312         float x, fade;
1313         float stat_items;
1314
1315         //Sbar_SortFrags();
1316         Sbar_UpdatePlayerTeams();
1317
1318         sb_lines = 24;
1319
1320         if (sb_showscores)
1321                 Sbar_DrawScoreboard();
1322         else if (intermission == 1)
1323         {
1324                 Sbar_DrawScoreboard();
1325                 return;
1326         }
1327         else if (intermission == 2)
1328                 Sbar_FinaleOverlay();
1329         else
1330         {
1331                 if (sb_showscores || sb_showscores_force || (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard")))
1332                 {
1333                         sbar_x = (vid_conwidth - 640.0)*0.5;
1334                         sbar_y = vid_conheight - 47;
1335                         //Sbar_DrawAlphaPic (sbar_x, sbar_y, sb_scorebar, sbar_alpha_bg.value);
1336                         //drawpic('0 0 0', "gfx/scorebar", '0 0 0', '1 1 1', cvar("sbar_alpha_bg"), 0);
1337                         Sbar_DrawScoreboard ();
1338                 }
1339                 else
1340                 {
1341                         if (sb_lines && sbar_hudselector == 1)
1342                         {
1343                                 stat_items = getstati(STAT_ITEMS);
1344
1345                                 sbar_x = (vid_conwidth - 320.0)*0.5;
1346                                 sbar_y = vid_conheight - 24.0 - 16.0;
1347                                 sbar_z = 0;
1348
1349                                 fade = 3.2 - 2 * (time - weapontime);
1350                                 fade = bound(0.7, fade, 1);
1351
1352                                 x = 1.0;
1353                                 for(i = 0; i < 8; ++i)
1354                                 {
1355                                         if(stat_items & x)
1356                                         {
1357                                                 Sbar_DrawWeapon(i+1, fade, (i + 2 == activeweapon));
1358                                         }
1359                                         x *= 2;
1360                                 }
1361                                 x *= 2*2*2*2;
1362                                 if(stat_items & x)
1363                                 {
1364                                         Sbar_DrawWeapon(0, fade, (activeweapon == 1));
1365                                 }
1366
1367                                 // armor
1368                                 x = getstati(STAT_ARMOR);
1369                                 if (x > 0)
1370                                 {
1371                                         // "gfx/sb_armor"
1372                                         //Sbar_DrawStretchPic (72, 0, sb_armor[0], sbar_alpha_fg.value, 24, 24);
1373                                         drawpic(sbar + '72 0 0', "gfx/sb_armor", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1374                                         if(x > 200)
1375                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0 1 0', 1, 0);
1376                                         else if(x > 100)
1377                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1378                                         else if(x > 50)
1379                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1380                                         else if(x > 25)
1381                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1382                                         else
1383                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1384                                 }
1385
1386                                 // health
1387                                 x = getstati(STAT_HEALTH);
1388                                 if (x != 0)
1389                                 {
1390                                         // "gfx/sb_health"
1391                                         //Sbar_DrawStretchPic (184, 0, sb_health, sbar_alpha_fg.value, 24, 24);
1392                                         drawpic(sbar + '184 0 0', "gfx/sb_health", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1393                                         if(x > 200)
1394                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0 1 0', 1, 0);
1395                                         else if(x > 100)
1396                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1397                                         else if(x > 50)
1398                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1399                                         else if(x > 25)
1400                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1401                                         else
1402                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1403                                 }
1404
1405                                 // ammo
1406                                 x = getstati(STAT_AMMO);
1407                                 if ((stat_items & (NEX_IT_SHELLS | NEX_IT_BULLETS | NEX_IT_ROCKETS | NEX_IT_CELLS)) || x != 0)
1408                                 {
1409                                         if (stat_items & NEX_IT_SHELLS)
1410                                                 drawpic(sbar + '296 0 0', "gfx/sb_shells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1411                                         else if (stat_items & NEX_IT_BULLETS)
1412                                                 drawpic(sbar + '296 0 0', "gfx/sb_bullets", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1413                                         else if (stat_items & NEX_IT_ROCKETS)
1414                                                 drawpic(sbar + '296 0 0', "gfx/sb_rocket", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1415                                         else if (stat_items & NEX_IT_CELLS)
1416                                                 drawpic(sbar + '296 0 0', "gfx/sb_cells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1417                                         if(x > 10)
1418                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1419                                         else
1420                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1421                                 }
1422
1423                                 if (sbar_x + 320 + 160 <= vid_conwidth)
1424                                         Sbar_MiniDeathmatchOverlay(sbar + '320 0 0');
1425                                 if (sbar_x > 0)
1426                                         Sbar_Score(16);
1427                                 // The margin can be at most 8 to support 640x480 console size:
1428                                 //   320 + 2 * (144 + 16) = 640
1429                         }
1430                         else if (sb_lines)
1431                         {
1432
1433                                 stat_items = getstati(STAT_ITEMS);
1434
1435                                 sbar_x = (vid_conwidth - 640.0)*0.5;
1436                                 sbar_y = vid_conheight - 47;
1437                                 sbar_z = 0;
1438
1439                                 fade = 3 - 2 * (time - weapontime);
1440
1441                                 x = 1.0;
1442                                 for(i = 0; i < 8; ++i)
1443                                 {
1444                                         if(stat_items & x)
1445                                         {
1446                                                 Sbar_DrawWeapon(i+1, fade, (i + 2 == activeweapon));
1447                                         }
1448                                         x *= 2;
1449                                 }
1450                                 x *= 2*2*2*2;
1451                                 if(stat_items & x)
1452                                 {
1453                                         Sbar_DrawWeapon(0, fade, (activeweapon == 1));
1454                                 }
1455
1456                                 if (sb_lines > 24)
1457                                         drawpic(sbar, "gfx/sbar", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1458                                 else
1459                                         drawpic(sbar, "gfx/sbar_minimal", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1460
1461                                 // armor
1462                                 // (340-3*24) = 268
1463                                 Sbar_DrawXNum('268 12 0', getstati(STAT_ARMOR), 3, 24, '0.6 0.7 0.8', 1, 0);
1464
1465                                 // health
1466                                 // (154-3*24) = 82
1467                                 x = getstati(STAT_HEALTH);
1468                                 if(x > 100)
1469                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '1 1 1', 1, 0);
1470                                 else if(x <= 25 && time - floor(time) > 0.5)
1471                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '0.7 0 0', 1, 0);
1472                                 else
1473                                         Sbar_DrawXNum('81 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1474
1475                                 // AK dont draw ammo for the laser
1476                                 x = getstati(STAT_AMMO);
1477                                 if(activeweapon != 12)
1478                                 {
1479                                         // (519-3*24) = 447
1480                                         if (stat_items & NEX_IT_SHELLS)
1481                                                 drawpic(sbar + '519 0 0', "gfx/sb_shells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1482                                         else if (stat_items & NEX_IT_BULLETS)
1483                                                 drawpic(sbar + '519 0 0', "gfx/sb_bullets", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1484                                         else if (stat_items & NEX_IT_ROCKETS)
1485                                                 drawpic(sbar + '519 0 0', "gfx/sb_rocket", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1486                                         else if (stat_items & NEX_IT_CELLS)
1487                                                 drawpic(sbar + '519 0 0', "gfx/sb_cells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1488                                         if(x > 10)
1489                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1490                                         else
1491                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.7 0 0', 1, 0);
1492                                 }
1493
1494                                 if (sb_lines > 24)
1495                                         drawpic(sbar, "gfx/sbar_overlay", '0 0 0', '1 1 1', 1, DRAWFLAG_MODULATE);
1496
1497                                 if (sbar_x + 600 + 160 <= vid_conwidth)
1498                                         Sbar_MiniDeathmatchOverlay (sbar + '600 0 0');
1499
1500                                 if (sbar_x > 0)
1501                                         Sbar_Score(-16);
1502                                 // Because:
1503                                 //   Mini scoreboard uses 12*4 per other team, that is, 144
1504                                 //   pixels when there are four teams...
1505                                 //   Nexuiz by default sets vid_conwidth to 800... makes
1506                                 //   sbar_x == 80...
1507                                 //   so we need to shift it by 64 pixels to the right to fit
1508                                 //   BUT: then it overlaps with the image that gets drawn
1509                                 //   for viewsize 100! Therefore, just account for 3 teams,
1510                                 //   that is, 96 pixels mini scoreboard size, needing 16 pixels
1511                                 //   to the right!
1512                         }
1513
1514
1515                         if(gametype == GAME_KEYHUNT)
1516                         {
1517                                 CSQC_kh_hud();
1518                         } else if(gametype == GAME_CTF)
1519                         {
1520                                 CSQC_ctf_hud();
1521                         }
1522                 }
1523         }
1524 }
1525
1526 void CSQC_ctf_hud(void)
1527 {
1528         // cvar("sbar_flagstatus_right") move the flag icons right
1529         // cvar("sbar_flagstatus_pos") pixel position of the nexuiz flagstatus icons
1530         float redflag, blueflag;
1531         float stat_items;
1532         vector pos;
1533
1534         stat_items = getstati(STAT_ITEMS);
1535         redflag = (stat_items/32768) & 3;
1536         blueflag = (stat_items/131072) & 3;
1537
1538         /**
1539          * FTEQCC BUG!
1540          * For some reason now not even THAT works there...
1541          * Maybe the minus' precedence screws it up? The last one there, maybe I should use brackets
1542          **
1543          * pos_x = (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - sbar_x - 64 : 10 - sbar_x;
1544          ** Should try those later:
1545          * pos_x = (cvar("sbar_flagstatus_right")) ? (vid_conwidth - 10 - sbar_x - 64) : (10 - sbar_x);
1546          * pos_x = ( (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - 64 : 10 ) - sbar_x;
1547          */
1548
1549         if(cvar("sbar_flagstatus_right"))
1550                 pos_x = vid_conwidth - 10 - sbar_x - 64;
1551         else
1552                 pos_x = 10 - sbar_x;
1553
1554         pos_z = 0;
1555
1556         if(sbar_hudselector == 1)
1557                 pos_y = (vid_conheight - sbar_y) - cvar("sbar_flagstatus_pos") - 64;
1558         else
1559                 pos_y = -117;
1560
1561         pos += sbar;
1562
1563         switch(redflag)
1564         {
1565         case 1: drawpic(pos, "gfx/sb_flag_red_taken", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1566         case 2: drawpic(pos, "gfx/sb_flag_red_lost", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1567         case 3: drawpic(pos, "gfx/sb_flag_red_carrying", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1568         }
1569
1570         pos_y -= 64;
1571
1572         switch(blueflag)
1573         {
1574         case 1: drawpic(pos, "gfx/sb_flag_blue_taken", '0 0 0', '1 1 1', 1, 0); break;
1575         case 2: drawpic(pos, "gfx/sb_flag_blue_lost", '0 0 0', '1 1 1', 1, 0); break;
1576         case 3: drawpic(pos, "gfx/sb_flag_blue_carrying", '0 0 0', '1 1 1', 1, 0); break;
1577         }
1578 }