data/qcsrc/client/View.qc

   1 entity porto;\r
   2 vector polyline[16];\r
   3 float trace_dphitcontents;\r
   4 float Q3SURFACEFLAG_SLICK = 2; // low friction surface\r
   5 float DPCONTENTS_SOLID = 1; // blocks player movement\r
   6 float DPCONTENTS_BODY = 32; // blocks player movement\r
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement\r
   8 void Porto_Draw()\r
   9 {\r
  10         vector p, dir, ang, q, nextdir;\r
  11         float idx, portal_number, portal1_idx;\r
  12 \r
  13         if(activeweapon != WEP_PORTO)\r
  14                 return;\r
  15 \r
  16         dir = view_forward;\r
  17 \r
  18         if(angles_held_status)\r
  19         {\r
  20                 makevectors(angles_held);\r
  21                 dir = v_forward;\r
  22         }\r
  23 \r
  24         p = view_origin;\r
  25 \r
  26         polyline[0] = p;\r
  27         idx = 1;\r
  28         portal_number = 0;\r
  29         nextdir = dir;\r
  30 \r
  31         for(;;)\r
  32         {\r
  33                 dir = nextdir;\r
  34                 traceline(p, p + 65536 * dir, TRUE, porto);\r
  35                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)\r
  36                         return;\r
  37                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal\r
  38                 p = trace_endpos;\r
  39                 polyline[idx] = p;\r
  40                 ++idx;\r
  41                 if(idx >= 16)\r
  42                         return;\r
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)\r
  44                         continue;\r
  45                 ++portal_number;\r
  46                 ang = vectoangles2(trace_plane_normal, dir);\r
  47                 ang_x = -ang_x;\r
  48                 makevectors(ang);\r
  49                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))\r
  50                         return;\r
  51                 if(portal_number == 1)\r
  52                         portal1_idx = idx;\r
  53                 if(portal_number >= 2)\r
  54                         break;\r
  55         }\r
  56 \r
  57         while(idx >= 2)\r
  58         {\r
  59                 p = polyline[idx-2];\r
  60                 q = polyline[idx-1];\r
  61                 if(idx == 2)\r
  62                         p = p - view_up * 16;\r
  63                 if(idx-1 >= portal1_idx)\r
  64                 {\r
  65                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);\r
  66                 }\r
  67                 else\r
  68                 {\r
  69                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);\r
  70                 }\r
  71                 --idx;\r
  72         }\r
  73 }\r
  74 \r
  75 /**\r
  76  * Checks whether the server initiated a map restart (stat_game_starttime changed)\r
  77  *\r
  78  * TODO: Use a better solution where a common shared entitiy is used that contains\r
  79  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT\r
  80  * and STAT_FRAGLIMIT to be auto-sent)\r
  81  */\r
  82 void CheckForGamestartChange() {\r
  83         float startTime;\r
  84         startTime = getstatf(STAT_GAMESTARTTIME);\r
  85         if (previous_game_starttime != startTime) {\r
  86                 if ((time + 5.0) < startTime) {\r
  87                         //if connecting to server while restart was active don't always play prepareforbattle\r
  88                         sound(self, CHAN_VOICE, "announcer/robotic/prepareforbattle.wav", VOL_BASEVOICE, ATTN_NONE);\r
  89                 }\r
  90                 if (time < startTime) {\r
  91                         restartAnnouncer = spawn();\r
  92                         restartAnnouncer.think = restartAnnouncer_Think;\r
  93                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime\r
  94                 }\r
  95         }\r
  96         previous_game_starttime = startTime;\r
  97 }\r
  98 \r
  99 void Porto_Init()\r
 100 {\r
 101         porto = spawn();\r
 102         porto.classname = "porto";\r
 103         porto.draw = Porto_Draw;\r
 104         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;\r
 105 }\r
 106 \r
 107 float drawtime;\r
 108 \r
 109 float tan(float x)\r
 110 { \r
 111         return sin(x) / cos(x);\r
 112 }\r
 113 float atan2(float y, float x)\r
 114 {\r
 115         vector v;\r
 116         v = '1 0 0' * x + '0 1 0' * y;\r
 117         v = vectoangles(v);\r
 118         return v_y * 0.01745329251994329576;\r
 119 }\r
 120 \r
 121 vector GetCurrentFov(float fov)\r
 122 {\r
 123         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;\r
 124 \r
 125         zoomsensitivity = cvar("cl_zoomsensitivity");\r
 126         zoomfactor = cvar("cl_zoomfactor");\r
 127         if(zoomfactor < 1 || zoomfactor > 16)\r
 128                 zoomfactor = 2.5;\r
 129         zoomspeed = cvar("cl_zoomspeed");\r
 130         if(zoomspeed >= 0)\r
 131                 if(zoomspeed < 0.5 || zoomspeed > 16)\r
 132                         zoomspeed = 3.5;\r
 133 \r
 134         zoomdir = button_zoom;\r
 135         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here\r
 136                 zoomdir += button_attack2;\r
 137         if(spectatee_status > 0 || isdemo())\r
 138         {\r
 139                 if(spectatorbutton_zoom)\r
 140                         zoomdir = 0 + !zoomdir;\r
 141                         // do not even THINK about removing this 0\r
 142                         // _I_ know what I am doing\r
 143                         // fteqcc does not\r
 144         }\r
 145 \r
 146         if(zoomdir)\r
 147                 zoomin_effect = 0;\r
 148 \r
 149         if(zoomin_effect || camera_active)\r
 150         {\r
 151                 current_viewzoom = min(1, current_viewzoom + drawframetime);\r
 152         }\r
 153         else\r
 154         {\r
 155                 if(zoomspeed < 0) // instant zoom\r
 156                 {\r
 157                         if(zoomdir)\r
 158                                 current_viewzoom = 1 / zoomfactor;\r
 159                         else\r
 160                                 current_viewzoom = 1;\r
 161                 }\r
 162                 else\r
 163                 {\r
 164                         if(zoomdir)\r
 165                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);\r
 166                         else\r
 167                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);\r
 168                 }\r
 169         }\r
 170 \r
 171         if(almost_equals(current_viewzoom, 1))\r
 172                 current_zoomfraction = 0;\r
 173         else if(almost_equals(current_viewzoom, 1/zoomfactor))\r
 174                 current_zoomfraction = 1;\r
 175         else\r
 176                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);\r
 177 \r
 178         if(zoomsensitivity < 1)\r
 179                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));\r
 180         else\r
 181                 setsensitivityscale(1);\r
 182 \r
 183         float frustumx, frustumy, fovx, fovy;\r
 184         frustumy = tan(fov * 0.00872664625997164788) * 0.75 * current_viewzoom;\r
 185         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;\r
 186         fovx = atan2(frustumx, 1) / 0.00872664625997164788;\r
 187         fovy = atan2(frustumy, 1) / 0.00872664625997164788;\r
 188 \r
 189         return '1 0 0' * fovx + '0 1 0' * fovy;\r
 190 }\r
 191 \r
 192 void CSQC_common_hud(void);\r
 193 \r
 194 void CSQC_kh_hud(void);\r
 195 void CSQC_ctf_hud(void);\r
 196 void PostInit(void);\r
 197 void CSQC_Demo_Camera();\r
 198 float Sbar_WouldDrawScoreboard ();\r
 199 float zoomscript_caught;\r
 200 float view_set;\r
 201 float camera_mode;\r
 202 string NextFrameCommand;\r
 203 void CSQC_UpdateView(float w, float h)\r
 204 {\r
 205         entity e;\r
 206         float fov;\r
 207         float f;\r
 208 \r
 209         dprint_load();\r
 210         WaypointSprite_Load();\r
 211 \r
 212         ticrate = getstatf(STAT_SYS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);\r
 213 \r
 214         // Render the Scene\r
 215         if(!intermission || !view_set)\r
 216         {\r
 217                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);\r
 218                 view_angles = input_angles;\r
 219                 makevectors(view_angles);\r
 220                 view_forward = v_forward;\r
 221                 view_right = v_right;\r
 222                 view_up = v_up;\r
 223                 view_set = 1;\r
 224         }\r
 225 \r
 226         if(csqc_flags & CSQC_FLAG_COLORCODES)\r
 227         {\r
 228                 // supporting engine\r
 229                 vid_width = w;\r
 230                 vid_height = h;\r
 231         }\r
 232         else\r
 233         {\r
 234                 // non-supporting engine\r
 235                 vid_width = cvar("vid_width");\r
 236                 vid_height = cvar("vid_height");\r
 237         }\r
 238 \r
 239 #ifdef BLURTEST\r
 240         if(time > blurtest_time0 && time < blurtest_time1)\r
 241         {\r
 242                 float r, t;\r
 243 \r
 244                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);\r
 245                 r = t * blurtest_radius;\r
 246                 f = 1 / pow(t, blurtest_power) - 1;\r
 247 \r
 248                 cvar_set("r_glsl_postprocess", "1");\r
 249                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));\r
 250         }\r
 251         else\r
 252         {\r
 253                 cvar_set("r_glsl_postprocess", "0");\r
 254                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");\r
 255         }\r
 256 #endif\r
 257 \r
 258         Fog_Force();\r
 259 \r
 260         drawframetime = max(0.000001, time - drawtime);\r
 261         drawtime = time;\r
 262 \r
 263         // watch for gametype changes here...\r
 264         // in ParseStuffCMD the cmd isn't executed yet :/\r
 265         // might even be better to add the gametype to TE_CSQC_INIT...?\r
 266         if(!postinit)\r
 267                 PostInit();\r
 268         \r
 269         CheckForGamestartChange();\r
 270 \r
 271         fov = cvar("fov");\r
 272         if(button_zoom || fov <= 59.5)\r
 273         {\r
 274                 if(!zoomscript_caught)\r
 275                 {\r
 276                         localcmd("+button4\n");\r
 277                         zoomscript_caught = 1;\r
 278                         ignore_plus_zoom += 1;\r
 279                 }\r
 280         }\r
 281         else\r
 282         {\r
 283                 if(zoomscript_caught)\r
 284                 {\r
 285                         localcmd("-button4\n");\r
 286                         zoomscript_caught = 0;\r
 287                         ignore_minus_zoom += 1;\r
 288                 }\r
 289         }\r
 290         \r
 291         sbar_alpha_fg = cvar("sbar_alpha_fg" );\r
 292         sbar_hudselector = cvar("sbar_hudselector");\r
 293         ColorTranslateMode = cvar("cl_stripcolorcodes");\r
 294         activeweapon = getstati(STAT_SWITCHWEAPON);\r
 295         f = cvar("teamplay");\r
 296         if(f != teamplay)\r
 297         {\r
 298                 teamplay = f;\r
 299                 Sbar_InitScores();\r
 300         }\r
 301 \r
 302         if(last_weapon != activeweapon) {\r
 303                 weapontime = time;\r
 304                 last_weapon = activeweapon;\r
 305         }\r
 306 \r
 307         // ALWAYS Clear Current Scene First\r
 308         R_ClearScene();\r
 309 \r
 310         // Assign Standard Viewflags\r
 311         // Draw the World (and sky)\r
 312         R_SetView(VF_DRAWWORLD, 1);\r
 313 \r
 314         // Set the console size vars\r
 315         vid_conwidth = cvar("vid_conwidth");\r
 316         vid_conheight = cvar("vid_conheight");\r
 317         vid_pixelheight = cvar("vid_pixelheight");\r
 318 \r
 319         R_SetView(VF_FOV, GetCurrentFov(fov));\r
 320 \r
 321         // Camera for demo playback\r
 322         if(camera_active)\r
 323         {\r
 324                 if(cvar("camera_enable"))\r
 325                         CSQC_Demo_Camera();\r
 326                 else\r
 327                 {\r
 328                         cvar_set("chase_active", ftos(chase_active_backup));\r
 329                         cvar_set("cl_demo_mousegrab", "0");\r
 330                         camera_active = FALSE;\r
 331                 }\r
 332         }\r
 333 #ifdef CAMERATEST\r
 334         else if(cvar("camera_enable"))\r
 335 #else\r
 336         else if(cvar("camera_enable") && isdemo())\r
 337 #endif\r
 338         {\r
 339                 // Enable required Darkplaces cvars\r
 340                 chase_active_backup = cvar("chase_active");\r
 341                 cvar_set("chase_active", "2");          \r
 342                 cvar_set("cl_demo_mousegrab", "1");\r
 343                 camera_active = TRUE;\r
 344                 camera_mode = FALSE;\r
 345         }\r
 346         \r
 347         // Draw the Crosshair\r
 348         float scoreboard_active;\r
 349         scoreboard_active = Sbar_WouldDrawScoreboard();\r
 350         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden\r
 351         \r
 352         // Draw the Engine Status Bar (the default Quake HUD)\r
 353         R_SetView(VF_DRAWENGINESBAR, 0);\r
 354 \r
 355         // fetch this one only once per frame\r
 356         sbar_showbinds = cvar("sbar_showbinds");\r
 357         sbar_showbinds_limit = cvar("sbar_showbinds_limit");\r
 358 \r
 359         // Update the mouse position\r
 360         /*\r
 361         mousepos_x = vid_conwidth;\r
 362         mousepos_y = vid_conheight;\r
 363         mousepos = mousepos*0.5 + getmousepos();\r
 364         */\r
 365 \r
 366         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);\r
 367 \r
 368         e = self;\r
 369         for(self = world; (self = nextent(self)); )\r
 370                 if(self.draw)\r
 371                         self.draw();\r
 372         self = e;\r
 373         R_RenderScene();\r
 374 \r
 375         // now switch to 2D drawing mode by calling a 2D drawing function\r
 376         // then polygon drawing will draw as 2D stuff, and NOT get queued until the\r
 377         // next R_RenderScene call\r
 378         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);\r
 379 \r
 380         // Draw the mouse cursor\r
 381         // NOTE: drawpic must happen after R_RenderScene for some reason\r
 382         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);\r
 383         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);\r
 384         //self = edict_num(player_localnum);\r
 385         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);\r
 386         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);\r
 387         // as long as the ctf part isn't in, this is useless\r
 388         if(menu_visible)\r
 389                 menu_show();\r
 390         \r
 391         /*if(gametype == GAME_CTF)\r
 392         {\r
 393                 ctf_view();\r
 394         } else */\r
 395 \r
 396         // draw 2D entities\r
 397         e = self;\r
 398         for(self = world; (self = nextent(self)); )\r
 399                 if(self.draw2d)\r
 400                         self.draw2d();\r
 401         self = e;\r
 402         \r
 403         // draw radar\r
 404         if(\r
 405                 ons_showmap\r
 406                 ||\r
 407                 (\r
 408                         !scoreboard_active\r
 409                         &&\r
 410                         cvar_string("cl_teamradar") != "0"\r
 411                         &&\r
 412                         (\r
 413                                 cvar("cl_teamradar") == 2\r
 414                                 ||\r
 415                                 teamplay\r
 416                         )\r
 417                 )\r
 418         )\r
 419                 teamradar_view();\r
 420 \r
 421         if (cvar("cl_showpressedkeys")) // draw pressed keys when spectating and playing\r
 422         {\r
 423                 if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)\r
 424                         Sbar_DrawPressedKeys();\r
 425         }\r
 426 \r
 427         // draw sbar\r
 428         if(cvar("r_letterbox") == 0)\r
 429         if(cvar("viewsize") < 120)\r
 430                 CSQC_common_hud();\r
 431 \r
 432         // crosshair goes VERY LAST\r
 433         if(!scoreboard_active && !ons_showmap && !camera_active) {\r
 434                 string wcross_style;\r
 435                 wcross_style = cvar_string("crosshair");\r
 436 \r
 437                 if (wcross_style != "0") {\r
 438                         vector wcross_color, wcross_size;\r
 439                         string wcross_wep, wcross_name;\r
 440                         float wcross_alpha, wcross_sizefloat;\r
 441 \r
 442                         wcross_color_x = cvar("crosshair_color_red");\r
 443                         wcross_color_y = cvar("crosshair_color_green");\r
 444                         wcross_color_z = cvar("crosshair_color_blue");\r
 445                         wcross_alpha = cvar("crosshair_color_alpha");\r
 446                         wcross_sizefloat = cvar("crosshair_size");\r
 447                         if (cvar("crosshair_per_weapon")) {\r
 448                                 e = get_weaponinfo(activeweapon);\r
 449                                 if (e && e.netname != "")\r
 450                                 {\r
 451                                         wcross_wep = e.netname;\r
 452                                         wcross_style = cvar_string(strcat("crosshair_", wcross_wep));\r
 453                                         if(wcross_style == "")\r
 454                                                 wcross_style = e.netname;\r
 455 \r
 456                                         if(!cvar("crosshair_color_override"))\r
 457                                         {\r
 458                                                 wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));\r
 459                                                 wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));\r
 460                                                 wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));\r
 461                                         }\r
 462 \r
 463                                         wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));\r
 464                                         wcross_sizefloat *= cvar(strcat("crosshair_", wcross_wep, "_size"));\r
 465                                 }\r
 466                         }\r
 467 \r
 468                         wcross_name = strcat("gfx/crosshair", wcross_style);\r
 469                 \r
 470                         wcross_size = drawgetimagesize(wcross_name);\r
 471                         wcross_size_x *= wcross_sizefloat;\r
 472                         wcross_size_y *= wcross_sizefloat;\r
 473 \r
 474                         drawpic('0.5 0 0' * (vid_conwidth - wcross_size_x) + '0 0.5 0' * (vid_conheight - wcross_size_y), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);\r
 475                 }\r
 476         }\r
 477 \r
 478         if(NextFrameCommand)\r
 479         {\r
 480                 localcmd("\n", NextFrameCommand, "\n");\r
 481                 NextFrameCommand = string_null;\r
 482         }\r
 483 }\r
 484 \r
 485 void Sbar_Draw();\r
 486 void CSQC_common_hud(void)\r
 487 {\r
 488         // Sbar_SortFrags(); done in Sbar_Draw\r
 489         Sbar_Draw();\r
 490 }\r
 491 \r
 492 // KeyHunt HUD by victim\r
 493 void CSQC_kh_hud(void)\r
 494 {\r
 495         // HUD 0 has the weapons on the right hand side - temporarily shown when needed\r
 496         // HUD 1 has the weapons on the bottom - permanently\r
 497 \r
 498         // use the following two binds to check the icons move correctly\r
 499         // bind g "toggle sbar_flagstatus_right; echo Menu right $sbar_flagstatus_right"  // move the icons\r
 500         // bind h "toggle sbar_hudselector; echo HUD $sbar_hudselector"  // change the HUD\r
 501 \r
 502         float kh_keys, kh_keys_status, kh_teams_set;\r
 503         float kh_margin_x, kh_margin_y, kh_key_box;\r
 504         string kh_carrying, kh_outline;\r
 505         vector red_pos, blue_pos, yellow_pos, pink_pos, kh_size;\r
 506         vector red, blue, yellow, pink;\r
 507 \r
 508         kh_keys = getstati(STAT_KH_KEYS);\r
 509         kh_keys_status = kh_keys / 256;\r
 510         kh_teams_set = cvar("_teams_available");  // set in keyhunt.qc\r
 511 \r
 512         kh_margin_y = 8;\r
 513         kh_margin_x = (cvar("sbar_flagstatus_right") * sbar_hudselector * (vid_conwidth - 67)) + 10;\r
 514 //      sbar_flagstatus_right 0/1; sbar_hudselector 0/1; screen width - key width + margin\r
 515 \r
 516         red_pos_x = blue_pos_x = yellow_pos_x = pink_pos_x = kh_margin_x;\r
 517 \r
 518         kh_key_box = 120;\r
 519 \r
 520         pink_pos_y = kh_margin_y + 0;  // top\r
 521         yellow_pos_y = kh_margin_y + kh_key_box;\r
 522         blue_pos_y = kh_margin_y + kh_key_box * 2;\r
 523         red_pos_y = kh_margin_y + kh_key_box * 3;  //bottom\r
 524 \r
 525         red = '1 0 0';\r
 526         blue = '0 0 1';\r
 527         yellow = '1 1 0';\r
 528         pink = '1 0 1';\r
 529 \r
 530         kh_size = '0 0 0';  // don't resize the image\r
 531 \r
 532         kh_carrying = "gfx/sb_kh_full";\r
 533         kh_outline = "gfx/sb_kh_outline";\r
 534 \r
 535 //      drawpic(vector position, string pic, vector size, vector rgb, float alpha, float flag)\r
 536 //      vector position = '0 0';  // 'x y' 0 0 (the origin) is the top left. X 0 - 799, Y 0 - 599\r
 537 \r
 538 //      vector size = '0 0';  // 'x y' changes the x & y dimensions. '0 0' gives the default pic size\r
 539 //      vector rgb = '0 0 0';  // 'r g b' range 0 - 1\r
 540 \r
 541         if (kh_keys_status & 1)  // red\r
 542                 drawpic (red_pos, kh_carrying, kh_size, red, 0.2, 0);  // show 20% alpha key\r
 543         else\r
 544                 drawpic (red_pos, kh_outline, kh_size, red, 0.4, 0);  // show key outline 40% alpha\r
 545 \r
 546         if (kh_keys & 1)\r
 547                 drawpic (red_pos, kh_carrying, kh_size, red, 1.0, 0);  // show solid key 100% alpha\r
 548 \r
 549 \r
 550         if (kh_keys_status & 2)  // blue\r
 551                 drawpic (blue_pos, kh_carrying, kh_size, blue, 0.2, 0);\r
 552         else\r
 553                 drawpic (blue_pos, kh_outline, kh_size, blue, 0.4, 0);\r
 554 \r
 555         if (kh_keys & 2)\r
 556                 drawpic (blue_pos, kh_carrying, kh_size, blue, 1.0, 0);\r
 557 \r
 558 \r
 559         if (kh_teams_set & 4)  // yellow\r
 560         {\r
 561                 if (kh_keys_status & 4)\r
 562                         drawpic (yellow_pos, kh_carrying, kh_size, yellow, 0.2, 0);\r
 563                 else\r
 564                         drawpic (yellow_pos, kh_outline, kh_size, yellow, 0.4, 0);\r
 565 \r
 566                 if (kh_keys & 4)\r
 567                         drawpic (yellow_pos, kh_carrying, kh_size, yellow, 1.0, 0);\r
 568         }\r
 569 \r
 570 \r
 571         if (kh_teams_set & 8)  // pink\r
 572         {\r
 573                 if (kh_keys_status & 8)\r
 574                         drawpic (pink_pos, kh_carrying, kh_size, pink, 0.2, 0);\r
 575                 else\r
 576                         drawpic (pink_pos, kh_outline, kh_size, pink, 0.4, 0);\r
 577 \r
 578                 if (kh_keys & 8)\r
 579                         drawpic (pink_pos, kh_carrying, kh_size, pink, 1.0, 0);\r
 580         }\r
 581 \r
 582 }\r
 583 \r
 584 // following vectors must be global to allow seamless switching between camera modes\r
 585 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;\r
 586 void CSQC_Demo_Camera()\r
 587 {\r
 588         float speed, attenuation, dimensions;\r
 589         vector tmp, delta;\r
 590 \r
 591         if( cvar("camera_reset") || !camera_mode )\r
 592         {\r
 593                 camera_offset = '0 0 0';\r
 594                 current_angles = '0 0 0';\r
 595                 camera_direction = '0 0 0';\r
 596                 camera_offset_z += 30;\r
 597                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);\r
 598                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);\r
 599                 current_origin = view_origin;\r
 600                 current_camera_offset  = camera_offset;\r
 601                 cvar_set("camera_reset", "0");\r
 602                 camera_mode = CAMERA_CHASE;\r
 603         }\r
 604 \r
 605         // Camera angles\r
 606         if( camera_roll )\r
 607                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");\r
 608 \r
 609         if(cvar("camera_look_player"))\r
 610         {\r
 611                 local vector dir;\r
 612                 local float n;\r
 613 \r
 614                 dir = normalize(view_origin - current_position);\r
 615                 n = mouse_angles_z;\r
 616                 mouse_angles = vectoangles(dir);\r
 617                 mouse_angles_x = mouse_angles_x * -1;\r
 618                 mouse_angles_z = n;\r
 619         }\r
 620         else\r
 621         {\r
 622                 tmp = getmousepos() * 0.1;\r
 623                 if(vlen(tmp)>cvar("camera_mouse_treshold"))\r
 624                 {\r
 625                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));\r
 626                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));\r
 627                 }\r
 628         }\r
 629 \r
 630         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;\r
 631         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;\r
 632         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;\r
 633         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;\r
 634 \r
 635         // Fix difference when angles don't have the same sign\r
 636         delta = '0 0 0';\r
 637         if(mouse_angles_y < -60 && current_angles_y > 60)\r
 638                 delta = '0 360 0';\r
 639         if(mouse_angles_y > 60 && current_angles_y < -60)\r
 640                 delta = '0 -360 0';\r
 641 \r
 642         if(cvar("camera_look_player"))\r
 643                 attenuation = cvar("camera_look_attenuation");\r
 644         else\r
 645                 attenuation = cvar("camera_speed_attenuation");\r
 646 \r
 647         attenuation = 1 / max(1, attenuation);\r
 648         current_angles += (mouse_angles - current_angles + delta) * attenuation;\r
 649 \r
 650         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;\r
 651         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;\r
 652         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;\r
 653         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;\r
 654 \r
 655         // Camera position\r
 656         tmp = '0 0 0';\r
 657         dimensions = 0;\r
 658 \r
 659         if( camera_direction_x )\r
 660         {\r
 661                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);\r
 662                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);\r
 663                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )\r
 664                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);\r
 665                 ++dimensions;\r
 666         }\r
 667 \r
 668         if( camera_direction_y )\r
 669         {\r
 670                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);\r
 671                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);\r
 672                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);\r
 673                 ++dimensions;\r
 674         }\r
 675 \r
 676         if( camera_direction_z )\r
 677         {\r
 678                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);\r
 679                 ++dimensions;\r
 680         }\r
 681 \r
 682         if(cvar("camera_free"))\r
 683                 speed = cvar("camera_speed_free");\r
 684         else\r
 685                 speed = cvar("camera_speed_chase");\r
 686 \r
 687         if(dimensions)\r
 688         {\r
 689                 speed = speed * sqrt(1 / dimensions);\r
 690                 camera_offset += tmp * speed;\r
 691         }\r
 692 \r
 693         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;\r
 694 \r
 695         // Camera modes\r
 696         if( cvar("camera_free") )\r
 697         {\r
 698                 if ( camera_mode == CAMERA_CHASE )\r
 699                 {\r
 700                         current_camera_offset = current_origin + current_camera_offset;\r
 701                         camera_offset = current_origin + camera_offset;\r
 702                 }\r
 703 \r
 704                 camera_mode = CAMERA_FREE;\r
 705                 current_position = current_camera_offset;\r
 706         }\r
 707         else\r
 708         {\r
 709                 if ( camera_mode == CAMERA_FREE )\r
 710                 {\r
 711                         current_origin = view_origin;\r
 712                         camera_offset = camera_offset - current_origin;\r
 713                         current_camera_offset = current_camera_offset - current_origin;\r
 714                 }\r
 715 \r
 716                 camera_mode = CAMERA_CHASE;\r
 717 \r
 718                 if(cvar("camera_chase_smoothly"))\r
 719                         current_origin += (view_origin - current_origin) * attenuation;\r
 720                 else\r
 721                         current_origin = view_origin;\r
 722 \r
 723                 current_position = current_origin + current_camera_offset;\r
 724         }\r
 725 \r
 726         R_SetView(VF_ANGLES, current_angles);\r
 727         R_SetView(VF_ORIGIN, current_position);\r
 728 }\r