data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63         float i;
  64         CSQC_CheckEngine();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         drawfont = 0;
  72         menu_visible = FALSE;
  73         menu_show = menu_show_error;
  74         menu_action = menu_sub_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkey(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //ctf_temp_1 = "";
  82         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  83         //registercmd("ctf_menu");
  84         registercmd("ons_map");
  85         //registercmd("menu_action");
  86
  87         registercmd("+button3");
  88         registercmd("-button3");
  89         registercmd("+button4");
  90         registercmd("-button4");
  91         registercmd("+showaccuracy");registercmd("-showaccuracy");
  92
  93 #ifndef CAMERATEST
  94         if(isdemo())
  95         {
  96 #endif
  97                 registercmd("+forward");registercmd("-forward");
  98                 registercmd("+back");registercmd("-back");
  99                 registercmd("+moveup");registercmd("-moveup");
 100                 registercmd("+movedown");registercmd("-movedown");
 101                 registercmd("+moveright");registercmd("-moveright");
 102                 registercmd("+moveleft");registercmd("-moveleft");
 103                 registercmd("+roll_right");registercmd("-roll_right");
 104                 registercmd("+roll_left");registercmd("-roll_left");
 105 #ifndef CAMERATEST
 106         }
 107 #endif
 108         registercvar("sbar_usecsqc", "1");
 109         registercvar("sbar_columns", "default", CVAR_SAVE);
 110
 111         gametype = 0;
 112
 113         // sbar_fields uses strunzone on the titles!
 114         for(i = 0; i < MAX_SBAR_FIELDS; ++i)
 115                 sbar_title[i] = strzone("(null)");
 116
 117         postinit = false;
 118
 119         calledhooks = 0;
 120
 121         teams = Sort_Spawn();
 122         players = Sort_Spawn();
 123
 124         GetTeam(COLOR_SPECTATOR, true); // add specs first
 125
 126         cvar_clientsettemp("_supports_weaponpriority", "1");
 127
 128         RegisterWeapons();
 129
 130         WaypointSprite_Load();
 131
 132         // precaches
 133         Projectile_Precache();
 134         GibSplash_Precache();
 135         Casings_Precache();
 136         DamageInfo_Precache();
 137         if(cvar_string("cl_announcer") != cl_announcer_prev) {
 138                 Announcer_Precache();
 139                 if(cl_announcer_prev)
 140                         strunzone(cl_announcer_prev);
 141                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
 142         }
 143         Tuba_Precache();
 144
 145 #ifdef UID
 146         {
 147                 // find the user ID
 148                 string uid;
 149                 registercvar("_cl_userid", "", CVAR_SAVE);
 150                 uid = cvar_string("_cl_userid");
 151                 if(strlen(uid) < 16)
 152                 {
 153                         uid = "";
 154                         for(i = 0; i < 4; ++i)
 155                                 uid = strcat(uid, substring(ftos(floor(10000 + random() * 10000)), 1, -1));
 156                 }
 157                 cvar_set("_cl_userid", uid);
 158                 localcmd(strcat("\ncmd uid ", uid, "\n"));
 159         }
 160 #endif
 161
 162         get_mi_min_max_texcoords(1); // try the CLEVER way first
 163         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 164         shortmapname = mi_shortname;
 165
 166         if(precache_pic(minimapname) == "")
 167         {
 168                 // but maybe we have a non-clever minimap
 169                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 170                 if(precache_pic(minimapname) == "")
 171                         minimapname = ""; // FAIL
 172                 else
 173                         get_mi_min_max_texcoords(0); // load new texcoords
 174         }
 175
 176         mi_center = (mi_min + mi_max) * 0.5;
 177         mi_scale = mi_max - mi_min;
 178         minimapname = strzone(minimapname);
 179 }
 180
 181 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 182 void CSQC_Shutdown(void)
 183 {
 184 #ifdef USE_FTE
 185 #pragma TARGET id
 186         if(!__engine_check)
 187                 return 0;
 188 #pragma TARGET fte
 189 #endif
 190
 191         remove(teams);
 192         remove(players);
 193         db_close(binddb);
 194         db_close(tempdb);
 195         db_save(ClientProgsDB, "client.db");
 196         db_close(ClientProgsDB);
 197
 198         cvar_clientsettemp_restore();
 199
 200         if(camera_active)
 201                 cvar_set("chase_active",ftos(chase_active_backup));
 202
 203         if not(isdemo())
 204         {
 205                 if not(calledhooks & HOOK_START)
 206                         localcmd("\n_cl_hook_gamestart nop;");
 207                 if not(calledhooks & HOOK_END)
 208                         localcmd("\ncl_hook_gameend;");
 209         }
 210 }
 211
 212 .float has_team;
 213 float SetTeam(entity o, float Team)
 214 {
 215         entity tm;
 216         if(teamplay)
 217         {
 218                 switch(Team)
 219                 {
 220                         case -1:
 221                         case COLOR_TEAM1:
 222                         case COLOR_TEAM2:
 223                         case COLOR_TEAM3:
 224                         case COLOR_TEAM4:
 225                                 break;
 226                         default:
 227                                 if(GetTeam(Team, false) == NULL)
 228                                 {
 229                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 230                                         Team = COLOR_SPECTATOR;
 231                                 }
 232                                 break;
 233                 }
 234         }
 235         else
 236         {
 237                 switch(Team)
 238                 {
 239                         case -1:
 240                         case 0:
 241                                 break;
 242                         default:
 243                                 if(GetTeam(Team, false) == NULL)
 244                                 {
 245                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 246                                         Team = COLOR_SPECTATOR;
 247                                 }
 248                                 break;
 249                 }
 250         }
 251         if(Team == -1) // leave
 252         {
 253                 if(o.has_team)
 254                 {
 255                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
 256                         tm = GetTeam(o.team, false);
 257                         tm.team_size -= 1;
 258                         o.has_team = 0;
 259                         return TRUE;
 260                 }
 261         }
 262         else
 263         {
 264                 if not(o.has_team)
 265                 {
 266                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
 267                         o.team = Team;
 268                         tm = GetTeam(Team, true);
 269                         tm.team_size += 1;
 270                         o.has_team = 1;
 271                         return TRUE;
 272                 }
 273                 else if(Team != o.team)
 274                 {
 275                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
 276                         tm = GetTeam(o.team, false);
 277                         tm.team_size -= 1;
 278                         o.team = Team;
 279                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
 280                         tm = GetTeam(Team, true);
 281                         tm.team_size += 1;
 282                         return TRUE;
 283                 }
 284         }
 285         return FALSE;
 286 }
 287
 288 void Playerchecker_Think()
 289 {
 290         float i;
 291         entity e;
 292         for(i = 0; i < maxclients; ++i)
 293         {
 294                 e = playerslots[i];
 295                 if(GetPlayerName(i) == "")
 296                 {
 297                         if(e.sort_prev)
 298                         {
 299                                 //print("playerchecker: KILL KILL KILL\n");
 300                                 // player disconnected
 301                                 SetTeam(e, -1);
 302                                 RemovePlayer(e);
 303                                 e.sort_prev = world;
 304                                 //e.gotscores = 0;
 305                         }
 306                 }
 307                 else
 308                 {
 309                         if not(e.sort_prev)
 310                         {
 311                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
 312                                 // player connected
 313                                 if not(e)
 314                                         playerslots[i] = e = spawn();
 315                                 e.sv_entnum = i;
 316                                 e.ping = 0;
 317                                 e.ping_packetloss = 0;
 318                                 e.ping_movementloss = 0;
 319                                 //e.gotscores = 0; // we might already have the scores...
 320                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams
 321                                 RegisterPlayer(e);
 322                                 Sbar_UpdatePlayerPos(e);
 323                         }
 324                 }
 325         }
 326         self.nextthink = time + 0.2;
 327 }
 328
 329 void Porto_Init();
 330 void TrueAim_Init();
 331 void PostInit(void)
 332 {
 333         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
 334         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));
 335
 336         entity playerchecker;
 337         playerchecker = spawn();
 338         playerchecker.think = Playerchecker_Think;
 339         playerchecker.nextthink = time + 0.2;
 340
 341         Porto_Init();
 342         TrueAim_Init();
 343
 344         postinit = true;
 345 }
 346
 347 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 348 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 349 float button_zoom;
 350 void Cmd_Sbar_SetFields(float);
 351 void Cmd_Sbar_Help(float);
 352 float CSQC_ConsoleCommand(string strMessage)
 353 {
 354         float argc;
 355         // Tokenize String
 356         //argc = tokenize(strMessage);
 357         argc = tokenize_console(strMessage);
 358
 359         // Acquire Command
 360         local string strCmd;
 361         strCmd = argv(0);
 362
 363         if(strCmd == "+button4") { // zoom
 364                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 365                 if(ignore_plus_zoom)
 366                 {
 367                         --ignore_plus_zoom;
 368                         return false;
 369                 }
 370                 button_zoom = 1;
 371                 return true;
 372         } else if(strCmd == "-button4") { // zoom
 373                 if(ignore_minus_zoom)
 374                 {
 375                         --ignore_minus_zoom;
 376                         return false;
 377                 }
 378                 button_zoom = 0;
 379                 return true;
 380         } else if(strCmd == "+button3") { // secondary
 381                 button_attack2 = 1;
 382                 return false;
 383         } else if(strCmd == "-button3") { // secondary
 384                 button_attack2 = 0;
 385                 return false;
 386         } else if(strCmd == "+showscores") {
 387                 sb_showscores = true;
 388                 return true;
 389         } else if(strCmd == "-showscores") {
 390                 sb_showscores = false;
 391                 return true;
 392         } else if(strCmd == "+showaccuracy") {
 393                 sb_showaccuracy = true;
 394                 return true;
 395         } else if(strCmd == "-showaccuracy") {
 396                 sb_showaccuracy = false;
 397                 return true;
 398         }
 399
 400         if(camera_active)
 401         if(strCmd == "+forward" || strCmd == "-back") {
 402                 ++camera_direction_x;
 403                 return true;
 404         } else if(strCmd == "-forward" || strCmd == "+back") {
 405                 --camera_direction_x;
 406                 return true;
 407         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 408                 --camera_direction_y;
 409                 return true;
 410         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 411                 ++camera_direction_y;
 412                 return true;
 413         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 414                 ++camera_direction_z;
 415                 return true;
 416         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 417                 --camera_direction_z;
 418                 return true;
 419         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 420                 ++camera_roll;
 421                 return true;
 422         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 423                 --camera_roll;
 424                 return true;
 425         }
 426
 427         return false;
 428 }
 429
 430 .vector view_ofs;
 431 entity debug_shotorg;
 432 void ShotOrg_Draw()
 433 {
 434         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 435         self.angles = view_angles;
 436         self.angles_x = -self.angles_x;
 437         if not(self.cnt)
 438                 R_AddEntity(self);
 439 }
 440 void ShotOrg_Draw2D()
 441 {
 442         vector coord2d_topleft, coord2d_topright, coord2d;
 443         string s;
 444         vector fs;
 445
 446         s = vtos(self.view_ofs);
 447         s = substring(s, 1, strlen(s) - 2);
 448         if(tokenize_console(s) == 3)
 449                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 450
 451         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 452         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 453
 454         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 455
 456         coord2d = coord2d_topleft;
 457         if(fs_x < 8)
 458         {
 459                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 460                 fs = '8 8 0';
 461         }
 462         coord2d_y -= fs_y;
 463         coord2d_z = 0;
 464         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 465 }
 466
 467 void ShotOrg_Spawn()
 468 {
 469         debug_shotorg = spawn();
 470         debug_shotorg.draw = ShotOrg_Draw;
 471         debug_shotorg.draw2d = ShotOrg_Draw2D;
 472         debug_shotorg.renderflags = RF_VIEWMODEL;
 473         debug_shotorg.effects = EF_FULLBRIGHT;
 474         precache_model("models/shotorg_adjuster.md3");
 475         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 476         debug_shotorg.scale = 2;
 477         debug_shotorg.view_ofs = '25 8 -8';
 478 }
 479
 480 void DrawDebugModel()
 481 {
 482         if(time - floor(time) > 0.5)
 483         {
 484                 PolyDrawModel(self);
 485         }
 486         else
 487         {
 488                 self.renderflags = 0;
 489                 R_AddEntity(self);
 490         }
 491 }
 492
 493 void GameCommand(string msg)
 494 {
 495         string s;
 496         float argc;
 497         entity e;
 498         argc = tokenize_console(msg);
 499
 500         if(argv(0) == "help" || argc == 0)
 501         {
 502                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
 503                 print("  settemp cvar value\n");
 504                 print("  radar\n");
 505                 print("  sbar_columns_set ...\n");
 506                 print("  sbar_columns_help\n");
 507                 GameCommand_Generic("help");
 508                 return;
 509         }
 510
 511         if(GameCommand_Generic(msg))
 512                 return;
 513
 514         string cmd;
 515         cmd = argv(0);
 516         if(cmd == "mv_download") {
 517                 Cmd_MapVote_MapDownload(argc);
 518         }
 519         else if(cmd == "settemp") {
 520                 cvar_clientsettemp(argv(1), argv(2));
 521         }
 522         else if(cmd == "radar") {
 523                 ons_showmap = !ons_showmap;
 524         }
 525         else if(cmd == "sbar_columns_set") {
 526                 Cmd_Sbar_SetFields(argc);
 527         }
 528         else if(cmd == "sbar_columns_help") {
 529                 Cmd_Sbar_Help(argc);
 530         }
 531 #ifdef BLURTEST
 532         else if(cmd == "blurtest") {
 533                 blurtest_time0 = time;
 534                 blurtest_time1 = time + stof(argv(1));
 535                 blurtest_radius = stof(argv(2));
 536                 blurtest_power = stof(argv(3));
 537         }
 538 #endif
 539         else if(cmd == "shotorg_move") {
 540                 if(!debug_shotorg)
 541                         ShotOrg_Spawn();
 542                 else
 543                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 544                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 545         }
 546         else if(cmd == "shotorg_movez") {
 547                 if(!debug_shotorg)
 548                         ShotOrg_Spawn();
 549                 else
 550                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 551                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 552         }
 553         else if(cmd == "shotorg_set") {
 554                 if(!debug_shotorg)
 555                         ShotOrg_Spawn();
 556                 else
 557                         debug_shotorg.view_ofs = stov(argv(1));
 558                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 559         }
 560         else if(cmd == "shotorg_setz") {
 561                 if(!debug_shotorg)
 562                         ShotOrg_Spawn();
 563                 else
 564                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 565                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 566         }
 567         else if(cmd == "shotorg_toggle_hide") {
 568                 if(debug_shotorg)
 569                 {
 570                         debug_shotorg.cnt = !debug_shotorg.cnt;
 571                 }
 572         }
 573         else if(cmd == "shotorg_end") {
 574                 if(debug_shotorg)
 575                 {
 576                         print(vtos(debug_shotorg.view_ofs), "\n");
 577                         remove(debug_shotorg);
 578                         debug_shotorg = world;
 579                 }
 580                 localcmd("sv_cmd debug_shotorg\n");
 581         }
 582         else if(cmd == "sendcvar") {
 583                 s = cvar_string(argv(1));
 584                 if(argv(1) == "cl_weaponpriority")
 585                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 586                 else if(substring(argv(1), 0, 17) == "cl_weaponpriority" && strlen(argv(1)) == 18)
 587                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 588                 localcmd("cmd sentcvar ", argv(1), " \"", s, "\"\n");
 589         }
 590         else if(cmd == "spawn") {
 591                 s = argv(1);
 592                 e = spawn();
 593                 precache_model(s);
 594                 setmodel(e, s);
 595                 setorigin(e, view_origin);
 596                 e.angles = view_angles;
 597                 e.draw = DrawDebugModel;
 598                 e.classname = "debugmodel";
 599         }
 600         else
 601         {
 602                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 603         }
 604
 605         return;
 606 }
 607
 608 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 609 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 610 // All keys are in ascii.
 611 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 612 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 613 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 614 float hudconf_active;
 615 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 616 {
 617         local float bSkipKey;
 618         bSkipKey = false;
 619
 620         if(hudconf_active)
 621                 if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 622                         return true;
 623
 624         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 625                 return true;
 626
 627         if(menu_visible)
 628                 if(menu_action(bInputType, nPrimary, nSecondary))
 629                         return TRUE;
 630         return bSkipKey;
 631 }
 632
 633 // END REQUIRED CSQC FUNCTIONS
 634 // --------------------------------------------------------------------------
 635
 636 // --------------------------------------------------------------------------
 637 // BEGIN OPTIONAL CSQC FUNCTIONS
 638 void Ent_ReadEntCS()
 639 {
 640         InterpolateOrigin_Undo();
 641
 642         self.classname = "entcs_receiver";
 643         self.sv_entnum = ReadByte() - 1;
 644         self.origin_x = ReadShort();
 645         self.origin_y = ReadShort();
 646         self.origin_z = ReadShort();
 647         self.angles_y = ReadByte() * 360.0 / 256;
 648         self.origin_z = self.angles_x = self.angles_z = 0;
 649
 650         InterpolateOrigin_Note();
 651 }
 652
 653 void Ent_Remove();
 654
 655 void Ent_RemovePlayerScore()
 656 {
 657         float i;
 658
 659         if(self.owner)
 660         {
 661                 SetTeam(self.owner, -1);
 662                 self.owner.gotscores = 0;
 663                 for(i = 0; i < MAX_SCORE; ++i)
 664                         self.owner.(scores[i]) = 0; // clear all scores
 665         }
 666 }
 667
 668 void Ent_ReadPlayerScore()
 669 {
 670         float i, n;
 671         float isNew;
 672         entity o;
 673
 674         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN
 675         // (no I've never heard of M-x replace-string, sed, or anything like that)
 676         isNew = !self.owner; // workaround for DP bug
 677         n = ReadByte()-1;
 678
 679 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 680         if(!isNew && n != self.sv_entnum)
 681         {
 682                 print("A CSQC entity changed its owner!\n");
 683                 isNew = true;
 684                 Ent_Remove();
 685                 self.enttype = ENT_CLIENT_SCORES;
 686         }
 687 #endif
 688
 689         self.sv_entnum = n;
 690
 691         if not(playerslots[self.sv_entnum])
 692                 playerslots[self.sv_entnum] = spawn();
 693         o = self.owner = playerslots[self.sv_entnum];
 694         o.sv_entnum = self.sv_entnum;
 695         o.gotscores = 1;
 696
 697         //if not(o.sort_prev)
 698         //      RegisterPlayer(o);
 699         //playerchecker will do this for us later, if it has not already done so
 700
 701         float sf, lf;
 702 #if MAX_SCORE <= 8
 703         sf = ReadByte();
 704         lf = ReadByte();
 705 #else
 706         sf = ReadShort();
 707         lf = ReadShort();
 708 #endif
 709         float p;
 710         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 711                 if(sf & p)
 712                 {
 713                         if(lf & p)
 714                                 o.(scores[i]) = ReadInt24_t();
 715                         else
 716                                 o.(scores[i]) = ReadChar();
 717                 }
 718
 719         if(o.sort_prev)
 720                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 721
 722         self.entremove = Ent_RemovePlayerScore;
 723 }
 724
 725 void Ent_ReadTeamScore()
 726 {
 727         float i;
 728         entity o;
 729
 730         self.team = ReadByte();
 731         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 732
 733         float sf, lf;
 734 #if MAX_TEAMSCORE <= 8
 735         sf = ReadByte();
 736         lf = ReadByte();
 737 #else
 738         sf = ReadShort();
 739         lf = ReadShort();
 740 #endif
 741         float p;
 742         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 743                 if(sf & p)
 744                 {
 745                         if(lf & p)
 746                                 o.(teamscores[i]) = ReadInt24_t();
 747                         else
 748                                 o.(teamscores[i]) = ReadChar();
 749                 }
 750
 751         Sbar_UpdateTeamPos(o);
 752 }
 753
 754 void Net_Reset()
 755 {
 756 }
 757
 758 void Ent_ClientData()
 759 {
 760         float f;
 761         float newspectatee_status;
 762
 763         f = ReadByte();
 764
 765         sb_showscores_force = (f & 1);
 766
 767         if(f & 2)
 768         {
 769                 newspectatee_status = ReadByte();
 770                 if(newspectatee_status == player_localentnum)
 771                         newspectatee_status = -1; // observing
 772         }
 773         else
 774                 newspectatee_status = 0;
 775
 776         spectatorbutton_zoom = (f & 4);
 777
 778         if(f & 8)
 779         {
 780                 angles_held_status = 1;
 781                 angles_held_x = ReadAngle();
 782                 angles_held_y = ReadAngle();
 783                 angles_held_z = 0;
 784         }
 785         else
 786                 angles_held_status = 0;
 787
 788         if(newspectatee_status != spectatee_status)
 789         {
 790                 float i;
 791                 // clear the weapon accuracy stats
 792                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
 793                         weapon_hits[i] = 0;
 794                         weapon_fired[i] = 0;
 795                 }
 796
 797                 // clear race stuff
 798                 race_laptime = 0;
 799                 race_checkpointtime = 0;
 800         }
 801         spectatee_status = newspectatee_status;
 802 }
 803
 804 void Ent_Nagger()
 805 {
 806         float nags, i, j, b, f;
 807
 808         nags = ReadByte();
 809
 810         if(nags & 128)
 811         {
 812                 if(vote_called_vote)
 813                         strunzone(vote_called_vote);
 814                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 815         }
 816
 817         if(nags & 1)
 818         {
 819                 for(j = 0; j < maxclients; ++j)
 820                         if(playerslots[j])
 821                                 playerslots[j].ready = 1;
 822                 for(i = 1; i <= maxclients; i += 8)
 823                 {
 824                         f = ReadByte();
 825                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 826                                 if not(f & b)
 827                                         if(playerslots[j])
 828                                                 playerslots[j].ready = 0;
 829                 }
 830         }
 831
 832         ready_waiting = (nags & 1);
 833         ready_waiting_for_me = (nags & 2);
 834         vote_waiting = (nags & 4);
 835         vote_waiting_for_me = (nags & 8);
 836         warmup_stage = (nags & 16);
 837 }
 838
 839 void Ent_RandomSeed()
 840 {
 841         float s;
 842         prandom_debug();
 843         s = ReadShort();
 844         psrandom(s);
 845 }
 846
 847 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 848 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 849 void Ent_RadarLink();
 850 void Ent_Init();
 851 void Ent_ScoresInfo();
 852 void(float bIsNewEntity) CSQC_Ent_Update =
 853 {
 854         float t;
 855         float savetime;
 856         t = ReadByte();
 857
 858         // set up the "time" global for received entities to be correct for interpolation purposes
 859         savetime = time;
 860         if(servertime)
 861         {
 862                 time = servertime;
 863         }
 864         else
 865         {
 866                 serverprevtime = time;
 867                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 868                 time = serverprevtime + serverdeltatime;
 869         }
 870
 871 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 872         if(self.enttype)
 873                 if(t != self.enttype)
 874                 {
 875                         print("A CSQC entity changed its type!\n");
 876                         Ent_Remove();
 877                         bIsNewEntity = 1;
 878                 }
 879 #endif
 880         self.enttype = t;
 881         switch(t)
 882         {
 883                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 884                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 885                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 886                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 887                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 888                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 889                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 890                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 891                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 892                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 893                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 894                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 895                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 896                 case ENT_CLIENT_INIT: Ent_Init(); break;
 897                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 898                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 899                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 900                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 901                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 902                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 903                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 904                 default:
 905                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
 906                         break;
 907         }
 908
 909         time = savetime;
 910 };
 911 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 912 // used when an entity changes its type. For an entity that someone interacts
 913 // with others, make sure it can no longer do so.
 914 void Ent_Remove()
 915 {
 916         if(self.entremove)
 917                 self.entremove();
 918
 919         self.enttype = 0;
 920         self.classname = "";
 921         self.draw = menu_sub_null;
 922         self.entremove = menu_sub_null;
 923         // TODO possibly set more stuff to defaults
 924 }
 925 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 926 void CSQC_Ent_Remove()
 927 {
 928         if(self.enttype)
 929                 Ent_Remove();
 930         remove(self);
 931 }
 932
 933 void Gamemode_Init()
 934 {
 935         if(gametype == GAME_ONSLAUGHT) {
 936                 print(strcat("Using ", minimapname, " as minimap.\n"));
 937                 precache_pic("gfx/ons-cp-neutral.tga");
 938                 precache_pic("gfx/ons-cp-red.tga");
 939                 precache_pic("gfx/ons-cp-blue.tga");
 940                 precache_pic("gfx/ons-frame.tga");
 941                 precache_pic("gfx/ons-frame-team.tga");
 942         } else if(gametype == GAME_KEYHUNT) {
 943                 precache_pic("gfx/sb_key_carrying");
 944                 precache_pic("gfx/sb_key_carrying_outline");
 945         }
 946
 947         if not(isdemo())
 948         {
 949                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), ";");
 950                 calledhooks |= HOOK_START;
 951         }
 952 }
 953 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 954 void CSQC_Parse_StuffCmd(string strMessage)
 955 {
 956         localcmd(strMessage);
 957 }
 958 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 959 void CSQC_Parse_Print(string strMessage)
 960 {
 961         print(ColorTranslateRGB(strMessage));
 962 }
 963
 964 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
 965 void CSQC_Parse_CenterPrint(string strMessage)
 966 {
 967         centerprint(strMessage);
 968 }
 969
 970 string notranslate_fogcmd1 = "\nfog ";
 971 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 972 void Fog_Force()
 973 {
 974         // TODO somehow thwart prvm_globalset client ...
 975
 976         if(forcefog != "")
 977                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 978 }
 979
 980 void Gamemode_Init();
 981 void Ent_ScoresInfo()
 982 {
 983         float i;
 984         self.classname = "ent_client_scores_info";
 985         gametype = ReadByte();
 986         for(i = 0; i < MAX_SCORE; ++i)
 987         {
 988                 scores_label[i] = strzone(ReadString());
 989                 scores_flags[i] = ReadByte();
 990         }
 991         for(i = 0; i < MAX_TEAMSCORE; ++i)
 992         {
 993                 teamscores_label[i] = strzone(ReadString());
 994                 teamscores_flags[i] = ReadByte();
 995         }
 996         Sbar_InitScores();
 997         Gamemode_Init();
 998 }
 999
1000 void Ent_Init()
1001 {
1002         self.classname = "ent_client_init";
1003
1004         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1005
1006         hook_shotorigin_x = ReadCoord();
1007         hook_shotorigin_y = ReadCoord();
1008         hook_shotorigin_z = ReadCoord();
1009
1010         if(forcefog)
1011                 strunzone(forcefog);
1012         forcefog = strzone(ReadString());
1013
1014         armorblockpercent = ReadByte() / 255.0;
1015
1016         g_weaponswitchdelay = ReadByte() / 255.0;
1017
1018         if(!postinit)
1019                 PostInit();
1020 }
1021
1022 void Net_ReadRace()
1023 {
1024         float b;
1025
1026         b = ReadByte();
1027
1028         switch(b)
1029         {
1030                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1031                         race_checkpoint = ReadByte();
1032                         race_time = ReadInt24_t();
1033                         race_previousbesttime = ReadInt24_t();
1034                         if(race_previousbestname)
1035                                 strunzone(race_previousbestname);
1036                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1037
1038                         race_checkpointtime = time;
1039
1040                         if(race_checkpoint == 0 || race_checkpoint == 254)
1041                         {
1042                                 race_penaltyaccumulator = 0;
1043                                 race_laptime = time; // valid
1044                         }
1045
1046                         break;
1047
1048                 case RACE_NET_CHECKPOINT_CLEAR:
1049                         race_laptime = 0;
1050                         race_checkpointtime = 0;
1051                         break;
1052
1053                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1054                         race_laptime = ReadCoord();
1055                         race_checkpointtime = -99999;
1056                         // fall through
1057                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1058                         race_nextcheckpoint = ReadByte();
1059
1060                         race_nextbesttime = ReadInt24_t();
1061                         if(race_nextbestname)
1062                                 strunzone(race_nextbestname);
1063                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1064                         break;
1065
1066                 case RACE_NET_CHECKPOINT_HIT_RACE:
1067                         race_mycheckpoint = ReadByte();
1068                         race_mycheckpointtime = time;
1069                         race_mycheckpointdelta = ReadInt24_t();
1070                         race_mycheckpointlapsdelta = ReadByte();
1071                         if(race_mycheckpointlapsdelta >= 128)
1072                                 race_mycheckpointlapsdelta -= 256;
1073                         if(race_mycheckpointenemy)
1074                                 strunzone(race_mycheckpointenemy);
1075                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1076                         break;
1077
1078                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1079                         race_othercheckpoint = ReadByte();
1080                         race_othercheckpointtime = time;
1081                         race_othercheckpointdelta = ReadInt24_t();
1082                         race_othercheckpointlapsdelta = ReadByte();
1083                         if(race_othercheckpointlapsdelta >= 128)
1084                                 race_othercheckpointlapsdelta -= 256;
1085                         if(race_othercheckpointenemy)
1086                                 strunzone(race_othercheckpointenemy);
1087                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1088                         break;
1089
1090                 case RACE_NET_PENALTY_RACE:
1091                         race_penaltyeventtime = time;
1092                         race_penaltytime = ReadShort();
1093                         //race_penaltyaccumulator += race_penaltytime;
1094                         if(race_penaltyreason)
1095                                 strunzone(race_penaltyreason);
1096                         race_penaltyreason = strzone(ReadString());
1097                         break;
1098
1099                 case RACE_NET_PENALTY_QUALIFYING:
1100                         race_penaltyeventtime = time;
1101                         race_penaltytime = ReadShort();
1102                         race_penaltyaccumulator += race_penaltytime;
1103                         if(race_penaltyreason)
1104                                 strunzone(race_penaltyreason);
1105                         race_penaltyreason = strzone(ReadString());
1106                         break;
1107
1108                 case RACE_NET_SERVER_RECORD:
1109                         race_server_record = ReadInt24_t();
1110                         break;
1111                 case RACE_NET_SPEED_AWARD:
1112                         race_speedaward = ReadInt24_t();
1113                         if(race_speedaward_holder)
1114                                 strunzone(race_speedaward_holder);
1115                         race_speedaward_holder = strzone(ReadString());
1116                         break;
1117                 case RACE_NET_SPEED_AWARD_BEST:
1118                         race_speedaward_alltimebest = ReadInt24_t();
1119                         if(race_speedaward_alltimebest_holder)
1120                                 strunzone(race_speedaward_alltimebest_holder);
1121                         race_speedaward_alltimebest_holder = strzone(ReadString());
1122                         break;
1123                 case RACE_NET_SERVER_RANKINGS:
1124                         float pos, prevpos, del;
1125                         pos = ReadShort();
1126                         prevpos = ReadShort();
1127                         del = ReadShort();
1128
1129                         // move other rankings out of the way
1130                         float i;
1131                         if (prevpos) {
1132                                 for (i=prevpos-1;i>pos-1;--i) {
1133                                         grecordtime[i] = grecordtime[i-1];
1134                                         if(grecordholder[i])
1135                                                 strunzone(grecordholder[i]);
1136                                         grecordholder[i] = strzone(grecordholder[i-1]);
1137                                 }
1138                         } else if (del) { // a record has been deleted by the admin
1139                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1140                                         if (i == RANKINGS_CNT-1) { // clear out last record
1141                                                 grecordtime[i] = 0;
1142                                                 if (grecordholder[i])
1143                                                         strunzone(grecordholder[i]);
1144                                                 grecordholder[i] = string_null;
1145                                         }
1146                                         else {
1147                                                 grecordtime[i] = grecordtime[i+1];
1148                                                 if (grecordholder[i])
1149                                                         strunzone(grecordholder[i]);
1150                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1151                                         }
1152                                 }
1153                         } else { // player has no ranked record yet
1154                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1155                                         grecordtime[i] = grecordtime[i-1];
1156                                         if(grecordholder[i])
1157                                                 strunzone(grecordholder[i]);
1158                                         grecordholder[i] = strzone(grecordholder[i-1]);
1159                                 }
1160                         }
1161
1162                         // store new ranking
1163                         if(grecordholder[pos-1] != "")
1164                                 strunzone(grecordholder[pos-1]);
1165                         grecordholder[pos-1] = strzone(ReadString());
1166                         grecordtime[pos-1] = ReadInt24_t();
1167                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1168                                 race_myrank = pos;
1169                         break;
1170                 case RACE_NET_SERVER_STATUS:
1171                         race_status = ReadShort();
1172                         if(race_status_name)
1173                                 strunzone(race_status_name);
1174                         race_status_name = strzone(ReadString());
1175         }
1176 }
1177
1178 void Net_ReadSpawn()
1179 {
1180         zoomin_effect = 1;
1181         current_viewzoom = 0.6;
1182 }
1183
1184 void Net_TeamNagger()
1185 {
1186         teamnagger = 1;
1187 }
1188
1189 void Net_ReadPingPLReport()
1190 {
1191         float e, pi, pl, ml;
1192         e = ReadByte();
1193         pi = ReadShort();
1194         pl = ReadByte();
1195         ml = ReadByte();
1196         if not(playerslots[e])
1197                 return;
1198         playerslots[e].ping = pi;
1199         playerslots[e].ping_packetloss = pl / 255.0;
1200         playerslots[e].ping_movementloss = ml / 255.0;
1201 }
1202
1203 void Net_VoteDialog(float highlight) {
1204         if(highlight) {
1205                 vote_highlighted = ReadShort();
1206                 return;
1207         }
1208
1209         vote_yescount = ReadShort();
1210         vote_nocount = ReadShort();
1211         vote_needed = ReadShort();
1212         vote_active = 1;
1213 }
1214
1215 void Net_VoteDialogReset() {
1216         vote_active = 0;
1217 }
1218
1219 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1220 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1221 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1222 float CSQC_Parse_TempEntity()
1223 {
1224         local float bHandled;
1225                 bHandled  = true;
1226         // Acquire TE ID
1227         local float nTEID;
1228                 nTEID = ReadByte();
1229
1230                 // NOTE: Could just do return instead of break...
1231         switch(nTEID)
1232         {
1233                 case TE_CSQC_PICTURE:
1234                         Net_MapVote_Picture();
1235                         bHandled = true;
1236                         break;
1237                 case TE_CSQC_RACE:
1238                         Net_ReadRace();
1239                         bHandled = true;
1240                         break;
1241                 case 13: // TE_BEAM
1242                         Net_GrapplingHook();
1243                         bHandled = true;
1244                         break;
1245                 case TE_CSQC_SPAWN:
1246                         Net_ReadSpawn();
1247                         bHandled = true;
1248                         break;
1249                 case TE_CSQC_ZCURVEPARTICLES:
1250                         Net_ReadZCurveParticles();
1251                         bHandled = true;
1252                         break;
1253                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1254                         Net_ReadNexgunBeamParticle();
1255                         bHandled = true;
1256                         break;
1257                 case TE_CSQC_TEAMNAGGER:
1258                         Net_TeamNagger();
1259                         bHandled = true;
1260                         break;
1261                 case TE_CSQC_VOTE:
1262                         Net_VoteDialog(ReadByte());
1263                         bHandled = true;
1264                         break;
1265                 case TE_CSQC_VOTERESET:
1266                         Net_VoteDialogReset();
1267                         bHandled = true;
1268                         break;
1269                 case TE_CSQC_LIGHTNINGARC:
1270                         Net_ReadLightningarc();
1271                         bHandled = true;
1272                         break;
1273                 case TE_CSQC_PINGPLREPORT:
1274                         Net_ReadPingPLReport();
1275                         bHandled = true;
1276                         break;
1277                 case TE_CSQC_ANNOUNCE:
1278                         announce_snd = strzone(ReadString());
1279                         bHandled = true;
1280                         break;
1281                 default:
1282                         // No special logic for this temporary entity; return 0 so the engine can handle it
1283                         bHandled = false;
1284                         break;
1285         }
1286
1287         return bHandled;
1288 }
1289
1290 string getcommandkey(string text, string command)
1291 {
1292         string keys;
1293         float n, j, k, l;
1294
1295         if (!sbar_showbinds)
1296                 return text;
1297
1298         keys = db_get(binddb, command);
1299         if (!keys)
1300         {
1301                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1302                 for(j = 0; j < n; ++j)
1303                 {
1304                         k = stof(argv(j));
1305                         if(k != -1)
1306                         {
1307                                 if ("" == keys)
1308                                         keys = keynumtostring(k);
1309                                 else
1310                                         keys = strcat(keys, ", ", keynumtostring(k));
1311
1312                                 ++l;
1313                                 if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;
1314                         }
1315
1316                 }
1317                 db_put(binddb, command, keys);
1318         }
1319
1320         if ("" == keys) {
1321                 if (sbar_showbinds > 1)
1322                         return strcat(text, " (not bound)");
1323                 else
1324                         return text;
1325         }
1326         else if (sbar_showbinds > 1)
1327                 return strcat(text, " (", keys, ")");
1328         else
1329                 return keys;
1330 }