data/qcsrc/client/View.qc

   1 entity porto;\r
   2 vector polyline[16];\r
   3 float trace_dphitcontents;\r
   4 float Q3SURFACEFLAG_SLICK = 2; // low friction surface\r
   5 float DPCONTENTS_SOLID = 1; // blocks player movement\r
   6 float DPCONTENTS_BODY = 32; // blocks player movement\r
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement\r
   8 void Porto_Draw()\r
   9 {\r
  10         vector p, dir, ang, q, nextdir;\r
  11         float idx, portal_number, portal1_idx;\r
  12 \r
  13         if(activeweapon != WEP_PORTO)\r
  14                 return;\r
  15 \r
  16         dir = view_forward;\r
  17 \r
  18         if(angles_held_status)\r
  19         {\r
  20                 makevectors(angles_held);\r
  21                 dir = v_forward;\r
  22         }\r
  23 \r
  24         p = view_origin;\r
  25 \r
  26         polyline[0] = p;\r
  27         idx = 1;\r
  28         portal_number = 0;\r
  29         nextdir = dir;\r
  30 \r
  31         for(;;)\r
  32         {\r
  33                 dir = nextdir;\r
  34                 traceline(p, p + 65536 * dir, TRUE, porto);\r
  35                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)\r
  36                         return;\r
  37                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal\r
  38                 p = trace_endpos;\r
  39                 polyline[idx] = p;\r
  40                 ++idx;\r
  41                 if(idx >= 16)\r
  42                         return;\r
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)\r
  44                         continue;\r
  45                 ++portal_number;\r
  46                 ang = vectoangles2(trace_plane_normal, dir);\r
  47                 ang_x = -ang_x;\r
  48                 makevectors(ang);\r
  49                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))\r
  50                         return;\r
  51                 if(portal_number == 1)\r
  52                         portal1_idx = idx;\r
  53                 if(portal_number >= 2)\r
  54                         break;\r
  55         }\r
  56 \r
  57         while(idx >= 2)\r
  58         {\r
  59                 p = polyline[idx-2];\r
  60                 q = polyline[idx-1];\r
  61                 if(idx == 2)\r
  62                         p = p - view_up * 16;\r
  63                 if(idx-1 >= portal1_idx)\r
  64                 {\r
  65                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);\r
  66                 }\r
  67                 else\r
  68                 {\r
  69                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);\r
  70                 }\r
  71                 --idx;\r
  72         }\r
  73 }\r
  74 \r
  75 /**\r
  76  * Checks whether the server initiated a map restart (stat_game_starttime changed)\r
  77  *\r
  78  * TODO: Use a better solution where a common shared entitiy is used that contains\r
  79  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT\r
  80  * and STAT_FRAGLIMIT to be auto-sent)\r
  81  */\r
  82 void CheckForGamestartChange() {\r
  83         float startTime;\r
  84         startTime = getstatf(STAT_GAMESTARTTIME);\r
  85         if (previous_game_starttime != startTime) {\r
  86                 if ((time + 5.0) < startTime) {\r
  87                         //if connecting to server while restart was active don't always play prepareforbattle\r
  88                         sound(self, CHAN_VOICE, "announcer/robotic/prepareforbattle.wav", VOL_BASEVOICE, ATTN_NONE);\r
  89                 }\r
  90                 if (time < startTime) {\r
  91                         restartAnnouncer = spawn();\r
  92                         restartAnnouncer.think = restartAnnouncer_Think;\r
  93                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime\r
  94                 }\r
  95         }\r
  96         previous_game_starttime = startTime;\r
  97 }\r
  98 \r
  99 void Porto_Init()\r
 100 {\r
 101         porto = spawn();\r
 102         porto.classname = "porto";\r
 103         porto.draw = Porto_Draw;\r
 104         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;\r
 105 }\r
 106 \r
 107 float drawtime;\r
 108 \r
 109 float tan(float x)\r
 110 { \r
 111         return sin(x) / cos(x);\r
 112 }\r
 113 float atan2(float y, float x)\r
 114 {\r
 115         vector v;\r
 116         v = '1 0 0' * x + '0 1 0' * y;\r
 117         v = vectoangles(v);\r
 118         return v_y * 0.01745329251994329576;\r
 119 }\r
 120 \r
 121 vector GetCurrentFov(float fov)\r
 122 {\r
 123         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;\r
 124 \r
 125         zoomsensitivity = cvar("cl_zoomsensitivity");\r
 126         zoomfactor = cvar("cl_zoomfactor");\r
 127         if(zoomfactor < 1 || zoomfactor > 16)\r
 128                 zoomfactor = 2.5;\r
 129         zoomspeed = cvar("cl_zoomspeed");\r
 130         if(zoomspeed >= 0)\r
 131                 if(zoomspeed < 0.5 || zoomspeed > 16)\r
 132                         zoomspeed = 3.5;\r
 133 \r
 134         zoomdir = button_zoom;\r
 135         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here\r
 136                 zoomdir += button_attack2;\r
 137         if(spectatee_status > 0 || isdemo())\r
 138         {\r
 139                 if(spectatorbutton_zoom)\r
 140                         zoomdir = 0 + !zoomdir;\r
 141                         // do not even THINK about removing this 0\r
 142                         // _I_ know what I am doing\r
 143                         // fteqcc does not\r
 144         }\r
 145 \r
 146         if(zoomdir)\r
 147                 zoomin_effect = 0;\r
 148 \r
 149         if(zoomin_effect || camera_active)\r
 150         {\r
 151                 current_viewzoom = min(1, current_viewzoom + drawframetime);\r
 152         }\r
 153         else\r
 154         {\r
 155                 if(zoomspeed < 0) // instant zoom\r
 156                 {\r
 157                         if(zoomdir)\r
 158                                 current_viewzoom = 1 / zoomfactor;\r
 159                         else\r
 160                                 current_viewzoom = 1;\r
 161                 }\r
 162                 else\r
 163                 {\r
 164                         if(zoomdir)\r
 165                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);\r
 166                         else\r
 167                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);\r
 168                 }\r
 169         }\r
 170 \r
 171         if(almost_equals(current_viewzoom, 1))\r
 172                 current_zoomfraction = 0;\r
 173         else if(almost_equals(current_viewzoom, 1/zoomfactor))\r
 174                 current_zoomfraction = 1;\r
 175         else\r
 176                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);\r
 177 \r
 178         if(zoomsensitivity < 1)\r
 179                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));\r
 180         else\r
 181                 setsensitivityscale(1);\r
 182 \r
 183         float frustumx, frustumy, fovx, fovy;\r
 184         frustumy = tan(fov * 0.00872664625997164788) * 0.75 * current_viewzoom;\r
 185         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;\r
 186         fovx = atan2(frustumx, 1) / 0.00872664625997164788;\r
 187         fovy = atan2(frustumy, 1) / 0.00872664625997164788;\r
 188 \r
 189         return '1 0 0' * fovx + '0 1 0' * fovy;\r
 190 }\r
 191 \r
 192 void CSQC_common_hud(void);\r
 193 \r
 194 void CSQC_kh_hud(void);\r
 195 void CSQC_ctf_hud(void);\r
 196 void PostInit(void);\r
 197 void CSQC_Demo_Camera();\r
 198 float Sbar_WouldDrawScoreboard ();\r
 199 float zoomscript_caught;\r
 200 float view_set;\r
 201 float camera_mode;\r
 202 void CSQC_UpdateView(float w, float h)\r
 203 {\r
 204         entity e;\r
 205         float fov;\r
 206         float f;\r
 207 \r
 208         dprint_load();\r
 209         WaypointSprite_Load();\r
 210 \r
 211         ticrate = getstatf(STAT_SYS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);\r
 212 \r
 213         // Render the Scene\r
 214         if(!intermission || !view_set)\r
 215         {\r
 216                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);\r
 217                 view_angles = input_angles;\r
 218                 makevectors(view_angles);\r
 219                 view_forward = v_forward;\r
 220                 view_right = v_right;\r
 221                 view_up = v_up;\r
 222                 view_set = 1;\r
 223         }\r
 224 \r
 225         if(csqc_flags & CSQC_FLAG_COLORCODES)\r
 226         {\r
 227                 // supporting engine\r
 228                 vid_width = w;\r
 229                 vid_height = h;\r
 230         }\r
 231         else\r
 232         {\r
 233                 // non-supporting engine\r
 234                 vid_width = cvar("vid_width");\r
 235                 vid_height = cvar("vid_height");\r
 236         }\r
 237 \r
 238 #ifdef BLURTEST\r
 239         if(time > blurtest_time0 && time < blurtest_time1)\r
 240         {\r
 241                 float r, t;\r
 242 \r
 243                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);\r
 244                 r = t * blurtest_radius;\r
 245                 f = 1 / pow(t, blurtest_power) - 1;\r
 246 \r
 247                 cvar_set("r_glsl_postprocess", "1");\r
 248                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));\r
 249         }\r
 250         else\r
 251         {\r
 252                 cvar_set("r_glsl_postprocess", "0");\r
 253                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");\r
 254         }\r
 255 #endif\r
 256 \r
 257         Fog_Force();\r
 258 \r
 259         drawframetime = max(0.000001, time - drawtime);\r
 260         drawtime = time;\r
 261 \r
 262         // watch for gametype changes here...\r
 263         // in ParseStuffCMD the cmd isn't executed yet :/\r
 264         // might even be better to add the gametype to TE_CSQC_INIT...?\r
 265         if(!postinit)\r
 266                 PostInit();\r
 267         \r
 268         CheckForGamestartChange();\r
 269 \r
 270         fov = cvar("fov");\r
 271         if(button_zoom || fov <= 59.5)\r
 272         {\r
 273                 if(!zoomscript_caught)\r
 274                 {\r
 275                         localcmd("+button4\n");\r
 276                         zoomscript_caught = 1;\r
 277                         ignore_plus_zoom += 1;\r
 278                 }\r
 279         }\r
 280         else\r
 281         {\r
 282                 if(zoomscript_caught)\r
 283                 {\r
 284                         localcmd("-button4\n");\r
 285                         zoomscript_caught = 0;\r
 286                         ignore_minus_zoom += 1;\r
 287                 }\r
 288         }\r
 289         \r
 290         sbar_alpha_fg = cvar("sbar_alpha_fg" );\r
 291         sbar_hudselector = cvar("sbar_hudselector");\r
 292         ColorTranslateMode = cvar("cl_stripcolorcodes");\r
 293         activeweapon = getstati(STAT_SWITCHWEAPON);\r
 294         f = cvar("teamplay");\r
 295         if(f != teamplay)\r
 296         {\r
 297                 teamplay = f;\r
 298                 Sbar_InitScores();\r
 299         }\r
 300 \r
 301         if(last_weapon != activeweapon) {\r
 302                 weapontime = time;\r
 303                 last_weapon = activeweapon;\r
 304         }\r
 305 \r
 306         // ALWAYS Clear Current Scene First\r
 307         R_ClearScene();\r
 308 \r
 309         // Assign Standard Viewflags\r
 310         // Draw the World (and sky)\r
 311         R_SetView(VF_DRAWWORLD, 1);\r
 312 \r
 313         // Set the console size vars\r
 314         vid_conwidth = cvar("vid_conwidth");\r
 315         vid_conheight = cvar("vid_conheight");\r
 316         vid_pixelheight = cvar("vid_pixelheight");\r
 317 \r
 318         R_SetView(VF_FOV, GetCurrentFov(fov));\r
 319 \r
 320         // Camera for demo playback\r
 321         if(camera_active)\r
 322         {\r
 323                 if(cvar("camera_enable"))\r
 324                         CSQC_Demo_Camera();\r
 325                 else\r
 326                 {\r
 327                         cvar_set("chase_active", ftos(chase_active_backup));\r
 328                         cvar_set("cl_demo_mousegrab", "0");\r
 329                         camera_active = FALSE;\r
 330                 }\r
 331         }\r
 332 #ifdef CAMERATEST\r
 333         else if(cvar("camera_enable"))\r
 334 #else\r
 335         else if(cvar("camera_enable") && isdemo())\r
 336 #endif\r
 337         {\r
 338                 // Enable required Darkplaces cvars\r
 339                 chase_active_backup = cvar("chase_active");\r
 340                 cvar_set("chase_active", "2");          \r
 341                 cvar_set("cl_demo_mousegrab", "1");\r
 342                 camera_active = TRUE;\r
 343                 camera_mode = FALSE;\r
 344         }\r
 345         \r
 346         // Draw the Crosshair\r
 347         float scoreboard_active;\r
 348         scoreboard_active = Sbar_WouldDrawScoreboard();\r
 349         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden\r
 350         \r
 351         // Draw the Engine Status Bar (the default Quake HUD)\r
 352         R_SetView(VF_DRAWENGINESBAR, 0);\r
 353 \r
 354         // fetch this one only once per frame\r
 355         sbar_showbinds = cvar("sbar_showbinds");\r
 356         sbar_showbinds_limit = cvar("sbar_showbinds_limit");\r
 357 \r
 358         // Update the mouse position\r
 359         /*\r
 360         mousepos_x = vid_conwidth;\r
 361         mousepos_y = vid_conheight;\r
 362         mousepos = mousepos*0.5 + getmousepos();\r
 363         */\r
 364 \r
 365         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);\r
 366 \r
 367         e = self;\r
 368         for(self = world; (self = nextent(self)); )\r
 369                 if(self.draw)\r
 370                         self.draw();\r
 371         self = e;\r
 372         R_RenderScene();\r
 373 \r
 374         // now switch to 2D drawing mode by calling a 2D drawing function\r
 375         // then polygon drawing will draw as 2D stuff, and NOT get queued until the\r
 376         // next R_RenderScene call\r
 377         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);\r
 378 \r
 379         // Draw the mouse cursor\r
 380         // NOTE: drawpic must happen after R_RenderScene for some reason\r
 381         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);\r
 382         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);\r
 383         //self = edict_num(player_localnum);\r
 384         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);\r
 385         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);\r
 386         // as long as the ctf part isn't in, this is useless\r
 387         if(menu_visible)\r
 388                 menu_show();\r
 389         \r
 390         /*if(gametype == GAME_CTF)\r
 391         {\r
 392                 ctf_view();\r
 393         } else */\r
 394 \r
 395         // draw 2D entities\r
 396         e = self;\r
 397         for(self = world; (self = nextent(self)); )\r
 398                 if(self.draw2d)\r
 399                         self.draw2d();\r
 400         self = e;\r
 401         \r
 402         // draw radar\r
 403         if(\r
 404                 ons_showmap\r
 405                 ||\r
 406                 (\r
 407                         !scoreboard_active\r
 408                         &&\r
 409                         cvar_string("cl_teamradar") != "0"\r
 410                         &&\r
 411                         (\r
 412                                 cvar("cl_teamradar") == 2\r
 413                                 ||\r
 414                                 teamplay\r
 415                         )\r
 416                 )\r
 417         )\r
 418                 teamradar_view();\r
 419 \r
 420         if (cvar("cl_showpressedkeys")) // draw pressed keys when spectating and playing\r
 421         {\r
 422                 if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)\r
 423                         Sbar_DrawPressedKeys();\r
 424         }\r
 425 \r
 426         // draw sbar\r
 427         if(cvar("r_letterbox") == 0)\r
 428         if(cvar("viewsize") < 120)\r
 429                 CSQC_common_hud();\r
 430 \r
 431         // crosshair goes VERY LAST\r
 432         if(!scoreboard_active && !ons_showmap) {\r
 433                 string wcross_style;\r
 434                 wcross_style = cvar_string("crosshair");\r
 435 \r
 436                 if (wcross_style != "0") {\r
 437                         vector wcross_color, wcross_size;\r
 438                         string wcross_wep, wcross_name;\r
 439                         float wcross_alpha, wcross_sizefloat;\r
 440 \r
 441                         wcross_color_x = cvar("crosshair_color_red");\r
 442                         wcross_color_y = cvar("crosshair_color_green");\r
 443                         wcross_color_z = cvar("crosshair_color_blue");\r
 444                         wcross_alpha = cvar("crosshair_color_alpha");\r
 445                         wcross_sizefloat = cvar("crosshair_size");\r
 446                         if (cvar("crosshair_per_weapon")) {\r
 447                                 e = get_weaponinfo(activeweapon);\r
 448                                 if (e && e.netname != "")\r
 449                                 {\r
 450                                         wcross_wep = e.netname;\r
 451                                         wcross_style = cvar_string(strcat("crosshair_", wcross_wep));\r
 452                                         if(wcross_style == "")\r
 453                                                 wcross_style = e.netname;\r
 454 \r
 455                                         if(!cvar("crosshair_color_override"))\r
 456                                         {\r
 457                                                 wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));\r
 458                                                 wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));\r
 459                                                 wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));\r
 460                                         }\r
 461 \r
 462                                         wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));\r
 463                                         wcross_sizefloat *= cvar(strcat("crosshair_", wcross_wep, "_size"));\r
 464                                 }\r
 465                         }\r
 466 \r
 467                         wcross_name = strcat("gfx/crosshair", wcross_style);\r
 468                 \r
 469                         wcross_size = drawgetimagesize(wcross_name);\r
 470                         wcross_size_x *= wcross_sizefloat;\r
 471                         wcross_size_y *= wcross_sizefloat;\r
 472 \r
 473                         drawpic('0.5 0 0' * (vid_conwidth - wcross_size_x) + '0 0.5 0' * (vid_conheight - wcross_size_y), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);\r
 474                 }\r
 475         }\r
 476 }\r
 477 \r
 478 void Sbar_Draw();\r
 479 void CSQC_common_hud(void)\r
 480 {\r
 481         // Sbar_SortFrags(); done in Sbar_Draw\r
 482         Sbar_Draw();\r
 483 }\r
 484 \r
 485 // KeyHunt HUD by victim\r
 486 void CSQC_kh_hud(void)\r
 487 {\r
 488         // HUD 0 has the weapons on the right hand side - temporarily shown when needed\r
 489         // HUD 1 has the weapons on the bottom - permanently\r
 490 \r
 491         // use the following two binds to check the icons move correctly\r
 492         // bind g "toggle sbar_flagstatus_right; echo Menu right $sbar_flagstatus_right"  // move the icons\r
 493         // bind h "toggle sbar_hudselector; echo HUD $sbar_hudselector"  // change the HUD\r
 494 \r
 495         float kh_keys, kh_keys_status, kh_teams_set;\r
 496         float kh_margin_x, kh_margin_y, kh_key_box;\r
 497         string kh_carrying, kh_outline;\r
 498         vector red_pos, blue_pos, yellow_pos, pink_pos, kh_size;\r
 499         vector red, blue, yellow, pink;\r
 500 \r
 501         kh_keys = getstati(STAT_KH_KEYS);\r
 502         kh_keys_status = kh_keys / 256;\r
 503         kh_teams_set = cvar("_teams_available");  // set in keyhunt.qc\r
 504 \r
 505         kh_margin_y = 8;\r
 506         kh_margin_x = (cvar("sbar_flagstatus_right") * sbar_hudselector * (vid_conwidth - 67)) + 10;\r
 507 //      sbar_flagstatus_right 0/1; sbar_hudselector 0/1; screen width - key width + margin\r
 508 \r
 509         red_pos_x = blue_pos_x = yellow_pos_x = pink_pos_x = kh_margin_x;\r
 510 \r
 511         kh_key_box = 120;\r
 512 \r
 513         pink_pos_y = kh_margin_y + 0;  // top\r
 514         yellow_pos_y = kh_margin_y + kh_key_box;\r
 515         blue_pos_y = kh_margin_y + kh_key_box * 2;\r
 516         red_pos_y = kh_margin_y + kh_key_box * 3;  //bottom\r
 517 \r
 518         red = '1 0 0';\r
 519         blue = '0 0 1';\r
 520         yellow = '1 1 0';\r
 521         pink = '1 0 1';\r
 522 \r
 523         kh_size = '0 0 0';  // don't resize the image\r
 524 \r
 525         kh_carrying = "gfx/sb_kh_full";\r
 526         kh_outline = "gfx/sb_kh_outline";\r
 527 \r
 528 //      drawpic(vector position, string pic, vector size, vector rgb, float alpha, float flag)\r
 529 //      vector position = '0 0';  // 'x y' 0 0 (the origin) is the top left. X 0 - 799, Y 0 - 599\r
 530 \r
 531 //      vector size = '0 0';  // 'x y' changes the x & y dimensions. '0 0' gives the default pic size\r
 532 //      vector rgb = '0 0 0';  // 'r g b' range 0 - 1\r
 533 \r
 534         if (kh_keys_status & 1)  // red\r
 535                 drawpic (red_pos, kh_carrying, kh_size, red, 0.2, 0);  // show 20% alpha key\r
 536         else\r
 537                 drawpic (red_pos, kh_outline, kh_size, red, 0.4, 0);  // show key outline 40% alpha\r
 538 \r
 539         if (kh_keys & 1)\r
 540                 drawpic (red_pos, kh_carrying, kh_size, red, 1.0, 0);  // show solid key 100% alpha\r
 541 \r
 542 \r
 543         if (kh_keys_status & 2)  // blue\r
 544                 drawpic (blue_pos, kh_carrying, kh_size, blue, 0.2, 0);\r
 545         else\r
 546                 drawpic (blue_pos, kh_outline, kh_size, blue, 0.4, 0);\r
 547 \r
 548         if (kh_keys & 2)\r
 549                 drawpic (blue_pos, kh_carrying, kh_size, blue, 1.0, 0);\r
 550 \r
 551 \r
 552         if (kh_teams_set & 4)  // yellow\r
 553         {\r
 554                 if (kh_keys_status & 4)\r
 555                         drawpic (yellow_pos, kh_carrying, kh_size, yellow, 0.2, 0);\r
 556                 else\r
 557                         drawpic (yellow_pos, kh_outline, kh_size, yellow, 0.4, 0);\r
 558 \r
 559                 if (kh_keys & 4)\r
 560                         drawpic (yellow_pos, kh_carrying, kh_size, yellow, 1.0, 0);\r
 561         }\r
 562 \r
 563 \r
 564         if (kh_teams_set & 8)  // pink\r
 565         {\r
 566                 if (kh_keys_status & 8)\r
 567                         drawpic (pink_pos, kh_carrying, kh_size, pink, 0.2, 0);\r
 568                 else\r
 569                         drawpic (pink_pos, kh_outline, kh_size, pink, 0.4, 0);\r
 570 \r
 571                 if (kh_keys & 8)\r
 572                         drawpic (pink_pos, kh_carrying, kh_size, pink, 1.0, 0);\r
 573         }\r
 574 \r
 575 }\r
 576 \r
 577 // following vectors must be global to allow seamless switching between camera modes\r
 578 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;\r
 579 void CSQC_Demo_Camera()\r
 580 {\r
 581         float speed, attenuation, dimensions;\r
 582         vector tmp, delta;\r
 583 \r
 584         if( cvar("camera_reset") || !camera_mode )\r
 585         {\r
 586                 camera_offset = '0 0 0';\r
 587                 current_angles = '0 0 0';\r
 588                 camera_direction = '0 0 0';\r
 589                 camera_offset_z += 30;\r
 590                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);\r
 591                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);\r
 592                 current_origin = view_origin;\r
 593                 current_camera_offset  = camera_offset;\r
 594                 cvar_set("camera_reset", "0");\r
 595                 camera_mode = CAMERA_CHASE;\r
 596         }\r
 597 \r
 598         // Camera angles\r
 599         if( camera_roll )\r
 600                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");\r
 601 \r
 602         if(cvar("camera_look_player"))\r
 603         {\r
 604                 local vector dir;\r
 605                 local float n;\r
 606 \r
 607                 dir = normalize(view_origin - current_position);\r
 608                 n = mouse_angles_z;\r
 609                 mouse_angles = vectoangles(dir);\r
 610                 mouse_angles_x = mouse_angles_x * -1;\r
 611                 mouse_angles_z = n;\r
 612         }\r
 613         else\r
 614         {\r
 615                 tmp = getmousepos() * 0.1;\r
 616                 if(vlen(tmp)>cvar("camera_mouse_treshold"))\r
 617                 {\r
 618                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));\r
 619                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));\r
 620                 }\r
 621         }\r
 622 \r
 623         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;\r
 624         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;\r
 625         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;\r
 626         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;\r
 627 \r
 628         // Fix difference when angles don't have the same sign\r
 629         delta = '0 0 0';\r
 630         if(mouse_angles_y < -60 && current_angles_y > 60)\r
 631                 delta = '0 360 0';\r
 632         if(mouse_angles_y > 60 && current_angles_y < -60)\r
 633                 delta = '0 -360 0';\r
 634 \r
 635         if(cvar("camera_look_player"))\r
 636                 attenuation = cvar("camera_look_attenuation");\r
 637         else\r
 638                 attenuation = cvar("camera_speed_attenuation");\r
 639 \r
 640         attenuation = 1 / max(1, attenuation);\r
 641         current_angles += (mouse_angles - current_angles + delta) * attenuation;\r
 642 \r
 643         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;\r
 644         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;\r
 645         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;\r
 646         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;\r
 647 \r
 648         // Camera position\r
 649         tmp = '0 0 0';\r
 650         dimensions = 0;\r
 651 \r
 652         if( camera_direction_x )\r
 653         {\r
 654                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);\r
 655                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);\r
 656                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )\r
 657                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);\r
 658                 ++dimensions;\r
 659         }\r
 660 \r
 661         if( camera_direction_y )\r
 662         {\r
 663                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);\r
 664                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);\r
 665                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);\r
 666                 ++dimensions;\r
 667         }\r
 668 \r
 669         if( camera_direction_z )\r
 670         {\r
 671                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);\r
 672                 ++dimensions;\r
 673         }\r
 674 \r
 675         if(cvar("camera_free"))\r
 676                 speed = cvar("camera_speed_free");\r
 677         else\r
 678                 speed = cvar("camera_speed_chase");\r
 679 \r
 680         if(dimensions)\r
 681         {\r
 682                 speed = speed * sqrt(1 / dimensions);\r
 683                 camera_offset += tmp * speed;\r
 684         }\r
 685 \r
 686         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;\r
 687 \r
 688         // Camera modes\r
 689         if( cvar("camera_free") )\r
 690         {\r
 691                 if ( camera_mode == CAMERA_CHASE )\r
 692                 {\r
 693                         current_camera_offset = current_origin + current_camera_offset;\r
 694                         camera_offset = current_origin + camera_offset;\r
 695                 }\r
 696 \r
 697                 camera_mode = CAMERA_FREE;\r
 698                 current_position = current_camera_offset;\r
 699         }\r
 700         else\r
 701         {\r
 702                 if ( camera_mode == CAMERA_FREE )\r
 703                 {\r
 704                         current_origin = view_origin;\r
 705                         camera_offset = camera_offset - current_origin;\r
 706                         current_camera_offset = current_camera_offset - current_origin;\r
 707                 }\r
 708 \r
 709                 camera_mode = CAMERA_CHASE;\r
 710 \r
 711                 if(cvar("camera_chase_smoothly"))\r
 712                         current_origin += (view_origin - current_origin) * attenuation;\r
 713                 else\r
 714                         current_origin = view_origin;\r
 715 \r
 716                 current_position = current_origin + current_camera_offset;\r
 717         }\r
 718 \r
 719         R_SetView(VF_ANGLES, current_angles);\r
 720         R_SetView(VF_ORIGIN, current_position);\r
 721 }\r