data/qcsrc/client/mapvoting.qc

   1 float mv_num_maps;
   2
   3 string mv_maps[MAPVOTE_COUNT];
   4 string mv_pics[MAPVOTE_COUNT];
   5 string mv_pk3[MAPVOTE_COUNT];
   6 float mv_preview[MAPVOTE_COUNT];
   7 float mv_votes[MAPVOTE_COUNT];
   8 entity mv_pk3list;
   9 float mv_abstain;
  10 float mv_ownvote;
  11 float mv_detail;
  12 float mv_timeout;
  13
  14 string MapVote_FormatMapItem(float id, string map, float count, float maxwidth)
  15 {
  16         string pre, post;
  17         pre = strcat(ftos(id+1), ". ");
  18         if(mv_detail)
  19                 post = strcat(" (", ftos(count), " votes)");
  20         else
  21                 post = "";
  22         maxwidth -= stringwidth(pre, FALSE) + stringwidth(post, FALSE);
  23         map = textShortenToWidth(map, maxwidth, FALSE);
  24         return strcat(pre, map, post);
  25 }
  26
  27 vector MapVote_RGB(float id)
  28 {
  29         if(id == mv_ownvote)
  30                 return '1 1 0';
  31         else
  32                 return '1 1 1';
  33 }
  34
  35 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float count, float id)
  36 {
  37         vector img_size, a, b;
  38         vector rgb;
  39         string label;
  40         float text_size;
  41
  42         isize -= sbar_fontsize_y; // respect the text when calculating the image size
  43
  44         rgb = MapVote_RGB(id);
  45
  46         img_size_y = isize;
  47         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  48
  49         drawfont = sbar_font;
  50         pos_y = pos_y + img_size_y;
  51
  52         label = MapVote_FormatMapItem(id, map, count, tsize / sbar_fontsize_x);
  53
  54         text_size = stringwidth(label, false) * sbar_fontsize_x;
  55
  56         pos_x -= text_size*0.5;
  57         drawstring(pos, label, sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);
  58
  59         pos_x = pos_x + text_size*0.5 - img_size_x*0.5;
  60         pos_y = pos_y - img_size_y;
  61
  62         if(pic == "")
  63         {
  64                 a_x = img_size_x; // for the lines
  65                 b_y = img_size_y;
  66                 drawfill(pos, img_size, '.5 .5 .5', .7, DRAWFLAG_NORMAL);
  67                 drawline(2, pos, pos + a, '1 1 1', 1, DRAWFLAG_NORMAL);
  68                 drawline(2, pos, pos + b, '1 1 1', 1, DRAWFLAG_NORMAL);
  69                 drawline(2, pos + img_size, pos + a, '1 1 1', 1, DRAWFLAG_NORMAL);
  70                 drawline(2, pos + img_size, pos + b, '1 1 1', 1, DRAWFLAG_NORMAL);
  71         }
  72         else
  73         {
  74                 drawpic(pos, pic, img_size, '1 1 1', 1, DRAWFLAG_NORMAL);
  75         }
  76 }
  77
  78 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float count, float id)
  79 {
  80         vector img_size;
  81         vector rgb;
  82         float text_size;
  83         string label;
  84
  85         rgb = MapVote_RGB(id);
  86
  87         drawfont = sbar_font;
  88         pos_y = pos_y + sbar_fontsize_y;
  89
  90         label = MapVote_FormatMapItem(id, "Don't care", count, tsize / sbar_fontsize_x);
  91
  92         text_size = stringwidth(label, false) * sbar_fontsize_x;
  93
  94         pos_x -= text_size*0.5;
  95         drawstring(pos, label, sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);
  96 }
  97
  98 vector MapVote_GridVec(vector gridspec, float i, float m)
  99 {
 100         float r;
 101         r = mod(i, m);
 102         return
 103                 '1 0 0' * (gridspec_x * r)
 104                 +
 105                 '0 1 0' * (gridspec_y * (i - r) / m);
 106 }
 107
 108 void MapVote_Draw()
 109 {
 110         string map;
 111         float i, tmp;
 112         vector pos;
 113         float isize;
 114         float center;
 115         float columns, rows;
 116         float tsize;
 117         vector dist;
 118
 119         center = (vid_conwidth - 1)/2;
 120         xmin = vid_conwidth*0.05; // 5% border must suffice
 121         xmax = vid_conwidth - xmin;
 122         ymin = 20;
 123         i = cvar("con_chatpos"); //*cvar("con_chatsize");
 124         if(i < 0)
 125                 ymax = vid_conheight + (i - cvar("con_chat")) * cvar("con_chatsize");
 126         if(i >= 0 || ymax < (vid_conheight*0.5))
 127                 ymax = vid_conheight - ymin;
 128
 129         drawfont = sbar_bigfont;
 130         sbar_fontsize = stov(cvar_string("sbar_fontsize"));
 131         if(sbar_fontsize_x == 0)
 132                 sbar_fontsize = '8 8 0';
 133         if(sbar_fontsize_y == 0)
 134                 sbar_fontsize_y = sbar_fontsize_x;
 135
 136         pos_y = ymin;
 137         pos_z = 0;
 138         pos_x = center - stringwidth("Vote for a map", false) * 0.5 * 24;
 139         drawstring(pos, "Vote for a map", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 140         pos_y += 26;
 141
 142         i = ceil(max(0, mv_timeout - time));
 143         map = strcat(ftos(i), " seconds left");
 144         pos_x = center - stringwidth(map, false) * 0.5 * 16;
 145         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 146         pos_y += 22;
 147         pos_x = xmin;
 148
 149         drawfont = sbar_bigfont; // FIXME change this to sbar_font when it gets a SANE size later
 150
 151         // base for multi-column stuff...
 152         ymin = pos_y;
 153         if(mv_abstain)
 154                 mv_num_maps -= 1;
 155
 156         if(mv_num_maps > 3)
 157         {
 158                 columns = 3;
 159         } else {
 160                 columns = mv_num_maps;
 161         }
 162         rows = ceil(mv_num_maps / columns);
 163
 164         dist_x = (xmax - xmin) / columns;
 165         dist_y = (ymax - pos_y) / rows;
 166         tsize = dist_x - 10;
 167         isize = min(dist_y - 10, 0.75 * tsize);
 168
 169         pos_x += (xmax - xmin) / (2 * columns);
 170         pos_y += (dist_y - isize) / 2;
 171         ymax -= isize;
 172         for(i = 0; i < mv_num_maps; ++i)
 173         {
 174                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 175                 if(tmp < 0)
 176                         continue;
 177                 map = mv_maps[i];
 178                 if(mv_preview[i])
 179                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, mv_pics[i], tmp, i);
 180                 else
 181                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, "", tmp, i);
 182         }
 183
 184         if(mv_abstain)
 185                 ++mv_num_maps;
 186
 187         if(mv_abstain && i < mv_num_maps) {
 188                 tmp = mv_votes[i];
 189                 pos_y = ymax + isize - sbar_fontsize_y;
 190                 pos_x = (xmax+xmin)*0.5;
 191                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 192         }
 193 }
 194
 195 void Cmd_MapVote_MapDownload(float argc)
 196 {
 197         float id;
 198         entity pak;
 199
 200         if(argc != 2 || !mv_pk3list)
 201         {
 202                 print("mv_mapdownload: ^3You're not supposed to use this command on your own!\n");
 203                 return;
 204         }
 205
 206         id = stof(argv(1));
 207         for(pak = mv_pk3list; pak; pak = pak.chain)
 208                 if(pak.sv_entnum == id)
 209                         break;
 210
 211         if(!pak || pak.sv_entnum != id) {
 212                 print("^1Error:^7 Couldn't find pak index.\n");
 213                 return;
 214         }
 215
 216         //print(strcat("^3Adding: ", ftos(id), " - ", pak.message, " - "));
 217
 218         if(PreviewExists(pak.message))
 219         {
 220                 mv_preview[id] = true;
 221                 //print("^2Found...\n");
 222                 return;
 223         } else if(csqc_flags & CSQC_FLAG_READPICTURE) {
 224                 print("Requesting preview...\n");
 225                 localcmd(strcat("\ncmd mv_getpic ", ftos(id), "\n"));
 226         } else {
 227                 print("^3Missing map preview - Update to a newer build to be able to see them.\n");
 228         }
 229 }
 230
 231 void MapVote_CheckPK3(string pic, string pk3, float id)
 232 {
 233         entity pak;
 234         pak = spawn();
 235         pak.netname = pk3;
 236         pak.message = pic;
 237         pak.sv_entnum = id;
 238
 239         pak.chain = mv_pk3list;
 240         mv_pk3list = pak;
 241
 242         localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 243 }
 244
 245 void MapVote_CheckPic(string pic, string pk3, float id)
 246 {
 247         if(PreviewExists(pic))
 248         {
 249                 mv_preview[id] = true;
 250                 return;
 251         }
 252         MapVote_CheckPK3(pic, pk3, id);
 253 }
 254
 255 void MapVote_Init()
 256 {
 257         float i, power, m;
 258         string map, pk3;
 259
 260         registercmd("+showscores");
 261         registercmd("-showscores");
 262
 263         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 264         mv_abstain = ReadByte();
 265         if(mv_abstain)
 266                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 267         mv_detail = ReadByte();
 268
 269         mv_ownvote = -1;
 270         mv_timeout = ReadCoord();
 271
 272         if(mv_num_maps <= 8)
 273                 m = ReadByte();
 274         else
 275                 m = ReadShort();
 276
 277         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 278         mv_pk3list = NULL; // I'm still paranoid!
 279
 280         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 281         {
 282                 mv_votes[i] = 0;
 283
 284                 if(m & power)
 285                 {
 286                         map = strzone(ReadString());
 287                         pk3 = strzone(ReadString());
 288                         mv_maps[i] = map;
 289                         mv_pk3[i] = pk3;
 290                         map = strzone(strcat(config_get("mv_screenshot_dir", "maps"), "/", map));
 291                         mv_pics[i] = map;
 292
 293                         mv_preview[i] = false;
 294
 295                         //print(strcat("RECV: ", map, " in ", pk3, "\n"));
 296                         MapVote_CheckPic(map, pk3, i);
 297                 }
 298                 else
 299                 {
 300                         mv_maps[i] = strzone("if-you-see-this-the-code-is-broken");
 301                         mv_pk3[i] = strzone("if-you-see-this-the-code-is-broken");
 302                         mv_pics[i] = strzone("if-you-see-this-the-code-is-broken");
 303                         mv_preview[i] = false;
 304                 }
 305         }
 306 }
 307
 308 void MapVote_Update()
 309 {
 310         float i, power;
 311         float m;
 312         if(mv_num_maps <= 8)
 313                 m = ReadByte();
 314         else
 315                 m = ReadShort();
 316         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 317         {
 318                 if(m & power)
 319                 {
 320                         if(mv_detail)
 321                                 mv_votes[i] = ReadByte();
 322                         else
 323                                 mv_votes[i] = 0;
 324                 }
 325                 else
 326                         mv_votes[i] = -1;
 327         }
 328 }
 329
 330 string Net_ReadPicture();
 331 void Net_Mapvote()
 332 {
 333         float type;
 334         type = ReadByte();
 335         switch(type)
 336         {
 337         case MAPVOTE_NET_INIT:
 338                 MapVote_Init();
 339                 // do we NEED this, or can we handle key presses directly in CSQC?
 340                 localcmd("\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
 341                 break;
 342         case MAPVOTE_NET_UPDATE:
 343                 MapVote_Update();
 344                 break;
 345         case MAPVOTE_NET_OWNVOTE:
 346                 mv_ownvote = ReadByte()-1;
 347                 break;
 348         case MAPVOTE_NET_PIC:
 349                 type = ReadByte();
 350                 mv_preview[type] = true;
 351                 mv_pics[type] = strzone(Net_ReadPicture());
 352                 break;
 353         }
 354 }