data/qcsrc/client/sbar.qc

   1 void drawstringright(vector, string, vector, vector, float, float);
   2 void drawstringcenter(vector, string, vector, vector, float, float);
   3
   4 float weapon_hits[WEP_COUNT];
   5 float weapon_fired[WEP_COUNT];
   6 float weapon_number;
   7
   8 float last_weapon;
   9 float weapontime;
  10
  11 float sbar_alpha_fg;
  12 float sbar_alpha_bg;
  13 float sbar_color_bg_team;
  14 float sbar_border_thickness;
  15 float sbar_scoreboard_alpha_bg;
  16 float sbar_scoreboard_alpha_fg;
  17 float sbar_scoreboard_highlight;
  18 float sbar_scoreboard_highlight_alpha;
  19 float sbar_scoreboard_highlight_alpha_self;
  20 float sbar_hudselector;
  21 float sbar_hud_accuracy;
  22 float sbar_scoreboard_alpha_name;
  23 float sbar_scoreboard_alpha_name_self;
  24
  25 float ps_primary, ps_secondary;
  26 float ts_primary, ts_secondary;
  27
  28 vector color;
  29 float SCOREBOARD_OFFSET = 50;
  30
  31 void CSQC_kh_hudreset();
  32 void CSQC_kh_hud();
  33 void CSQC_ctf_hudreset();
  34 void CSQC_ctf_hud();
  35 void CSQC_nb_hud();
  36 void MapVote_Draw();
  37 void Sbar_FinaleOverlay()
  38 {
  39         /*vector pos;
  40         pos_x = (vid_conwidth - 1)/2;
  41         pos_y = 16;
  42         pos_z = 0;*/
  43
  44         //drawpic(pos, "gfx/finale", '0 0 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
  45
  46         //drawstring(pos, "END", sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
  47         MapVote_Draw();
  48 }
  49
  50 float weaponspace[10];
  51 float weapon_first, weapon_last;
  52 void Sbar_DrawWeapon_Clear()
  53 {
  54         float idx;
  55         weapon_first = -2;
  56         weapon_last = -1;
  57         for(idx = 0; idx < 10; ++idx)
  58                 weaponspace[idx] = 0;
  59         for(idx = 0; idx <= 23; ++idx)
  60         {
  61                 if(weaponimpulse[idx] >= 0)
  62                 {
  63                         if(weapon_first < 0)
  64                                 weapon_first = idx;
  65                         weapon_last = idx;
  66                 }
  67         }
  68 }
  69 void Sbar_DrawWeapon(float nr, float fade, float active, float wc)
  70 {
  71         vector pos, vsize, fill_colour;
  72         float value, idx, imp, sp, weapon_hit, weapon_damage, weapon_stats;
  73
  74         imp = weaponimpulse[nr];
  75         weapon_hit = weapon_hits[wc];
  76         weapon_damage = weapon_fired[wc];
  77         if(imp == 0)
  78                 idx = 9;
  79         else
  80                 idx = imp - 1;
  81
  82         value = (active) ? 1 : 0.6;
  83         color_x = color_y = color_z = value;
  84
  85         // width = 300, height = 100
  86         const float w_width = 24, w_height = 12, w_space = 2, font_size = 8;
  87
  88         sp = weaponspace[idx] + 1;
  89         weaponspace[idx] = sp;
  90
  91         pos_x = (vid_conwidth + 6 - w_width * 9) * 0.5 + w_width * idx;
  92         pos_y = (vid_conheight - w_height * sp) - 38; // move 38 pixels up
  93         pos_z = 0;
  94         vsize_x = w_width;
  95         vsize_y = w_height;
  96         vsize_z = 0;
  97         if (active)
  98                 drawpic(pos, "gfx/hud/sb_ammobg", vsize, color, value * fade * sbar_alpha_fg, DRAWFLAG_NORMAL);
  99         drawpic(pos, strcat("gfx/hud/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, DRAWFLAG_NORMAL);
 100         pos_x += w_space;
 101         pos_y += w_space;
 102         vsize_x = font_size;
 103         vsize_y = font_size;
 104         vsize_z = 0;
 105         drawstring(pos, ftos(imp), vsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
 106
 107         // draw the weapon accuracy on the HUD
 108         if(sbar_hud_accuracy)
 109         {
 110                 weapon_stats = rint(100*weapon_hit/weapon_damage);
 111                 fill_colour_x = 1 - 0.015 * weapon_stats;
 112                 fill_colour_y = 1 - 0.015 * (100 - weapon_stats);
 113                 drawstringright(pos + '22 0 0', strcat(ftos(weapon_stats),"%"), '6 6 0', fill_colour, sbar_alpha_fg, 0);
 114         }
 115 }
 116
 117 void Sbar_DrawXNum (vector pos, float num, float digits, float showminusplus, float lettersize, vector rgb, float highlighted, float stroke, float alpha, float dflags)
 118 {
 119         float l, i;
 120         string str, tmp, l_length;
 121         float minus, plus;
 122         vector vsize, num_color;
 123
 124         vsize_x = vsize_y = lettersize;
 125         vsize_z = 0;
 126
 127         // showminusplus 1: always prefix with minus sign (useful in race distribution display)
 128         // showminusplus 2: always prefix with plus sign (useful in race distribution display)
 129         // showminusplus 3: prefix with minus sign if negative, plus sign if positive (useful in score distribution display)
 130
 131         if((showminusplus == 2 && num >= 0) || (num > 0 && showminusplus == 3))
 132         {
 133                 plus = true;
 134                 pos_x -= lettersize;
 135         } else
 136                 plus = false;
 137
 138         if(num < 0 || (num < 0 && showminusplus == 3) || (showminusplus == 1 && num <= 0))
 139         {
 140                 minus = true;
 141                 num = -num;
 142                 pos_x -= lettersize;
 143         } else
 144                 minus = false;
 145
 146         if(digits < 0)
 147         {
 148                 tmp = ftos(num);
 149                 digits = -digits;
 150                 str = strcat(substring("0000000000", 0, digits - strlen(tmp)), tmp);
 151         } else
 152                 str = ftos(num);
 153
 154         l = strlen(str);
 155         l_length = ftos(l);
 156
 157         if(l > digits)
 158         {
 159                 str = substring(str, l-digits, 999);
 160                 l = strlen(str);
 161         } else if(l < digits)
 162                 pos_x += (digits-l) * lettersize;
 163
 164         if (highlighted == 1) {
 165                 vector hl_size;
 166                 hl_size_x = vsize_x * l + vsize_x * 0.2;
 167                 hl_size_y = vsize_y * 1.1;
 168                 hl_size_z = 0;
 169                 if(minus)
 170                         hl_size_x = hl_size_x + vsize_x;
 171
 172                 vector hl_pos;
 173                 hl_pos_x = pos_x - lettersize/10;
 174                 hl_pos_y = pos_y - lettersize/20;
 175                 hl_pos_z = 0;
 176
 177                 drawpic(hl_pos, strcat("gfx/hud/sb_highlight_", l_length), hl_size, '1 1 1', alpha, dflags);
 178         }
 179
 180         if (stroke == 1)
 181                 num_color = '1 1 1';
 182         else
 183                 num_color = rgb;
 184
 185         if(minus)
 186         {
 187                 if (stroke == 1)
 188                         drawpic(pos, "gfx/hud/num_minus_stroke", vsize, rgb, alpha, dflags);
 189                 drawpic(pos, "gfx/hud/num_minus", vsize, num_color, alpha, dflags);
 190                 pos_x += lettersize;
 191         } else if(plus)
 192         {
 193                 if (stroke == 1)
 194                         drawpic(pos, "gfx/hud/num_plus_stroke", vsize, rgb, alpha, dflags);
 195                 drawpic(pos, "gfx/hud/num_plus", vsize, num_color, alpha, dflags);
 196                 pos_x += lettersize;
 197         }
 198
 199         for(i = 0; i < l; ++i)
 200         {
 201                 tmp = substring(str, i, 1);
 202                 if (stroke == 1)
 203                         drawpic(pos, strcat("gfx/hud/num_", tmp, "_stroke"), vsize, rgb, alpha, dflags);
 204                 drawpic(pos, strcat("gfx/hud/num_", tmp), vsize, num_color, alpha, dflags);
 205                 pos_x += lettersize;
 206         }
 207 }
 208
 209 void Sbar_DrawXNum_Colored (vector pos, float x, float lettersize, float alpha)
 210 {
 211         if(x > 200) {
 212                 color_x = 0;
 213                 color_y = 1;
 214                 color_z = 0;
 215         }
 216         else if(x > 150) {
 217                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 218                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 219                 color_z = 0;
 220         }
 221         else if(x > 100) {
 222                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 223                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 224                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 225         }
 226         else if(x > 50) {
 227                 color_x = 1;
 228                 color_y = 1;
 229                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 230         }
 231         else if(x > 20) {
 232                 color_x = 1;
 233                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
 234                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 235         }
 236         else {
 237                 color_x = 1;
 238                 color_y = 0;
 239                 color_z = 0;
 240         }
 241         Sbar_DrawXNum(pos, x, 3, 0, lettersize, color, 0, 0, alpha, DRAWFLAG_NORMAL);
 242 }
 243
 244 void Cmd_Sbar_SetFields(float argc);
 245 void Sbar_InitScores()
 246 {
 247         float i, f;
 248
 249         ps_primary = ps_secondary = ts_primary = ts_secondary = -1;
 250         for(i = 0; i < MAX_SCORE; ++i)
 251         {
 252                 f = (scores_flags[i] & SFL_SORT_PRIO_MASK);
 253                 if(f == SFL_SORT_PRIO_PRIMARY)
 254                         ps_primary = i;
 255                 if(f == SFL_SORT_PRIO_SECONDARY)
 256                         ps_secondary = i;
 257         }
 258         if(ps_secondary == -1)
 259                 ps_secondary = ps_primary;
 260
 261         for(i = 0; i < MAX_TEAMSCORE; ++i)
 262         {
 263                 f = (teamscores_flags[i] & SFL_SORT_PRIO_MASK);
 264                 if(f == SFL_SORT_PRIO_PRIMARY)
 265                         ts_primary = i;
 266                 if(f == SFL_SORT_PRIO_SECONDARY)
 267                         ts_secondary = i;
 268         }
 269         if(ts_secondary == -1)
 270                 ts_secondary = ts_primary;
 271
 272         Cmd_Sbar_SetFields(0);
 273 }
 274
 275 void Sbar_UpdatePlayerPos(entity pl);
 276 float SetTeam(entity pl, float Team);
 277 //float lastpnum;
 278 void Sbar_UpdatePlayerTeams()
 279 {
 280         float Team;
 281         entity pl, tmp;
 282         float num;
 283
 284         num = 0;
 285         for(pl = players.sort_next; pl; pl = pl.sort_next)
 286         {
 287                 num += 1;
 288                 Team = GetPlayerColor(pl.sv_entnum);
 289                 if(SetTeam(pl, Team))
 290                 {
 291                         tmp = pl.sort_prev;
 292                         Sbar_UpdatePlayerPos(pl);
 293                         if(tmp)
 294                                 pl = tmp;
 295                         else
 296                                 pl = players.sort_next;
 297                 }
 298         }
 299         /*
 300         if(num != lastpnum)
 301                 print(strcat("PNUM: ", ftos(num), "\n"));
 302         lastpnum = num;
 303         */
 304 }
 305
 306 float Sbar_ComparePlayerScores(entity left, entity right)
 307 {
 308         float vl, vr;
 309         vl = GetPlayerColor(left.sv_entnum);
 310         vr = GetPlayerColor(right.sv_entnum);
 311
 312         if(!left.gotscores)
 313                 vl = COLOR_SPECTATOR;
 314         if(!right.gotscores)
 315                 vr = COLOR_SPECTATOR;
 316
 317         if(vl > vr)
 318                 return true;
 319         if(vl < vr)
 320                 return false;
 321
 322         if(vl == COLOR_SPECTATOR)
 323         {
 324                 // FIRST the one with scores (spectators), THEN the ones without (downloaders)
 325                 // no other sorting
 326                 if(!left.gotscores && right.gotscores)
 327                         return true;
 328                 return false;
 329         }
 330
 331         vl = left.scores[ps_primary];
 332         vr = right.scores[ps_primary];
 333         if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
 334         {
 335                 if(vl == 0 && vr != 0)
 336                         return 1;
 337                 if(vl != 0 && vr == 0)
 338                         return 0;
 339         }
 340         if(vl > vr)
 341                 return IS_INCREASING(scores_flags[ps_primary]);
 342         if(vl < vr)
 343                 return IS_DECREASING(scores_flags[ps_primary]);
 344
 345         vl = left.scores[ps_secondary];
 346         vr = right.scores[ps_secondary];
 347         if(scores_flags[ps_secondary] & SFL_ZERO_IS_WORST)
 348         {
 349                 if(vl == 0 && vr != 0)
 350                         return 1;
 351                 if(vl != 0 && vr == 0)
 352                         return 0;
 353         }
 354         if(vl > vr)
 355                 return IS_INCREASING(scores_flags[ps_secondary]);
 356         if(vl < vr)
 357                 return IS_DECREASING(scores_flags[ps_secondary]);
 358
 359         return false;
 360 }
 361
 362 void Sbar_UpdatePlayerPos(entity player)
 363 {
 364         for(other = player.sort_next; other && Sbar_ComparePlayerScores(player, other); other = player.sort_next)
 365         {
 366                 SORT_SWAP(player, other);
 367         }
 368         for(other = player.sort_prev; other != players && Sbar_ComparePlayerScores(other, player); other = player.sort_prev)
 369         {
 370                 SORT_SWAP(other, player);
 371         }
 372 }
 373
 374 float Sbar_CompareTeamScores(entity left, entity right)
 375 {
 376         float vl, vr;
 377
 378         if(left.team == COLOR_SPECTATOR)
 379                 return 1;
 380         if(right.team == COLOR_SPECTATOR)
 381                 return 0;
 382
 383         vl = left.teamscores[ts_primary];
 384         vr = right.teamscores[ts_primary];
 385         if(vl > vr)
 386                 return IS_INCREASING(teamscores_flags[ts_primary]);
 387         if(vl < vr)
 388                 return IS_DECREASING(teamscores_flags[ts_primary]);
 389
 390         vl = left.teamscores[ts_secondary];
 391         vr = right.teamscores[ts_secondary];
 392         if(vl > vr)
 393                 return IS_INCREASING(teamscores_flags[ts_secondary]);
 394         if(vl < vr)
 395                 return IS_DECREASING(teamscores_flags[ts_secondary]);
 396
 397         return false;
 398 }
 399
 400 void Sbar_UpdateTeamPos(entity Team)
 401 {
 402         for(other = Team.sort_next; other && Sbar_CompareTeamScores(Team, other); other = Team.sort_next)
 403         {
 404                 SORT_SWAP(Team, other);
 405         }
 406         for(other = Team.sort_prev; other != teams && Sbar_CompareTeamScores(other, Team); other = Team.sort_prev)
 407         {
 408                 SORT_SWAP(other, Team);
 409         }
 410 }
 411
 412 void Cmd_Sbar_Help(float argc)
 413 {
 414         print("You can modify the scoreboard using the ^2sbar_columns_set command.\n");
 415         print("^3|---------------------------------------------------------------|\n");
 416         print("Usage:\n");
 417         print("^2sbar_columns_set default\n");
 418         print("^2sbar_columns_set ^7filed1 field2 ...\n");
 419         print("The following field names are recognized (case insensitive):\n");
 420         print("You can use a ^3|^7 to start the right-aligned fields.\n\n");
 421
 422         print("^3name^7 or ^3nick^7         Name of a player\n");
 423         print("^3ping^7                     Ping time\n");
 424         print("^3pl^7                       Packet loss\n");
 425         print("^3kills^7                    Number of kills\n");
 426         print("^3deaths^7                   Number of deaths\n");
 427         print("^3suicides^7                 Number of suicides\n");
 428         print("^3frags^7                    kills - suicides\n");
 429         print("^3kd^7                       The kill-death ratio\n");
 430         print("^3caps^7                     How often a flag (CTF) or a key (KeyHunt) was captured\n");
 431         print("^3pickups^7                  How often a flag (CTF) or a key (KeyHunt) was picked up\n");
 432         print("^3fckills^7                  Number of flag carrier kills\n");
 433         print("^3returns^7                  Number of flag returns\n");
 434         print("^3drops^7                    Number of flag drops\n");
 435         print("^3lives^7                    Number of lives (LMS)\n");
 436         print("^3rank^7                     Player rank\n");
 437         print("^3pushes^7                   Number of players pushed into void\n");
 438         print("^3destroyed^7                Number of keys destroyed by pushing them into void\n");
 439         print("^3kckills^7                  Number of keys carrier kills\n");
 440         print("^3losses^7                   Number of times a key was lost\n");
 441         print("^3laps^7                     Number of laps finished (race/cts)\n");
 442         print("^3time^7                     Total time raced (race/cts)\n");
 443         print("^3fastest^7                  Time of fastest lap (race/cts)\n");
 444         print("^3ticks^7                    Number of ticks (DOM)\n");
 445         print("^3takes^7                    Number of domination points taken (DOM)\n");
 446         print("^3score^7                    Total score\n\n");
 447
 448         print("Before a field you can put a + or - sign, then a comma separated list\n");
 449         print("of game types, then a slash, to make the field show up only in these\n");
 450         print("or in all but these game types. You can also specify 'all' as a\n");
 451         print("field to show all fields available for the current game mode.\n\n");
 452
 453         print("The special game type names 'teams' and 'noteams' can be used to\n");
 454         print("include/exclude ALL teams/noteams game modes.\n\n");
 455
 456         print("Example: sbar_columns_set name ping pl | +ctf/field3 -dm/field4\n");
 457         print("will display name, ping and pl aligned to the left, and the fields\n");
 458         print("right of the vertical bar aligned to the right.\n");
 459         print("'field3' will only be shown in CTF, and 'field4' will be shown in all\n");
 460         print("other gamemodes except DM.\n");
 461 }
 462
 463 string Sbar_DefaultColumnLayout()
 464 {
 465         return strcat( // fteqcc sucks
 466                 "ping pl name | ",
 467                 "-teams,race,lms/kills -teams,lms/deaths -teams,lms,race/suicides -race,dm,tdm/frags ", // tdm already has this in "score"
 468                 "+ctf/caps +ctf/pickups +ctf/fckills +ctf/returns ",
 469                 "+lms/lives +lms/rank ",
 470                 "+kh/caps +kh/pushes +kh/destroyed ",
 471                 "?+race/laps ?+race/time ?+race/fastest ",
 472                 "+as/objectives +nexball/faults +nexball/goals ",
 473                 "-lms,race,nexball/score");
 474 }
 475
 476 void Cmd_Sbar_SetFields(float argc)
 477 {
 478         float i, j, slash;
 479         string str, pattern;
 480         float digit;
 481         float have_name, have_primary, have_secondary, have_separator;
 482         float missing;
 483
 484         // TODO: re enable with gametype dependant cvars?
 485         if(argc < 2) // no arguments provided
 486                 argc = tokenizebyseparator(strcat("x ", cvar_string("sbar_columns")), " ");
 487
 488         if(argc < 2)
 489                 argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 490
 491         if(argc == 2)
 492         {
 493                 if(argv(1) == "default")
 494                         argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 495                 else if(argv(1) == "all")
 496                 {
 497                         string s;
 498                         s = "ping pl color name |";
 499                         for(i = 0; i < MAX_SCORE; ++i)
 500                         {
 501                                 if(i != ps_primary)
 502                                 if(i != ps_secondary)
 503                                 if(scores_label[i] != "")
 504                                         s = strcat(s, " ", scores_label[i]);
 505                         }
 506                         if(ps_secondary != ps_primary)
 507                                 s = strcat(s, " ", scores_label[ps_secondary]);
 508                         s = strcat(s, " ", scores_label[ps_primary]);
 509                         argc = tokenizebyseparator(strcat("x ", s), " ");
 510                 }
 511         }
 512
 513
 514         sbar_num_fields = 0;
 515
 516         drawfont = sbar_font;
 517         digit = stringwidth("0123456789", FALSE) / 10;
 518
 519         for(i = 0; i < argc - 1; ++i)
 520         {
 521                 float nocomplain;
 522                 str = argv(i+1);
 523
 524                 nocomplain = FALSE;
 525                 if(substring(str, 0, 1) == "?")
 526                 {
 527                         nocomplain = TRUE;
 528                         str = substring(str, 1, strlen(str) - 1);
 529                 }
 530
 531                 slash = strstrofs(str, "/", 0);
 532                 if(slash >= 0)
 533                 {
 534                         pattern = substring(str, 0, slash);
 535                         str = substring(str, slash + 1, strlen(str) - (slash + 1));
 536
 537                         if not(isGametypeInFilter(gametype, teamplay, pattern))
 538                                 continue;
 539                 }
 540
 541                 strunzone(sbar_title[sbar_num_fields]);
 542                 sbar_title[sbar_num_fields] = strzone(str);
 543                 sbar_size[sbar_num_fields] = stringwidth(str, FALSE);
 544                 str = strtolower(str);
 545
 546                 if(str == "ping") {
 547                         sbar_field[sbar_num_fields] = SP_PING;
 548                 } else if(str == "pl") {
 549                         sbar_field[sbar_num_fields] = SP_PL;
 550                 } else if(str == "kd" || str == "kdr" || str == "kdratio" || str == "k/d") {
 551                         sbar_field[sbar_num_fields] = SP_KDRATIO;
 552                 } else if(str == "name" || str == "nick") {
 553                         sbar_field[sbar_num_fields] = SP_NAME;
 554                         have_name = 1;
 555                 } else if(str == "|") {
 556                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 557                         have_separator = 1;
 558                 } else {
 559                         for(j = 0; j < MAX_SCORE; ++j)
 560                                 if(str == strtolower(scores_label[j]))
 561                                         goto found; // sorry, but otherwise fteqcc -O3 miscompiles this and warns about "unreachable code"
 562 :notfound
 563                         if(str == "frags")
 564                         {
 565                                 j = SP_FRAGS;
 566                         }
 567                         else
 568                         {
 569                                 if not(nocomplain)
 570                                         print(strcat("^1Error:^7 Unknown score field: '", str, "'\n"));
 571                                 continue;
 572                         }
 573 :found
 574                         sbar_field[sbar_num_fields] = j;
 575                         if(j == ps_primary)
 576                                 have_primary = 1;
 577                         if(j == ps_secondary)
 578                                 have_secondary = 1;
 579                 }
 580                 ++sbar_num_fields;
 581                 if(sbar_num_fields >= MAX_SBAR_FIELDS)
 582                         break;
 583         }
 584
 585         if(scores_flags[ps_primary] & SFL_ALLOW_HIDE)
 586                 have_primary = 1;
 587         if(scores_flags[ps_secondary] & SFL_ALLOW_HIDE)
 588                 have_secondary = 1;
 589         if(ps_primary == ps_secondary)
 590                 have_secondary = 1;
 591         missing = (!have_primary) + (!have_secondary) + (!have_separator) + (!have_name);
 592
 593         if(sbar_num_fields+missing < MAX_SBAR_FIELDS)
 594         {
 595                 if(!have_name)
 596                 {
 597                         strunzone(sbar_title[sbar_num_fields]);
 598                         for(i = sbar_num_fields; i > 0; --i)
 599                         {
 600                                 sbar_title[i] = sbar_title[i-1];
 601                                 sbar_size[i] = sbar_size[i-1];
 602                                 sbar_field[i] = sbar_field[i-1];
 603                         }
 604                         sbar_title[0] = strzone("name");
 605                         sbar_field[0] = SP_NAME;
 606                         ++sbar_num_fields;
 607                         print("fixed missing field 'name'\n");
 608
 609                         if(!have_separator)
 610                         {
 611                                 strunzone(sbar_title[sbar_num_fields]);
 612                                 for(i = sbar_num_fields; i > 1; --i)
 613                                 {
 614                                         sbar_title[i] = sbar_title[i-1];
 615                                         sbar_size[i] = sbar_size[i-1];
 616                                         sbar_field[i] = sbar_field[i-1];
 617                                 }
 618                                 sbar_title[1] = strzone("|");
 619                                 sbar_field[1] = SP_SEPARATOR;
 620                                 sbar_size[1] = stringwidth("|", FALSE);
 621                                 ++sbar_num_fields;
 622                                 print("fixed missing field '|'\n");
 623                         }
 624                 }
 625                 else if(!have_separator)
 626                 {
 627                         strunzone(sbar_title[sbar_num_fields]);
 628                         sbar_title[sbar_num_fields] = strzone("|");
 629                         sbar_size[sbar_num_fields] = stringwidth("|", FALSE);
 630                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 631                         ++sbar_num_fields;
 632                         print("fixed missing field '|'\n");
 633                 }
 634                 if(!have_secondary)
 635                 {
 636                         strunzone(sbar_title[sbar_num_fields]);
 637                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_secondary]);
 638                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 639                         sbar_field[sbar_num_fields] = ps_secondary;
 640                         ++sbar_num_fields;
 641                         print("fixed missing field '", scores_label[ps_secondary], "'\n");
 642                 }
 643                 if(!have_primary)
 644                 {
 645                         strunzone(sbar_title[sbar_num_fields]);
 646                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_primary]);
 647                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 648                         sbar_field[sbar_num_fields] = ps_primary;
 649                         ++sbar_num_fields;
 650                         print("fixed missing field '", scores_label[ps_primary], "'\n");
 651                 }
 652         }
 653
 654         sbar_field[sbar_num_fields] = SP_END;
 655 }
 656
 657 // MOVEUP::
 658 vector sbar_field_rgb;
 659 string sbar_field_icon0;
 660 string sbar_field_icon1;
 661 string sbar_field_icon2;
 662 vector sbar_field_icon0_rgb;
 663 vector sbar_field_icon1_rgb;
 664 vector sbar_field_icon2_rgb;
 665 float sbar_field_icon0_alpha;
 666 float sbar_field_icon1_alpha;
 667 float sbar_field_icon2_alpha;
 668 string Sbar_GetField(entity pl, float field)
 669 {
 670         float tmp, num, denom, f;
 671         string str;
 672         sbar_field_rgb = '1 1 1';
 673         sbar_field_icon0 = "";
 674         sbar_field_icon1 = "";
 675         sbar_field_icon2 = "";
 676         sbar_field_icon0_rgb = '1 1 1';
 677         sbar_field_icon1_rgb = '1 1 1';
 678         sbar_field_icon2_rgb = '1 1 1';
 679         sbar_field_icon0_alpha = 1;
 680         sbar_field_icon1_alpha = 1;
 681         sbar_field_icon2_alpha = 1;
 682         switch(field)
 683         {
 684                 case SP_PING:
 685                         if not(pl.gotscores)
 686                                 return "\x8D\x8D\x8D"; // >>> sign
 687                         str = getplayerkey(pl.sv_entnum, "ping");
 688                         if(str == "0")
 689                                 return "N/A";
 690                         tmp = max(0, min(220, stof(str)-80)) / 220;
 691                         sbar_field_rgb = '1 1 1' - '0 1 1'*tmp;
 692                         return str;
 693
 694                 case SP_PL:
 695                         if not(pl.gotscores)
 696                                 return "N/A";
 697                         str = getplayerkey(pl.sv_entnum, "pl");
 698                         if(str == "0")
 699                                 return "";
 700                         tmp = bound(0, stof(str), 20) / 20; // 20% is REALLY BAD pl
 701                         sbar_field_rgb = '1 0.5 0.5' - '0 0.5 0.5'*tmp;
 702                         return str;
 703
 704                 case SP_NAME:
 705                         if(ready_waiting && pl.ready)
 706                         {
 707                                 sbar_field_icon0 = "gfx/sb_player_ready";
 708                         }
 709                         else if(!teamplay)
 710                         {
 711                                 f = stof(getplayerkey(pl.sv_entnum, "colors"));
 712                                 {
 713                                         sbar_field_icon0 = "gfx/sb_playercolor_base";
 714                                         sbar_field_icon1 = "gfx/sb_playercolor_shirt";
 715                                         sbar_field_icon1_rgb = colormapPaletteColor(floor(f / 16), 0);
 716                                         sbar_field_icon2 = "gfx/sb_playercolor_pants";
 717                                         sbar_field_icon2_rgb = colormapPaletteColor(mod(f, 16), 1);
 718                                 }
 719                         }
 720                         return GetPlayerName(pl.sv_entnum);
 721
 722                 case SP_FRAGS:
 723                         f = pl.(scores[SP_KILLS]);
 724                         f -= pl.(scores[SP_SUICIDES]);
 725                         return ftos(f);
 726
 727                 case SP_KDRATIO:
 728                         num = pl.(scores[SP_KILLS]);
 729                         denom = pl.(scores[SP_DEATHS]);
 730
 731                         if(denom == 0) {
 732                                 sbar_field_rgb = '0 1 0';
 733                                 str = ftos(num);
 734                         } else if(num <= 0) {
 735                                 sbar_field_rgb = '1 0 0';
 736                                 str = ftos(num/denom);
 737                         } else
 738                                 str = ftos(num/denom);
 739
 740                         tmp = strstrofs(str, ".", 0);
 741                         if(tmp > 0)
 742                                 str = substring(str, 0, tmp+2);
 743                         return str;
 744
 745                 default:
 746                         tmp = pl.(scores[field]);
 747                         f = scores_flags[field];
 748                         if(field == ps_primary)
 749                                 sbar_field_rgb = '1 1 0';
 750                         else if(field == ps_secondary)
 751                                 sbar_field_rgb = '0 1 1';
 752                         else
 753                                 sbar_field_rgb = '1 1 1';
 754                         return ScoreString(f, tmp);
 755         }
 756         //return "error";
 757 }
 758
 759 float xmin, xmax, ymin, ymax, sbwidth;
 760 float sbar_fixscoreboardcolumnwidth_len;
 761 float sbar_fixscoreboardcolumnwidth_iconlen;
 762 float sbar_fixscoreboardcolumnwidth_marginlen;
 763
 764 float stringwidth_colors(string s)
 765 {
 766         return stringwidth(s, TRUE);
 767 }
 768
 769 float stringwidth_nocolors(string s)
 770 {
 771         return stringwidth(s, FALSE);
 772 }
 773
 774 string Sbar_FixScoreboardColumnWidth(float i, string str)
 775 {
 776         float field, f;
 777         vector sz;
 778         field = sbar_field[i];
 779
 780         sbar_fixscoreboardcolumnwidth_iconlen = 0;
 781
 782         if(sbar_field_icon0 != "")
 783         {
 784                 sz = drawgetimagesize(sbar_field_icon0);
 785                 f = sz_x / sz_y;
 786                 if(sbar_fixscoreboardcolumnwidth_iconlen < f)
 787                         sbar_fixscoreboardcolumnwidth_iconlen = f;
 788         }
 789
 790         if(sbar_field_icon1 != "")
 791         {
 792                 sz = drawgetimagesize(sbar_field_icon1);
 793                 f = sz_x / sz_y;
 794                 if(sbar_fixscoreboardcolumnwidth_iconlen < f)
 795                         sbar_fixscoreboardcolumnwidth_iconlen = f;
 796         }
 797
 798         if(sbar_field_icon2 != "")
 799         {
 800                 sz = drawgetimagesize(sbar_field_icon2);
 801                 f = sz_x / sz_y;
 802                 if(sbar_fixscoreboardcolumnwidth_iconlen < f)
 803                         sbar_fixscoreboardcolumnwidth_iconlen = f;
 804         }
 805
 806         sbar_fixscoreboardcolumnwidth_iconlen *= sbar_fontsize_y / sbar_fontsize_x; // fix icon aspect
 807
 808         if(sbar_fixscoreboardcolumnwidth_iconlen != 0)
 809                 sbar_fixscoreboardcolumnwidth_marginlen = stringwidth(" ", FALSE);
 810         else
 811                 sbar_fixscoreboardcolumnwidth_marginlen = 0;
 812
 813         if(field == SP_NAME) // name gets all remaining space
 814         {
 815                 float namesize, j;
 816                 namesize = sbwidth / sbar_fontsize_x;
 817                 for(j = 0; j < sbar_num_fields; ++j)
 818                         if(j != i)
 819                                 if (sbar_field[i] != SP_SEPARATOR)
 820                                         namesize -= sbar_size[j] + 1;
 821                 namesize += 1;
 822                 sbar_size[i] = namesize;
 823
 824                 if (sbar_fixscoreboardcolumnwidth_iconlen != 0)
 825                         namesize -= sbar_fixscoreboardcolumnwidth_marginlen + sbar_fixscoreboardcolumnwidth_iconlen;
 826                 str = textShortenToWidth(str, namesize, stringwidth_colors);
 827                 sbar_fixscoreboardcolumnwidth_len = stringwidth(str, TRUE);
 828         }
 829         else
 830                 sbar_fixscoreboardcolumnwidth_len = stringwidth(str, FALSE);
 831
 832         f = sbar_fixscoreboardcolumnwidth_len + sbar_fixscoreboardcolumnwidth_marginlen + sbar_fixscoreboardcolumnwidth_iconlen;
 833         if(sbar_size[i] < f)
 834                 sbar_size[i] = f;
 835
 836         return str;
 837 }
 838
 839 void Sbar_PrintScoreboardItem(vector pos, entity pl, float is_self, float pl_number)
 840 {
 841         vector tmp, plteamrgb;
 842         plteamrgb = GetTeamRGB(pl.team);
 843         string str;
 844         float i, field;
 845         float is_spec;
 846         is_spec = (GetPlayerColor(pl.sv_entnum) == COLOR_SPECTATOR);
 847
 848         // Layout:
 849         tmp_x = sbwidth;
 850         tmp_y = sbar_fontsize_y * 1.25;
 851         tmp_z = 0;
 852
 853         // alternated rows highlighting
 854         if (is_self)
 855                 drawfill(pos - '1 1 0', tmp + '2 0 0', plteamrgb, sbar_scoreboard_highlight_alpha_self, DRAWFLAG_NORMAL);
 856         else
 857         {
 858                 if (sbar_scoreboard_highlight)
 859                         if(!mod(pl_number,2))
 860                                 drawfill(pos - '1 1 0', tmp + '2 0 0', plteamrgb, sbar_scoreboard_highlight_alpha, DRAWFLAG_NORMAL);
 861         }
 862
 863         tmp_y = 0;
 864
 865         for(i = 0; i < sbar_num_fields; ++i)
 866         {
 867                 field = sbar_field[i];
 868                 if(field == SP_SEPARATOR)
 869                         break;
 870
 871                 if(is_spec && field != SP_NAME && field != SP_PING) {
 872                         pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 873                         continue;
 874                 }
 875                 str = Sbar_GetField(pl, field);
 876                 str = Sbar_FixScoreboardColumnWidth(i, str);
 877
 878                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 879
 880                 if(field == SP_NAME) {
 881                         tmp_x = sbar_fontsize_x*(sbar_size[i] - sbar_fixscoreboardcolumnwidth_iconlen - sbar_fixscoreboardcolumnwidth_marginlen) + sbar_fontsize_x;
 882                         if (is_self)
 883                                 drawcolorcodedstring(pos - tmp, str, sbar_fontsize, sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 884                         else
 885                                 drawcolorcodedstring(pos - tmp, str, sbar_fontsize, sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 886                 } else {
 887                         tmp_x = sbar_fixscoreboardcolumnwidth_len*sbar_fontsize_x + sbar_fontsize_x;
 888                         if (is_self)
 889                                 drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 890                         else
 891                                 drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 892                 }
 893
 894                 tmp_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 895                 if(sbar_field_icon0 != "")
 896                         if (is_self)
 897                                 drawpic(pos - tmp, sbar_field_icon0, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon0_alpha * sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 898                         else
 899                                 drawpic(pos - tmp, sbar_field_icon0, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon0_alpha * sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 900                 if(sbar_field_icon1 != "")
 901                         if (is_self)
 902                                 drawpic(pos - tmp, sbar_field_icon1, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon1_alpha * sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 903                         else
 904                                 drawpic(pos - tmp, sbar_field_icon1, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon1_alpha * sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 905                 if(sbar_field_icon2 != "")
 906                         if (is_self)
 907                                 drawpic(pos - tmp, sbar_field_icon2, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon2_rgb, sbar_field_icon2_alpha * sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 908                         else
 909                                 drawpic(pos - tmp, sbar_field_icon2, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon2_rgb, sbar_field_icon2_alpha * sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 910         }
 911
 912         if(sbar_field[i] == SP_SEPARATOR)
 913         {
 914                 pos_x = xmax;
 915                 for(i = sbar_num_fields-1; i > 0; --i)
 916                 {
 917                         field = sbar_field[i];
 918                         if(field == SP_SEPARATOR)
 919                                 break;
 920
 921                         if(is_spec && field != SP_NAME && field != SP_PING) {
 922                                 pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 923                                 continue;
 924                         }
 925
 926                         str = Sbar_GetField(pl, field);
 927                         str = Sbar_FixScoreboardColumnWidth(i, str);
 928
 929                         if(field == SP_NAME) {
 930                                 tmp_x = sbar_fontsize_x*sbar_fixscoreboardcolumnwidth_len; // left or right aligned? let's put it right...
 931                                 if(is_self)
 932                                         drawcolorcodedstring(pos - tmp, str, sbar_fontsize, sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 933                                 else
 934                                         drawcolorcodedstring(pos - tmp, str, sbar_fontsize, sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 935                         } else {
 936                                 tmp_x = sbar_fontsize_x*sbar_fixscoreboardcolumnwidth_len;
 937                                 if(is_self)
 938                                         drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 939                                 else
 940                                         drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 941                         }
 942
 943                         tmp_x = sbar_fontsize_x*sbar_size[i];
 944                         if(sbar_field_icon0 != "")
 945                                 if (is_self)
 946                                         drawpic(pos - tmp, sbar_field_icon0, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon0_alpha * sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 947                                 else
 948                                         drawpic(pos - tmp, sbar_field_icon0, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon0_alpha * sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 949                         if(sbar_field_icon1 != "")
 950                                 if (is_self)
 951                                         drawpic(pos - tmp, sbar_field_icon1, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon1_alpha * sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 952                                 else
 953                                         drawpic(pos - tmp, sbar_field_icon1, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon1_alpha * sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 954                         if(sbar_field_icon2 != "")
 955                                 if (is_self)
 956                                         drawpic(pos - tmp, sbar_field_icon2, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon2_rgb, sbar_field_icon2_alpha * sbar_scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 957                                 else
 958                                         drawpic(pos - tmp, sbar_field_icon2, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon2_rgb, sbar_field_icon2_alpha * sbar_scoreboard_alpha_name, DRAWFLAG_NORMAL);
 959                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 960                 }
 961         }
 962 }
 963
 964 /*
 965  * Sbar_Scoreboard_MakeTable
 966  *
 967  * Makes a table for a team (for all playing players in DM) and fills it
 968  */
 969
 970 vector Sbar_Scoreboard_MakeTable(vector pos, entity tm, vector rgb, vector bg_size)
 971 {
 972         float body_table_height, i;
 973         vector tmp, column_dim;
 974         entity pl;
 975
 976         body_table_height = 1.25 * sbar_fontsize_y * max(1, tm.team_size); // no player? show 1 empty line
 977
 978         pos -= '1 1 0';
 979
 980         tmp_x = sbwidth + 2;
 981         tmp_y = 1.25 * sbar_fontsize_y;
 982
 983         // rounded header
 984         drawpic(pos, "gfx/hud/sb_scoreboard_tableheader", tmp, '0.5 0.5 0.5', sbar_scoreboard_alpha_bg, DRAWFLAG_NORMAL);
 985
 986         // table border
 987         tmp_y += sbar_border_thickness;
 988         tmp_y += body_table_height;
 989         drawborderlines(sbar_border_thickness, pos, tmp, '0 0 0', sbar_scoreboard_alpha_bg, DRAWFLAG_NORMAL); // more transparency for the scoreboard
 990
 991         // separator header/table
 992         pos_y += 1.25 * sbar_fontsize_y;
 993         tmp_y = sbar_border_thickness;
 994         drawfill(pos, tmp, '0 0 0', sbar_scoreboard_alpha_bg, DRAWFLAG_NORMAL);
 995
 996         pos_y += sbar_border_thickness;
 997
 998         // table background
 999         tmp_y = body_table_height;
1000         drawpic_tiled(pos, "gfx/hud/sb_scoreboard_bg", bg_size, tmp, rgb * sbar_color_bg_team, sbar_scoreboard_alpha_bg, DRAWFLAG_NORMAL);
1001
1002         // anyway, apply some color
1003         //drawfill(pos, tmp + '2 0 0', rgb, 0.1, DRAWFLAG_NORMAL);
1004
1005         // go back to the top to make alternated columns highlighting and to print the strings
1006         pos_y -= 1.25 * sbar_fontsize_y;
1007         pos_y -= sbar_border_thickness;
1008
1009         pos += '1 1 0';
1010
1011         if (sbar_scoreboard_highlight)
1012         {
1013                 column_dim_y = 1.25 * sbar_fontsize_y; // header
1014                 column_dim_y += sbar_border_thickness;
1015                 column_dim_y += body_table_height;
1016         }
1017
1018         // print the strings of the columns headers and draw the columns
1019         for(i = 0; i < sbar_num_fields; ++i)
1020         {
1021                 if(sbar_field[i] == SP_SEPARATOR)
1022                         break;
1023                 column_dim_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
1024                 if (sbar_scoreboard_highlight)
1025                 {
1026                         if (mod(i,2))
1027                                 drawfill(pos - '0 1 0' - sbar_fontsize_x / 2 * '1 0 0', column_dim, '0 0 0', sbar_scoreboard_alpha_bg * 0.2, DRAWFLAG_NORMAL);
1028                 }
1029                 drawstring(pos, sbar_title[i], sbar_fontsize, rgb, sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1030                 pos_x += column_dim_x;
1031         }
1032         if(sbar_field[i] == SP_SEPARATOR)
1033         {
1034                 pos_x = xmax;
1035                 tmp_y = 0;
1036                 for(i = sbar_num_fields-1; i > 0; --i)
1037                 {
1038                         if(sbar_field[i] == SP_SEPARATOR)
1039                                 break;
1040
1041                         pos_x -= sbar_size[i]*sbar_fontsize_x;
1042
1043                         if (sbar_scoreboard_highlight)
1044                         {
1045                                 if (!mod(i,2))
1046                                 {
1047                                         if (i == sbar_num_fields-1)
1048                                                 column_dim_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x / 2 + 1;
1049                                         else
1050                                                 column_dim_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
1051                                         drawfill(pos - '0 1 0' - sbar_fontsize_x / 2 * '1 0 0', column_dim, '0 0 0', sbar_scoreboard_alpha_bg * 0.2, DRAWFLAG_NORMAL);
1052                                 }
1053                         }
1054
1055                         tmp_x = stringwidth(sbar_title[i], FALSE);
1056                         tmp_x = (sbar_size[i] - tmp_x) * sbar_fontsize_x;
1057                         drawstring(pos + tmp, sbar_title[i], sbar_fontsize, rgb, sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1058                         pos_x -= sbar_fontsize_x;
1059                 }
1060         }
1061
1062         pos_x = xmin;
1063         pos_y += 1.25 * sbar_fontsize_y; // skip the header
1064         pos_y += sbar_border_thickness;
1065
1066         // fill the table and draw the rows
1067         i = 0;
1068         if (teamplay)
1069                 for(pl = players.sort_next; pl; pl = pl.sort_next)
1070                 {
1071                         if(pl.team != tm.team)
1072                                 continue;
1073                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1), i);
1074                         pos_y += 1.25 * sbar_fontsize_y;
1075                         ++i;
1076                 }
1077         else
1078                 for(pl = players.sort_next; pl; pl = pl.sort_next)
1079                 {
1080                         if(pl.team == COLOR_SPECTATOR)
1081                                 continue;
1082                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1), i);
1083                         pos_y += 1.25 * sbar_fontsize_y;
1084                         ++i;
1085                 }
1086
1087         if (i == 0)
1088                 pos_y += 1.25 * sbar_fontsize_y; // move to the end of the table
1089         pos_y += 1.25 * sbar_fontsize_y; // move empty row (out of the table)
1090
1091         return pos;
1092 }
1093
1094 float Sbar_WouldDrawScoreboard() {
1095         if (sb_showscores)
1096                 return 1;
1097         else if (intermission == 1)
1098                 return 1;
1099         else if (intermission == 2)
1100                 return 1;
1101         else if (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard"))
1102                 return 1;
1103         else if(sb_showscores_force)
1104                 return 1;
1105         return 0;
1106 }
1107
1108 float lastpingstime;
1109 float scoreboard_bottom;
1110 float sbar_scoreboard_fade_alpha;
1111 float sbar_woulddrawscoreboard_prev;
1112 float sbar_woulddrawscoreboard_change; // "time" at which Sbar_WouldDrawScoreboard() changed
1113 void Sbar_DrawScoreboard()
1114 {
1115         float sbar_woulddrawscoreboard;
1116         sbar_woulddrawscoreboard = Sbar_WouldDrawScoreboard();
1117         if(sbar_woulddrawscoreboard != sbar_woulddrawscoreboard_prev) {
1118                 sbar_woulddrawscoreboard_change = time;
1119                 sbar_woulddrawscoreboard_prev = sbar_woulddrawscoreboard;
1120         }
1121
1122         float scoreboard_fadeinspeed = 10;
1123         float scoreboard_fadeoutspeed = 5;
1124         if(sbar_woulddrawscoreboard)
1125                 sbar_scoreboard_fade_alpha = bound (0, (time - sbar_woulddrawscoreboard_change) * scoreboard_fadeinspeed, 1);
1126         else
1127                 sbar_scoreboard_fade_alpha = bound (0, (1/scoreboard_fadeoutspeed - (time - sbar_woulddrawscoreboard_change)) * scoreboard_fadeoutspeed, 1);
1128
1129         if not(sbar_scoreboard_fade_alpha)
1130                 return;
1131         sbar_scoreboard_alpha_bg = cvar("sbar_scoreboard_alpha_bg") * sbar_scoreboard_fade_alpha;
1132         sbar_scoreboard_alpha_fg = cvar("sbar_scoreboard_alpha_fg") * sbar_scoreboard_fade_alpha;
1133         sbar_scoreboard_highlight = cvar("sbar_scoreboard_highlight");
1134         sbar_scoreboard_highlight_alpha = cvar("sbar_scoreboard_highlight_alpha") * sbar_scoreboard_fade_alpha;
1135         sbar_scoreboard_highlight_alpha_self = cvar("sbar_scoreboard_highlight_alpha_self") * sbar_scoreboard_fade_alpha;
1136         sbar_scoreboard_alpha_name = cvar("sbar_scoreboard_alpha_name") * sbar_scoreboard_fade_alpha;
1137         sbar_scoreboard_alpha_name_self = cvar("sbar_scoreboard_alpha_name_self") * sbar_scoreboard_fade_alpha;
1138
1139         vector rgb, pos, tmp;
1140         entity pl, tm;
1141
1142         if(time > lastpingstime + 10)
1143         {
1144                 localcmd("pings\n");
1145                 lastpingstime = time;
1146         }
1147
1148         sbwidth = Sbar_GetWidth(6.5 * sbar_fontsize_y);
1149
1150         xmin = 0.5 * (vid_conwidth - sbwidth);
1151         ymin = SCOREBOARD_OFFSET;
1152
1153         xmax = vid_conwidth - xmin;
1154         ymax = vid_conheight - 0.2*vid_conheight;
1155
1156         // Initializes position
1157         pos_x = xmin;
1158         pos_y = ymin;
1159         pos_z = 0;
1160
1161         // Heading
1162         drawfont = sbar_bigfont;
1163         drawstringcenter('0 1 0' * ymin, "Scoreboard", '24 24 0', '1 1 1', sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1164
1165         pos_y += 24 + 4;
1166         pos_y += sbar_fontsize_y;
1167
1168         drawfont = sbar_font;
1169
1170         // Draw the scoreboard
1171         vector bg_size;
1172         bg_size = drawgetimagesize("gfx/hud/sb_scoreboard_bg");
1173
1174         if(teamplay)
1175         {
1176                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
1177                 {
1178                         if(tm.team == COLOR_SPECTATOR)
1179                                 continue;
1180
1181                         rgb = GetTeamRGB(tm.team);
1182                         Sbar_DrawXNum(pos - '6.5 0 0' * sbar_fontsize_y + '0 1 0' * sbar_fontsize_y, tm.(teamscores[ts_primary]), 4, 0, sbar_fontsize_y * 1.5, rgb, 0, 1, sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1183
1184                         if(ts_primary != ts_secondary)
1185                                 Sbar_DrawXNum(pos - '4.5 0 0' * sbar_fontsize_y + '0 2.5 0' * sbar_fontsize_y, tm.(teamscores[ts_secondary]), 4, 0, sbar_fontsize_y * 1, rgb, 0, 1, sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1186
1187                         pos = Sbar_Scoreboard_MakeTable(pos, tm, rgb, bg_size);
1188                 }
1189         }
1190         else
1191         {
1192                 rgb_x = cvar("sbar_color_bg_r");
1193                 rgb_y = cvar("sbar_color_bg_g");
1194                 rgb_z = cvar("sbar_color_bg_b");
1195
1196                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
1197                 {
1198                         if(tm.team == COLOR_SPECTATOR)
1199                                 continue;
1200
1201                         pos = Sbar_Scoreboard_MakeTable(pos, tm, rgb, bg_size);
1202                 }
1203         }
1204
1205         tmp = pos + '0 1.5 0' * sbar_fontsize_y;
1206         pos_y += 3 * sbar_fontsize_y;
1207
1208         // List spectators
1209         float specs;
1210         specs = 0;
1211         for(pl = players.sort_next; pl; pl = pl.sort_next)
1212         {
1213                 if(pl.team != COLOR_SPECTATOR)
1214                         continue;
1215                 Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1), specs);
1216                 pos_y += 1.25 * sbar_fontsize_y;
1217                 ++specs;
1218         }
1219
1220         if(specs)
1221                 drawstring(tmp, "Spectators", sbar_fontsize, '1 1 1', sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1222
1223         // Print info string
1224         string str;
1225         float tl, fl, ll;
1226         str = strcat("playing on ^2", shortmapname, "^7");
1227         tl = getstatf(STAT_TIMELIMIT);
1228         fl = getstatf(STAT_FRAGLIMIT);
1229         ll = getstatf(STAT_LEADLIMIT);
1230         if(gametype == GAME_LMS)
1231         {
1232                 if(tl > 0)
1233                         str = strcat(str, " for up to ^1", ftos(tl), " minutes^7");
1234         }
1235         else
1236         {
1237                 if(tl > 0)
1238                         str = strcat(str, " for ^1", ftos(tl), " minutes^7");
1239                 if(fl > 0)
1240                 {
1241                         if(tl > 0)
1242                                 str = strcat(str, " or");
1243                         if(teamplay)
1244                         {
1245                                 str = strcat(str, " until ^3", ScoreString(teamscores_flags[ts_primary], fl));
1246                                 if(teamscores_label[ts_primary] == "score")
1247                                         str = strcat(str, " points^7");
1248                                 else if(teamscores_label[ts_primary] == "fastest")
1249                                         str = strcat(str, " is beaten^7");
1250                                 else
1251                                         str = strcat(str, " ", teamscores_label[ts_primary]);
1252                         }
1253                         else
1254                         {
1255                                 str = strcat(str, " until ^3", ScoreString(scores_flags[ps_primary], fl));
1256                                 if(scores_label[ps_primary] == "score")
1257                                         str = strcat(str, " points^7");
1258                                 else if(scores_label[ps_primary] == "fastest")
1259                                         str = strcat(str, " is beaten^7");
1260                                 else
1261                                         str = strcat(str, " ", scores_label[ps_primary]);
1262                         }
1263                 }
1264                 if(ll > 0)
1265                 {
1266                         if(tl > 0 || fl > 0)
1267                                 str = strcat(str, " or");
1268                         if(teamplay)
1269                         {
1270                                 str = strcat(str, " until a lead of ^3", ScoreString(teamscores_flags[ts_primary], ll));
1271                                 if(teamscores_label[ts_primary] == "score")
1272                                         str = strcat(str, " points^7");
1273                                 else if(teamscores_label[ts_primary] == "fastest")
1274                                         str = strcat(str, " is beaten^7");
1275                                 else
1276                                         str = strcat(str, " ", teamscores_label[ts_primary]);
1277                         }
1278                         else
1279                         {
1280                                 str = strcat(str, " until a lead of ^3", ScoreString(scores_flags[ps_primary], ll));
1281                                 if(scores_label[ps_primary] == "score")
1282                                         str = strcat(str, " points^7");
1283                                 else if(scores_label[ps_primary] == "fastest")
1284                                         str = strcat(str, " is beaten^7");
1285                                 else
1286                                         str = strcat(str, " ", scores_label[ps_primary]);
1287                         }
1288                 }
1289         }
1290
1291
1292         pos_y += 1.2 * sbar_fontsize_y;
1293         drawcolorcodedstring(pos + '0.5 0 0' * (sbwidth - sbar_fontsize_x * stringwidth(str, TRUE)), str, sbar_fontsize, sbar_scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1294
1295         scoreboard_bottom = pos_y + 2 * sbar_fontsize_y;
1296 }
1297
1298 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
1299 {
1300         string col;
1301         string timestr;
1302         string cpname;
1303         string lapstr;
1304         lapstr = "";
1305
1306         if(histime == 0) // goal hit
1307         {
1308                 if(mytime > 0)
1309                 {
1310                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
1311                         col = "^1";
1312                 }
1313                 else if(mytime == 0)
1314                 {
1315                         timestr = "+0.0";
1316                         col = "^3";
1317                 }
1318                 else
1319                 {
1320                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
1321                         col = "^2";
1322                 }
1323
1324                 if(lapdelta > 0)
1325                 {
1326                         lapstr = strcat(" (-", ftos(lapdelta), "L)");
1327                         col = "^2";
1328                 }
1329                 else if(lapdelta < 0)
1330                 {
1331                         lapstr = strcat(" (+", ftos(-lapdelta), "L)");
1332                         col = "^1";
1333                 }
1334         }
1335         else if(histime > 0) // anticipation
1336         {
1337                 if(mytime >= histime)
1338                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
1339                 else
1340                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
1341                 col = "^3";
1342         }
1343         else
1344                 col = "^7";
1345
1346         if(cp == 254)
1347                 cpname = "Start line";
1348         else if(cp == 255)
1349                 cpname = "Finish line";
1350         else if(cp)
1351                 cpname = strcat("Intermediate ", ftos(cp));
1352         else
1353                 cpname = "Finish line";
1354
1355         if(histime < 0)
1356                 return strcat(col, cpname);
1357         else if(hisname == "")
1358                 return strcat(col, cpname, " (", timestr, ")");
1359         else
1360                 return strcat(col, cpname, " (", timestr, " ", strcat(hisname, col, lapstr), ")");
1361 }
1362
1363 void Sbar_Score()
1364 {
1365         float score, distribution, leader;
1366         vector score_pos, secondary_score_pos, distribution_color;
1367         entity tm, pl, me;
1368         me = (spectatee_status > 0) ? playerslots[spectatee_status - 1] : playerslots[player_localentnum - 1];
1369
1370         vector bottomright;
1371         bottomright_x = vid_conwidth;
1372         bottomright_y = vid_conheight;
1373         bottomright_z = 0;
1374
1375         score_pos = bottomright - '196 42 0';
1376         secondary_score_pos = score_pos + '132 -6 0';
1377
1378         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
1379                 pl = players.sort_next;
1380                 if(pl == me)
1381                         pl = pl.sort_next;
1382                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
1383                         if(pl.scores[ps_primary] == 0)
1384                                 pl = world;
1385
1386                 score = me.(scores[ps_primary]);
1387
1388                 float racemin, racesec, racemsec;
1389                 float distsec, distmsec, minusplus;
1390
1391                 racemin = floor(score/(60 * TIME_FACTOR));
1392                 racesec = floor((score - racemin*(60 * TIME_FACTOR))/TIME_FACTOR);
1393                 racemsec = score - racemin*60*TIME_FACTOR - racesec*TIME_FACTOR;
1394
1395                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
1396                         // distribution display
1397                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
1398
1399                         if (distribution < TIME_FACTOR && distribution > -TIME_FACTOR)
1400                                 distmsec = fabs(distribution);
1401                         else {
1402                                 distsec = floor(fabs(distribution)/TIME_FACTOR);
1403                                 distmsec = fabs(distribution) - distsec*TIME_FACTOR;
1404                                 if (distribution < 0)
1405                                         distsec = -distsec;
1406                         }
1407
1408                         if (distribution <= 0) {
1409                                 distribution_color = '0 1 0';
1410                                 minusplus = 1; // minusplus 1: always prefix with minus sign
1411                         }
1412                         else {
1413                                 distribution_color = '1 0 0';
1414                                 minusplus = 2; // minusplus 1: always prefix with plus sign
1415                         }
1416                         Sbar_DrawXNum(bottomright - '0 48 0' - '16 0 0' * TIME_DECIMALS, distmsec, -TIME_DECIMALS, 0, 16, distribution_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1417                         Sbar_DrawXNum(bottomright - '68 48 0' - '16 0 0' * TIME_DECIMALS, distsec, 4, minusplus, 16, distribution_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1418                         drawpic(bottomright - '10 48 0' - '16 0 0' * TIME_DECIMALS, "gfx/hud/num_dot", '16 16 0', distribution_color, sbar_alpha_fg, DRAWFLAG_ADDITIVE);
1419                 }
1420                 // race record display
1421                 if (distribution <= 0 || distribution == score) // draw the highlight background behind the timer if we have the lead
1422                         drawpic(bottomright - '0 32 0' - '32 0 0' * (4 + TIME_DECIMALS), "gfx/hud/sb_highlight_4", '0 28 0' + '32 0 0' * (4 + TIME_DECIMALS), '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1423
1424                 Sbar_DrawXNum(bottomright - '0 32 0' - TIME_DECIMALS * '30 0 0', racemsec, -TIME_DECIMALS, 0, 30, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1425                 Sbar_DrawXNum(bottomright - '0 32 0' - TIME_DECIMALS * '30 0 0'  - '66 0 0', racesec, -2, 0, 30, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1426                 drawpic(bottomright - '0 32 0' - TIME_DECIMALS * '30 0 0' - '18 0 0', "gfx/hud/num_dot", '30 30 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE);
1427
1428                 Sbar_DrawXNum(bottomright - '0 32 0' - TIME_DECIMALS * '30 0 0' - '132 0 0', racemin, -2, 0, 30, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1429                 drawpic(bottomright - '0 32 0' - TIME_DECIMALS * '30 0 0' - '84 0 0', "gfx/hud/num_colon", '30 30 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE);
1430
1431         } else if (!teamplay) { // non-teamgames, except race/cts
1432                 // me vector := [team/connected frags id]
1433                 pl = players.sort_next;
1434                 if(pl == me)
1435                         pl = pl.sort_next;
1436
1437                 if(pl)
1438                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
1439                 else
1440                         distribution = 0;
1441
1442                 score = me.(scores[ps_primary]);
1443
1444                 if(distribution >= 5) {
1445                         distribution_color = '0 1 0';
1446                         leader = 1;
1447                 } else if(distribution >= 0) {
1448                         distribution_color = '1 1 1';
1449                         leader = 1;
1450                 } else if(distribution >= -5)
1451                         distribution_color = '1 1 0';
1452                 else
1453                         distribution_color = '1 0 0';
1454
1455                 Sbar_DrawXNum(secondary_score_pos, distribution, 4, 3, 16, distribution_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1456                 Sbar_DrawXNum(score_pos, score, 4, 0, 34, distribution_color, leader, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1457         } else { // teamgames
1458                 float max_fragcount;
1459                 max_fragcount = -999;
1460
1461                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
1462                         if(tm.team == COLOR_SPECTATOR || !tm.team_size) // no players? don't display
1463                                 continue;
1464                         score = tm.(teamscores[ts_primary]);
1465                         leader = 0;
1466
1467                         if (score > max_fragcount)
1468                                 max_fragcount = score;
1469
1470                         if(tm.team == myteam) {
1471                                 if (max_fragcount == score)
1472                                         leader = 1;
1473                                 Sbar_DrawXNum(score_pos, score, 4, 0, 34, GetTeamRGB(tm.team) * 0.8, leader, 1, sbar_alpha_fg, DRAWFLAG_NORMAL);
1474                         } else {
1475                                 if (max_fragcount == score)
1476                                         leader = 1;
1477                                 Sbar_DrawXNum(secondary_score_pos, score, 4, 0, 16, GetTeamRGB(tm.team) * 0.8, leader, 1, sbar_alpha_fg, DRAWFLAG_NORMAL);
1478                                 secondary_score_pos = secondary_score_pos + '0 16 0';
1479                         }
1480                 }
1481         }
1482
1483         if(gametype == GAME_RACE || gametype == GAME_CTS)
1484         {
1485                 drawfont = sbar_bigfont;
1486                 float a, t;
1487                 vector m;
1488                 string s, forcetime;
1489
1490                 m = '0.5 0 0' * vid_conwidth + '0 0.25 0' * vid_conheight;
1491
1492                 if(race_checkpointtime)
1493                 {
1494                         a = bound(0, 2 - (time - race_checkpointtime), 1);
1495                         s = "";
1496                         forcetime = "";
1497                         if(a > 0) // just hit a checkpoint?
1498                         {
1499                                 if(race_checkpoint != 254)
1500                                 {
1501                                         if(race_time && race_previousbesttime)
1502                                                 s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
1503                                         else
1504                                                 s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
1505                                         if(race_time)
1506                                                 forcetime = TIME_ENCODED_TOSTRING(race_time);
1507                                 }
1508                         }
1509                         else
1510                         {
1511                                 if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
1512                                 {
1513                                         a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
1514                                         if(a > 0) // next one?
1515                                         {
1516                                                 s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
1517                                         }
1518                                 }
1519                         }
1520
1521                         if(s != "" && a > 0)
1522                         {
1523                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1524                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1525                         }
1526
1527                         if(race_penaltytime)
1528                         {
1529                                 a = bound(0, 2 - (time - race_penaltyeventtime), 1);
1530                                 if(a > 0)
1531                                 {
1532                                         s = strcat("^1PENALTY: ", ftos_decimals(race_penaltytime * 0.1, 1), " (", race_penaltyreason, ")");
1533                                         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1534                                         drawcolorcodedstring(m - '0 32 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1535                                 }
1536                         }
1537
1538                         if(forcetime != "")
1539                         {
1540                                 a = bound(0, (time - race_checkpointtime) / 0.5, 1);
1541                                 drawstring_expanding(m - '16 0 0' * stringwidth(forcetime, FALSE), forcetime, '32 32 0', '1 1 1', sbar_alpha_fg, 0, a);
1542                         }
1543                         else
1544                                 a = 1;
1545
1546                         if(race_laptime && race_checkpoint != 255)
1547                         {
1548                                 s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
1549                                 drawstring(m - '16 0 0' * stringwidth(s, FALSE), s, '32 32 0', '1 1 1', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1550                         }
1551                 }
1552                 else
1553                 {
1554                         if(race_mycheckpointtime)
1555                         {
1556                                 a = bound(0, 2 - (time - race_mycheckpointtime), 1);
1557                                 s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -!race_mycheckpointenemy, race_mycheckpointlapsdelta, race_mycheckpointenemy);
1558                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1559                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1560                         }
1561                         if(race_othercheckpointtime && race_othercheckpointenemy != "")
1562                         {
1563                                 a = bound(0, 2 - (time - race_othercheckpointtime), 1);
1564                                 s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -!race_othercheckpointenemy, race_othercheckpointlapsdelta, race_othercheckpointenemy);
1565                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1566                                 drawcolorcodedstring(m - '0 0 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1567                         }
1568
1569                         if(race_penaltytime && !race_penaltyaccumulator)
1570                         {
1571                                 t = race_penaltytime * 0.1 + race_penaltyeventtime;
1572                                 a = bound(0, (1 + t - time), 1);
1573                                 if(a > 0)
1574                                 {
1575                                         if(time < t)
1576                                                 s = strcat("^1PENALTY: ", ftos_decimals(t - time, 1), " (", race_penaltyreason, ")");
1577                                         else
1578                                                 s = strcat("^2PENALTY: 0.0 (", race_penaltyreason, ")");
1579                                         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1580                                         drawcolorcodedstring(m - '0 32 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1581                                 }
1582                         }
1583                 }
1584
1585                 drawfont = sbar_font;
1586         }
1587 }
1588
1589 void Sbar_Timer()
1590 {
1591         float timelimit, elapsedTime, minutes, seconds, timeleft, minutesLeft, secondsLeft;
1592         vector bgpos, timer_color;
1593         bgpos = '0 0 0';
1594
1595         vector topright;
1596         topright = '0 0 0';
1597         topright_x = vid_conwidth;
1598
1599         timelimit = getstatf(STAT_TIMELIMIT);
1600
1601         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1602         timeleft = ceil(timeleft);
1603         minutesLeft = floor(timeleft / 60);
1604         secondsLeft = timeleft - minutesLeft*60;
1605
1606         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1607                 timer_color = '1 1 1'; //white
1608         else if(minutesLeft >= 1)
1609                 timer_color = '1 1 0'; //yellow
1610         else
1611                 timer_color = '1 0 0'; //red
1612
1613         if (cvar("sbar_increment_maptime") || timelimit == 0 || warmup_stage) {
1614                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1615                         //while restart is still active, show 00:00
1616                         minutes = seconds = 0;
1617                 } else {
1618                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1619                         minutes = floor(elapsedTime / 60);
1620                         seconds = elapsedTime - minutes*60;
1621                 }
1622                 if (minutes < 10)
1623                         bgpos_x = topright_x - 54 - 17 - 12;
1624                 else if (minutes < 100) // nudge the timer background left if more digits are drawn
1625                         bgpos_x = topright_x - 72 - 17 - 12;
1626                 else
1627                         bgpos_x = topright_x - 90 - 17 - 12;
1628                 bgpos_y = 0;
1629                 bgpos_z = 0;
1630         } else {
1631                 minutes = minutesLeft;
1632                 seconds = secondsLeft;
1633                 if (minutes == 0)
1634                 bgpos_x = topright_x - 36 - 7 - 12;
1635                 else if (minutes < 10) // nudge the timer background left if more digits are drawn
1636                         bgpos_x = topright_x - 54 - 17 - 12;
1637                 else if (minutes < 100)
1638                         bgpos_x = topright_x - 72 - 17 - 12;
1639                 else
1640                         bgpos_x = topright_x - 90 - 17 - 12;
1641                 bgpos_y = 0;
1642                 bgpos_z = 0;
1643         }
1644
1645         if (cvar("viewsize") <= 100) { // draw timer background when viewsize <= 100
1646                 if (teamplay)
1647                         drawpic(bgpos, "gfx/hud/sb_timerbg", '120 30 0', GetTeamRGB(myteam) * sbar_color_bg_team, sbar_alpha_bg, DRAWFLAG_NORMAL); // timer bg color = myteam color
1648                 else {
1649                         color_x = cvar("sbar_color_bg_r");
1650                         color_y = cvar("sbar_color_bg_g");
1651                         color_z = cvar("sbar_color_bg_b");
1652
1653                         drawpic(bgpos, "gfx/hud/sb_timerbg", '120 30 0', color, sbar_alpha_bg, DRAWFLAG_NORMAL);
1654                 }
1655         }
1656
1657         if(minutesLeft >= 1 || cvar("sbar_increment_maptime") || timelimit == 0 || warmup_stage) {
1658                 Sbar_DrawXNum(topright - '103 0 0' + '0 2 0', minutes, 3, 0, 18, timer_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1659                 drawpic(topright - '53 0 0' + '0 1 0', "gfx/hud/num_colon", '18 18 0', timer_color, sbar_alpha_fg, DRAWFLAG_NORMAL);
1660         }
1661         Sbar_DrawXNum(topright - '36 0 0' - '3 0 0' + '0 2 0', seconds, -2, 0, 18, timer_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1662 }
1663
1664 void CSQC_Strength_Timer() {
1665         vector pos;
1666         vector bottom;
1667
1668         bottom_x = vid_conwidth/2;
1669         bottom_y = vid_conheight;
1670         bottom_z = 0;
1671
1672         float stat_items, dt;
1673         stat_items = getstati(STAT_ITEMS);
1674         /*
1675         if not(stat_items & IT_STRENGTH)
1676                 if not(stat_items & IT_INVINCIBLE)
1677                         return;
1678         */
1679
1680         if (getstati(STAT_HEALTH) <= 0)
1681                 return;
1682
1683         vector picsize;
1684         float strength_time, invincibility_time, countdown_fontsize;
1685
1686         picsize = '22 22 0';
1687         countdown_fontsize = 18;
1688
1689         if (vid_conwidth >= 800)
1690                 pos = bottom + '192 -46 0';
1691         else
1692                 pos = bottom + '192 -94 0';
1693
1694         //strength
1695         strength_time = getstatf(STAT_STRENGTH_FINISHED);
1696         invincibility_time = getstatf(STAT_INVINCIBLE_FINISHED);
1697
1698         if (strength_time) {
1699                 dt = strength_time - time;
1700                 if(dt > 0)
1701                 {
1702                         if(dt < 5)
1703                         {
1704                                 drawpic_expanding_two(pos, "gfx/hud/sb_str", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE,
1705                                         bound(0, (ceil(dt) - dt) / 0.5, 1));
1706                         }
1707                         else
1708                         {
1709                                 drawpic(pos, "gfx/hud/sb_str", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE);
1710                         }
1711                         Sbar_DrawXNum(pos - '40 -2 0', ceil(dt), 2, 0, countdown_fontsize, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1712                 }
1713                 else if(dt > -1)
1714                 {
1715                         drawpic_expanding(pos, "gfx/hud/sb_str", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE,
1716                                 bound(0, -dt / 0.5, 1));
1717                 }
1718         }
1719
1720         //invincibility
1721         if (invincibility_time) {
1722                 dt = invincibility_time - time;
1723                 if(dt > 0)
1724                 {
1725                         if(dt < 5)
1726                         {
1727                                 drawpic_expanding_two(pos - '0 -22 0', "gfx/hud/sb_invinc", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE,
1728                                         bound(0, (ceil(dt) - dt) / 0.5, 1));
1729                         }
1730                         else
1731                         {
1732                                 drawpic(pos - '0 -22 0', "gfx/hud/sb_invinc", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE);
1733                         }
1734                         Sbar_DrawXNum(pos - '40 -24 0', ceil(dt), 2, 0, countdown_fontsize, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1735                 }
1736                 else if(dt > -1)
1737                 {
1738                         drawpic_expanding(pos - '0 -22 0', "gfx/hud/sb_invinc", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE,
1739                                 bound(0, -dt / 0.5, 1));
1740                 }
1741         }
1742 }
1743
1744 #define CENTERPRINT_MAX_LINES 30
1745 string centerprint_messages[CENTERPRINT_MAX_LINES];
1746 float centerprint_width[CENTERPRINT_MAX_LINES];
1747 vector centerprint_start;
1748 float centerprint_expire;
1749 float centerprint_num;
1750 float centerprint_offset_hint;
1751 vector centerprint_fontsize;
1752
1753 void centerprint(string strMessage)
1754 {
1755         float i, j, n, hcount;
1756         string s;
1757
1758         centerprint_fontsize = Sbar_GetFontsize("scr_centersize");
1759
1760         centerprint_expire = min(centerprint_expire, time); // if any of the returns happens, this message will fade out
1761
1762         if(cvar("scr_centertime") <= 0)
1763                 return;
1764
1765         if(strMessage == "")
1766                 return;
1767
1768         // strip trailing newlines
1769         j = strlen(strMessage) - 1;
1770         while(substring(strMessage, j, 1) == "\n" && j >= 0)
1771                 j = j - 1;
1772         strMessage = substring(strMessage, 0, j + 1);
1773
1774         if(strMessage == "")
1775                 return;
1776
1777         // strip leading newlines and remember them, they are a hint that the message should be lower on the screen
1778         j = 0;
1779         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
1780                 j = j + 1;
1781         strMessage = substring(strMessage, j, strlen(strMessage) - j);
1782         centerprint_offset_hint = j;
1783
1784         if(strMessage == "")
1785                 return;
1786
1787         // if we get here, we have a message. Initialize its height.
1788         centerprint_num = 0;
1789
1790         n = tokenizebyseparator(strMessage, "\n");
1791         i = hcount = 0;
1792         for(j = 0; j < n; ++j)
1793         {
1794                 getWrappedLine_remaining = argv(j);
1795                 while(getWrappedLine_remaining)
1796                 {
1797                         s = getWrappedLine(vid_conwidth * 0.75 / centerprint_fontsize_x, stringwidth_colors);
1798                         if(centerprint_messages[i])
1799                                 strunzone(centerprint_messages[i]);
1800                         centerprint_messages[i] = strzone(s);
1801                         centerprint_width[i] = stringwidth(s, TRUE);
1802                         ++i;
1803
1804                         // half height for empty lines looks better
1805                         if(s == "")
1806                                 hcount += 0.5;
1807                         else
1808                                 hcount += 1;
1809
1810                         if(i >= CENTERPRINT_MAX_LINES)
1811                                 break;
1812                 }
1813         }
1814
1815         float h, havail;
1816         h = centerprint_fontsize_y*hcount;
1817
1818         havail = vid_conheight;
1819         if(cvar("con_chatpos") < 0)
1820                 havail -= (-cvar("con_chatpos") + cvar("con_chat")) * cvar("con_chatsize"); // avoid overlapping chat
1821         if(havail > vid_conheight - 70)
1822                 havail = vid_conheight - 70; // avoid overlapping HUD
1823
1824         centerprint_start_x = 0;
1825
1826 #if 0
1827         float forbiddenmin, forbiddenmax, allowedmin, allowedmax, preferred;
1828
1829         // here, the centerprint would cover the crosshair. REALLY BAD.
1830         forbiddenmin = vid_conheight * 0.5 - h - 16;
1831         forbiddenmax = vid_conheight * 0.5 + 16;
1832
1833         allowedmin = scoreboard_bottom;
1834         allowedmax = havail - h;
1835         preferred = (havail - h)/2;
1836
1837
1838         // possible orderings (total: 4! / 4 = 6)
1839         //  allowedmin allowedmax forbiddenmin forbiddenmax
1840         //  forbiddenmin forbiddenmax allowedmin allowedmax
1841         if(allowedmax < forbiddenmin || allowedmin > forbiddenmax)
1842         {
1843                 // forbidden doesn't matter in this case
1844                 centerprint_start_y = bound(allowedmin, preferred, allowedmax);
1845         }
1846         //  allowedmin forbiddenmin allowedmax forbiddenmax
1847         else if(allowedmin < forbiddenmin && allowedmax < forbiddenmax)
1848         {
1849                 centerprint_start_y = bound(allowedmin, preferred, forbiddenmin);
1850         }
1851         //  allowedmin forbiddenmin forbiddenmax allowedmax
1852         else if(allowedmin < forbiddenmin)
1853         {
1854                 // make sure the forbidden zone is not covered
1855                 if(preferred > (forbiddenmin + forbiddenmax) * 0.5)
1856                         centerprint_start_y = bound(allowedmin, preferred, forbiddenmin);
1857                 else
1858                         centerprint_start_y = bound(forbiddenmax, preferred, allowedmin);
1859         }
1860         //  forbiddenmin allowedmin allowedmax forbiddenmax
1861         else if(allowedmax < forbiddenmax)
1862         {
1863                 // it's better to leave the allowed zone (overlap with scoreboard) than
1864                 // to cover the forbidden zone (crosshair)
1865                 if(preferred > (forbiddenmin + forbiddenmax) * 0.5)
1866                         centerprint_start_y = forbiddenmax;
1867                 else
1868                         centerprint_start_y = forbiddenmin;
1869         }
1870         //  forbiddenmin allowedmin forbiddenmax allowedmax
1871         else
1872         {
1873                 centerprint_start_y = bound(forbiddenmax, preferred, allowedmax);
1874         }
1875 #else
1876         centerprint_start_y =
1877                 min(
1878                         max(
1879                                 max(scoreboard_bottom, vid_conheight * 0.5 + 16),
1880                                 (havail - h)/2
1881                         ),
1882                         havail - h
1883                 );
1884 #endif
1885
1886         centerprint_num = i;
1887         centerprint_expire = time + cvar("scr_centertime");
1888 }
1889
1890 void Sbar_DrawCenterPrint (void)
1891 {
1892         float i;
1893         vector pos;
1894         string ts;
1895         float a;
1896
1897         //if(time > centerprint_expire)
1898         //      return;
1899
1900         //a = bound(0, 1 - 2 * (time - centerprint_expire), 1);
1901         a = bound(0, 1 - 4 * (time - centerprint_expire), 1);
1902         //sz = 1.2 / (a + 0.2);
1903
1904         if(a <= 0)
1905                 return;
1906
1907         pos = centerprint_start;
1908         for (i=0; i<centerprint_num; i = i + 1)
1909         {
1910                 pos_x = (vid_conwidth - centerprint_fontsize_x * centerprint_width[i]) * 0.5;
1911                 ts = centerprint_messages[i];
1912                 if (ts != "")
1913                 {
1914                         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1915                         drawcolorcodedstring(pos, ts, centerprint_fontsize, a, DRAWFLAG_NORMAL);
1916                         //  - '0 0.5 0' * (sz - 1) * centerprint_fontsize_x - '0.5 0 0' * (sz - 1) * centerprint_width[i] * centerprint_fontsize_y, centerprint_fontsize * sz
1917                         pos_y = pos_y + centerprint_fontsize_y;
1918                 }
1919                 else
1920                         // half height for empty lines looks better
1921                         pos_y = pos_y + centerprint_fontsize_y * 0.5;
1922         }
1923 }
1924
1925 vector Sbar_DrawNoteLine(vector offset, string s)
1926 {
1927         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1928         drawcolorcodedstring(
1929                 offset - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1930                 s,
1931                 sbar_fontsize,
1932                 sbar_alpha_fg,
1933                 0
1934         );
1935         return offset + sbar_fontsize_y * '0 1 0';
1936 }
1937
1938 void Sbar_DrawPressedKeys(void)
1939 {
1940         vector pos, bgsize;
1941         float pressedkeys;
1942
1943         pos = stov(cvar_string("cl_showpressedkeys_position"));
1944
1945         bgsize = '126 75 0';
1946
1947         pos = '1 0 0' * (vid_conwidth - bgsize_x) * pos_x
1948             + '0 1 0' * (vid_conheight - bgsize_y) * pos_y;
1949         pos -= '-15 -6 0'; // adjust to the origin of these numbers
1950
1951         pressedkeys = getstatf(STAT_PRESSED_KEYS);
1952         drawpic(pos + '-15   -6   0', "gfx/hud/keys/key_bg.tga",           bgsize, '1 1 1', 0.1 * sbar_alpha_fg, DRAWFLAG_NORMAL);
1953         drawpic(pos + ' 83.5  9   0', ((pressedkeys & KEY_CROUCH) ? "gfx/hud/keys/key_crouch_inv.tga" : "gfx/hud/keys/key_crouch.tga"), ' 24 24 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1954         drawpic(pos + ' 32   -1.5 0', ((pressedkeys & KEY_FORWARD) ? "gfx/hud/keys/key_forward_inv.tga" : "gfx/hud/keys/key_forward.tga"),  ' 32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1955         drawpic(pos + '-11.5  9   0', ((pressedkeys & KEY_JUMP) ? "gfx/hud/keys/key_jump_inv.tga" : "gfx/hud/keys/key_jump.tga"),     ' 24 24 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1956         drawpic(pos + ' -1   32   0', ((pressedkeys & KEY_LEFT) ? "gfx/hud/keys/key_left_inv.tga" : "gfx/hud/keys/key_left.tga"),     ' 32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1957         drawpic(pos + ' 32   32   0', ((pressedkeys & KEY_BACKWARD) ? "gfx/hud/keys/key_backward_inv.tga" : "gfx/hud/keys/key_backward.tga"), ' 32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1958         drawpic(pos + ' 65   32   0', ((pressedkeys & KEY_RIGHT) ? "gfx/hud/keys/key_right_inv.tga" : "gfx/hud/keys/key_right.tga"),    ' 32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1959 }
1960
1961 void Sbar_ShowSpeed(void)
1962 {
1963         vector numsize;
1964         float pos, conversion_factor;
1965         string speed, unit;
1966
1967         switch(cvar("cl_showspeed_unit"))
1968         {
1969                 default:
1970                 case 0:
1971                         unit = "";
1972                         conversion_factor = 1.0;
1973                         break;
1974                 case 1:
1975                         unit = " qu/s";
1976                         conversion_factor = 1.0;
1977                         break;
1978                 case 2:
1979                         unit = " m/s";
1980                         conversion_factor = 0.0254;
1981                         break;
1982                 case 3:
1983                         unit = " km/h";
1984                         conversion_factor = 0.0254 * 3.6;
1985                         break;
1986                 case 4:
1987                         unit = " mph";
1988                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
1989                         break;
1990                 case 5:
1991                         unit = " knots";
1992                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1993                         break;
1994         }
1995
1996         if (cvar("cl_showspeed_z") == 1)
1997                 speed = strcat(ftos(floor( vlen(pmove_vel) * conversion_factor + 0.5 )), unit);
1998         else
1999                 speed = strcat(ftos(floor( vlen(pmove_vel - pmove_vel_z * '0 0 1') * conversion_factor + 0.5 )), unit);
2000
2001         numsize_x = numsize_y = cvar("cl_showspeed_size");
2002         pos = (vid_conheight - numsize_y) * cvar("cl_showspeed_position");
2003
2004         drawfont = sbar_bigfont;
2005         drawstringcenter('1 0 0' + pos * '0 1 0', speed, numsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2006         drawfont = sbar_font;
2007 }
2008
2009 vector acc_prevspeed;
2010 float acc_prevtime;
2011 float acc_avg;
2012
2013 void Sbar_ShowAcceleration(void)
2014 {
2015         float acceleration, sz, scale, alpha, f;
2016         vector pos, top, rgb;
2017         top_x = vid_conwidth/2;
2018         top_y = 0;
2019
2020         f = time - acc_prevtime;
2021         if(cvar("cl_showacceleration_z"))
2022                 acceleration = (vlen(pmove_vel) - vlen(acc_prevspeed)) * (1 / f);
2023         else
2024                 acceleration = (vlen(pmove_vel - '0 0 1' * pmove_vel_z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed_z)) * (1 / f);
2025         acc_prevspeed = pmove_vel;
2026         acc_prevtime = time;
2027
2028         f = bound(0, f * 10, 1);
2029         acc_avg = acc_avg * (1 - f) + acceleration * f;
2030         acceleration = acc_avg / getstatf(STAT_MOVEVARS_MAXSPEED);
2031
2032         pos = top - sz/2 * '0 1 0' + (cvar("cl_showacceleration_position") * vid_conheight) * '0 1 0';
2033
2034         sz = cvar("cl_showacceleration_size");
2035         scale = cvar("cl_showacceleration_scale");
2036         alpha = cvar("cl_showacceleration_alpha");
2037         if (cvar("cl_showacceleration_color_custom"))
2038                 rgb = stov(cvar_string("cl_showacceleration_color"));
2039         else {
2040                 rgb = '1 1 1';
2041                 if (acceleration < 0) {
2042                         rgb = '1 .5 .5' - '0 .5 .5' * bound(0, -acceleration * 0.2, 1);
2043                 } else if (acceleration > 0) {
2044                         rgb = '.5 1 .5' - '.5 0 .5' * bound(0, +acceleration * 0.2, 1);
2045                 }
2046         }
2047
2048         if (acceleration > 0)
2049                 drawpic(pos, "gfx/hud/accelerometer_gradient", acceleration * scale * '40 0 0' + sz * '0 1 0', rgb, alpha * sbar_alpha_fg, DRAWFLAG_NORMAL);
2050         else if (acceleration < 0)
2051                 drawpic(pos + acceleration * scale * '40 0 0', "gfx/hud/accelerometer_gradient", -acceleration * scale * '40 0 0' + sz * '0 1 0', rgb, alpha * sbar_alpha_fg, DRAWFLAG_NORMAL);
2052 }
2053
2054 void Sbar_DrawAccuracyStats_Description_Hitscan(vector position)
2055 {
2056         drawstring(position + '0 3 0' * sbar_fontsize_y, "Shots fired:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2057         drawstring(position + '0 5 0' * sbar_fontsize_y, "Shots hit:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2058         drawstring(position + '0 7 0' * sbar_fontsize_y, "Accuracy:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2059         drawstring(position + '0 9 0' * sbar_fontsize_y, "Shots missed:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2060 }
2061
2062 void Sbar_DrawAccuracyStats_Description_Splash(vector position)
2063 {
2064         drawstring(position + '0 3 0' * sbar_fontsize_y, "Maximum damage:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2065         drawstring(position + '0 5 0' * sbar_fontsize_y, "Actual damage:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2066         drawstring(position + '0 7 0' * sbar_fontsize_y, "Accuracy:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2067         drawstring(position + '0 9 0' * sbar_fontsize_y, "Damage wasted:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2068 }
2069
2070 float sbar_accuracystats_fade_alpha;
2071 float sbar_woulddrawscoreboard_prev;
2072 float sbar_woulddrawscoreboard_change; // "time" at which Sbar_WouldDrawScoreboard() changed
2073 void Sbar_DrawAccuracyStats()
2074 {
2075         float i, count_hitscan, count_splash, row;  // count is the number of 'colums'
2076         float weapon_hit, weapon_damage, weapon_stats;
2077         float left_border;  // position where the weapons start, the description is in the border
2078         vector fill_colour, fill_size;
2079         vector pos;
2080
2081         float col_margin = 20;  // pixels between the columns
2082         float row_margin = 20;  // pixels between the rows
2083
2084         fill_size_x = 5 * sbar_fontsize_x;  // width of the background
2085         fill_size_y = 10 * sbar_fontsize_y;  // height of the background
2086
2087         drawfont = sbar_bigfont;
2088         pos_x = 0;
2089         pos_y = SCOREBOARD_OFFSET;
2090         pos_z = 0;
2091         drawstringcenter(pos, "Weapon Accuracy", 2 * sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2092
2093         left_border = col_margin + 11 * sbar_fontsize_x;
2094
2095         drawfont = sbar_font;
2096
2097         if(warmup_stage)
2098         {
2099                 pos_y += 40;
2100                 if(mod(time, 1) >= 0.4)
2101                         drawstringcenter(pos, "Stats are not tracked during warmup stage", sbar_fontsize, '1 1 0', sbar_alpha_fg, DRAWFLAG_NORMAL);
2102
2103                 return;
2104         }
2105
2106         float top_border_hitscan = SCOREBOARD_OFFSET + 55;  // position where the hitscan row starts: pixels down the screen
2107         Sbar_DrawAccuracyStats_Description_Hitscan('1 0 0' * col_margin + '0 1 0' * top_border_hitscan);
2108
2109         float top_border_splash = SCOREBOARD_OFFSET + 175;  // position where the splash row starts: pixels down the screen
2110         Sbar_DrawAccuracyStats_Description_Splash('1 0 0' * col_margin + '0 1 0' * top_border_splash);
2111
2112         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
2113         {
2114                 weapon_hit = weapon_hits[i];
2115                 weapon_damage = weapon_fired[i];
2116                 self = get_weaponinfo(i);
2117
2118                 //if ((weapon_number != 42))  // print them all :)
2119                 if (weapon_damage) {
2120                         if (self.weapon_type == WEP_TYPE_SPLASH) {
2121                                 weapon_stats = bound(0, rint(100 * weapon_hit / weapon_damage), 100);
2122
2123                                 fill_colour_x = 1 - 0.015 * weapon_stats;
2124                                 fill_colour_y = 1 - 0.015 * (100 - weapon_stats);
2125
2126                                 // how the background colour is calculated
2127                                 // %    red             green   red_2                   green_2
2128                                 // 0    1               0               1 - % * 0.015   1 - (100 - %) * 0.015
2129                                 // 10   0.85    0               1 - % * 0.015   1 - (100 - %) * 0.015
2130                                 // 20   0.70    0               1 - % * 0.015   1 - (100 - %) * 0.015
2131                                 // 30   0.55    0               1 - % * 0.015   1 - (100 - %) * 0.015
2132                                 // 40   0.40    0.10    1 - % * 0.015   1 - (100 - %) * 0.015
2133                                 // 50   0.25    0.25    1 - % * 0.015   1 - (100 - %) * 0.015
2134                                 // 60   0.10    0.40    1 - % * 0.015   1 - (100 - %) * 0.015
2135                                 // 70   0               0.55    1 - % * 0.015   1 - (100 - %) * 0.015
2136                                 // 80   0               0.70    1 - % * 0.015   1 - (100 - %) * 0.015
2137                                 // 90   0               0.85    1 - % * 0.015   1 - (100 - %) * 0.015
2138                                 // 100  0               1               1 - % * 0.015   1 - (100 - %) * 0.015
2139
2140                                 if ((left_border + count_splash * (fill_size_x + col_margin) + fill_size_x) >= vid_conwidth)
2141                                 {
2142                                         count_splash = 0;
2143                                         ++row;
2144                                         Sbar_DrawAccuracyStats_Description_Splash('1 0 0' * col_margin + '0 1 0' * (top_border_splash + row * (fill_size_y + row_margin)));
2145                                 }
2146
2147                                 pos_x = left_border + count_splash * (fill_size_x + col_margin);
2148                                 pos_y = top_border_splash + row * (fill_size_y + row_margin);
2149
2150                                 // background
2151                                 drawpic(pos, "gfx/hud/sb_accuracy", fill_size , fill_colour, sbar_alpha_bg, DRAWFLAG_NORMAL);
2152                                 drawborderlines(sbar_border_thickness, pos, fill_size, '0 0 0', sbar_alpha_bg, DRAWFLAG_NORMAL);
2153
2154                                 // the weapon
2155                                 drawpic(pos, strcat("gfx/hud/inv_weapon", ftos(i-1)), '1 0.5 0' * fill_size_x , '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2156
2157                                 // the amount of shots fired or max damage
2158                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 3 0' * sbar_fontsize_y, ftos(weapon_damage), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2159
2160                                 // the amount of hits or actual damage
2161                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 5 0' * sbar_fontsize_y, ftos(weapon_hit), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2162
2163                                 // the accuracy
2164                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 7 0' * sbar_fontsize_y, strcat(ftos(weapon_stats),"%"), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2165
2166                                 // the amount of shots missed or damage wasted
2167                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 9 0' * sbar_fontsize_y, ftos(max(0, weapon_damage - weapon_hit)), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2168
2169                                 ++count_splash;
2170                         } else if ((self.weapon_type == WEP_TYPE_HITSCAN) && (weapon_damage)) {
2171                                 weapon_stats = bound(0, rint(100 * weapon_hit / weapon_damage), 100);
2172
2173                                 fill_colour_x = 1 - 0.015 * weapon_stats;
2174                                 fill_colour_y = 1 - 0.015 * (100 - weapon_stats);
2175
2176                                 // how the background colour is calculated
2177                                 // %    red             green   red_2                   green_2
2178                                 // 0    1               0               1 - % * 0.015   1 - (100 - %) * 0.015
2179                                 // 10   0.850   0               1 - % * 0.015   1 - (100 - %) * 0.015
2180                                 // 20   0.70    0               1 - % * 0.015   1 - (100 - %) * 0.015
2181                                 // 30   0.55    0               1 - % * 0.015   1 - (100 - %) * 0.015
2182                                 // 40   0.40    0.10    1 - % * 0.015   1 - (100 - %) * 0.015
2183                                 // 50   0.25    0.25    1 - % * 0.015   1 - (100 - %) * 0.015
2184                                 // 60   0.10    0.40    1 - % * 0.015   1 - (100 - %) * 0.015
2185                                 // 70   0               0.55    1 - % * 0.015   1 - (100 - %) * 0.015
2186                                 // 80   0               0.70    1 - % * 0.015   1 - (100 - %) * 0.015
2187                                 // 90   0               0.85    1 - % * 0.015   1 - (100 - %) * 0.015
2188                                 // 100  0               1               1 - % * 0.015   1 - (100 - %) * 0.015
2189
2190                                 if ((left_border + count_hitscan * (fill_size_x + col_margin) + fill_size_x + cvar("stats_right_margin")) >= vid_conwidth)
2191                                 {
2192                                         count_hitscan = 0;
2193                                         ++row;
2194                                         Sbar_DrawAccuracyStats_Description_Hitscan('1 0 0' * col_margin + '0 1 0' * (top_border_hitscan + row * (fill_size_y + row_margin)));
2195                                 }
2196
2197                                 pos_x = left_border + count_hitscan * (fill_size_x + col_margin);
2198                                 pos_y = top_border_hitscan + row * (fill_size_y + row_margin);
2199
2200                                 // background
2201                                 drawpic(pos, "gfx/hud/sb_accuracy", fill_size , fill_colour, sbar_alpha_bg, DRAWFLAG_NORMAL);
2202                                 drawborderlines(sbar_border_thickness, pos, fill_size, '0 0 0', sbar_alpha_bg, DRAWFLAG_NORMAL);
2203
2204                                 // the weapon
2205                                 drawpic(pos, strcat("gfx/hud/inv_weapon", ftos(i-1)), '1 0.5 0' * fill_size_x , '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2206
2207                                 // the amount of shots fired or max damage
2208                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 3 0' * sbar_fontsize_y, ftos(weapon_damage), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2209
2210                                 // the amount of hits or actual damage
2211                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 5 0' * sbar_fontsize_y, ftos(weapon_hit), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2212
2213                                 // the accuracy
2214                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 7 0' * sbar_fontsize_y, strcat(ftos(weapon_stats),"%"), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2215
2216                                 // the amount of shots missed or damage wasted
2217                                 drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 9 0' * sbar_fontsize_y, ftos(max(0, weapon_damage - weapon_hit)), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2218
2219                                 ++count_hitscan;
2220                         }
2221                 }
2222         }
2223 }
2224
2225 void drawstringright(vector position, string text, vector scale, vector rgb, float alpha, float flag)
2226 {
2227         position_x -= 2 / 3 * strlen(text) * scale_x;
2228         drawstring(position, text, scale, rgb, alpha, flag);
2229 }
2230
2231 void drawstringcenter(vector position, string text, vector scale, vector rgb, float alpha, float flag)
2232 {
2233         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * scale_x);
2234         drawstring(position, text, scale, rgb, alpha, flag);
2235 }
2236
2237 float GetAmmoStat(float i)
2238 {
2239         switch(i)
2240         {
2241                 case 0: return STAT_SHELLS;
2242                 case 1: return STAT_NAILS;
2243                 case 2: return STAT_ROCKETS;
2244                 case 3: return STAT_CELLS;
2245                 case 4: return STAT_FUEL;
2246                 default: return -1;
2247         }
2248 }
2249
2250 float GetAmmoItemCode(float i)
2251 {
2252         switch(i)
2253         {
2254                 case 0: return IT_SHELLS;
2255                 case 1: return IT_NAILS;
2256                 case 2: return IT_ROCKETS;
2257                 case 3: return IT_CELLS;
2258                 case 4: return IT_FUEL;
2259                 default: return -1;
2260         }
2261 }
2262
2263 string GetAmmoPicture(float i)
2264 {
2265         switch(i)
2266         {
2267                 case 0: return "gfx/hud/sb_shells";
2268                 case 1: return "gfx/hud/sb_bullets";
2269                 case 2: return "gfx/hud/sb_rocket";
2270                 case 3: return "gfx/hud/sb_cells";
2271                 case 4: return "gfx/hud/sb_fuel";
2272                 default: return "";
2273         }
2274 }
2275
2276 void Sbar_Reset (void)
2277 {
2278         // reset gametype specific icons
2279         if(gametype == GAME_KEYHUNT)
2280                 CSQC_kh_hudreset();
2281         else if(gametype == GAME_CTF)
2282                 CSQC_ctf_hudreset();
2283 }
2284
2285 void Sbar_Draw (void)
2286 {
2287         // vectors for top right, bottom right, bottom and bottom left corners
2288         vector topright;
2289         vector bottom;
2290         vector bottomright;
2291         vector bottomleft;
2292
2293         topright_x = vid_conwidth;
2294         topright_y = 0;
2295         topright_z = 0;
2296
2297         bottom_x = vid_conwidth/2;
2298         bottom_y = vid_conheight;
2299         bottom_z = 0;
2300
2301         bottomright_x = vid_conwidth;
2302         bottomright_y = vid_conheight;
2303         bottomright_z = 0;
2304
2305         bottomleft_x = 0;
2306         bottomleft_y = vid_conheight;
2307         bottomleft_z = 0;
2308
2309         sbar_alpha_bg = cvar("sbar_alpha_bg") * (1 - cvar("_menu_alpha"));
2310         sbar_border_thickness = bound(0, cvar("sbar_border_thickness"), 5);
2311         sbar_color_bg_team = cvar("sbar_color_bg_team");
2312
2313         float i;
2314         float weapon_stats;
2315         float x, fade;
2316         float stat_items, stat_weapons;
2317
2318         weapon_stats = getstati(STAT_DAMAGE_HITS);
2319         weapon_number = weapon_stats & 63;
2320         weapon_hits[weapon_number] = rint(weapon_stats / 64);
2321
2322         weapon_stats = getstati(STAT_DAMAGE_FIRED);
2323         weapon_number = weapon_stats & 63;
2324         weapon_fired[weapon_number] = rint(weapon_stats / 64);
2325
2326         vector o; o = '1 0 0' * vid_conwidth;
2327         o_y = 28; // move spectator text slightly down to prevent overlapping the timer
2328
2329         string s;
2330         vector pos;
2331         pos = '0 0 0';
2332
2333         sbar_fontsize = Sbar_GetFontsize("sbar_fontsize");
2334         sbar_fontsize_spec = Sbar_GetFontsize("sbar_fontsize_spec");
2335
2336         if(spectatee_status && !intermission)
2337         {
2338                 drawfont = sbar_bigfont;
2339                 if(spectatee_status == -1)
2340                         s = "^1Observing";
2341                 else
2342                         s = GetPlayerName(spectatee_status - 1);
2343                 // spectated player name between HUD and chat area, aligned to the left
2344                 pos_x = bottomleft_x;
2345                 pos_y = bottom_y - 50 - sbar_fontsize_spec_y;
2346                 s = textShortenToWidth(s, vid_conwidth/2.5/sbar_fontsize_spec_x, stringwidth_colors);
2347                 drawcolorcodedstring(pos, s, sbar_fontsize_spec, sbar_alpha_fg, DRAWFLAG_NORMAL);
2348                 drawfont = sbar_font;
2349
2350                 // spectator text in the upper right corner
2351                 if(spectatee_status == -1)
2352                         s = strcat("^1Press ^3", getcommandkey("primary fire", "+attack"), "^1 to spectate");
2353                 else
2354                         s = strcat("^1Press ^3", getcommandkey("primary fire", "+attack"), "^1 for another player");
2355                 o = Sbar_DrawNoteLine(o, s);
2356
2357                 if(spectatee_status == -1)
2358                         s = strcat("^1Use ^3", getcommandkey("next weapon", "weapnext"), "^1 or ^3", getcommandkey("previous weapon", "weapprev"), "^1 to change the speed");
2359                 else
2360                         s = strcat("^1Press ^3", getcommandkey("secondary fire", "+attack2"), "^1 to observe");
2361                 o = Sbar_DrawNoteLine(o, s);
2362
2363                 s = strcat("^1Press ^3", getcommandkey("server info", "+show_info"), "^1 for gamemode info");
2364                 o = Sbar_DrawNoteLine(o, s);
2365
2366                 if(gametype == GAME_ARENA)
2367                         s = "^1Wait for your turn to join";
2368                 else if(gametype == GAME_LMS)
2369                 {
2370                         entity sk;
2371                         sk = playerslots[player_localentnum - 1];
2372                         if(sk.(scores[ps_primary]) >= 666)
2373                                 s = "^1Match has already begun";
2374                         else if(sk.(scores[ps_primary]) > 0)
2375                                 s = "^1You have no more lives left";
2376                         else
2377                                 s = strcat("^1Press ^3", getcommandkey("jump", "+jump"), "^1 to join");
2378                 }
2379                 else
2380                         s = strcat("^1Press ^3", getcommandkey("jump", "+jump"), "^1 to join");
2381                 o = Sbar_DrawNoteLine(o, s);
2382
2383                 //show restart countdown:
2384                 if (time < getstatf(STAT_GAMESTARTTIME)) {
2385                         float countdown;
2386                         //we need to ceil, otherwise the countdown would be off by .5 when using round()
2387                         countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
2388                         s = strcat("^1Game starts in ^3", ftos(countdown), "^1 seconds");
2389                         o = Sbar_DrawNoteLine(o, s);
2390                 }
2391         }
2392         if(warmup_stage && !intermission)
2393         {
2394                 s = "^2Currently in ^1warmup^2 stage!";
2395                 o = Sbar_DrawNoteLine(o, s);
2396         }
2397
2398         // move more important stuff more to the middle so its more visible
2399         o_y = vid_conheight * 0.66;
2400
2401         string blinkcolor;
2402         if(mod(time, 1) >= 0.5)
2403                 blinkcolor = "^1";
2404         else
2405                 blinkcolor = "^3";
2406
2407         if(ready_waiting && !intermission && !spectatee_status)
2408         {
2409                 if(ready_waiting_for_me)
2410                 {
2411                         if(warmup_stage)
2412                                 s = strcat(blinkcolor, "Press ^3", getcommandkey("ready", "ready"), blinkcolor, " to end warmup");
2413                         else
2414                                 s = strcat(blinkcolor, "Press ^3", getcommandkey("ready", "ready"), blinkcolor, " once you are ready");
2415                 }
2416                 else
2417                 {
2418                         if(warmup_stage)
2419                                 s = strcat("^2Waiting for others to ready up to end warmup...");
2420                         else
2421                                 s = strcat("^2Waiting for others to ready up...");
2422                 }
2423                 o = Sbar_DrawNoteLine(o, s);
2424         }
2425         else if(warmup_stage && !intermission && !spectatee_status)
2426         {
2427                 s = strcat("^2Press ^3", getcommandkey("ready", "ready"), "^2 to end warmup");
2428                 o = Sbar_DrawNoteLine(o, s);
2429         }
2430         if(vote_waiting)
2431         {
2432                 s = strcat("^2A vote has been called for ^1", vote_called_vote);
2433                 o = Sbar_DrawNoteLine(o, s);
2434
2435                 if(vote_waiting_for_me)
2436                 {
2437                         s = strcat(blinkcolor, "Press ^3", getcommandkey("vote yes", "vyes"), blinkcolor, " to accept");
2438                         o = Sbar_DrawNoteLine(o, s);
2439
2440                         s = strcat(blinkcolor, "Press ^3", getcommandkey("vote no", "vno"), blinkcolor, " to reject");
2441                         o = Sbar_DrawNoteLine(o, s);
2442
2443                         s = strcat(blinkcolor, "Press ^3", getcommandkey("vote abstain", "vabstain"), blinkcolor, " to abstain");
2444                         o = Sbar_DrawNoteLine(o, s);
2445                 }
2446                 else
2447                 {
2448                         s = strcat("^2Waiting for others to vote...");
2449                         o = Sbar_DrawNoteLine(o, s);
2450                 }
2451         }
2452         if(teamplay && !intermission && !spectatee_status)
2453         {
2454                 entity tm;
2455                 float ts_min, ts_max;
2456                 tm = teams.sort_next;
2457                 if (tm)
2458                 {
2459                         for(; tm.sort_next; tm = tm.sort_next)
2460                         {
2461                                 if(!tm.team_size || tm.team == COLOR_SPECTATOR)
2462                                         continue;
2463                                 if(!ts_min) ts_min = tm.team_size;
2464                                 else ts_min = min(ts_min, tm.team_size);
2465                                 if(!ts_max) ts_max = tm.team_size;
2466                                 else ts_max = max(ts_max, tm.team_size);
2467                         }
2468                         if ((ts_max - ts_min) > 1)
2469                         {
2470                                 s = strcat(blinkcolor, "Teamnumbers are unbalanced!");
2471                                 tm = GetTeam(myteam, false);
2472                                 if (tm)
2473                                 if (tm.team != COLOR_SPECTATOR)
2474                                 if (tm.team_size == ts_max)
2475                                         s = strcat(s, " Press ^3", getcommandkey("team menu", "menu_showteamselect"), blinkcolor, " to adjust");
2476
2477                                 o = Sbar_DrawNoteLine(o, s);
2478                         }
2479                 }
2480         }
2481
2482         Sbar_UpdatePlayerTeams();
2483         if (intermission == 2) // map voting screen
2484         {
2485                 if(sb_showaccuracy) {
2486                         Sbar_DrawAccuracyStats();
2487                         Sbar_Score();
2488                         Sbar_Timer();
2489                 }
2490                 else if(sb_showscores) {
2491                         Sbar_DrawScoreboard();
2492                         Sbar_Score();
2493                         Sbar_Timer();
2494                 }
2495                 else
2496                         Sbar_FinaleOverlay();
2497
2498                 Sbar_Reset();
2499         }
2500         else if (sb_showscores_force || getstati(STAT_HEALTH) <= 0 || intermission == 1)
2501         {
2502                 if(sb_showaccuracy)
2503                         Sbar_DrawAccuracyStats();
2504                 else
2505                         Sbar_DrawScoreboard();
2506                 Sbar_Score();
2507                 Sbar_Timer();
2508
2509                 Sbar_Reset();
2510         }
2511         else
2512         {
2513                 if(sb_showaccuracy)
2514                         Sbar_DrawAccuracyStats();
2515                 else
2516                         Sbar_DrawScoreboard();
2517                 float armor, health;
2518                 armor = getstati(STAT_ARMOR);
2519                 health = getstati(STAT_HEALTH);
2520
2521                 stat_items = getstati(STAT_ITEMS);
2522                 stat_weapons = getstati(STAT_WEAPONS);
2523
2524                 fade = 3.2 - 2 * (time - weapontime);
2525                 fade = bound(0.7, fade, 1);
2526
2527                 vector bg_size; // hud background size
2528                 bg_size = '1600 58 0';
2529
2530                 if (cvar("viewsize") <= 100 && vid_conwidth <= 1600) {
2531                         if (teamplay)
2532                                 drawpic(bottom - '800 58 0', "gfx/hud/sbar", bg_size, GetTeamRGB(myteam) * sbar_color_bg_team, sbar_alpha_bg, DRAWFLAG_NORMAL); // hud color = myteam color
2533                         else {
2534                                 // allow for custom HUD colors in non-teamgames
2535                                 color_x = cvar("sbar_color_bg_r");
2536                                 color_y = cvar("sbar_color_bg_g");
2537                                 color_z = cvar("sbar_color_bg_b");
2538
2539                                 drawpic(bottom - '800 58 0', "gfx/hud/sbar", bg_size, color, sbar_alpha_bg, DRAWFLAG_NORMAL);
2540                         }
2541                 }
2542
2543                 if(sbar_hudselector == 2) // combined health and armor display
2544                 {
2545                         vector v;
2546                         v = healtharmor_maxdamage(health, armor, armorblockpercent);
2547
2548                         vector num_pos;
2549                         num_pos = bottom - '96 28 0';
2550
2551                         x = floor(v_x + 1);
2552
2553                         if(v_z) // fully armored
2554                         {
2555                                 // here, armorideal > armor
2556                                 drawpic(num_pos + '78 -4.5 0', "gfx/hud/sb_health", '32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2557                                 drawpic(num_pos + '108 -4.5 0', "gfx/hud/sb_armor", '20 20 0', '1 1 1', sbar_alpha_fg * armor / v_y, DRAWFLAG_NORMAL);
2558                         }
2559                         else
2560                         {
2561                                 drawpic(num_pos + '108 -4.5 0', "gfx/hud/sb_health", '20 20 0', '1 1 1', sbar_alpha_fg * v_y / armor, DRAWFLAG_NORMAL);
2562                                 drawpic(num_pos + '78 -4.5 0', "gfx/hud/sb_armor", '32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2563                         }
2564                         Sbar_DrawXNum_Colored(num_pos, x, 24, sbar_alpha_fg); // draw the combined health and armor
2565                 }
2566
2567                 else
2568                 {
2569                         vector health_pos, armor_pos;
2570
2571                         if (sbar_hudselector == 0) { // old style layout with armor left of health
2572                                 armor_pos = bottom - '96 28 0';
2573                                 health_pos = bottom - '-14 28 0';
2574                         }
2575                         else {
2576                                 health_pos = bottom - '96 28 0';
2577                                 armor_pos = bottom - '-14 28 0';
2578                         }
2579
2580                         // armor
2581                         x = armor;
2582                         if (x > 0)
2583                         {
2584                                 if (x > 45) {
2585                                         drawpic(armor_pos + '78 -4.5 0', "gfx/hud/sb_armor", '32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2586                                         Sbar_DrawXNum_Colored(armor_pos, x, 24, sbar_alpha_fg);
2587                                 }
2588                                 else {
2589                                         drawpic(armor_pos + '78 -4.5 0', "gfx/hud/sb_armor", '32 32 0', '1 1 1', (x+10)/55 * sbar_alpha_fg, DRAWFLAG_NORMAL);
2590                                         Sbar_DrawXNum_Colored(armor_pos, x, 24, sbar_alpha_fg);
2591                                 }
2592                         }
2593
2594                         // health
2595                         x = health;
2596                         drawpic(health_pos + '78 -4.5 0', "gfx/hud/sb_health", '32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2597                         Sbar_DrawXNum_Colored(health_pos, x, 24, sbar_alpha_fg);
2598                 }
2599
2600                 // ammo
2601                 float a; // i will be the ammo type (already declared), a will contain how much ammo there is of type i
2602
2603                 for (i = 0; i < 4; ++i) {
2604                         a = getstati(GetAmmoStat(i)); // how much ammo do we have of type i?
2605
2606                         if(sbar_currentammo || vid_conwidth < 800) { // force showing current ammo only with conwidths < 800
2607                                 if (stat_items & GetAmmoItemCode(i)) {
2608                                         if (vid_conwidth >= 800) {
2609                                                 pos_x = 230;
2610                                                 pos_y = 40;
2611                                         } else {
2612                                                 pos_x = 206;
2613                                                 pos_y = 33;
2614                                         }
2615
2616                                         pos = bottom - pos;
2617                                         if(vid_conwidth >= 800)
2618                                                 drawpic(pos + '0 1.5 0', "gfx/hud/sb_ammobg", '107 29 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2619                                         drawpic(pos + '76 3 0', GetAmmoPicture(i), '24 24 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2620                                         if(a < 10)
2621                                                 Sbar_DrawXNum(pos + '5 5 0', a, 3, 0, 24, '0.7 0 0', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2622                                         else
2623                                                 Sbar_DrawXNum(pos + '5 5 0', a, 3, 0, 24, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2624                                 }
2625                         } else {
2626                                 if (a > 0) {
2627                                         switch (i) {
2628                                                 case 0: pos_x = 286; pos_y = 48; break; // shells
2629                                                 case 1: pos_x = 286; pos_y = 26; break; // bullets
2630                                                 case 2: pos_x = 200; pos_y = 48; break; // rockets
2631                                                 case 3: pos_x = 200; pos_y = 26; break; // cells
2632                                         }
2633
2634                                         pos = bottom - pos;
2635                                         if (stat_items & GetAmmoItemCode(i))
2636                                                 drawpic(pos + '0 1.5 0', "gfx/hud/sb_ammobg", '80 22 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2637                                         drawpic(pos + '56 3 0', GetAmmoPicture(i), '18 18 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2638                                         if (a < 10) {
2639                                                 if(stat_items & GetAmmoItemCode(i))
2640                                                         Sbar_DrawXNum(pos + '6 4.5 0', a, 3, 0, 16, '0.7 0 0', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2641                                                 else
2642                                                         Sbar_DrawXNum(pos + '6 4.5 0', a, 3, 0, 16, '0.7 0 0', 0, 0, sbar_alpha_fg * 0.7, DRAWFLAG_NORMAL);
2643                                         } else {
2644                                                 if(stat_items & GetAmmoItemCode(i))
2645                                                         Sbar_DrawXNum(pos + '6 4.5 0', a, 3, 0, 16, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2646                                                 else
2647                                                         Sbar_DrawXNum(pos + '6 4.5 0', a, 3, 0, 16, '0.7 0.7 0.7', 0, 0, sbar_alpha_fg * 0.7, DRAWFLAG_NORMAL);
2648                                         }
2649                                 }
2650                         }
2651                 }
2652
2653                 // fuel ammo
2654                 a = getstati(GetAmmoStat(4)); // how much fuel do we have?
2655
2656                 if (a > 0) { // if we have fuel, draw the amount
2657                         float invincibility_time, dt;
2658                         invincibility_time = getstatf(STAT_INVINCIBLE_FINISHED);
2659                         dt = invincibility_time - time;
2660                         if (vid_conwidth >= 800) {
2661                                 if (dt > 0) { // if the invincibility timer is active, draw fuel ammo elsewhere
2662                                         pos_x = bottom_x + 140;
2663                                         pos_y = bottom_y - 72;
2664                                 }
2665                                 else { // if the invincibility timer is inactive, draw the fuel ammo there (it's rare to have invincibility + fuel anyway)
2666                                         pos_x = bottom_x + 140;
2667                                         pos_y = bottom_y - 20;
2668                                 }
2669                         }
2670                         else { // draw fuel on top of ammo if vid_conwidth < 800
2671                                 pos_x = bottom_x - 200;
2672                                 pos_y = bottom_y - 45;
2673                         }
2674                         drawpic(pos - '0 2 0' + '52 0 0', GetAmmoPicture(4), '20 20 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2675                         if (a > 10)
2676                                 Sbar_DrawXNum(pos, a, 3, 0, 16, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2677                         else
2678                                 Sbar_DrawXNum(pos, a, 3, 0, 16, '0.7 0 0', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2679                 }
2680
2681                 // draw scores and timer
2682                 Sbar_Score();
2683                 Sbar_Timer();
2684
2685                 // draw strength/invincibility icon and timer
2686                 CSQC_Strength_Timer();
2687
2688                 // weapon icons
2689                 if(cvar("sbar_showweaponicons")) {
2690                         x = 1.0;
2691                         Sbar_DrawWeapon_Clear();
2692                         for(i = 1; i <= 24; ++i)
2693                         {
2694                                 if(weaponimpulse[i-1] >= 0)
2695                                 if(stat_weapons & x)
2696                                         Sbar_DrawWeapon(i-1, fade, (i == activeweapon), i);
2697                                 x *= 2;
2698                         }
2699                 }
2700
2701                 // draw gametype specific icons
2702                 if(gametype == GAME_KEYHUNT)
2703                         CSQC_kh_hud();
2704                 else if(gametype == GAME_CTF)
2705                         CSQC_ctf_hud();
2706                 else if(gametype == GAME_NEXBALL)
2707                         CSQC_nb_hud();
2708         }
2709         return;
2710 }
2711
2712 // CTF HUD
2713 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2714 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2715 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2716
2717 void CSQC_ctf_hudreset(void)
2718 {
2719         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2720 }
2721
2722 void CSQC_ctf_hud(void)
2723 {
2724         vector bottomleft, redflag_pos, blueflag_pos, sz;
2725         float f; // every function should have that
2726         bottomleft_x = 0;
2727         bottomleft_y = vid_conheight;
2728         bottomleft_z = 0;
2729
2730         float redflag, blueflag; // current status
2731         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2732         float stat_items;
2733
2734         stat_items = getstati(STAT_ITEMS);
2735         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2736         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2737
2738         // when status CHANGES, set old status into prevstatus and current status into status
2739         if (redflag != redflag_prevframe)
2740         {
2741                 redflag_statuschange_time = time;
2742                 redflag_prevstatus = redflag_prevframe;
2743                 redflag_prevframe = redflag;
2744         }
2745
2746         if (blueflag != blueflag_prevframe)
2747         {
2748                 blueflag_statuschange_time = time;
2749                 blueflag_prevstatus = blueflag_prevframe;
2750                 blueflag_prevframe = blueflag;
2751         }
2752
2753         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2754         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2755
2756         float BLINK_FACTOR = 0.15;
2757         float BLINK_BASE = 0.85;
2758         // note:
2759         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2760         // thus
2761         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2762         // ensure RMS == 1
2763         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2764
2765         string red_icon, red_icon_prevstatus;
2766         float red_alpha, red_alpha_prevstatus;
2767         red_alpha = red_alpha_prevstatus = 1;
2768         switch(redflag) {
2769                 case 1: red_icon = "gfx/hud/sb_flag_red_taken"; break;
2770                 case 2: red_icon = "gfx/hud/sb_flag_red_lost"; break;
2771                 case 3: red_icon = "gfx/hud/sb_flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2772                 default:
2773                         if((stat_items & IT_CTF_SHIELDED) && (myteam == COLOR_TEAM2))
2774                                 red_icon = "gfx/hud/sb_flag_red_shielded";
2775                         else
2776                                 red_icon = string_null;
2777                         break;
2778         }
2779         switch(redflag_prevstatus) {
2780                 case 1: red_icon_prevstatus = "gfx/hud/sb_flag_red_taken"; break;
2781                 case 2: red_icon_prevstatus = "gfx/hud/sb_flag_red_lost"; break;
2782                 case 3: red_icon_prevstatus = "gfx/hud/sb_flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2783                 default:
2784                         if(redflag == 3)
2785                                 red_icon_prevstatus = "gfx/hud/sb_flag_red_carrying"; // make it more visible
2786                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == COLOR_TEAM2))
2787                                 red_icon_prevstatus = "gfx/hud/sb_flag_red_shielded";
2788                         else
2789                                 red_icon_prevstatus = string_null;
2790                         break;
2791         }
2792
2793         string blue_icon, blue_icon_prevstatus;
2794         float blue_alpha, blue_alpha_prevstatus;
2795         blue_alpha = blue_alpha_prevstatus = 1;
2796         switch(blueflag) {
2797                 case 1: blue_icon = "gfx/hud/sb_flag_blue_taken"; break;
2798                 case 2: blue_icon = "gfx/hud/sb_flag_blue_lost"; break;
2799                 case 3: blue_icon = "gfx/hud/sb_flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2800                 default:
2801                         if((stat_items & IT_CTF_SHIELDED) && (myteam == COLOR_TEAM1))
2802                                 blue_icon = "gfx/hud/sb_flag_blue_shielded";
2803                         else
2804                                 blue_icon = string_null;
2805                         break;
2806         }
2807         switch(blueflag_prevstatus) {
2808                 case 1: blue_icon_prevstatus = "gfx/hud/sb_flag_blue_taken"; break;
2809                 case 2: blue_icon_prevstatus = "gfx/hud/sb_flag_blue_lost"; break;
2810                 case 3: blue_icon_prevstatus = "gfx/hud/sb_flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2811                 default:
2812                         if(blueflag == 3)
2813                                 blue_icon_prevstatus = "gfx/hud/sb_flag_blue_carrying"; // make it more visible
2814                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == COLOR_TEAM1))
2815                                 blue_icon_prevstatus = "gfx/hud/sb_flag_blue_shielded";
2816                         else
2817                                 blue_icon_prevstatus = string_null;
2818                         break;
2819         }
2820
2821         if (myteam == COLOR_TEAM1) { // always draw own flag on left
2822                 redflag_pos = bottomleft - '-4 50 0';
2823                 blueflag_pos = bottomleft - '-62 50 0';
2824         } else {
2825                 blueflag_pos = bottomleft - '-4 50 0';
2826                 redflag_pos = bottomleft - '-62 50 0';
2827         }
2828
2829         sz = '52 52 0';
2830
2831         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2832         if(red_icon_prevstatus && f < 1)
2833                 drawpic_expanding(redflag_pos, red_icon_prevstatus, sz, '1 1 1', sbar_alpha_fg * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2834         if(red_icon)
2835                 drawpic(redflag_pos, red_icon, sz, '1 1 1', sbar_alpha_fg * red_alpha * f, DRAWFLAG_NORMAL);
2836
2837         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2838         if(blue_icon_prevstatus && f < 1)
2839                 drawpic_expanding(blueflag_pos, blue_icon_prevstatus, sz, '1 1 1', sbar_alpha_fg * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2840         if(blue_icon)
2841                 drawpic(blueflag_pos, blue_icon, sz, '1 1 1', sbar_alpha_fg * blue_alpha * f, DRAWFLAG_NORMAL);
2842 }
2843
2844 // Keyhunt HUD
2845 float kh_runheretime;
2846
2847 void CSQC_kh_hudreset(void)
2848 {
2849         kh_runheretime = 0;
2850 }
2851
2852 void CSQC_kh_hud(void)
2853 {
2854         float kh_keys;
2855         float keyteam;
2856         float a, aa;
2857         vector p, pa, kh_size, kh_asize;
2858
2859         vector bottomleft;
2860         bottomleft_x = 0;
2861         bottomleft_y = vid_conheight;
2862         bottomleft_z = 0;
2863
2864         p_x = 6;
2865         p_y = vid_conheight - 34 - 3;
2866         p_z = 0;
2867
2868         kh_keys = getstati(STAT_KH_KEYS);
2869
2870         kh_size = '19 34 0';
2871         kh_asize = '19 10 0';
2872         pa = p + '0 -10 0';
2873
2874         float i, key;
2875
2876         float keycount;
2877         keycount = 0;
2878         for(i = 0; i < 4; ++i)
2879         {
2880                 key = floor(kh_keys / pow(32, i)) & 31;
2881                 keyteam = key - 1;
2882                 if(keyteam == 30 && keycount <= 4)
2883                         keycount += 4;
2884                 if(keyteam == myteam || keyteam == -1 || keyteam == 30)
2885                         keycount += 1;
2886         }
2887         // this yields 8 exactly if "RUN HERE" shows
2888
2889         if(keycount == 8)
2890         {
2891                 if(!kh_runheretime)
2892                         kh_runheretime = time;
2893                 pa_y -= fabs(sin((time - kh_runheretime) * 3.5)) * 6; // make the arrows jump in case of RUN HERE
2894         }
2895         else
2896                 kh_runheretime = 0;
2897
2898         for(i = 0; i < 4; ++i)
2899         {
2900                 key = floor(kh_keys / pow(32, i)) & 31;
2901                 keyteam = key - 1;
2902                 switch(keyteam)
2903                 {
2904                         case 30: // my key
2905                                 keyteam = myteam;
2906                                 a = 1;
2907                                 aa = 1;
2908                                 break;
2909                         case -1: // no key
2910                                 a = 0;
2911                                 aa = 0;
2912                                 break;
2913                         default: // owned or dropped
2914                                 a = 0.2;
2915                                 aa = 0.5;
2916                                 break;
2917                 }
2918                 a = a * sbar_alpha_fg;
2919                 aa = aa * sbar_alpha_fg;
2920                 if(a > 0)
2921                 {
2922                         switch(keyteam)
2923                         {
2924                                 case COLOR_TEAM1:
2925                                         drawpic (pa, "gfx/hud/sb_kh_redarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% alpha key
2926                                         break;
2927                                 case COLOR_TEAM2:
2928                                         drawpic (pa, "gfx/hud/sb_kh_bluearrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% alpha key
2929                                         break;
2930                                 case COLOR_TEAM3:
2931                                         drawpic (pa, "gfx/hud/sb_kh_yellowarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% alpha key
2932                                         break;
2933                                 case COLOR_TEAM4:
2934                                         drawpic (pa, "gfx/hud/sb_kh_pinkarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% alpha key
2935                                         break;
2936                                 default:
2937                                         break;
2938                         }
2939                         switch(i) // YAY! switch(i) inside a for loop for i. DailyWTF, here we come!
2940                         {
2941                                 case 0:
2942                                         drawpic (p, "gfx/hud/sb_kh_red", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% alpha key
2943                                         break;
2944                                 case 1:
2945                                         drawpic (p, "gfx/hud/sb_kh_blue", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% alpha key
2946                                         break;
2947                                 case 2:
2948                                         drawpic (p, "gfx/hud/sb_kh_yellow", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% alpha key
2949                                         break;
2950                                 case 3:
2951                                         drawpic (p, "gfx/hud/sb_kh_pink", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% alpha key
2952                                         break;
2953                         }
2954                 }
2955                 p_x += 24;
2956                 pa_x += 24;
2957         }
2958 }
2959
2960 //Nexball HUD
2961 #define NBPB_SIZE '96 38 0'
2962 #define NBPB_BT 2                   //thickness
2963 #define NBPB_BRGB '1 1 1'
2964 #define NBPB_BALPH 1                //alpha
2965 #define NBPB_BFLAG DRAWFLAG_NORMAL
2966 #define NBPB_IALPH 0.4
2967 #define NBPB_IFLAG DRAWFLAG_NORMAL
2968 #define NBPB_IRGB '0.7 0.1 0'
2969
2970 void CSQC_nb_hud(void)
2971 {
2972         float stat_items, nb_pb_starttime, dt, p;
2973         vector pos;
2974
2975         stat_items = getstati(STAT_ITEMS);
2976         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
2977
2978         pos_x = 4;
2979         pos_y = vid_conheight - 42;
2980         pos_z = 0;
2981
2982         //Manage the progress bar if any
2983         if (nb_pb_starttime > 0)
2984         {
2985                 vector s;
2986                 dt = mod(time - nb_pb_starttime, nb_pb_period);
2987                 // one period of positive triangle
2988                 p = 2 * dt / nb_pb_period;
2989                 if (p > 1)
2990                         p = 2 - p;
2991
2992                 s = NBPB_SIZE;
2993                 //Draw the filling
2994                 drawfill(pos, p * s_x * '1 0 0' + s_y * '0 1 0', NBPB_IRGB, NBPB_IALPH, NBPB_IFLAG);
2995
2996                 //Draw the box
2997                 s = NBPB_SIZE;
2998                 drawline(NBPB_BT, pos    , pos + '1 0 0' * s_x, NBPB_BRGB, NBPB_BALPH, NBPB_BFLAG);
2999                 drawline(NBPB_BT, pos    , pos + '0 1 0' * s_y, NBPB_BRGB, NBPB_BALPH, NBPB_BFLAG);
3000                 drawline(NBPB_BT, pos + s, pos + '1 0 0' * s_x, NBPB_BRGB, NBPB_BALPH, NBPB_BFLAG);
3001                 drawline(NBPB_BT, pos + s, pos + '0 1 0' * s_y, NBPB_BRGB, NBPB_BALPH, NBPB_BFLAG);
3002         }
3003
3004         pos_x += 12; //horizontal margin to the picture
3005         pos_y += 2; //vertical margin to the picture
3006
3007         if (stat_items & IT_KEY1)
3008                 drawpic(pos, "gfx/hud/sb_nexball_carrying", '80 34 0', '1 1 1', 1, DRAWFLAG_NORMAL);
3009 }