data/qcsrc/client/gibs.qc

   1 float  gibcount;
   2 entity giblist;
   3 .float silent;
   4
   5 void Gib_Delete()
   6 {
   7     --gibcount;
   8     remove(self);
   9 }
  10
  11 string species_prefix(float specnum)
  12 {
  13         switch(specnum)
  14         {
  15                 case SPECIES_HUMAN:       return "";
  16                 case SPECIES_ALIEN:       return "alien_";
  17                 case SPECIES_ROBOT_SHINY: return "robot_";
  18                 case SPECIES_ROBOT_RUSTY: return "robot_"; // use the same effects, only different gibs
  19                 case SPECIES_ANIMAL:      return "animal_";
  20                 case SPECIES_RESERVED:    return "reserved_";
  21                 default:         return "";
  22         }
  23 }
  24
  25 void new_te_bloodshower (float ef, vector org, float explosionspeed, float howmany)
  26 {
  27         float i, pmod;
  28         pmod = cvar("cl_particles_quality");
  29         for (i = 0; i < 250 * pmod; ++i)
  30                 pointparticles(ef, org, randomvec() * explosionspeed, howmany / 250);
  31 }
  32
  33 void SUB_RemoveOnNoImpact()
  34 {
  35         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  36                 Gib_Delete();
  37 }
  38
  39 void Gib_Touch()
  40 {
  41         // TODO maybe bounce of walls, make more gibs, etc.
  42
  43         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44         {
  45                 Gib_Delete();
  46                 return;
  47         }
  48
  49         if(!self.silent)
  50                 sound(self, CHAN_PAIN, strcat("misc/gib_splat0", ftos(floor(prandom() * 4 + 1)), ".wav"), VOL_BASE, ATTN_NORM);
  51         pointparticles(particleeffectnum(strcat(species_prefix(self.cnt), "blood")), self.origin + '0 0 1', '0 0 30', 10);
  52
  53         Gib_Delete();
  54 }
  55
  56 void Gib_Draw()
  57 {
  58         vector oldorg;
  59         oldorg = self.origin;
  60
  61         Movetype_Physics_NoMatchServer();
  62         if(wasfreed(self))
  63                 return;
  64
  65         if(self.touch == Gib_Touch) // don't do this for the "chunk" thingie...
  66                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_SLIGHTBLOOD")), oldorg, self.origin);
  67         else
  68                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_BLOOD")), oldorg, self.origin);
  69
  70         self.renderflags = 0;
  71         self.alpha = bound(0, self.nextthink - time, 1);
  72
  73         if(self.alpha < ALPHA_MIN_VISIBLE)
  74                 Gib_Delete();
  75         else
  76                 R_AddEntity(self);
  77 }
  78
  79 void TossGib (string mdlname, vector org, vector vconst, vector vrand, float specnum, float destroyontouch, float issilent)
  80 {
  81         entity gib;
  82
  83         if not(giblist)
  84         giblist = spawn();
  85
  86         // TODO remove some gibs according to cl_nogibs
  87         gib = RubbleNew(giblist);
  88         ++gibcount;
  89         if(gibcount >= cvar_or("cl_gibs_maxcount",100))
  90         RubbleDrop(giblist,Gib_Delete);
  91
  92         //gib = spawn();
  93
  94         gib.classname = "gib";
  95         gib.move_movetype = MOVETYPE_BOUNCE;
  96         gib.gravity = 1;
  97         gib.solid = SOLID_CORPSE;
  98         gib.cnt = specnum;
  99         gib.silent = issilent;
 100
 101         setmodel (gib, mdlname); // precision set above
 102         gib.skin = specnum;
 103
 104         setsize (gib, '-8 -8 -8', '8 8 8');
 105
 106         gib.draw = Gib_Draw;
 107         if(destroyontouch)
 108                 gib.move_touch = Gib_Touch;
 109         else
 110                 gib.move_touch = SUB_RemoveOnNoImpact;
 111
 112         gib.move_origin = gib.origin = org;
 113         gib.move_velocity = vconst * cvar_or("cl_gibs_velocity_scale", 1) + vrand * cvar_or("cl_gibs_velocity_random", 1) + '0 0 1' * cvar("cl_gibs_velocity_up");
 114         gib.move_avelocity = prandomvec() * vlen(gib.move_velocity);
 115         gib.move_time = time;
 116         gib.damageforcescale = cvar_or("cl_gibs_damageforcescale", 3.5);
 117
 118         gib.nextthink = time + cvar_or("cl_gibs_lifetime", 14) * (1 + prandom() * 0.15);
 119 }
 120
 121 void Ent_GibSplash()
 122 {
 123         float amount, type, specnum;
 124         vector org, vel;
 125         string specstr;
 126         float issilent;
 127
 128         float c, gibfactor, randomvalue;
 129
 130         type = ReadByte(); // gibbage type
 131         amount = ReadByte() / 16.0; // gibbage amount
 132         org_x = ReadShort() * 4 + 2;
 133         org_y = ReadShort() * 4 + 2;
 134         org_z = ReadShort() * 4 + 2;
 135         vel = decompressShortVector(ReadShort());
 136
 137         if(cvar("cl_gentle"))
 138                 type |= 0x80; // set gentle bit
 139
 140         gibfactor = 1 - cvar("cl_nogibs");
 141         if(gibfactor <= 0)
 142                 return;
 143
 144         amount *= gibfactor;
 145
 146         if(cvar("ekg"))
 147                 amount *= 5;
 148
 149         self.origin = org; // for the sounds
 150
 151         specnum = (type & 0x78) / 8; // blood/gibmodel type: using four bits (0..7, bit indexes 3,4,5)
 152         issilent = (type & 0x40);
 153         type = type & 0x87; // remove the species bits: bit 7 = gentle, bit 0,1,2 = kind of gib
 154         specstr = species_prefix(specnum);
 155
 156         switch(type)
 157         {
 158                 case 0x01:
 159                         if(!issilent)
 160                                 sound (self, CHAN_PAIN, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 161
 162                         if(prandom() < amount)
 163                                 TossGib ("models/gibs/eye.md3", org, vel, prandomvec() * 150, specnum, 0, issilent);
 164                         new_te_bloodshower(particleeffectnum(strcat(specstr, "bloodshower")), org, 1200, amount);
 165                         if(prandom() < amount)
 166                                 TossGib ("models/gibs/bloodyskull.md3", org, vel, prandomvec() * 100, specnum, 0, issilent);
 167
 168                         for(c = 0; c < amount; ++c)
 169                         {
 170                                 randomvalue = amount - c;
 171
 172                                 if(prandom() < randomvalue)
 173                                         TossGib ("models/gibs/arm.md3", org, vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
 174                                 if(prandom() < randomvalue)
 175                                         TossGib ("models/gibs/arm.md3", org, vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
 176                                 if(prandom() < randomvalue)
 177                                         TossGib ("models/gibs/chest.md3", org + '0 0 -12', vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
 178                                 if(prandom() < randomvalue)
 179                                         TossGib ("models/gibs/smallchest.md3", org, vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
 180                                 if(prandom() < randomvalue)
 181                                         TossGib ("models/gibs/leg1.md3", org + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
 182                                 if(prandom() < randomvalue)
 183                                         TossGib ("models/gibs/leg2.md3", org + '0 0 -9', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
 184
 185                                 // these splat on impact
 186                                 if(prandom() < randomvalue)
 187                                         TossGib ("models/gibs/chunk.mdl", org, vel, prandomvec() * 450, specnum,1, issilent);
 188                                 if(prandom() < randomvalue)
 189                                         TossGib ("models/gibs/chunk.mdl", org, vel, prandomvec() * 450, specnum,1, issilent);
 190                                 if(prandom() < randomvalue)
 191                                         TossGib ("models/gibs/chunk.mdl", org, vel, prandomvec() * 450, specnum,1, issilent);
 192                                 if(prandom() < randomvalue)
 193                                         TossGib ("models/gibs/chunk.mdl", org, vel, prandomvec() * 450, specnum,1, issilent);
 194                         }
 195                         break;
 196                 case 0x02:
 197                         pointparticles(particleeffectnum(strcat(specstr, "blood")), org, vel, amount * 16);
 198                         break;
 199                 case 0x03:
 200                         if(prandom() < amount)
 201                                 TossGib ("models/gibs/chunk.mdl", org, vel, prandomvec() * (prandom() * 30 + 20), specnum, 1, issilent); // TODO maybe adjust to more randomization?
 202                         break;
 203                 case 0x81:
 204                         pointparticles(particleeffectnum("damage_dissolve"), org, vel, amount);
 205                         break;
 206                 case 0x82:
 207                         pointparticles(particleeffectnum("damage_hit"), org, vel, amount * 16);
 208                         break;
 209                 case 0x83:
 210                         // no gibs in gentle mode, sorry
 211                         break;
 212         }
 213 }
 214
 215 void GibSplash_Precache()
 216 {
 217         precache_model("models/gibs/chunk.mdl");
 218         precache_model("models/gibs/leg1.md3");
 219         precache_model("models/gibs/leg2.md3");
 220         precache_model("models/gibs/chest.md3");
 221         precache_model("models/gibs/smallchest.md3");
 222         precache_model("models/gibs/arm.md3");
 223         precache_model("models/gibs/bloodyskull.md3");
 224         precache_model("models/gibs/eye.md3");
 225
 226         precache_sound ("misc/gib.wav");
 227     precache_sound ("misc/gib_splat01.wav");
 228     precache_sound ("misc/gib_splat02.wav");
 229     precache_sound ("misc/gib_splat03.wav");
 230     precache_sound ("misc/gib_splat04.wav");
 231 }