add accuracy stats to the scoreboard, replace accuracy percentage on hud weapon icons...
[divverent/nexuiz.git] / data / qcsrc / client / View.qc
1 #define spider_rocket_icon "gfx/spiderbot/rocket_ico.tga"
2 #define spider_rocket_targ "gfx/spiderbot/target.tga"
3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
4 #define rkt_size 32
5 #define rld_size_x 256
6 #define rld_size_y 16
7
8 void CSQC_WAKIZASHI_HUD();
9
10 entity porto;
11 vector polyline[16];
12 float trace_dphitcontents;
13 float trace_networkentity;
14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
15 float DPCONTENTS_SOLID = 1; // blocks player movement
16 float DPCONTENTS_BODY = 32; // blocks player movement
17 float DPCONTENTS_CORPSE = 64; // blocks player movement
18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
19 void Porto_Draw()
20 {
21         vector p, dir, ang, q, nextdir;
22         float idx, portal_number, portal1_idx;
23
24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
25                 return;
26         if(intermission == 1)
27                 return;
28         if(intermission == 2)
29                 return;
30         if (getstati(STAT_HEALTH) <= 0)
31                 return;
32
33         dir = view_forward;
34
35         if(angles_held_status)
36         {
37                 makevectors(angles_held);
38                 dir = v_forward;
39         }
40
41         p = view_origin;
42
43         polyline[0] = p;
44         idx = 1;
45         portal_number = 0;
46         nextdir = dir;
47
48         for(;;)
49         {
50                 dir = nextdir;
51                 traceline(p, p + 65536 * dir, TRUE, porto);
52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
53                         return;
54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
55                 p = trace_endpos;
56                 polyline[idx] = p;
57                 ++idx;
58                 if(idx >= 16)
59                         return;
60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
61                         continue;
62                 ++portal_number;
63                 ang = vectoangles2(trace_plane_normal, dir);
64                 ang_x = -ang_x;
65                 makevectors(ang);
66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
67                         return;
68                 if(portal_number == 1)
69                         portal1_idx = idx;
70                 if(portal_number >= 2)
71                         break;
72         }
73
74         while(idx >= 2)
75         {
76                 p = polyline[idx-2];
77                 q = polyline[idx-1];
78                 if(idx == 2)
79                         p = p - view_up * 16;
80                 if(idx-1 >= portal1_idx)
81                 {
82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);
83                 }
84                 else
85                 {
86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);
87                 }
88                 --idx;
89         }
90 }
91
92 /**
93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
94  *
95  * TODO: Use a better solution where a common shared entitiy is used that contains
96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
97  * and STAT_FRAGLIMIT to be auto-sent)
98  */
99 void CheckForGamestartChange() {
100         float startTime;
101         startTime = getstatf(STAT_GAMESTARTTIME);
102         if (previous_game_starttime != startTime) {
103                 if ((time + 5.0) < startTime) {
104                         //if connecting to server while restart was active don't always play prepareforbattle
105                         sound(self, CHAN_VOICE, "announcer/robotic/prepareforbattle.wav", VOL_BASEVOICE, ATTN_NONE);
106                 }
107                 if (time < startTime) {
108                         restartAnnouncer = spawn();
109                         restartAnnouncer.think = restartAnnouncer_Think;
110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
111                 }
112         }
113         previous_game_starttime = startTime;
114 }
115
116 void Porto_Init()
117 {
118         porto = spawn();
119         porto.classname = "porto";
120         porto.draw = Porto_Draw;
121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
122 }
123
124 float drawtime;
125
126 float tan(float x)
127 {
128         return sin(x) / cos(x);
129 }
130 float atan2(float y, float x)
131 {
132         vector v;
133         v = '1 0 0' * x + '0 1 0' * y;
134         v = vectoangles(v);
135         return v_y * 0.01745329251994329576;
136 }
137 float avgspeed;
138 vector GetCurrentFov(float fov)
139 {
140         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
141
142         zoomsensitivity = cvar("cl_zoomsensitivity");
143         zoomfactor = cvar("cl_zoomfactor");
144         if(zoomfactor < 1 || zoomfactor > 16)
145                 zoomfactor = 2.5;
146         zoomspeed = cvar("cl_zoomspeed");
147         if(zoomspeed >= 0)
148                 if(zoomspeed < 0.5 || zoomspeed > 16)
149                         zoomspeed = 3.5;
150
151         zoomdir = button_zoom;
152         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here
153                 zoomdir += button_attack2;
154         if(spectatee_status > 0 || isdemo())
155         {
156                 if(spectatorbutton_zoom)
157                         zoomdir = 0 + !zoomdir;
158                 // do not even THINK about removing this 0
159                 // _I_ know what I am doing
160                 // fteqcc does not
161         }
162
163         if(zoomdir)
164                 zoomin_effect = 0;
165
166         if(zoomin_effect || camera_active)
167         {
168                 current_viewzoom = min(1, current_viewzoom + drawframetime);
169         }
170         else
171         {
172                 if(zoomspeed < 0) // instant zoom
173                 {
174                         if(zoomdir)
175                                 current_viewzoom = 1 / zoomfactor;
176                         else
177                                 current_viewzoom = 1;
178                 }
179                 else
180                 {
181                         if(zoomdir)
182                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
183                         else
184                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
185                 }
186         }
187
188         if(almost_equals(current_viewzoom, 1))
189                 current_zoomfraction = 0;
190         else if(almost_equals(current_viewzoom, 1/zoomfactor))
191                 current_zoomfraction = 1;
192         else
193                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
194
195         if(zoomsensitivity < 1)
196                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
197         else
198                 setsensitivityscale(1);
199                 
200         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
201         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
202         velocityzoom = pow(2.718281828459, float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
203         
204         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
205         
206         float frustumx, frustumy, fovx, fovy;
207         frustumy = tan(fov * 0.00872664625997164788) * 0.75 * current_viewzoom * velocityzoom;
208         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
209         fovx = atan2(frustumx, 1) / 0.00872664625997164788;
210         fovy = atan2(frustumy, 1) / 0.00872664625997164788;
211
212         return '1 0 0' * fovx + '0 1 0' * fovy;
213 }
214
215 // this function must match W_SetupShot!
216 float zoomscript_caught;
217
218 vector wcross_origin;
219 float wcross_scale_prev, wcross_alpha_prev;
220 vector wcross_color_prev;
221 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
222 vector wcross_color_goal_prev;
223 float wcross_changedonetime;
224
225 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
226 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
227 float wcross_name_changestarttime, wcross_name_changedonetime;
228 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
229 entity trueaim;
230 entity trueaim_rifle;
231
232 #define SHOTTYPE_HITTEAM 1
233 #define SHOTTYPE_HITOBSTRUCTION 2
234 #define SHOTTYPE_HITWORLD 3
235 #define SHOTTYPE_HITENEMY 4
236
237 void TrueAim_Init()
238 {
239         trueaim = spawn();
240         trueaim.classname = "trueaim";
241         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
242         trueaim_rifle = spawn();
243         trueaim_rifle.classname = "trueaim_rifle";
244         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
245 }
246
247 float EnemyHitCheck()
248 {
249         float t;
250         wcross_origin = project_3d_to_2d(trace_endpos);
251         wcross_origin_z = 0;
252         if(trace_networkentity < 1)
253                 return SHOTTYPE_HITWORLD;
254         if(trace_networkentity > maxclients)
255                 return SHOTTYPE_HITWORLD;
256         t = GetPlayerColor(trace_networkentity - 1);
257         if(teamplay)
258                 if(t == myteam)
259                         return SHOTTYPE_HITTEAM;
260         if(t == COLOR_SPECTATOR)
261                 return SHOTTYPE_HITWORLD;
262         return SHOTTYPE_HITENEMY;
263 }
264
265 float TrueAimCheck()
266 {
267         float nudge = 1; // added to traceline target and subtracted from result
268         vector vecs, trueaimpoint, w_shotorg;
269         vector mi, ma, dv;
270         float shottype;
271         entity ta;
272         float mv;
273
274         mi = ma = '0 0 0';
275         ta = trueaim;
276         mv = MOVE_NOMONSTERS;
277
278         switch(activeweapon)
279         {
280                 case WEP_TUBA: // no aim
281                 case WEP_PORTO: // shoots from eye
282                 case WEP_HOOK: // no trueaim
283                 case WEP_GRENADE_LAUNCHER: // toss curve
284                         return SHOTTYPE_HITWORLD;
285                 case WEP_NEX:
286                 case WEP_MINSTANEX:
287                         mv = MOVE_NORMAL;
288                         break;
289                 case WEP_CAMPINGRIFLE:
290                         ta = trueaim_rifle;
291                         mv = MOVE_NORMAL;
292                         if(zoomscript_caught)
293                         {
294                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
295                                 return EnemyHitCheck();
296                         }
297                         break;
298                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
299                         mi = '-3 -3 -3';
300                         ma = '3 3 3';
301                         break;
302                 case WEP_FIREBALL: // projectile has a size!
303                         mi = '-16 -16 -16';
304                         ma = '16 16 16';
305                         break;
306                 case WEP_ELECTRO: // projectile has a size!
307                         mi = '0 0 -3';
308                         ma = '0 0 -3';
309                         break;
310         }
311
312         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
313
314         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
315         trueaimpoint = trace_endpos;
316
317         if(vecs_x > 0)
318                 vecs_y = -vecs_y;
319         else
320                 vecs = '0 0 0';
321
322         dv = view_right * vecs_y + view_up * vecs_z;
323         w_shotorg = view_origin + dv;
324
325         // now move the vecs forward as much as requested if possible
326         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
327         w_shotorg = trace_endpos - view_forward * nudge;
328
329         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
330         shottype = EnemyHitCheck();
331         if(shottype != SHOTTYPE_HITWORLD)
332                 return shottype;
333
334 #if 0
335         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
336         // or rather, I know why, but see no fix
337         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
338                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
339                 return SHOTTYPE_HITOBSTRUCTION;
340 #endif
341
342         return SHOTTYPE_HITWORLD;
343 }
344
345 void CSQC_common_hud(void);
346
347 void CSQC_kh_hud(void);
348 void CSQC_ctf_hud(void);
349 void PostInit(void);
350 void CSQC_Demo_Camera();
351 float Sbar_WouldDrawScoreboard ();
352 float view_set;
353 float camera_mode;
354 string NextFrameCommand;
355 void CSQC_spider_HUD();
356 void CSQC_UpdateView(float w, float h)
357 {
358         entity e;
359         float fov;
360         float f, i, j;
361         vector v;
362
363         dprint_load();
364         WaypointSprite_Load();
365
366         if(spectatee_status)
367                 myteam = GetPlayerColor(spectatee_status - 1);
368         else
369                 myteam = GetPlayerColor(player_localentnum - 1);
370
371         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
372
373         // Render the Scene
374         if(!intermission || !view_set)
375         {
376                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);
377                 view_angles = input_angles;
378                 makevectors(view_angles);
379                 view_forward = v_forward;
380                 view_right = v_right;
381                 view_up = v_up;
382                 view_set = 1;
383         }
384
385         vid_width = w;
386         vid_height = h;
387
388 #ifdef BLURTEST
389         if(time > blurtest_time0 && time < blurtest_time1)
390         {
391                 float r, t;
392
393                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
394                 r = t * blurtest_radius;
395                 f = 1 / pow(t, blurtest_power) - 1;
396
397                 cvar_set("r_glsl_postprocess", "1");
398                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
399         }
400         else
401         {
402                 cvar_set("r_glsl_postprocess", "0");
403                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
404         }
405 #endif
406
407         Fog_Force();
408
409         drawframetime = max(0.000001, time - drawtime);
410         drawtime = time;
411
412         // watch for gametype changes here...
413         // in ParseStuffCMD the cmd isn't executed yet :/
414         // might even be better to add the gametype to TE_CSQC_INIT...?
415         if(!postinit)
416                 PostInit();
417
418         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
419                 if(calledhooks & HOOK_START)
420                 {
421                         localcmd("\ncl_hook_gameend;");
422                         calledhooks |= HOOK_END;
423                 }
424
425         CheckForGamestartChange();
426         maptimeAnnouncer();
427
428         fov = cvar("fov");
429         if(button_zoom || fov <= 59.5)
430         {
431                 if(!zoomscript_caught)
432                 {
433                         localcmd("+button4\n");
434                         zoomscript_caught = 1;
435                         ignore_plus_zoom += 1;
436                 }
437         }
438         else
439         {
440                 if(zoomscript_caught)
441                 {
442                         localcmd("-button4\n");
443                         zoomscript_caught = 0;
444                         ignore_minus_zoom += 1;
445                 }
446         }
447
448         sbar_alpha_fg = cvar("sbar_alpha_fg" ) * (1 - cvar("_menu_alpha"));
449         sbar_currentammo = cvar("sbar_showcurrentammo");
450         sbar_hudselector = cvar("sbar_hudselector");
451         sbar_accuracy_hud = cvar_or("sbar_accuracy_hud", 1);
452         ColorTranslateMode = cvar("cl_stripcolorcodes");
453         activeweapon = getstati(STAT_SWITCHWEAPON);
454         f = cvar("teamplay");
455         if(f != teamplay)
456         {
457                 teamplay = f;
458                 Sbar_InitScores();
459         }
460
461         if(last_weapon != activeweapon) {
462                 weapontime = time;
463                 last_weapon = activeweapon;
464         }
465
466         // ALWAYS Clear Current Scene First
467         R_ClearScene();
468
469         // Assign Standard Viewflags
470         // Draw the World (and sky)
471         R_SetView(VF_DRAWWORLD, 1);
472
473         // Set the console size vars
474         vid_conwidth = cvar("vid_conwidth");
475         vid_conheight = cvar("vid_conheight");
476         vid_pixelheight = cvar("vid_pixelheight");
477
478         R_SetView(VF_FOV, GetCurrentFov(fov));
479
480         // Camera for demo playback
481         if(camera_active)
482         {
483                 if(cvar("camera_enable"))
484                         CSQC_Demo_Camera();
485                 else
486                 {
487                         cvar_set("chase_active", ftos(chase_active_backup));
488                         cvar_set("cl_demo_mousegrab", "0");
489                         camera_active = FALSE;
490                 }
491         }
492 #ifdef CAMERATEST
493         else if(cvar("camera_enable"))
494 #else
495         else if(cvar("camera_enable") && isdemo())
496 #endif
497         {
498                 // Enable required Darkplaces cvars
499                 chase_active_backup = cvar("chase_active");
500                 cvar_set("chase_active", "2");
501                 cvar_set("cl_demo_mousegrab", "1");
502                 camera_active = TRUE;
503                 camera_mode = FALSE;
504         }
505
506         // Draw the Crosshair
507         float scoreboard_active;
508         scoreboard_active = Sbar_WouldDrawScoreboard();
509         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
510
511         // Draw the Engine Status Bar (the default Quake HUD)
512         R_SetView(VF_DRAWENGINESBAR, 0);
513
514         // fetch this one only once per frame
515         sbar_showbinds = cvar("sbar_showbinds");
516         sbar_showbinds_limit = cvar("sbar_showbinds_limit");
517
518         // Update the mouse position
519         /*
520            mousepos_x = vid_conwidth;
521            mousepos_y = vid_conheight;
522            mousepos = mousepos*0.5 + getmousepos();
523          */
524
525         e = self;
526         for(self = world; (self = nextent(self)); )
527                 if(self.draw)
528                         self.draw();
529         self = e;
530
531         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
532         R_RenderScene();
533
534         // now switch to 2D drawing mode by calling a 2D drawing function
535         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
536         // next R_RenderScene call
537         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
538
539         // Draw the mouse cursor
540         // NOTE: drawpic must happen after R_RenderScene for some reason
541         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
542         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
543         //self = edict_num(player_localnum);
544         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
545         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
546         // as long as the ctf part isn't in, this is useless
547         if(menu_visible)
548                 menu_show();
549
550         /*if(gametype == GAME_CTF)
551           {
552           ctf_view();
553           } else */
554
555         // draw 2D entities
556         e = self;
557         for(self = world; (self = nextent(self)); )
558                 if(self.draw2d)
559                         self.draw2d();
560         self = e;
561
562         // draw radar
563         if(
564                         ons_showmap
565                         ||
566                         (
567                          !scoreboard_active
568                          &&
569                          cvar_string("cl_teamradar") != "0"
570                          &&
571                          (
572                           cvar("cl_teamradar") == 2
573                           ||
574                           teamplay
575                          )
576                         )
577           )
578                 teamradar_view();
579
580         // draw sbar
581         if(cvar("r_letterbox") == 0) {
582                 if (cvar("cl_showpressedkeys")) { // draw pressed keys when spectating and playing
583                         if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)
584                                 Sbar_DrawPressedKeys();
585                 }
586
587                 if (cvar("cl_showspeed"))
588                         Sbar_ShowSpeed();
589                 if (cvar("cl_showacceleration"))
590                         Sbar_ShowAcceleration();
591
592                 Sbar_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120
593         }
594
595         float hud;
596         hud = getstati(STAT_HUD);
597         if(hud == HUD_SPIDERBOT)
598         {
599                 CSQC_spider_HUD();
600         }
601         else if(hud == HUD_WAKIZASHI)
602         CSQC_WAKIZASHI_HUD();
603         else
604         {
605                 if(cvar("r_letterbox") == 0)
606                         if(cvar("viewsize") < 120)
607                                 CSQC_common_hud();
608
609                 // crosshair goes VERY LAST
610                 if(!scoreboard_active && !ons_showmap && !camera_active) {
611                         // TrueAim check
612                         float shottype;
613                         float bullets, ring_scale;
614                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
615                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
616                         wcross_origin_z = 0;
617                         if(cvar("crosshair_hittest"))
618                         {
619                                 vector wcross_oldorigin;
620                                 wcross_oldorigin = wcross_origin;
621                                 shottype = TrueAimCheck();
622                                 if(shottype == SHOTTYPE_HITWORLD)
623                                 {
624                                         v = wcross_origin - wcross_oldorigin;
625                                         v_x /= vid_conwidth;
626                                         v_y /= vid_conheight;
627                                         if(vlen(v) > 0.01)
628                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
629                                 }
630                                 if(!cvar("crosshair_hittest_showimpact"))
631                                         wcross_origin = wcross_oldorigin;
632                         }
633                         else
634                                 shottype = SHOTTYPE_HITWORLD;
635
636                         string wcross_style;
637                         wcross_style = cvar_string("crosshair");
638
639                         if (wcross_style != "0") {
640                                 vector wcross_color, wcross_size;
641                                 string wcross_wep, wcross_name;
642                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;
643
644                                 wcross_color_x = cvar("crosshair_color_red");
645                                 wcross_color_y = cvar("crosshair_color_green");
646                                 wcross_color_z = cvar("crosshair_color_blue");
647                                 wcross_alpha = cvar("crosshair_color_alpha");
648                                 wcross_resolution = cvar("crosshair_size");
649                                 if (cvar("crosshair_per_weapon")) {
650                                         e = get_weaponinfo(activeweapon);
651                                         if (e && e.netname != "")
652                                         {
653                                                 wcross_wep = e.netname;
654                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
655                                                 if(wcross_style == "")
656                                                         wcross_style = e.netname;
657
658                                                 if(!cvar("crosshair_color_override"))
659                                                 {
660                                                         wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
661                                                         wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
662                                                         wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
663                                                 }
664
665                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
666                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
667                                         }
668                                 }
669
670                                 wcross_name = strcat("gfx/crosshair", wcross_style);
671
672                                 if(cvar("crosshair_effect_scalefade"))
673                                 {
674                                         wcross_scale = wcross_resolution;
675                                         wcross_resolution = 1;
676                                 }
677                                 else
678                                 {
679                                         wcross_scale = 1;
680                                 }
681
682                                 if(shottype == SHOTTYPE_HITENEMY)
683                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
684                                 if(shottype == SHOTTYPE_HITTEAM)
685                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
686
687                                 f = cvar("crosshair_effect_speed");
688                                 if(f < 0)
689                                         f *= -2 * g_weaponswitchdelay;
690                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
691                                 {
692                                         wcross_changedonetime = time + f;
693                                 }
694                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
695                                 {
696                                         wcross_name_changestarttime = time;
697                                         wcross_name_changedonetime = time + f;
698                                         if(wcross_name_goal_prev_prev)
699                                                 strunzone(wcross_name_goal_prev_prev);
700                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
701                                         wcross_name_goal_prev = strzone(wcross_name);
702                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
703                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
704                                         wcross_resolution_goal_prev = wcross_resolution;
705                                 }
706
707                                 wcross_scale_goal_prev = wcross_scale;
708                                 wcross_alpha_goal_prev = wcross_alpha;
709                                 wcross_color_goal_prev = wcross_color;
710
711                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
712                                 {
713                                         wcross_blur = 1;
714                                         wcross_alpha *= 0.75;
715                                 }
716                                 else
717                                         wcross_blur = 0;
718                                 // *_prev is at time-frametime
719                                 // * is at wcross_changedonetime+f
720                                 // what do we have at time?
721                                 if(time < wcross_changedonetime)
722                                 {
723                                         f = frametime / (wcross_changedonetime - time + frametime);
724                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
725                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
726                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
727                                 }
728
729                                 wcross_scale_prev = wcross_scale;
730                                 wcross_alpha_prev = wcross_alpha;
731                                 wcross_color_prev = wcross_color;
732
733                                 wcross_scale *= 1 - cvar("_menu_alpha");
734                                 wcross_alpha *= 1 - cvar("_menu_alpha");
735
736                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
737
738                                 // ring around crosshair representing bullets left in camping rifle clip
739                                 if (activeweapon == WEP_CAMPINGRIFLE)
740                                 {
741                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
742                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 8);
743                                 }
744                                 else
745                                         bullets = 0;
746
747 #define CROSSHAIR_DRAW_RING(i,j,sz,wcross_name,wcross_alpha) \
748                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x * ring_scale + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y * ring_scale + j * wcross_blur)), strcat("gfx/hud/rifle_ring_", ftos(bullets)), sz * wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
749
750 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
751                                 do \
752                                 { \
753                                         if(wcross_blur > 0) \
754                                         { \
755                                                 for(i = -2; i <= 2; ++i) \
756                                                         for(j = -2; j <= 2; ++j) \
757                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
758                                         } \
759                                         else \
760                                         { \
761                                                 M(0,0,sz,wcross_name,wcross_alpha); \
762                                         } \
763                                 } \
764                                 while(0)
765
766 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
767                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
768
769 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
770                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
771
772                                 if(bullets)
773                                 {
774                                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_RING, wcross_resolution, wcross_name, wcross_alpha);
775                                 }
776
777                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
778                                 {
779                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
780                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
781                                         f = 1 - f;
782                                 }
783                                 else
784                                 {
785                                         f = 1;
786                                 }
787                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
788                                 wcross_name_alpha_goal_prev = f;
789                         }
790                 }
791                 else
792                 {
793                         wcross_scale_prev = 0;
794                         wcross_alpha_prev = 0;
795                         wcross_scale_goal_prev = 0;
796                         wcross_alpha_goal_prev = 0;
797                         wcross_changedonetime = 0;
798                         if(wcross_name_goal_prev)
799                                 strunzone(wcross_name_goal_prev);
800                         wcross_name_goal_prev = string_null;
801                         if(wcross_name_goal_prev_prev)
802                                 strunzone(wcross_name_goal_prev_prev);
803                         wcross_name_goal_prev_prev = string_null;
804                         wcross_name_changestarttime = 0;
805                         wcross_name_changedonetime = 0;
806                         wcross_name_alpha_goal_prev = 0;
807                         wcross_name_alpha_goal_prev_prev = 0;
808                         wcross_resolution_goal_prev = 0;
809                         wcross_resolution_goal_prev_prev = 0;
810                 }
811         }
812
813         if(NextFrameCommand)
814         {
815                 localcmd("\n", NextFrameCommand, "\n");
816                 NextFrameCommand = string_null;
817         }
818
819         // we must do this check AFTER a frame was rendered, or it won't work
820         if(cs_project_is_b0rked == 0)
821         {
822                 string w0, h0;
823                 w0 = cvar_string("vid_conwidth");
824                 h0 = cvar_string("vid_conheight");
825                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
826                 //R_SetView(VF_FOV, '90 90 0');
827                 R_SetView(VF_ORIGIN, '0 0 0');
828                 R_SetView(VF_ANGLES, '0 0 0');
829                 R_SetView(VF_PERSPECTIVE, 1);
830                 makevectors('0 0 0');
831                 vector v1, v2;
832                 cvar_set("vid_conwidth", "800");
833                 cvar_set("vid_conheight", "600");
834                 v1 = cs_project(v_forward);
835                 cvar_set("vid_conwidth", "640");
836                 cvar_set("vid_conheight", "480");
837                 v2 = cs_project(v_forward);
838                 if(v1 == v2)
839                         cs_project_is_b0rked = 1;
840                 else
841                         cs_project_is_b0rked = -1;
842                 cvar_set("vid_conwidth", w0);
843                 cvar_set("vid_conheight", h0);
844         }
845
846         // be safe against triggerbots until everyone has the fixed engine
847         // this call is meant to overwrite the trace globals by something
848         // unsuspicious
849         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);
850 }
851
852 void Sbar_Draw();
853 void CSQC_spider_HUD()
854 {
855         float rockets,reload,heat,hp,shield,i;
856         vector p,pp;
857
858     p = drawgetimagesize(SPIDER_CROSS);
859     p_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
860     p_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
861     drawpic('0.5 0 0' * (vid_conwidth - p_x) + '0 0.5 0' * (vid_conheight - p_y), SPIDER_CROSS, p, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
862
863     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
864         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
865         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
866         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
867         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
868
869         // Draw health bar
870         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
871         p = p + '0 1 0' * vid_conheight - '0 32 0';
872         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
873         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
874         p_y += 8;
875         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
876         p_x += 256 * hp;
877         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
878
879         // Draw minigun heat indicator
880         p = '0.5 0 0' * (vid_conwidth - 256);
881         p = p + '0 1 0' * vid_conheight - '0 34  0';
882         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
883         p_x += 256 * (1-heat);
884         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
885
886         // Draw rocket icons for loaded/empty tubes.
887         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
888         pp += '0 1 0' * vid_conheight - '0 64 0';
889         for(i = 0; i < 8; ++i)
890         {
891                 p = pp + '1 0 0' * (rkt_size * i);
892                 if(rockets == 8)
893                 {
894                         if(floor(reload * 8) == i)
895                         {
896                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
897                         }
898                         else if(i < reload * 8)
899                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
900                         else
901                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
902                 }
903                 else
904                 {
905                         if(i < rockets)
906                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
907                         else
908                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
909                 }
910         }
911
912         if (sb_showscores)
913         {
914                 Sbar_DrawScoreboard();
915                 Sbar_DrawCenterPrint();
916         }
917
918 }
919
920 void CSQC_WAKIZASHI_HUD()
921 {
922         // 0--1 floats. 1 = 100%, 0.6 = 50%.
923         float health, shield, energy, rockets;
924
925         vector p;
926
927     p = drawgetimagesize(SPIDER_CROSS);
928     p_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
929     p_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
930     drawpic('0.5 0 0' * (vid_conwidth - p_x) + '0 0.5 0' * (vid_conheight - p_y), SPIDER_CROSS, p, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
931
932 /*
933 const float STAT_VEHICLESTAT_HEALTH  = 60;
934 const float STAT_VEHICLESTAT_SHIELD  = 61;
935 const float STAT_VEHICLESTAT_ENERGY  = 62;
936 const float STAT_VEHICLESTAT_AMMO1   = 63;
937 const float STAT_VEHICLESTAT_RELAOD1 = 64;
938 const float STAT_VEHICLESTAT_AMMO2   = 65;
939 const float STAT_VEHICLESTAT_RELOAD2 = 66;
940 */
941     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
942         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
943         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
944         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
945
946
947         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
948         p = p + '0 1 0' * vid_conheight - '0 32 0';
949
950         // Draw health bar
951         p_y += 8;
952         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
953         p_x += 256 * health;
954         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
955
956         // Draw shiled bar
957         p_x -= 256 * health;
958         p_y += 4;
959         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
960
961         // Draw energy
962         //p_x -= 256 * health;
963         p_y -= 8;
964         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
965
966         // Draw rockets bar
967         p_y += 12;
968         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
969
970
971         /*
972         // Draw energy bar
973         p = '0.5 0 0' * (vid_conwidth - 256);
974         p = p + '0 1 0' * vid_conheight - '0 34  0';
975         drawfill(p, '256 0 0' * (1 - energy) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
976         p_x += 256 * (1 - energy);
977         drawfill(p, '256 0 0' * energy  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
978
979         // Draw rockets bar
980         p_y += 8;
981         drawfill(p, '256 0 0' * rockets + '0 8 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
982         p_x += 256 * health;
983         drawfill(p, '256 0 0' * (1 - rockets) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
984     */
985
986
987         if (sb_showscores)
988         {
989                 Sbar_DrawScoreboard();
990                 Sbar_DrawCenterPrint();
991         }
992
993 }
994
995
996 void CSQC_common_hud(void)
997 {
998         // Sbar_SortFrags(); done in Sbar_Draw
999         float hud;
1000         hud = getstati(STAT_HUD);
1001
1002         //hud = 10;
1003         switch(hud)
1004         {
1005                 case HUD_NORMAL:
1006                         Sbar_Draw();
1007                         break;
1008
1009                 case HUD_SPIDERBOT:
1010                         CSQC_spider_HUD();
1011                         break;
1012
1013                 case HUD_WAKIZASHI:
1014                         CSQC_WAKIZASHI_HUD();
1015                         break;
1016         }
1017 }
1018
1019
1020 // following vectors must be global to allow seamless switching between camera modes
1021 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1022 void CSQC_Demo_Camera()
1023 {
1024         float speed, attenuation, dimensions;
1025         vector tmp, delta;
1026
1027         if( cvar("camera_reset") || !camera_mode )
1028         {
1029                 camera_offset = '0 0 0';
1030                 current_angles = '0 0 0';
1031                 camera_direction = '0 0 0';
1032                 camera_offset_z += 30;
1033                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1034                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1035                 current_origin = view_origin;
1036                 current_camera_offset  = camera_offset;
1037                 cvar_set("camera_reset", "0");
1038                 camera_mode = CAMERA_CHASE;
1039         }
1040
1041         // Camera angles
1042         if( camera_roll )
1043                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1044
1045         if(cvar("camera_look_player"))
1046         {
1047                 local vector dir;
1048                 local float n;
1049
1050                 dir = normalize(view_origin - current_position);
1051                 n = mouse_angles_z;
1052                 mouse_angles = vectoangles(dir);
1053                 mouse_angles_x = mouse_angles_x * -1;
1054                 mouse_angles_z = n;
1055         }
1056         else
1057         {
1058                 tmp = getmousepos() * 0.1;
1059                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1060                 {
1061                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1062                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1063                 }
1064         }
1065
1066         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1067         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1068         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1069         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1070
1071         // Fix difference when angles don't have the same sign
1072         delta = '0 0 0';
1073         if(mouse_angles_y < -60 && current_angles_y > 60)
1074                 delta = '0 360 0';
1075         if(mouse_angles_y > 60 && current_angles_y < -60)
1076                 delta = '0 -360 0';
1077
1078         if(cvar("camera_look_player"))
1079                 attenuation = cvar("camera_look_attenuation");
1080         else
1081                 attenuation = cvar("camera_speed_attenuation");
1082
1083         attenuation = 1 / max(1, attenuation);
1084         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1085
1086         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1087         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1088         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1089         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1090
1091         // Camera position
1092         tmp = '0 0 0';
1093         dimensions = 0;
1094
1095         if( camera_direction_x )
1096         {
1097                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1098                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1099                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1100                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1101                 ++dimensions;
1102         }
1103
1104         if( camera_direction_y )
1105         {
1106                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1107                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1108                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1109                 ++dimensions;
1110         }
1111
1112         if( camera_direction_z )
1113         {
1114                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1115                 ++dimensions;
1116         }
1117
1118         if(cvar("camera_free"))
1119                 speed = cvar("camera_speed_free");
1120         else
1121                 speed = cvar("camera_speed_chase");
1122
1123         if(dimensions)
1124         {
1125                 speed = speed * sqrt(1 / dimensions);
1126                 camera_offset += tmp * speed;
1127         }
1128
1129         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1130
1131         // Camera modes
1132         if( cvar("camera_free") )
1133         {
1134                 if ( camera_mode == CAMERA_CHASE )
1135                 {
1136                         current_camera_offset = current_origin + current_camera_offset;
1137                         camera_offset = current_origin + camera_offset;
1138                 }
1139
1140                 camera_mode = CAMERA_FREE;
1141                 current_position = current_camera_offset;
1142         }
1143         else
1144         {
1145                 if ( camera_mode == CAMERA_FREE )
1146                 {
1147                         current_origin = view_origin;
1148                         camera_offset = camera_offset - current_origin;
1149                         current_camera_offset = current_camera_offset - current_origin;
1150                 }
1151
1152                 camera_mode = CAMERA_CHASE;
1153
1154                 if(cvar("camera_chase_smoothly"))
1155                         current_origin += (view_origin - current_origin) * attenuation;
1156                 else
1157                         current_origin = view_origin;
1158
1159                 current_position = current_origin + current_camera_offset;
1160         }
1161
1162         R_SetView(VF_ANGLES, current_angles);
1163         R_SetView(VF_ORIGIN, current_position);
1164 }