data/qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/spiderbot/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/spiderbot/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 entity porto;
   9 vector polyline[16];
  10 float trace_dphitcontents;
  11 float trace_networkentity;
  12 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  13 float DPCONTENTS_SOLID = 1; // blocks player movement
  14 float DPCONTENTS_BODY = 32; // blocks player movement
  15 float DPCONTENTS_CORPSE = 64; // blocks player movement
  16 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  17 void Porto_Draw()
  18 {
  19         vector p, dir, ang, q, nextdir;
  20         float idx, portal_number, portal1_idx;
  21
  22         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  23                 return;
  24         if(intermission == 1)
  25                 return;
  26         if(intermission == 2)
  27                 return;
  28         if (getstati(STAT_HEALTH) <= 0)
  29                 return;
  30
  31         dir = view_forward;
  32
  33         if(angles_held_status)
  34         {
  35                 makevectors(angles_held);
  36                 dir = v_forward;
  37         }
  38
  39         p = view_origin;
  40
  41         polyline[0] = p;
  42         idx = 1;
  43         portal_number = 0;
  44         nextdir = dir;
  45
  46         for(;;)
  47         {
  48                 dir = nextdir;
  49                 traceline(p, p + 65536 * dir, TRUE, porto);
  50                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  51                         return;
  52                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  53                 p = trace_endpos;
  54                 polyline[idx] = p;
  55                 ++idx;
  56                 if(idx >= 16)
  57                         return;
  58                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  59                         continue;
  60                 ++portal_number;
  61                 ang = vectoangles2(trace_plane_normal, dir);
  62                 ang_x = -ang_x;
  63                 makevectors(ang);
  64                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  65                         return;
  66                 if(portal_number == 1)
  67                         portal1_idx = idx;
  68                 if(portal_number >= 2)
  69                         break;
  70         }
  71
  72         while(idx >= 2)
  73         {
  74                 p = polyline[idx-2];
  75                 q = polyline[idx-1];
  76                 if(idx == 2)
  77                         p = p - view_up * 16;
  78                 if(idx-1 >= portal1_idx)
  79                 {
  80                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);
  81                 }
  82                 else
  83                 {
  84                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);
  85                 }
  86                 --idx;
  87         }
  88 }
  89
  90 /**
  91  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  92  *
  93  * TODO: Use a better solution where a common shared entitiy is used that contains
  94  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  95  * and STAT_FRAGLIMIT to be auto-sent)
  96  */
  97 void CheckForGamestartChange() {
  98         float startTime;
  99         startTime = getstatf(STAT_GAMESTARTTIME);
 100         if (previous_game_starttime != startTime) {
 101                 if ((time + 5.0) < startTime) {
 102                         //if connecting to server while restart was active don't always play prepareforbattle
 103                         sound(self, CHAN_VOICE, "announcer/robotic/prepareforbattle.wav", VOL_BASEVOICE, ATTN_NONE);
 104                 }
 105                 if (time < startTime) {
 106                         restartAnnouncer = spawn();
 107                         restartAnnouncer.think = restartAnnouncer_Think;
 108                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 109                 }
 110         }
 111         previous_game_starttime = startTime;
 112 }
 113
 114 void Porto_Init()
 115 {
 116         porto = spawn();
 117         porto.classname = "porto";
 118         porto.draw = Porto_Draw;
 119         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 120 }
 121
 122 float drawtime;
 123
 124 float tan(float x)
 125 {
 126         return sin(x) / cos(x);
 127 }
 128 float atan2(float y, float x)
 129 {
 130         vector v;
 131         v = '1 0 0' * x + '0 1 0' * y;
 132         v = vectoangles(v);
 133         return v_y * 0.01745329251994329576;
 134 }
 135
 136 vector GetCurrentFov(float fov)
 137 {
 138         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 139
 140         zoomsensitivity = cvar("cl_zoomsensitivity");
 141         zoomfactor = cvar("cl_zoomfactor");
 142         if(zoomfactor < 1 || zoomfactor > 16)
 143                 zoomfactor = 2.5;
 144         zoomspeed = cvar("cl_zoomspeed");
 145         if(zoomspeed >= 0)
 146                 if(zoomspeed < 0.5 || zoomspeed > 16)
 147                         zoomspeed = 3.5;
 148
 149         zoomdir = button_zoom;
 150         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here
 151                 zoomdir += button_attack2;
 152         if(spectatee_status > 0 || isdemo())
 153         {
 154                 if(spectatorbutton_zoom)
 155                         zoomdir = 0 + !zoomdir;
 156                         // do not even THINK about removing this 0
 157                         // _I_ know what I am doing
 158                         // fteqcc does not
 159         }
 160
 161         if(zoomdir)
 162                 zoomin_effect = 0;
 163
 164         if(zoomin_effect || camera_active)
 165         {
 166                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 167         }
 168         else
 169         {
 170                 if(zoomspeed < 0) // instant zoom
 171                 {
 172                         if(zoomdir)
 173                                 current_viewzoom = 1 / zoomfactor;
 174                         else
 175                                 current_viewzoom = 1;
 176                 }
 177                 else
 178                 {
 179                         if(zoomdir)
 180                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 181                         else
 182                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 183                 }
 184         }
 185
 186         if(almost_equals(current_viewzoom, 1))
 187                 current_zoomfraction = 0;
 188         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 189                 current_zoomfraction = 1;
 190         else
 191                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 192
 193         if(zoomsensitivity < 1)
 194                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 195         else
 196                 setsensitivityscale(1);
 197
 198         float frustumx, frustumy, fovx, fovy;
 199         frustumy = tan(fov * 0.00872664625997164788) * 0.75 * current_viewzoom;
 200         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 201         fovx = atan2(frustumx, 1) / 0.00872664625997164788;
 202         fovy = atan2(frustumy, 1) / 0.00872664625997164788;
 203
 204         return '1 0 0' * fovx + '0 1 0' * fovy;
 205 }
 206
 207 // this function must match W_SetupShot!
 208 float zoomscript_caught;
 209
 210 vector wcross_origin;
 211 entity trueaim;
 212
 213 #define SHOTTYPE_HITTEAM 1
 214 #define SHOTTYPE_HITOBSTRUCTION 2
 215 #define SHOTTYPE_HITWORLD 3
 216 #define SHOTTYPE_HITENEMY 4
 217
 218 void TrueAim_Init()
 219 {
 220         trueaim = spawn();
 221         trueaim.classname = "trueaim";
 222         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 223 }
 224
 225 float EnemyHitCheck()
 226 {
 227         float t;
 228         wcross_origin = project_3d_to_2d(trace_endpos);
 229         wcross_origin_z = 0;
 230         if(trace_networkentity < 1)
 231                 return SHOTTYPE_HITWORLD;
 232         if(trace_networkentity > maxclients)
 233                 return SHOTTYPE_HITWORLD;
 234         t = GetPlayerColor(trace_networkentity - 1);
 235         if(teamplay)
 236         if(t == myteam)
 237                 return SHOTTYPE_HITTEAM;
 238         if(t == COLOR_SPECTATOR)
 239                 return SHOTTYPE_HITWORLD;
 240         return SHOTTYPE_HITENEMY;
 241 }
 242
 243 float TrueAimCheck()
 244 {
 245         float nudge = 1; // added to traceline target and subtracted from result
 246         vector vecs, trueaimpoint, w_shotorg;
 247         vector mi, ma, dv;
 248         float shottype;
 249
 250         mi = ma = '0 0 0';
 251
 252         switch(activeweapon)
 253         {
 254                 case WEP_TUBA: // no aim
 255                 case WEP_PORTO: // shoots from eye
 256                 case WEP_HOOK: // no trueaim
 257                 case WEP_GRENADE_LAUNCHER: // toss curve
 258                         return SHOTTYPE_HITWORLD;
 259                 case WEP_CAMPINGRIFLE:
 260                         if(zoomscript_caught)
 261                         {
 262                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, trueaim);
 263                                 return EnemyHitCheck();
 264                         }
 265                         break;
 266                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 267                         mi = '-3 -3 -3';
 268                         ma = '3 3 3';
 269                         break;
 270                 case WEP_FIREBALL: // projectile has a size!
 271                         mi = '-16 -16 -16';
 272                         ma = '16 16 16';
 273                         break;
 274                 case WEP_ELECTRO: // projectile has a size!
 275                         mi = '0 0 -3';
 276                         ma = '0 0 -3';
 277                         break;
 278         }
 279
 280         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 281
 282         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, trueaim);
 283         trueaimpoint = trace_endpos;
 284
 285         if(vecs_x > 0)
 286                 vecs_y = -vecs_y;
 287         else
 288                 vecs = '0 0 0';
 289
 290         dv = view_right * vecs_y + view_up * vecs_z;
 291         w_shotorg = view_origin + dv;
 292
 293         // now move the vecs forward as much as requested if possible
 294         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, trueaim); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 295         w_shotorg = trace_endpos - view_forward * nudge;
 296
 297         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, trueaim);
 298         shottype = EnemyHitCheck();
 299         if(shottype != SHOTTYPE_HITWORLD)
 300                 return shottype;
 301
 302 #if 0
 303         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 304         // or rather, I know why, but see no fix
 305         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 306                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 307                 return SHOTTYPE_HITOBSTRUCTION;
 308 #endif
 309
 310         return SHOTTYPE_HITWORLD;
 311 }
 312
 313 void CSQC_common_hud(void);
 314
 315 void CSQC_kh_hud(void);
 316 void CSQC_ctf_hud(void);
 317 void PostInit(void);
 318 void CSQC_Demo_Camera();
 319 float Sbar_WouldDrawScoreboard ();
 320 float view_set;
 321 float camera_mode;
 322 string NextFrameCommand;
 323 void CSQC_spider_HUD();
 324 void CSQC_UpdateView(float w, float h)
 325 {
 326         entity e;
 327         float fov;
 328         float f, i, j;
 329         vector v;
 330
 331         dprint_load();
 332         WaypointSprite_Load();
 333
 334         if(spectatee_status)
 335                 myteam = GetPlayerColor(spectatee_status - 1);
 336         else
 337                 myteam = GetPlayerColor(player_localentnum - 1);
 338
 339         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 340
 341         // Render the Scene
 342         if(!intermission || !view_set)
 343         {
 344                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);
 345                 view_angles = input_angles;
 346                 makevectors(view_angles);
 347                 view_forward = v_forward;
 348                 view_right = v_right;
 349                 view_up = v_up;
 350                 view_set = 1;
 351         }
 352
 353         vid_width = w;
 354         vid_height = h;
 355
 356 #ifdef BLURTEST
 357         if(time > blurtest_time0 && time < blurtest_time1)
 358         {
 359                 float r, t;
 360
 361                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 362                 r = t * blurtest_radius;
 363                 f = 1 / pow(t, blurtest_power) - 1;
 364
 365                 cvar_set("r_glsl_postprocess", "1");
 366                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 367         }
 368         else
 369         {
 370                 cvar_set("r_glsl_postprocess", "0");
 371                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 372         }
 373 #endif
 374
 375         Fog_Force();
 376
 377         drawframetime = max(0.000001, time - drawtime);
 378         drawtime = time;
 379
 380         // watch for gametype changes here...
 381         // in ParseStuffCMD the cmd isn't executed yet :/
 382         // might even be better to add the gametype to TE_CSQC_INIT...?
 383         if(!postinit)
 384                 PostInit();
 385
 386         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 387         if(calledhooks & HOOK_START)
 388         {
 389                 localcmd("\ncl_hook_gameend;");
 390                 calledhooks |= HOOK_END;
 391         }
 392
 393         CheckForGamestartChange();
 394         maptimeAnnouncer();
 395
 396         fov = cvar("fov");
 397         if(button_zoom || fov <= 59.5)
 398         {
 399                 if(!zoomscript_caught)
 400                 {
 401                         localcmd("+button4\n");
 402                         zoomscript_caught = 1;
 403                         ignore_plus_zoom += 1;
 404                 }
 405         }
 406         else
 407         {
 408                 if(zoomscript_caught)
 409                 {
 410                         localcmd("-button4\n");
 411                         zoomscript_caught = 0;
 412                         ignore_minus_zoom += 1;
 413                 }
 414         }
 415
 416         sbar_alpha_fg = cvar("sbar_alpha_fg" ) * (1 - cvar("_menu_alpha"));
 417         sbar_currentammo = cvar("sbar_showcurrentammo");
 418         sbar_hudselector = cvar("sbar_hudselector");
 419         sbar_hud_accuracy = cvar("sbar_hud_accuracy");
 420         ColorTranslateMode = cvar("cl_stripcolorcodes");
 421         activeweapon = getstati(STAT_SWITCHWEAPON);
 422         f = cvar("teamplay");
 423         if(f != teamplay)
 424         {
 425                 teamplay = f;
 426                 Sbar_InitScores();
 427         }
 428
 429         if(last_weapon != activeweapon) {
 430                 weapontime = time;
 431                 last_weapon = activeweapon;
 432         }
 433
 434         // ALWAYS Clear Current Scene First
 435         R_ClearScene();
 436
 437         // Assign Standard Viewflags
 438         // Draw the World (and sky)
 439         R_SetView(VF_DRAWWORLD, 1);
 440
 441         // Set the console size vars
 442         vid_conwidth = cvar("vid_conwidth");
 443         vid_conheight = cvar("vid_conheight");
 444         vid_pixelheight = cvar("vid_pixelheight");
 445
 446         R_SetView(VF_FOV, GetCurrentFov(fov));
 447
 448         // Camera for demo playback
 449         if(camera_active)
 450         {
 451                 if(cvar("camera_enable"))
 452                         CSQC_Demo_Camera();
 453                 else
 454                 {
 455                         cvar_set("chase_active", ftos(chase_active_backup));
 456                         cvar_set("cl_demo_mousegrab", "0");
 457                         camera_active = FALSE;
 458                 }
 459         }
 460 #ifdef CAMERATEST
 461         else if(cvar("camera_enable"))
 462 #else
 463         else if(cvar("camera_enable") && isdemo())
 464 #endif
 465         {
 466                 // Enable required Darkplaces cvars
 467                 chase_active_backup = cvar("chase_active");
 468                 cvar_set("chase_active", "2");
 469                 cvar_set("cl_demo_mousegrab", "1");
 470                 camera_active = TRUE;
 471                 camera_mode = FALSE;
 472         }
 473
 474         // Draw the Crosshair
 475         float scoreboard_active;
 476         scoreboard_active = Sbar_WouldDrawScoreboard();
 477         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 478
 479         // Draw the Engine Status Bar (the default Quake HUD)
 480         R_SetView(VF_DRAWENGINESBAR, 0);
 481
 482         // fetch this one only once per frame
 483         sbar_showbinds = cvar("sbar_showbinds");
 484         sbar_showbinds_limit = cvar("sbar_showbinds_limit");
 485
 486         // Update the mouse position
 487         /*
 488         mousepos_x = vid_conwidth;
 489         mousepos_y = vid_conheight;
 490         mousepos = mousepos*0.5 + getmousepos();
 491         */
 492
 493         e = self;
 494         for(self = world; (self = nextent(self)); )
 495                 if(self.draw)
 496                         self.draw();
 497         self = e;
 498
 499         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 500         R_RenderScene();
 501
 502         // now switch to 2D drawing mode by calling a 2D drawing function
 503         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 504         // next R_RenderScene call
 505         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 506
 507         // Draw the mouse cursor
 508         // NOTE: drawpic must happen after R_RenderScene for some reason
 509         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 510         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 511         //self = edict_num(player_localnum);
 512         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 513         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 514         // as long as the ctf part isn't in, this is useless
 515         if(menu_visible)
 516                 menu_show();
 517
 518         /*if(gametype == GAME_CTF)
 519         {
 520                 ctf_view();
 521         } else */
 522
 523         // draw 2D entities
 524         e = self;
 525         for(self = world; (self = nextent(self)); )
 526                 if(self.draw2d)
 527                         self.draw2d();
 528         self = e;
 529
 530         // draw radar
 531         if(
 532                 ons_showmap
 533                 ||
 534                 (
 535                         !scoreboard_active
 536                         &&
 537                         cvar_string("cl_teamradar") != "0"
 538                         &&
 539                         (
 540                                 cvar("cl_teamradar") == 2
 541                                 ||
 542                                 teamplay
 543                         )
 544                 )
 545         )
 546                 teamradar_view();
 547
 548         // draw sbar
 549         if(cvar("r_letterbox") == 0) {
 550                 if (cvar("cl_showpressedkeys")) { // draw pressed keys when spectating and playing
 551                         if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)
 552                                 Sbar_DrawPressedKeys();
 553                 }
 554
 555                 if (cvar("cl_showspeed"))
 556                         Sbar_ShowSpeed();
 557
 558                 Sbar_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120
 559         }
 560
 561     float hud;
 562     hud = getstati(STAT_HUD);
 563     if(hud == HUD_SPIDERBOT)
 564     {
 565         vector sz;
 566         CSQC_spider_HUD();
 567         sz = drawgetimagesize(SPIDER_CROSS);
 568         sz_x *= cvar_or("cl_vehicle_spiderbot_cross_size",1);
 569         sz_y *= cvar_or("cl_vehicle_spiderbot_cross_size",1);
 570         drawpic('0.5 0 0' * (vid_conwidth - sz_x) + '0 0.5 0' * (vid_conheight - sz_y), SPIDER_CROSS, sz, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 571     }
 572     else
 573     {
 574         if(cvar("r_letterbox") == 0)
 575             if(cvar("viewsize") < 120)
 576                 CSQC_common_hud();
 577
 578         // crosshair goes VERY LAST
 579         if(!scoreboard_active && !ons_showmap && !camera_active) {
 580                         // TrueAim check
 581                         float shottype;
 582                         float bullets, ring_scale;
 583                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 584                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 585                         wcross_origin_z = 0;
 586             if(cvar("crosshair_hittest"))
 587                         {
 588                                 vector wcross_oldorigin;
 589                                 wcross_oldorigin = wcross_origin;
 590                 shottype = TrueAimCheck();
 591                                 if(shottype == SHOTTYPE_HITWORLD)
 592                                 {
 593                                         v = wcross_origin - wcross_oldorigin;
 594                                         v_x /= vid_conwidth;
 595                                         v_y /= vid_conheight;
 596                                         if(vlen(v) > 0.01)
 597                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 598                                 }
 599                                 if(!cvar("crosshair_hittest_showimpact"))
 600                                         wcross_origin = wcross_oldorigin;
 601                         }
 602             else
 603                 shottype = SHOTTYPE_HITWORLD;
 604
 605             string wcross_style;
 606             wcross_style = cvar_string("crosshair");
 607
 608             if (wcross_style != "0") {
 609                 vector wcross_color, wcross_size;
 610                 string wcross_wep, wcross_name;
 611                 float wcross_alpha, wcross_sizefloat;
 612
 613                 wcross_color_x = cvar("crosshair_color_red");
 614                 wcross_color_y = cvar("crosshair_color_green");
 615                 wcross_color_z = cvar("crosshair_color_blue");
 616                 wcross_alpha = cvar("crosshair_color_alpha") * (1-cvar("_menu_alpha"));
 617                 wcross_sizefloat = cvar("crosshair_size") * (1-cvar("_menu_alpha"));
 618                 if (cvar("crosshair_per_weapon")) {
 619                     e = get_weaponinfo(activeweapon);
 620                     if (e && e.netname != "")
 621                     {
 622                         wcross_wep = e.netname;
 623                         wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 624                         if(wcross_style == "")
 625                             wcross_style = e.netname;
 626
 627                         if(!cvar("crosshair_color_override"))
 628                         {
 629                             wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 630                             wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 631                             wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 632                         }
 633
 634                         wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 635                         wcross_sizefloat *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 636                     }
 637                 }
 638
 639                 wcross_name = strcat("gfx/crosshair", wcross_style);
 640
 641                                 if(shottype == SHOTTYPE_HITENEMY)
 642                                         wcross_sizefloat *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 643                                 if(shottype == SHOTTYPE_HITTEAM)
 644                                         wcross_sizefloat /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 645
 646                 wcross_size = drawgetimagesize(wcross_name);
 647                 wcross_size_x *= wcross_sizefloat;
 648                 wcross_size_y *= wcross_sizefloat;
 649
 650                                 // ring around crosshair representing bullets left in camping rifle clip
 651                                 if (activeweapon == WEP_CAMPINGRIFLE)
 652                                 {
 653                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 654                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 8);
 655                                 }
 656                                 else
 657                                         bullets = 0;
 658
 659                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 660                 {
 661                     wcross_alpha *= 0.04 * 0.75;
 662                     for(i = -2; i <= 2; ++i)
 663                         for(j = -2; j <= 2; ++j)
 664                                                 {
 665                                                         if (bullets)
 666                                                                 drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x * ring_scale + i) - '0 0.5 0' * (wcross_size_y * ring_scale + j), strcat("gfx/hud/rifle_ring_", ftos(bullets)), wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 667                             drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x + i) - '0 0.5 0' * (wcross_size_y + j), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 668                                                 }
 669                 }
 670                 else
 671                 {
 672                                         if (bullets)
 673                                                 drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x * ring_scale) - '0 0.5 0' * (wcross_size_y * ring_scale), strcat("gfx/hud/rifle_ring_", ftos(bullets)), wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 674                     drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x) - '0 0.5 0' * ( wcross_size_y), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 675                 }
 676             }
 677         }
 678     }
 679
 680         if(NextFrameCommand)
 681         {
 682                 localcmd("\n", NextFrameCommand, "\n");
 683                 NextFrameCommand = string_null;
 684         }
 685
 686         // we must do this check AFTER a frame was rendered, or it won't work
 687         if(cs_project_is_b0rked == 0)
 688         {
 689                 string w0, h0;
 690                 w0 = cvar_string("vid_conwidth");
 691                 h0 = cvar_string("vid_conheight");
 692                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 693                 //R_SetView(VF_FOV, '90 90 0');
 694                 R_SetView(VF_ORIGIN, '0 0 0');
 695                 R_SetView(VF_ANGLES, '0 0 0');
 696                 R_SetView(VF_PERSPECTIVE, 1);
 697                 makevectors('0 0 0');
 698                 vector v1, v2;
 699                 cvar_set("vid_conwidth", "800");
 700                 cvar_set("vid_conheight", "600");
 701                 v1 = cs_project(v_forward);
 702                 cvar_set("vid_conwidth", "640");
 703                 cvar_set("vid_conheight", "480");
 704                 v2 = cs_project(v_forward);
 705                 if(v1 == v2)
 706                         cs_project_is_b0rked = 1;
 707                 else
 708                         cs_project_is_b0rked = -1;
 709                 cvar_set("vid_conwidth", w0);
 710                 cvar_set("vid_conheight", h0);
 711         }
 712 }
 713
 714 void Sbar_Draw();
 715 void CSQC_spider_HUD()
 716 {
 717     float rockets,reload,heat,hp,shield,i;
 718     vector p,pp;
 719
 720     rockets = getstati(STAT_SPIDERBOT_ROCKETS);
 721     heat    = min(getstatf(STAT_SPIDERBOT_HEAT),1);
 722     reload  = min(getstatf(STAT_SPIDERBOT_RELOAD),1);
 723     hp      = min(getstatf(STAT_SPIDERBOT_HEALTH),1);
 724     shield  = min(getstatf(STAT_SPIDERBOT_SHIELD),1);
 725
 726     // Draw health bar
 727     p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 728     p = p + '0 1 0' * vid_conheight - '0 32 0';
 729     //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
 730     drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
 731     p_y += 8;
 732     drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
 733     p_x += 256 * hp;
 734     drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 735
 736     // Draw minigun heat indicator
 737     p = '0.5 0 0' * (vid_conwidth - 256);
 738     p = p + '0 1 0' * vid_conheight - '0 34  0';
 739     drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 740     p_x += 256 * (1-heat);
 741     drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 742
 743     // Draw rocket icons for loaded/empty tubes.
 744     pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 745     pp += '0 1 0' * vid_conheight - '0 64 0';
 746     for(i = 0; i < 8; ++i)
 747     {
 748         p = pp + '1 0 0' * (rkt_size * i);
 749         if(rockets == 8)
 750         {
 751             if(floor(reload * 8) == i)
 752             {
 753                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
 754             }
 755             else if(i < reload * 8)
 756                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
 757             else
 758                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
 759         }
 760         else
 761         {
 762             if(i < rockets)
 763                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
 764             else
 765                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
 766         }
 767     }
 768
 769         if (sb_showscores)
 770         {
 771                 Sbar_DrawScoreboard();
 772                 Sbar_DrawCenterPrint();
 773         }
 774
 775 }
 776 void CSQC_common_hud(void)
 777 {
 778
 779         // Sbar_SortFrags(); done in Sbar_Draw
 780     float hud;
 781     hud = getstati(STAT_HUD);
 782
 783     //hud = 10;
 784     switch(hud)
 785     {
 786         case HUD_NORMAL:
 787             Sbar_Draw();
 788             break;
 789
 790         case HUD_SPIDERBOT:
 791             CSQC_spider_HUD();
 792             break;
 793     }
 794 }
 795
 796
 797 // following vectors must be global to allow seamless switching between camera modes
 798 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
 799 void CSQC_Demo_Camera()
 800 {
 801         float speed, attenuation, dimensions;
 802         vector tmp, delta;
 803
 804         if( cvar("camera_reset") || !camera_mode )
 805         {
 806                 camera_offset = '0 0 0';
 807                 current_angles = '0 0 0';
 808                 camera_direction = '0 0 0';
 809                 camera_offset_z += 30;
 810                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
 811                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
 812                 current_origin = view_origin;
 813                 current_camera_offset  = camera_offset;
 814                 cvar_set("camera_reset", "0");
 815                 camera_mode = CAMERA_CHASE;
 816         }
 817
 818         // Camera angles
 819         if( camera_roll )
 820                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
 821
 822         if(cvar("camera_look_player"))
 823         {
 824                 local vector dir;
 825                 local float n;
 826
 827                 dir = normalize(view_origin - current_position);
 828                 n = mouse_angles_z;
 829                 mouse_angles = vectoangles(dir);
 830                 mouse_angles_x = mouse_angles_x * -1;
 831                 mouse_angles_z = n;
 832         }
 833         else
 834         {
 835                 tmp = getmousepos() * 0.1;
 836                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
 837                 {
 838                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
 839                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
 840                 }
 841         }
 842
 843         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
 844         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
 845         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
 846         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
 847
 848         // Fix difference when angles don't have the same sign
 849         delta = '0 0 0';
 850         if(mouse_angles_y < -60 && current_angles_y > 60)
 851                 delta = '0 360 0';
 852         if(mouse_angles_y > 60 && current_angles_y < -60)
 853                 delta = '0 -360 0';
 854
 855         if(cvar("camera_look_player"))
 856                 attenuation = cvar("camera_look_attenuation");
 857         else
 858                 attenuation = cvar("camera_speed_attenuation");
 859
 860         attenuation = 1 / max(1, attenuation);
 861         current_angles += (mouse_angles - current_angles + delta) * attenuation;
 862
 863         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
 864         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
 865         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
 866         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
 867
 868         // Camera position
 869         tmp = '0 0 0';
 870         dimensions = 0;
 871
 872         if( camera_direction_x )
 873         {
 874                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
 875                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
 876                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
 877                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
 878                 ++dimensions;
 879         }
 880
 881         if( camera_direction_y )
 882         {
 883                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
 884                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
 885                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
 886                 ++dimensions;
 887         }
 888
 889         if( camera_direction_z )
 890         {
 891                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
 892                 ++dimensions;
 893         }
 894
 895         if(cvar("camera_free"))
 896                 speed = cvar("camera_speed_free");
 897         else
 898                 speed = cvar("camera_speed_chase");
 899
 900         if(dimensions)
 901         {
 902                 speed = speed * sqrt(1 / dimensions);
 903                 camera_offset += tmp * speed;
 904         }
 905
 906         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
 907
 908         // Camera modes
 909         if( cvar("camera_free") )
 910         {
 911                 if ( camera_mode == CAMERA_CHASE )
 912                 {
 913                         current_camera_offset = current_origin + current_camera_offset;
 914                         camera_offset = current_origin + camera_offset;
 915                 }
 916
 917                 camera_mode = CAMERA_FREE;
 918                 current_position = current_camera_offset;
 919         }
 920         else
 921         {
 922                 if ( camera_mode == CAMERA_FREE )
 923                 {
 924                         current_origin = view_origin;
 925                         camera_offset = camera_offset - current_origin;
 926                         current_camera_offset = current_camera_offset - current_origin;
 927                 }
 928
 929                 camera_mode = CAMERA_CHASE;
 930
 931                 if(cvar("camera_chase_smoothly"))
 932                         current_origin += (view_origin - current_origin) * attenuation;
 933                 else
 934                         current_origin = view_origin;
 935
 936                 current_position = current_origin + current_camera_offset;
 937         }
 938
 939         R_SetView(VF_ANGLES, current_angles);
 940         R_SetView(VF_ORIGIN, current_position);
 941 }