show server record on the hud (race/cts)
[divverent/nexuiz.git] / data / qcsrc / client / View.qc
1 #define spider_rocket_icon "gfx/spiderbot/rocket_ico.tga"
2 #define spider_rocket_targ "gfx/spiderbot/target.tga"
3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
4 #define rkt_size 32
5 #define rld_size_x 256
6 #define rld_size_y 16
7
8 entity porto;
9 vector polyline[16];
10 float trace_dphitcontents;
11 float trace_networkentity;
12 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
13 float DPCONTENTS_SOLID = 1; // blocks player movement
14 float DPCONTENTS_BODY = 32; // blocks player movement
15 float DPCONTENTS_CORPSE = 64; // blocks player movement
16 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
17 void Porto_Draw()
18 {
19         vector p, dir, ang, q, nextdir;
20         float idx, portal_number, portal1_idx;
21
22         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
23                 return;
24         if(intermission == 1)
25                 return;
26         if(intermission == 2)
27                 return;
28         if (getstati(STAT_HEALTH) <= 0)
29                 return;
30
31         dir = view_forward;
32
33         if(angles_held_status)
34         {
35                 makevectors(angles_held);
36                 dir = v_forward;
37         }
38
39         p = view_origin;
40
41         polyline[0] = p;
42         idx = 1;
43         portal_number = 0;
44         nextdir = dir;
45
46         for(;;)
47         {
48                 dir = nextdir;
49                 traceline(p, p + 65536 * dir, TRUE, porto);
50                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
51                         return;
52                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
53                 p = trace_endpos;
54                 polyline[idx] = p;
55                 ++idx;
56                 if(idx >= 16)
57                         return;
58                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
59                         continue;
60                 ++portal_number;
61                 ang = vectoangles2(trace_plane_normal, dir);
62                 ang_x = -ang_x;
63                 makevectors(ang);
64                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
65                         return;
66                 if(portal_number == 1)
67                         portal1_idx = idx;
68                 if(portal_number >= 2)
69                         break;
70         }
71
72         while(idx >= 2)
73         {
74                 p = polyline[idx-2];
75                 q = polyline[idx-1];
76                 if(idx == 2)
77                         p = p - view_up * 16;
78                 if(idx-1 >= portal1_idx)
79                 {
80                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);
81                 }
82                 else
83                 {
84                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);
85                 }
86                 --idx;
87         }
88 }
89
90 /**
91  * Checks whether the server initiated a map restart (stat_game_starttime changed)
92  *
93  * TODO: Use a better solution where a common shared entitiy is used that contains
94  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
95  * and STAT_FRAGLIMIT to be auto-sent)
96  */
97 void CheckForGamestartChange() {
98         float startTime;
99         startTime = getstatf(STAT_GAMESTARTTIME);
100         if (previous_game_starttime != startTime) {
101                 if ((time + 5.0) < startTime) {
102                         //if connecting to server while restart was active don't always play prepareforbattle
103                         sound(self, CHAN_VOICE, "announcer/robotic/prepareforbattle.wav", VOL_BASEVOICE, ATTN_NONE);
104                 }
105                 if (time < startTime) {
106                         restartAnnouncer = spawn();
107                         restartAnnouncer.think = restartAnnouncer_Think;
108                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
109                 }
110         }
111         previous_game_starttime = startTime;
112 }
113
114 void Porto_Init()
115 {
116         porto = spawn();
117         porto.classname = "porto";
118         porto.draw = Porto_Draw;
119         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
120 }
121
122 float drawtime;
123
124 float tan(float x)
125 {
126         return sin(x) / cos(x);
127 }
128 float atan2(float y, float x)
129 {
130         vector v;
131         v = '1 0 0' * x + '0 1 0' * y;
132         v = vectoangles(v);
133         return v_y * 0.01745329251994329576;
134 }
135
136 vector GetCurrentFov(float fov)
137 {
138         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
139
140         zoomsensitivity = cvar("cl_zoomsensitivity");
141         zoomfactor = cvar("cl_zoomfactor");
142         if(zoomfactor < 1 || zoomfactor > 16)
143                 zoomfactor = 2.5;
144         zoomspeed = cvar("cl_zoomspeed");
145         if(zoomspeed >= 0)
146                 if(zoomspeed < 0.5 || zoomspeed > 16)
147                         zoomspeed = 3.5;
148
149         zoomdir = button_zoom;
150         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here
151                 zoomdir += button_attack2;
152         if(spectatee_status > 0 || isdemo())
153         {
154                 if(spectatorbutton_zoom)
155                         zoomdir = 0 + !zoomdir;
156                         // do not even THINK about removing this 0
157                         // _I_ know what I am doing
158                         // fteqcc does not
159         }
160
161         if(zoomdir)
162                 zoomin_effect = 0;
163
164         if(zoomin_effect || camera_active)
165         {
166                 current_viewzoom = min(1, current_viewzoom + drawframetime);
167         }
168         else
169         {
170                 if(zoomspeed < 0) // instant zoom
171                 {
172                         if(zoomdir)
173                                 current_viewzoom = 1 / zoomfactor;
174                         else
175                                 current_viewzoom = 1;
176                 }
177                 else
178                 {
179                         if(zoomdir)
180                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
181                         else
182                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
183                 }
184         }
185
186         if(almost_equals(current_viewzoom, 1))
187                 current_zoomfraction = 0;
188         else if(almost_equals(current_viewzoom, 1/zoomfactor))
189                 current_zoomfraction = 1;
190         else
191                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
192
193         if(zoomsensitivity < 1)
194                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
195         else
196                 setsensitivityscale(1);
197
198         float frustumx, frustumy, fovx, fovy;
199         frustumy = tan(fov * 0.00872664625997164788) * 0.75 * current_viewzoom;
200         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
201         fovx = atan2(frustumx, 1) / 0.00872664625997164788;
202         fovy = atan2(frustumy, 1) / 0.00872664625997164788;
203
204         return '1 0 0' * fovx + '0 1 0' * fovy;
205 }
206
207 // this function must match W_SetupShot!
208 float zoomscript_caught;
209
210 vector wcross_origin;
211 entity trueaim;
212 entity trueaim_rifle;
213
214 #define SHOTTYPE_HITTEAM 1
215 #define SHOTTYPE_HITOBSTRUCTION 2
216 #define SHOTTYPE_HITWORLD 3
217 #define SHOTTYPE_HITENEMY 4
218
219 void TrueAim_Init()
220 {
221         trueaim = spawn();
222         trueaim.classname = "trueaim";
223         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
224         trueaim_rifle = spawn();
225         trueaim_rifle.classname = "trueaim_rifle";
226         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
227 }
228
229 float EnemyHitCheck()
230 {
231         float t;
232         wcross_origin = project_3d_to_2d(trace_endpos);
233         wcross_origin_z = 0;
234         if(trace_networkentity < 1)
235                 return SHOTTYPE_HITWORLD;
236         if(trace_networkentity > maxclients)
237                 return SHOTTYPE_HITWORLD;
238         t = GetPlayerColor(trace_networkentity - 1);
239         if(teamplay)
240         if(t == myteam)
241                 return SHOTTYPE_HITTEAM;
242         if(t == COLOR_SPECTATOR)
243                 return SHOTTYPE_HITWORLD;
244         return SHOTTYPE_HITENEMY;
245 }
246
247 float TrueAimCheck()
248 {
249         float nudge = 1; // added to traceline target and subtracted from result
250         vector vecs, trueaimpoint, w_shotorg;
251         vector mi, ma, dv;
252         float shottype;
253
254         mi = ma = '0 0 0';
255
256         switch(activeweapon)
257         {
258                 case WEP_TUBA: // no aim
259                 case WEP_PORTO: // shoots from eye
260                 case WEP_HOOK: // no trueaim
261                 case WEP_GRENADE_LAUNCHER: // toss curve
262                         return SHOTTYPE_HITWORLD;
263                 case WEP_CAMPINGRIFLE:
264                         if(zoomscript_caught)
265                         {
266                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, trueaim);
267                                 return EnemyHitCheck();
268                         }
269                         break;
270                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
271                         mi = '-3 -3 -3';
272                         ma = '3 3 3';
273                         break;
274                 case WEP_FIREBALL: // projectile has a size!
275                         mi = '-16 -16 -16';
276                         ma = '16 16 16';
277                         break;
278                 case WEP_ELECTRO: // projectile has a size!
279                         mi = '0 0 -3';
280                         ma = '0 0 -3';
281                         break;
282         }
283
284         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
285
286         if(activeweapon == WEP_CAMPINGRIFLE)
287                 traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, trueaim_rifle);
288         else
289                 traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, trueaim);
290         trueaimpoint = trace_endpos;
291
292         if(vecs_x > 0)
293                 vecs_y = -vecs_y;
294         else
295                 vecs = '0 0 0';
296
297         dv = view_right * vecs_y + view_up * vecs_z;
298         w_shotorg = view_origin + dv;
299
300         // now move the vecs forward as much as requested if possible
301         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, trueaim); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
302         w_shotorg = trace_endpos - view_forward * nudge;
303
304         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, trueaim);
305         shottype = EnemyHitCheck();
306         if(shottype != SHOTTYPE_HITWORLD)
307                 return shottype;
308         
309 #if 0
310         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
311         // or rather, I know why, but see no fix
312         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
313                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
314                 return SHOTTYPE_HITOBSTRUCTION;
315 #endif
316         
317         return SHOTTYPE_HITWORLD;
318 }
319
320 void CSQC_common_hud(void);
321
322 void CSQC_kh_hud(void);
323 void CSQC_ctf_hud(void);
324 void PostInit(void);
325 void CSQC_Demo_Camera();
326 float Sbar_WouldDrawScoreboard ();
327 float view_set;
328 float camera_mode;
329 string NextFrameCommand;
330 void CSQC_spider_HUD();
331 void CSQC_UpdateView(float w, float h)
332 {
333         entity e;
334         float fov;
335         float f, i, j;
336         vector v;
337
338         dprint_load();
339         WaypointSprite_Load();
340
341         if(spectatee_status)
342                 myteam = GetPlayerColor(spectatee_status - 1);
343         else
344                 myteam = GetPlayerColor(player_localentnum - 1);
345
346         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
347
348         // Render the Scene
349         if(!intermission || !view_set)
350         {
351                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);
352                 view_angles = input_angles;
353                 makevectors(view_angles);
354                 view_forward = v_forward;
355                 view_right = v_right;
356                 view_up = v_up;
357                 view_set = 1;
358         }
359
360         vid_width = w;
361         vid_height = h;
362
363 #ifdef BLURTEST
364         if(time > blurtest_time0 && time < blurtest_time1)
365         {
366                 float r, t;
367
368                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
369                 r = t * blurtest_radius;
370                 f = 1 / pow(t, blurtest_power) - 1;
371
372                 cvar_set("r_glsl_postprocess", "1");
373                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
374         }
375         else
376         {
377                 cvar_set("r_glsl_postprocess", "0");
378                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
379         }
380 #endif
381
382         Fog_Force();
383
384         drawframetime = max(0.000001, time - drawtime);
385         drawtime = time;
386
387         // watch for gametype changes here...
388         // in ParseStuffCMD the cmd isn't executed yet :/
389         // might even be better to add the gametype to TE_CSQC_INIT...?
390         if(!postinit)
391                 PostInit();
392
393         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
394         if(calledhooks & HOOK_START)
395         {
396                 localcmd("\ncl_hook_gameend;");
397                 calledhooks |= HOOK_END;
398         }
399
400         CheckForGamestartChange();
401         maptimeAnnouncer();
402
403         fov = cvar("fov");
404         if(button_zoom || fov <= 59.5)
405         {
406                 if(!zoomscript_caught)
407                 {
408                         localcmd("+button4\n");
409                         zoomscript_caught = 1;
410                         ignore_plus_zoom += 1;
411                 }
412         }
413         else
414         {
415                 if(zoomscript_caught)
416                 {
417                         localcmd("-button4\n");
418                         zoomscript_caught = 0;
419                         ignore_minus_zoom += 1;
420                 }
421         }
422
423         sbar_alpha_fg = cvar("sbar_alpha_fg" ) * (1 - cvar("_menu_alpha"));
424         sbar_currentammo = cvar("sbar_showcurrentammo");
425         sbar_hudselector = cvar("sbar_hudselector");
426         sbar_hud_accuracy = cvar("sbar_hud_accuracy");
427         ColorTranslateMode = cvar("cl_stripcolorcodes");
428         activeweapon = getstati(STAT_SWITCHWEAPON);
429         f = cvar("teamplay");
430         if(f != teamplay)
431         {
432                 teamplay = f;
433                 Sbar_InitScores();
434         }
435
436         if(last_weapon != activeweapon) {
437                 weapontime = time;
438                 last_weapon = activeweapon;
439         }
440
441         // ALWAYS Clear Current Scene First
442         R_ClearScene();
443
444         // Assign Standard Viewflags
445         // Draw the World (and sky)
446         R_SetView(VF_DRAWWORLD, 1);
447
448         // Set the console size vars
449         vid_conwidth = cvar("vid_conwidth");
450         vid_conheight = cvar("vid_conheight");
451         vid_pixelheight = cvar("vid_pixelheight");
452
453         R_SetView(VF_FOV, GetCurrentFov(fov));
454
455         // Camera for demo playback
456         if(camera_active)
457         {
458                 if(cvar("camera_enable"))
459                         CSQC_Demo_Camera();
460                 else
461                 {
462                         cvar_set("chase_active", ftos(chase_active_backup));
463                         cvar_set("cl_demo_mousegrab", "0");
464                         camera_active = FALSE;
465                 }
466         }
467 #ifdef CAMERATEST
468         else if(cvar("camera_enable"))
469 #else
470         else if(cvar("camera_enable") && isdemo())
471 #endif
472         {
473                 // Enable required Darkplaces cvars
474                 chase_active_backup = cvar("chase_active");
475                 cvar_set("chase_active", "2");
476                 cvar_set("cl_demo_mousegrab", "1");
477                 camera_active = TRUE;
478                 camera_mode = FALSE;
479         }
480
481         // Draw the Crosshair
482         float scoreboard_active;
483         scoreboard_active = Sbar_WouldDrawScoreboard();
484         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
485
486         // Draw the Engine Status Bar (the default Quake HUD)
487         R_SetView(VF_DRAWENGINESBAR, 0);
488
489         // fetch this one only once per frame
490         sbar_showbinds = cvar("sbar_showbinds");
491         sbar_showbinds_limit = cvar("sbar_showbinds_limit");
492
493         // Update the mouse position
494         /*
495         mousepos_x = vid_conwidth;
496         mousepos_y = vid_conheight;
497         mousepos = mousepos*0.5 + getmousepos();
498         */
499
500         e = self;
501         for(self = world; (self = nextent(self)); )
502                 if(self.draw)
503                         self.draw();
504         self = e;
505
506         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
507         R_RenderScene();
508
509         // now switch to 2D drawing mode by calling a 2D drawing function
510         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
511         // next R_RenderScene call
512         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
513
514         // Draw the mouse cursor
515         // NOTE: drawpic must happen after R_RenderScene for some reason
516         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
517         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
518         //self = edict_num(player_localnum);
519         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
520         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
521         // as long as the ctf part isn't in, this is useless
522         if(menu_visible)
523                 menu_show();
524
525         /*if(gametype == GAME_CTF)
526         {
527                 ctf_view();
528         } else */
529
530         // draw 2D entities
531         e = self;
532         for(self = world; (self = nextent(self)); )
533                 if(self.draw2d)
534                         self.draw2d();
535         self = e;
536
537         // draw radar
538         if(
539                 ons_showmap
540                 ||
541                 (
542                         !scoreboard_active
543                         &&
544                         cvar_string("cl_teamradar") != "0"
545                         &&
546                         (
547                                 cvar("cl_teamradar") == 2
548                                 ||
549                                 teamplay
550                         )
551                 )
552         )
553                 teamradar_view();
554
555         // draw sbar
556         if(cvar("r_letterbox") == 0) {
557                 if (cvar("cl_showpressedkeys")) { // draw pressed keys when spectating and playing
558                         if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)
559                                 Sbar_DrawPressedKeys();
560                 }
561                 
562                 if (cvar("cl_showspeed"))
563                         Sbar_ShowSpeed();
564                 if (cvar("cl_showacceleration"))
565                         Sbar_ShowAcceleration();
566                 
567                 Sbar_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120
568         }
569
570     float hud;
571     hud = getstati(STAT_HUD);
572     if(hud == HUD_SPIDERBOT)
573     {
574         vector sz;
575         CSQC_spider_HUD();
576         sz = drawgetimagesize(SPIDER_CROSS);
577         sz_x *= cvar_or("cl_vehicle_spiderbot_cross_size",1);
578         sz_y *= cvar_or("cl_vehicle_spiderbot_cross_size",1);
579         drawpic('0.5 0 0' * (vid_conwidth - sz_x) + '0 0.5 0' * (vid_conheight - sz_y), SPIDER_CROSS, sz, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
580     }
581     else
582     {
583         if(cvar("r_letterbox") == 0)
584             if(cvar("viewsize") < 120)
585                 CSQC_common_hud();
586
587         // crosshair goes VERY LAST
588         if(!scoreboard_active && !ons_showmap && !camera_active) {
589                         // TrueAim check
590                         float shottype;
591                         float bullets, ring_scale;
592                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
593                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
594                         wcross_origin_z = 0;
595             if(cvar("crosshair_hittest"))
596                         {
597                                 vector wcross_oldorigin;
598                                 wcross_oldorigin = wcross_origin;
599                 shottype = TrueAimCheck();
600                                 if(shottype == SHOTTYPE_HITWORLD)
601                                 {
602                                         v = wcross_origin - wcross_oldorigin;
603                                         v_x /= vid_conwidth;
604                                         v_y /= vid_conheight;
605                                         if(vlen(v) > 0.01)
606                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
607                                 }
608                                 if(!cvar("crosshair_hittest_showimpact"))
609                                         wcross_origin = wcross_oldorigin;
610                         }
611             else
612                 shottype = SHOTTYPE_HITWORLD;
613
614             string wcross_style;
615             wcross_style = cvar_string("crosshair");
616
617             if (wcross_style != "0") {
618                 vector wcross_color, wcross_size;
619                 string wcross_wep, wcross_name;
620                 float wcross_alpha, wcross_sizefloat;
621
622                 wcross_color_x = cvar("crosshair_color_red");
623                 wcross_color_y = cvar("crosshair_color_green");
624                 wcross_color_z = cvar("crosshair_color_blue");
625                 wcross_alpha = cvar("crosshair_color_alpha") * (1-cvar("_menu_alpha"));
626                 wcross_sizefloat = cvar("crosshair_size") * (1-cvar("_menu_alpha"));
627                 if (cvar("crosshair_per_weapon")) {
628                     e = get_weaponinfo(activeweapon);
629                     if (e && e.netname != "")
630                     {
631                         wcross_wep = e.netname;
632                         wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
633                         if(wcross_style == "")
634                             wcross_style = e.netname;
635
636                         if(!cvar("crosshair_color_override"))
637                         {
638                             wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
639                             wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
640                             wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
641                         }
642
643                         wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
644                         wcross_sizefloat *= cvar(strcat("crosshair_", wcross_wep, "_size"));
645                     }
646                 }
647
648                 wcross_name = strcat("gfx/crosshair", wcross_style);
649
650                                 if(shottype == SHOTTYPE_HITENEMY)
651                                         wcross_sizefloat *= cvar("crosshair_hittest"); // is not queried if hittest is 0
652                                 if(shottype == SHOTTYPE_HITTEAM)
653                                         wcross_sizefloat /= cvar("crosshair_hittest"); // is not queried if hittest is 0
654
655                 wcross_size = drawgetimagesize(wcross_name);
656                 wcross_size_x *= wcross_sizefloat;
657                 wcross_size_y *= wcross_sizefloat;
658                                 
659                                 // ring around crosshair representing bullets left in camping rifle clip
660                                 if (activeweapon == WEP_CAMPINGRIFLE)
661                                 {
662                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
663                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 8);
664                                 }
665                                 else
666                                         bullets = 0;
667                                 
668                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
669                 {
670                     wcross_alpha *= 0.04 * 0.75;
671                     for(i = -2; i <= 2; ++i)
672                         for(j = -2; j <= 2; ++j)
673                                                 {
674                                                         if (bullets)
675                                                                 drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x * ring_scale + i) - '0 0.5 0' * (wcross_size_y * ring_scale + j), strcat("gfx/hud/rifle_ring_", ftos(bullets)), wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
676                             drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x + i) - '0 0.5 0' * (wcross_size_y + j), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
677                                                 }
678                 }
679                 else
680                 {
681                                         if (bullets)
682                                                 drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x * ring_scale) - '0 0.5 0' * (wcross_size_y * ring_scale), strcat("gfx/hud/rifle_ring_", ftos(bullets)), wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
683                     drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x) - '0 0.5 0' * ( wcross_size_y), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
684                 }
685             }
686         }
687     }
688
689         if(NextFrameCommand)
690         {
691                 localcmd("\n", NextFrameCommand, "\n");
692                 NextFrameCommand = string_null;
693         }
694
695         // we must do this check AFTER a frame was rendered, or it won't work
696         if(cs_project_is_b0rked == 0)
697         {
698                 string w0, h0;
699                 w0 = cvar_string("vid_conwidth");
700                 h0 = cvar_string("vid_conheight");
701                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
702                 //R_SetView(VF_FOV, '90 90 0');
703                 R_SetView(VF_ORIGIN, '0 0 0');
704                 R_SetView(VF_ANGLES, '0 0 0');
705                 R_SetView(VF_PERSPECTIVE, 1);
706                 makevectors('0 0 0');
707                 vector v1, v2;
708                 cvar_set("vid_conwidth", "800");
709                 cvar_set("vid_conheight", "600");
710                 v1 = cs_project(v_forward);
711                 cvar_set("vid_conwidth", "640");
712                 cvar_set("vid_conheight", "480");
713                 v2 = cs_project(v_forward);
714                 if(v1 == v2)
715                         cs_project_is_b0rked = 1;
716                 else
717                         cs_project_is_b0rked = -1;
718                 cvar_set("vid_conwidth", w0);
719                 cvar_set("vid_conheight", h0);
720         }
721
722         // be safe against triggerbots until everyone has the fixed engine
723         // this call is meant to overwrite the trace globals by something
724         // unsuspicious
725         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);
726 }
727
728 void Sbar_Draw();
729 void CSQC_spider_HUD()
730 {
731     float rockets,reload,heat,hp,shield,i;
732     vector p,pp;
733
734     rockets = getstati(STAT_SPIDERBOT_ROCKETS);
735     heat    = min(getstatf(STAT_SPIDERBOT_HEAT),1);
736     reload  = min(getstatf(STAT_SPIDERBOT_RELOAD),1);
737     hp      = min(getstatf(STAT_SPIDERBOT_HEALTH),1);
738     shield  = min(getstatf(STAT_SPIDERBOT_SHIELD),1);
739
740     // Draw health bar
741     p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
742     p = p + '0 1 0' * vid_conheight - '0 32 0';
743     //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
744     drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
745     p_y += 8;
746     drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
747     p_x += 256 * hp;
748     drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
749
750     // Draw minigun heat indicator
751     p = '0.5 0 0' * (vid_conwidth - 256);
752     p = p + '0 1 0' * vid_conheight - '0 34  0';
753     drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
754     p_x += 256 * (1-heat);
755     drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
756
757     // Draw rocket icons for loaded/empty tubes.
758     pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
759     pp += '0 1 0' * vid_conheight - '0 64 0';
760     for(i = 0; i < 8; ++i)
761     {
762         p = pp + '1 0 0' * (rkt_size * i);
763         if(rockets == 8)
764         {
765             if(floor(reload * 8) == i)
766             {
767                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
768             }
769             else if(i < reload * 8)
770                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
771             else
772                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
773         }
774         else
775         {
776             if(i < rockets)
777                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
778             else
779                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
780         }
781     }
782
783         if (sb_showscores)
784         {
785                 Sbar_DrawScoreboard();
786                 Sbar_DrawCenterPrint();
787         }
788
789 }
790 void CSQC_common_hud(void)
791 {
792
793         // Sbar_SortFrags(); done in Sbar_Draw
794     float hud;
795     hud = getstati(STAT_HUD);
796
797     //hud = 10;
798     switch(hud)
799     {
800         case HUD_NORMAL:
801             Sbar_Draw();
802             break;
803
804         case HUD_SPIDERBOT:
805             CSQC_spider_HUD();
806             break;
807     }
808 }
809
810
811 // following vectors must be global to allow seamless switching between camera modes
812 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
813 void CSQC_Demo_Camera()
814 {
815         float speed, attenuation, dimensions;
816         vector tmp, delta;
817
818         if( cvar("camera_reset") || !camera_mode )
819         {
820                 camera_offset = '0 0 0';
821                 current_angles = '0 0 0';
822                 camera_direction = '0 0 0';
823                 camera_offset_z += 30;
824                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
825                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
826                 current_origin = view_origin;
827                 current_camera_offset  = camera_offset;
828                 cvar_set("camera_reset", "0");
829                 camera_mode = CAMERA_CHASE;
830         }
831
832         // Camera angles
833         if( camera_roll )
834                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
835
836         if(cvar("camera_look_player"))
837         {
838                 local vector dir;
839                 local float n;
840
841                 dir = normalize(view_origin - current_position);
842                 n = mouse_angles_z;
843                 mouse_angles = vectoangles(dir);
844                 mouse_angles_x = mouse_angles_x * -1;
845                 mouse_angles_z = n;
846         }
847         else
848         {
849                 tmp = getmousepos() * 0.1;
850                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
851                 {
852                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
853                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
854                 }
855         }
856
857         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
858         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
859         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
860         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
861
862         // Fix difference when angles don't have the same sign
863         delta = '0 0 0';
864         if(mouse_angles_y < -60 && current_angles_y > 60)
865                 delta = '0 360 0';
866         if(mouse_angles_y > 60 && current_angles_y < -60)
867                 delta = '0 -360 0';
868
869         if(cvar("camera_look_player"))
870                 attenuation = cvar("camera_look_attenuation");
871         else
872                 attenuation = cvar("camera_speed_attenuation");
873
874         attenuation = 1 / max(1, attenuation);
875         current_angles += (mouse_angles - current_angles + delta) * attenuation;
876
877         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
878         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
879         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
880         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
881
882         // Camera position
883         tmp = '0 0 0';
884         dimensions = 0;
885
886         if( camera_direction_x )
887         {
888                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
889                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
890                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
891                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
892                 ++dimensions;
893         }
894
895         if( camera_direction_y )
896         {
897                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
898                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
899                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
900                 ++dimensions;
901         }
902
903         if( camera_direction_z )
904         {
905                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
906                 ++dimensions;
907         }
908
909         if(cvar("camera_free"))
910                 speed = cvar("camera_speed_free");
911         else
912                 speed = cvar("camera_speed_chase");
913
914         if(dimensions)
915         {
916                 speed = speed * sqrt(1 / dimensions);
917                 camera_offset += tmp * speed;
918         }
919
920         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
921
922         // Camera modes
923         if( cvar("camera_free") )
924         {
925                 if ( camera_mode == CAMERA_CHASE )
926                 {
927                         current_camera_offset = current_origin + current_camera_offset;
928                         camera_offset = current_origin + camera_offset;
929                 }
930
931                 camera_mode = CAMERA_FREE;
932                 current_position = current_camera_offset;
933         }
934         else
935         {
936                 if ( camera_mode == CAMERA_FREE )
937                 {
938                         current_origin = view_origin;
939                         camera_offset = camera_offset - current_origin;
940                         current_camera_offset = current_camera_offset - current_origin;
941                 }
942
943                 camera_mode = CAMERA_CHASE;
944
945                 if(cvar("camera_chase_smoothly"))
946                         current_origin += (view_origin - current_origin) * attenuation;
947                 else
948                         current_origin = view_origin;
949
950                 current_position = current_origin + current_camera_offset;
951         }
952
953         R_SetView(VF_ANGLES, current_angles);
954         R_SetView(VF_ORIGIN, current_position);
955 }