data/qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/spiderbot/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/spiderbot/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(self, CHAN_VOICE, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_ELECTRO: // projectile has a size!
 295                         mi = '0 0 -3';
 296                         ma = '0 0 -3';
 297                         break;
 298         }
 299
 300         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 301
 302         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 303         trueaimpoint = trace_endpos;
 304
 305         if(vecs_x > 0)
 306                 vecs_y = -vecs_y;
 307         else
 308                 vecs = '0 0 0';
 309
 310         dv = view_right * vecs_y + view_up * vecs_z;
 311         w_shotorg = view_origin + dv;
 312
 313         // now move the vecs forward as much as requested if possible
 314         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 315         w_shotorg = trace_endpos - view_forward * nudge;
 316
 317         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 318         shottype = EnemyHitCheck();
 319         if(shottype != SHOTTYPE_HITWORLD)
 320                 return shottype;
 321
 322 #if 0
 323         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 324         // or rather, I know why, but see no fix
 325         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 326                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 327                 return SHOTTYPE_HITOBSTRUCTION;
 328 #endif
 329
 330         return SHOTTYPE_HITWORLD;
 331 }
 332
 333 void CSQC_common_hud(void);
 334
 335 void CSQC_kh_hud(void);
 336 void CSQC_ctf_hud(void);
 337 void PostInit(void);
 338 void CSQC_Demo_Camera();
 339 float Sbar_WouldDrawScoreboard ();
 340 float view_set;
 341 float camera_mode;
 342 string NextFrameCommand;
 343 void CSQC_spider_HUD();
 344 void CSQC_UpdateView(float w, float h)
 345 {
 346         entity e;
 347         float fov;
 348         float f, i, j;
 349         vector v;
 350
 351         WaypointSprite_Load();
 352
 353         if(spectatee_status)
 354                 myteam = GetPlayerColor(spectatee_status - 1);
 355         else
 356                 myteam = GetPlayerColor(player_localentnum - 1);
 357
 358         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 359
 360         // Render the Scene
 361         if(!intermission || !view_set)
 362         {
 363                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);
 364                 makevectors(view_angles);
 365                 view_forward = v_forward;
 366                 view_right = v_right;
 367                 view_up = v_up;
 368                 view_set = 1;
 369         }
 370
 371         hudconf_active = cvar("_hud_configure");
 372         if(hudconf_active)
 373                 R_SetView(VF_ANGLES, self.angles); // TODO: this should freeze the view as it is, not change it to '0 0 0' or whatever it currently does...
 374
 375         vid_width = w;
 376         vid_height = h;
 377
 378 #ifdef BLURTEST
 379         if(time > blurtest_time0 && time < blurtest_time1)
 380         {
 381                 float r, t;
 382
 383                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 384                 r = t * blurtest_radius;
 385                 f = 1 / pow(t, blurtest_power) - 1;
 386
 387                 cvar_set("r_glsl_postprocess", "1");
 388                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 389         }
 390         else
 391         {
 392                 cvar_set("r_glsl_postprocess", "0");
 393                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 394         }
 395 #endif
 396
 397         Fog_Force();
 398
 399         drawframetime = max(0.000001, time - drawtime);
 400         drawtime = time;
 401
 402         // watch for gametype changes here...
 403         // in ParseStuffCMD the cmd isn't executed yet :/
 404         // might even be better to add the gametype to TE_CSQC_INIT...?
 405         if(!postinit)
 406                 PostInit();
 407
 408         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 409                 if(calledhooks & HOOK_START)
 410                 {
 411                         localcmd("\ncl_hook_gameend;");
 412                         calledhooks |= HOOK_END;
 413                 }
 414
 415         CheckForGamestartChange();
 416         serverAnnouncer();
 417         maptimeAnnouncer();
 418         carrierAnnouncer();
 419
 420         fov = cvar("fov");
 421         if(button_zoom || fov <= 59.5)
 422         {
 423                 if(!zoomscript_caught)
 424                 {
 425                         localcmd("+button4\n");
 426                         zoomscript_caught = 1;
 427                         ignore_plus_zoom += 1;
 428                 }
 429         }
 430         else
 431         {
 432                 if(zoomscript_caught)
 433                 {
 434                         localcmd("-button4\n");
 435                         zoomscript_caught = 0;
 436                         ignore_minus_zoom += 1;
 437                 }
 438         }
 439
 440         hud_alpha_fg = cvar_or("hud_alpha_fg", 1) * (1 - cvar("_menu_alpha"));
 441         sbar_currentammo = cvar("hud_showcurrentammo");
 442         hud_hudselector = cvar("hud_hudselector");
 443         hud_accuracy_hud = cvar_or("hud_accuracy_hud", 1);
 444         ColorTranslateMode = cvar("cl_stripcolorcodes");
 445         activeweapon = getstati(STAT_SWITCHWEAPON);
 446         f = cvar("teamplay");
 447         if(f != teamplay)
 448         {
 449                 teamplay = f;
 450                 Sbar_InitScores();
 451         }
 452
 453         if(last_weapon != activeweapon) {
 454                 weapontime = time;
 455                 last_weapon = activeweapon;
 456         }
 457
 458         // ALWAYS Clear Current Scene First
 459         R_ClearScene();
 460
 461         // Assign Standard Viewflags
 462         // Draw the World (and sky)
 463         R_SetView(VF_DRAWWORLD, 1);
 464
 465         // Set the console size vars
 466         vid_conwidth = cvar("vid_conwidth");
 467         vid_conheight = cvar("vid_conheight");
 468         vid_pixelheight = cvar("vid_pixelheight");
 469
 470         R_SetView(VF_FOV, GetCurrentFov(fov));
 471
 472         // Camera for demo playback
 473         if(camera_active)
 474         {
 475                 if(cvar("camera_enable"))
 476                         CSQC_Demo_Camera();
 477                 else
 478                 {
 479                         cvar_set("chase_active", ftos(chase_active_backup));
 480                         cvar_set("cl_demo_mousegrab", "0");
 481                         camera_active = FALSE;
 482                 }
 483         }
 484 #ifdef CAMERATEST
 485         else if(cvar("camera_enable"))
 486 #else
 487         else if(cvar("camera_enable") && isdemo())
 488 #endif
 489         {
 490                 // Enable required Darkplaces cvars
 491                 chase_active_backup = cvar("chase_active");
 492                 cvar_set("chase_active", "2");
 493                 cvar_set("cl_demo_mousegrab", "1");
 494                 camera_active = TRUE;
 495                 camera_mode = FALSE;
 496         }
 497
 498         // Draw the Crosshair
 499         float scoreboard_active;
 500         scoreboard_active = Sbar_WouldDrawScoreboard();
 501         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 502
 503         // Draw the Engine Status Bar (the default Quake HUD)
 504         R_SetView(VF_DRAWENGINESBAR, 0);
 505
 506         // fetch this one only once per frame
 507         sbar_showbinds = cvar("sbar_showbinds");
 508         sbar_showbinds_limit = cvar("sbar_showbinds_limit");
 509
 510         // Update the mouse position
 511         /*
 512            mousepos_x = vid_conwidth;
 513            mousepos_y = vid_conheight;
 514            mousepos = mousepos*0.5 + getmousepos();
 515          */
 516
 517         e = self;
 518         for(self = world; (self = nextent(self)); )
 519                 if(self.draw)
 520                         self.draw();
 521         self = e;
 522
 523         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 524         R_RenderScene();
 525
 526         // now switch to 2D drawing mode by calling a 2D drawing function
 527         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 528         // next R_RenderScene call
 529         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 530
 531         // Draw the mouse cursor
 532         // NOTE: drawpic must happen after R_RenderScene for some reason
 533         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 534         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 535         //self = edict_num(player_localnum);
 536         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 537         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 538         // as long as the ctf part isn't in, this is useless
 539         if(menu_visible)
 540                 menu_show();
 541
 542         /*if(gametype == GAME_CTF)
 543           {
 544           ctf_view();
 545           } else */
 546
 547         // draw 2D entities
 548         e = self;
 549         for(self = world; (self = nextent(self)); )
 550                 if(self.draw2d)
 551                         self.draw2d();
 552         self = e;
 553
 554         // draw radar
 555         if(
 556                         ons_showmap
 557                         ||
 558                         (
 559                          !scoreboard_active
 560                          &&
 561                          cvar_string("cl_teamradar") != "0"
 562                          &&
 563                          (
 564                           cvar("cl_teamradar") == 2
 565                           ||
 566                           teamplay
 567                          )
 568                         )
 569           )
 570                 teamradar_view();
 571
 572         // draw sbar
 573         if(cvar("r_letterbox") == 0) {
 574                 if (cvar("cl_showpressedkeys")) { // draw pressed keys when spectating and playing
 575                         if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)
 576                                 HUD_DrawPressedKeys();
 577                 }
 578
 579                 if (cvar("cl_showspeed"))
 580                         HUD_ShowSpeed();
 581                 if (cvar("cl_showacceleration"))
 582                         HUD_ShowAcceleration();
 583
 584                 HUD_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120
 585         }
 586
 587         float hud;
 588         hud = getstati(STAT_HUD);
 589         if(hud == HUD_SPIDERBOT)
 590         {
 591                 CSQC_spider_HUD();
 592         }
 593         else if(hud == HUD_WAKIZASHI)
 594         CSQC_WAKIZASHI_HUD();
 595         else
 596         {
 597                 if(cvar("r_letterbox") == 0)
 598                         if(cvar("viewsize") < 120)
 599                                 CSQC_common_hud();
 600
 601                 // crosshair goes VERY LAST
 602                 if(!scoreboard_active && !ons_showmap && !camera_active && !hudconf_active) {
 603                         // TrueAim check
 604                         float shottype;
 605                         float bullets, ring_scale;
 606                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 607                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 608                         wcross_origin_z = 0;
 609                         if(cvar("crosshair_hittest"))
 610                         {
 611                                 vector wcross_oldorigin;
 612                                 wcross_oldorigin = wcross_origin;
 613                                 shottype = TrueAimCheck();
 614                                 if(shottype == SHOTTYPE_HITWORLD)
 615                                 {
 616                                         v = wcross_origin - wcross_oldorigin;
 617                                         v_x /= vid_conwidth;
 618                                         v_y /= vid_conheight;
 619                                         if(vlen(v) > 0.01)
 620                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 621                                 }
 622                                 if(!cvar("crosshair_hittest_showimpact"))
 623                                         wcross_origin = wcross_oldorigin;
 624                         }
 625                         else
 626                                 shottype = SHOTTYPE_HITWORLD;
 627
 628                         string wcross_style;
 629                         wcross_style = cvar_string("crosshair");
 630
 631                         if (wcross_style != "0") {
 632                                 vector wcross_color, wcross_size;
 633                                 string wcross_wep, wcross_name;
 634                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;
 635
 636                                 wcross_color_x = cvar("crosshair_color_red");
 637                                 wcross_color_y = cvar("crosshair_color_green");
 638                                 wcross_color_z = cvar("crosshair_color_blue");
 639                                 wcross_alpha = cvar("crosshair_color_alpha");
 640                                 wcross_resolution = cvar("crosshair_size");
 641                                 if (cvar("crosshair_per_weapon")) {
 642                                         e = get_weaponinfo(activeweapon);
 643                                         if (e && e.netname != "")
 644                                         {
 645                                                 wcross_wep = e.netname;
 646                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 647                                                 if(wcross_style == "")
 648                                                         wcross_style = e.netname;
 649
 650                                                 if(!cvar("crosshair_color_override"))
 651                                                 {
 652                                                         wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 653                                                         wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 654                                                         wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 655                                                 }
 656
 657                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 658                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 659                                         }
 660                                 }
 661
 662                                 wcross_name = strcat("gfx/crosshair", wcross_style);
 663
 664                                 if(cvar("crosshair_effect_scalefade"))
 665                                 {
 666                                         wcross_scale = wcross_resolution;
 667                                         wcross_resolution = 1;
 668                                 }
 669                                 else
 670                                 {
 671                                         wcross_scale = 1;
 672                                 }
 673
 674                                 if(shottype == SHOTTYPE_HITENEMY)
 675                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 676                                 if(shottype == SHOTTYPE_HITTEAM)
 677                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 678
 679                                 f = cvar("crosshair_effect_speed");
 680                                 if(f < 0)
 681                                         f *= -2 * g_weaponswitchdelay;
 682                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 683                                 {
 684                                         wcross_changedonetime = time + f;
 685                                 }
 686                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 687                                 {
 688                                         wcross_name_changestarttime = time;
 689                                         wcross_name_changedonetime = time + f;
 690                                         if(wcross_name_goal_prev_prev)
 691                                                 strunzone(wcross_name_goal_prev_prev);
 692                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 693                                         wcross_name_goal_prev = strzone(wcross_name);
 694                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 695                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 696                                         wcross_resolution_goal_prev = wcross_resolution;
 697                                 }
 698
 699                                 wcross_scale_goal_prev = wcross_scale;
 700                                 wcross_alpha_goal_prev = wcross_alpha;
 701                                 wcross_color_goal_prev = wcross_color;
 702
 703                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 704                                 {
 705                                         wcross_blur = 1;
 706                                         wcross_alpha *= 0.75;
 707                                 }
 708                                 else
 709                                         wcross_blur = 0;
 710                                 // *_prev is at time-frametime
 711                                 // * is at wcross_changedonetime+f
 712                                 // what do we have at time?
 713                                 if(time < wcross_changedonetime)
 714                                 {
 715                                         f = frametime / (wcross_changedonetime - time + frametime);
 716                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 717                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 718                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 719                                 }
 720
 721                                 wcross_scale_prev = wcross_scale;
 722                                 wcross_alpha_prev = wcross_alpha;
 723                                 wcross_color_prev = wcross_color;
 724
 725                                 wcross_scale *= 1 - cvar("_menu_alpha");
 726                                 wcross_alpha *= 1 - cvar("_menu_alpha");
 727
 728                                 // ring around crosshair representing bullets left in camping rifle clip
 729                                 if (activeweapon == WEP_CAMPINGRIFLE)
 730                                 {
 731                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 732                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 8);
 733                                 }
 734                                 else
 735                                         bullets = 0;
 736
 737 #define CROSSHAIR_DRAW_RING(i,j,sz,wcross_name,wcross_alpha) \
 738                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x * ring_scale + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y * ring_scale + j * wcross_blur)), strcat("gfx/hud/rifle_ring_", ftos(bullets)), sz * wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 739
 740 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 741                                 do \
 742                                 { \
 743                                         if(wcross_blur > 0) \
 744                                         { \
 745                                                 for(i = -2; i <= 2; ++i) \
 746                                                         for(j = -2; j <= 2; ++j) \
 747                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 748                                         } \
 749                                         else \
 750                                         { \
 751                                                 M(0,0,sz,wcross_name,wcross_alpha); \
 752                                         } \
 753                                 } \
 754                                 while(0)
 755
 756 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 757                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 758
 759 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 760                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 761
 762                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 763                                 {
 764                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 765                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 766                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 767                                         f = 1 - f;
 768                                 }
 769                                 else
 770                                 {
 771                                         f = 1;
 772                                 }
 773
 774                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 775                                 if(bullets)
 776                                 {
 777                                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_RING, wcross_resolution, wcross_name, wcross_alpha);
 778                                 }
 779                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 780                                 wcross_name_alpha_goal_prev = f;
 781                         }
 782                 }
 783                 else
 784                 {
 785                         wcross_scale_prev = 0;
 786                         wcross_alpha_prev = 0;
 787                         wcross_scale_goal_prev = 0;
 788                         wcross_alpha_goal_prev = 0;
 789                         wcross_changedonetime = 0;
 790                         if(wcross_name_goal_prev)
 791                                 strunzone(wcross_name_goal_prev);
 792                         wcross_name_goal_prev = string_null;
 793                         if(wcross_name_goal_prev_prev)
 794                                 strunzone(wcross_name_goal_prev_prev);
 795                         wcross_name_goal_prev_prev = string_null;
 796                         wcross_name_changestarttime = 0;
 797                         wcross_name_changedonetime = 0;
 798                         wcross_name_alpha_goal_prev = 0;
 799                         wcross_name_alpha_goal_prev_prev = 0;
 800                         wcross_resolution_goal_prev = 0;
 801                         wcross_resolution_goal_prev_prev = 0;
 802                 }
 803         }
 804
 805         if(NextFrameCommand)
 806         {
 807                 localcmd("\n", NextFrameCommand, "\n");
 808                 NextFrameCommand = string_null;
 809         }
 810
 811         // we must do this check AFTER a frame was rendered, or it won't work
 812         if(cs_project_is_b0rked == 0)
 813         {
 814                 string w0, h0;
 815                 w0 = cvar_string("vid_conwidth");
 816                 h0 = cvar_string("vid_conheight");
 817                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 818                 //R_SetView(VF_FOV, '90 90 0');
 819                 R_SetView(VF_ORIGIN, '0 0 0');
 820                 R_SetView(VF_ANGLES, '0 0 0');
 821                 R_SetView(VF_PERSPECTIVE, 1);
 822                 makevectors('0 0 0');
 823                 vector v1, v2;
 824                 cvar_set("vid_conwidth", "800");
 825                 cvar_set("vid_conheight", "600");
 826                 v1 = cs_project(v_forward);
 827                 cvar_set("vid_conwidth", "640");
 828                 cvar_set("vid_conheight", "480");
 829                 v2 = cs_project(v_forward);
 830                 if(v1 == v2)
 831                         cs_project_is_b0rked = 1;
 832                 else
 833                         cs_project_is_b0rked = -1;
 834                 cvar_set("vid_conwidth", w0);
 835                 cvar_set("vid_conheight", h0);
 836         }
 837
 838         if(hudconf_active)
 839                 HUD_Panel_Mouse();
 840         // be safe against triggerbots until everyone has the fixed engine
 841         // this call is meant to overwrite the trace globals by something
 842         // unsuspicious
 843         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);
 844 }
 845
 846 void CSQC_spider_HUD()
 847 {
 848         float rockets,reload,heat,hp,shield,i;
 849         vector p,pp;
 850
 851     p = drawgetimagesize(SPIDER_CROSS);
 852     p_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 853     p_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 854     drawpic('0.5 0 0' * (vid_conwidth - p_x) + '0 0.5 0' * (vid_conheight - p_y), SPIDER_CROSS, p, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 855
 856     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
 857         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
 858         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
 859         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
 860         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
 861
 862         // Draw health bar
 863         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 864         p = p + '0 1 0' * vid_conheight - '0 32 0';
 865         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
 866         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
 867         p_y += 8;
 868         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
 869         p_x += 256 * hp;
 870         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 871
 872         // Draw minigun heat indicator
 873         p = '0.5 0 0' * (vid_conwidth - 256);
 874         p = p + '0 1 0' * vid_conheight - '0 34  0';
 875         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 876         p_x += 256 * (1-heat);
 877         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 878
 879         // Draw rocket icons for loaded/empty tubes.
 880         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 881         pp += '0 1 0' * vid_conheight - '0 64 0';
 882         for(i = 0; i < 8; ++i)
 883         {
 884                 p = pp + '1 0 0' * (rkt_size * i);
 885                 if(rockets == 8)
 886                 {
 887                         if(floor(reload * 8) == i)
 888                         {
 889                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
 890                         }
 891                         else if(i < reload * 8)
 892                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
 893                         else
 894                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
 895                 }
 896                 else
 897                 {
 898                         if(i < rockets)
 899                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
 900                         else
 901                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
 902                 }
 903         }
 904
 905         if (sb_showscores)
 906         {
 907                 Sbar_DrawScoreboard();
 908                 HUD_DrawCenterPrint();
 909         }
 910
 911 }
 912
 913 void CSQC_WAKIZASHI_HUD()
 914 {
 915         // 0--1 floats. 1 = 100%, 0.6 = 50%.
 916         float health, shield, energy, rockets;
 917
 918         vector p;
 919
 920     p = drawgetimagesize(SPIDER_CROSS);
 921     p_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 922     p_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 923     drawpic('0.5 0 0' * (vid_conwidth - p_x) + '0 0.5 0' * (vid_conheight - p_y), SPIDER_CROSS, p, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 924
 925 /*
 926 const float STAT_VEHICLESTAT_HEALTH  = 60;
 927 const float STAT_VEHICLESTAT_SHIELD  = 61;
 928 const float STAT_VEHICLESTAT_ENERGY  = 62;
 929 const float STAT_VEHICLESTAT_AMMO1   = 63;
 930 const float STAT_VEHICLESTAT_RELAOD1 = 64;
 931 const float STAT_VEHICLESTAT_AMMO2   = 65;
 932 const float STAT_VEHICLESTAT_RELOAD2 = 66;
 933 */
 934     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
 935         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
 936         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
 937         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
 938
 939
 940         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 941         p = p + '0 1 0' * vid_conheight - '0 32 0';
 942
 943         // Draw health bar
 944         p_y += 8;
 945         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
 946         p_x += 256 * health;
 947         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 948
 949         // Draw shiled bar
 950         p_x -= 256 * health;
 951         p_y += 4;
 952         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
 953
 954         // Draw energy
 955         //p_x -= 256 * health;
 956         p_y -= 8;
 957         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
 958
 959         // Draw rockets bar
 960         p_y += 12;
 961         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
 962
 963
 964         /*
 965         // Draw energy bar
 966         p = '0.5 0 0' * (vid_conwidth - 256);
 967         p = p + '0 1 0' * vid_conheight - '0 34  0';
 968         drawfill(p, '256 0 0' * (1 - energy) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 969         p_x += 256 * (1 - energy);
 970         drawfill(p, '256 0 0' * energy  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 971
 972         // Draw rockets bar
 973         p_y += 8;
 974         drawfill(p, '256 0 0' * rockets + '0 8 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
 975         p_x += 256 * health;
 976         drawfill(p, '256 0 0' * (1 - rockets) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 977     */
 978
 979
 980         if (sb_showscores)
 981         {
 982                 Sbar_DrawScoreboard();
 983                 HUD_DrawCenterPrint();
 984         }
 985
 986 }
 987
 988
 989 void CSQC_common_hud(void)
 990 {
 991         // Sbar_SortFrags(); done in Sbar_Draw
 992         float hud;
 993         hud = getstati(STAT_HUD);
 994
 995         //hud = 10;
 996         switch(hud)
 997         {
 998                 case HUD_NORMAL:
 999                         HUD_Main();
1000                         break;
1001
1002                 case HUD_SPIDERBOT:
1003                         CSQC_spider_HUD();
1004                         break;
1005
1006                 case HUD_WAKIZASHI:
1007                         CSQC_WAKIZASHI_HUD();
1008                         break;
1009         }
1010 }
1011
1012
1013 // following vectors must be global to allow seamless switching between camera modes
1014 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1015 void CSQC_Demo_Camera()
1016 {
1017         float speed, attenuation, dimensions;
1018         vector tmp, delta;
1019
1020         if( cvar("camera_reset") || !camera_mode )
1021         {
1022                 camera_offset = '0 0 0';
1023                 current_angles = '0 0 0';
1024                 camera_direction = '0 0 0';
1025                 camera_offset_z += 30;
1026                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1027                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1028                 current_origin = view_origin;
1029                 current_camera_offset  = camera_offset;
1030                 cvar_set("camera_reset", "0");
1031                 camera_mode = CAMERA_CHASE;
1032         }
1033
1034         // Camera angles
1035         if( camera_roll )
1036                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1037
1038         if(cvar("camera_look_player"))
1039         {
1040                 local vector dir;
1041                 local float n;
1042
1043                 dir = normalize(view_origin - current_position);
1044                 n = mouse_angles_z;
1045                 mouse_angles = vectoangles(dir);
1046                 mouse_angles_x = mouse_angles_x * -1;
1047                 mouse_angles_z = n;
1048         }
1049         else
1050         {
1051                 tmp = getmousepos() * 0.1;
1052                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1053                 {
1054                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1055                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1056                 }
1057         }
1058
1059         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1060         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1061         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1062         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1063
1064         // Fix difference when angles don't have the same sign
1065         delta = '0 0 0';
1066         if(mouse_angles_y < -60 && current_angles_y > 60)
1067                 delta = '0 360 0';
1068         if(mouse_angles_y > 60 && current_angles_y < -60)
1069                 delta = '0 -360 0';
1070
1071         if(cvar("camera_look_player"))
1072                 attenuation = cvar("camera_look_attenuation");
1073         else
1074                 attenuation = cvar("camera_speed_attenuation");
1075
1076         attenuation = 1 / max(1, attenuation);
1077         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1078
1079         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1080         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1081         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1082         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1083
1084         // Camera position
1085         tmp = '0 0 0';
1086         dimensions = 0;
1087
1088         if( camera_direction_x )
1089         {
1090                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1091                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1092                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1093                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1094                 ++dimensions;
1095         }
1096
1097         if( camera_direction_y )
1098         {
1099                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1100                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1101                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1102                 ++dimensions;
1103         }
1104
1105         if( camera_direction_z )
1106         {
1107                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1108                 ++dimensions;
1109         }
1110
1111         if(cvar("camera_free"))
1112                 speed = cvar("camera_speed_free");
1113         else
1114                 speed = cvar("camera_speed_chase");
1115
1116         if(dimensions)
1117         {
1118                 speed = speed * sqrt(1 / dimensions);
1119                 camera_offset += tmp * speed;
1120         }
1121
1122         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1123
1124         // Camera modes
1125         if( cvar("camera_free") )
1126         {
1127                 if ( camera_mode == CAMERA_CHASE )
1128                 {
1129                         current_camera_offset = current_origin + current_camera_offset;
1130                         camera_offset = current_origin + camera_offset;
1131                 }
1132
1133                 camera_mode = CAMERA_FREE;
1134                 current_position = current_camera_offset;
1135         }
1136         else
1137         {
1138                 if ( camera_mode == CAMERA_FREE )
1139                 {
1140                         current_origin = view_origin;
1141                         camera_offset = camera_offset - current_origin;
1142                         current_camera_offset = current_camera_offset - current_origin;
1143                 }
1144
1145                 camera_mode = CAMERA_CHASE;
1146
1147                 if(cvar("camera_chase_smoothly"))
1148                         current_origin += (view_origin - current_origin) * attenuation;
1149                 else
1150                         current_origin = view_origin;
1151
1152                 current_position = current_origin + current_camera_offset;
1153         }
1154
1155         R_SetView(VF_ANGLES, current_angles);
1156         R_SetView(VF_ORIGIN, current_position);
1157 }