data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void cvar_clientsettemp(string cv, string val)\r
   8 {\r
   9         entity e;\r
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  11                 if(e.netname == cv)\r
  12                         goto saved;\r
  13         e = spawn();\r
  14         e.classname = "saved_cvar_value";\r
  15         e.netname = strzone(cv);\r
  16         e.message = strzone(cvar_string(cv));\r
  17 :saved\r
  18         cvar_set(cv, val);\r
  19 }\r
  20 \r
  21 void cvar_clientsettemp_restore()\r
  22 {\r
  23         entity e;\r
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  25                         cvar_set(e.netname, e.message);\r
  26 }\r
  27 \r
  28 void() menu_show_error =\r
  29 {\r
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  31 };\r
  32 \r
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  34 // Useful for precaching things\r
  35 \r
  36 void() menu_sub_null =\r
  37 {\r
  38 };\r
  39 \r
  40 // let's make this a general data buffer...\r
  41 float using_gps;\r
  42 \r
  43 #ifdef USE_FTE\r
  44 float __engine_check;\r
  45 #endif\r
  46 \r
  47 string config_get(string key, string defaultvalue)\r
  48 {\r
  49         string s;\r
  50         s = db_get(configdb, strcat("/s/", key));\r
  51         if(s == "")\r
  52                 return defaultvalue;\r
  53         else\r
  54                 return db_get(configdb, strcat("/v/", key));\r
  55 }\r
  56 \r
  57 string forcefog;\r
  58 void CSQC_Init(void)\r
  59 {\r
  60 #ifdef USE_FTE\r
  61 #pragma target ID\r
  62         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  63         if(!__engine_check)\r
  64         {\r
  65                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  66                 localcmd("\ndisconnect\n");\r
  67                 return;\r
  68         }\r
  69 #pragma target FTE\r
  70 #endif\r
  71         \r
  72         float i;\r
  73         CSQC_CheckEngine();\r
  74 \r
  75         configdb = db_create();\r
  76         binddb = db_create();\r
  77         compressShortVector_init();\r
  78 \r
  79         drawfont = 0;\r
  80         menu_visible = FALSE;\r
  81         menu_show = menu_show_error;\r
  82         menu_action = menu_sub_null;\r
  83         using_gps = false;\r
  84         maxclients = 255; // we later get the real maxclients to speed up stuff\r
  85         //ctf_temp_1 = "";\r
  86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  87         //registercmd("ctf_menu");\r
  88         registercmd("ons_map");\r
  89         //registercmd("menu_action");\r
  90         registercmd("sbar_columns_set");\r
  91         registercmd("sbar_columns_help");\r
  92 \r
  93         registercmd("+button3");\r
  94         registercmd("-button3");\r
  95         registercmd("+button4");\r
  96         registercmd("-button4");\r
  97 \r
  98         registercvar("sbar_usecsqc", "1");\r
  99         registercvar("sbar_columns", "default", CVAR_SAVE);\r
 100 \r
 101         gametype = 0;\r
 102 \r
 103         gps_start = world;\r
 104 \r
 105         // sbar_fields uses strunzone on the titles!\r
 106         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
 107                 sbar_title[i] = strzone("(null)");\r
 108 \r
 109         postinit = false;\r
 110 \r
 111         teams = Sort_Spawn();\r
 112         players = Sort_Spawn();\r
 113         \r
 114         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
 115 \r
 116         cvar_clientsettemp("_supports_weaponpriority", "1");\r
 117 }\r
 118 \r
 119 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
 120 void CSQC_Shutdown(void)\r
 121 {\r
 122 #ifdef USE_FTE\r
 123 #pragma TARGET id\r
 124         if(!__engine_check)\r
 125                 return 0;\r
 126 #pragma TARGET fte\r
 127 #endif\r
 128 \r
 129         remove(teams);\r
 130         remove(players);\r
 131         db_close(configdb);\r
 132         db_close(binddb);\r
 133 \r
 134         cvar_clientsettemp_restore();\r
 135 }\r
 136 \r
 137 .float has_team;\r
 138 float SetTeam(entity o, float Team)\r
 139 {\r
 140         entity tm;\r
 141         if(Team == -1) // leave\r
 142         {\r
 143                 if(o.has_team)\r
 144                 {\r
 145                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 146                         tm = GetTeam(o.team, false);\r
 147                         tm.team_size -= 1;\r
 148                         o.has_team = 0;\r
 149                         return TRUE;\r
 150                 }\r
 151         }\r
 152         else\r
 153         {\r
 154                 if not(o.has_team)\r
 155                 {\r
 156                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 157                         o.team = Team;\r
 158                         tm = GetTeam(Team, true);\r
 159                         tm.team_size += 1;\r
 160                         o.has_team = 1;\r
 161                         return TRUE;\r
 162                 }\r
 163                 else if(Team != o.team)\r
 164                 {\r
 165                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 166                         tm = GetTeam(o.team, false);\r
 167                         tm.team_size -= 1;\r
 168                         o.team = Team;\r
 169                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 170                         tm = GetTeam(Team, true);\r
 171                         tm.team_size += 1;\r
 172                         return TRUE;\r
 173                 }\r
 174         }\r
 175         return FALSE;\r
 176 }\r
 177 \r
 178 void Playerchecker_Think()\r
 179 {\r
 180         float i;\r
 181         for(i = 0; i < maxclients; ++i)\r
 182         {\r
 183                 if(getplayerkey(i, "name") == "")\r
 184                 {\r
 185                         if(playerslots[i].sort_prev)\r
 186                         {\r
 187                                 //print("playerchecker: KILL KILL KILL\n");\r
 188                                 // player disconnected\r
 189                                 SetTeam(playerslots[i], -1);\r
 190                                 RemovePlayer(playerslots[i]);\r
 191                                 playerslots[i].sort_prev = world;\r
 192                                 playerslots[i].gotscores = 0;\r
 193                         }\r
 194                 }\r
 195                 else\r
 196                 {\r
 197                         if not(playerslots[i].sort_prev)\r
 198                         {\r
 199                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 200                                 // player connected\r
 201                                 if not(playerslots[i])\r
 202                                         playerslots[i] = spawn();\r
 203                                 playerslots[i].sv_entnum = i;\r
 204                                 playerslots[i].gotscores = 0;\r
 205                                 SetTeam(playerslots[i], COLOR_SPECTATOR);\r
 206                                 RegisterPlayer(playerslots[i]);\r
 207                                 Sbar_UpdatePlayerPos(playerslots[i]);\r
 208                         }\r
 209                 }\r
 210         }\r
 211         self.nextthink = time + 0.2;\r
 212 }\r
 213 \r
 214 void Porto_Init();\r
 215 void PostInit(void)\r
 216 {\r
 217         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 218         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 219 \r
 220         entity playerchecker;\r
 221         playerchecker = spawn();\r
 222         playerchecker.think = Playerchecker_Think;\r
 223         playerchecker.nextthink = time + 0.2;\r
 224 \r
 225         Porto_Init();\r
 226 \r
 227         postinit = true;\r
 228 }\r
 229 \r
 230 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 231 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 232 float button_zoom;\r
 233 void Cmd_Sbar_SetFields(float);\r
 234 void Cmd_Sbar_Help(float);\r
 235 float CSQC_ConsoleCommand(string strMessage)\r
 236 {\r
 237         float argc;\r
 238         // Tokenize String\r
 239         //argc = tokenize(strMessage);\r
 240         argc = tokenizebyseparator(strMessage, " ");\r
 241         \r
 242         // Acquire Command\r
 243         local string strCmd;\r
 244         strCmd = argv(0);\r
 245 \r
 246         if(strCmd == "+button4") { // zoom\r
 247                 // return false, because the message shall be sent to the server anyway (for demos/speccing)\r
 248                 if(ignore_plus_zoom)\r
 249                 {\r
 250                         --ignore_plus_zoom;\r
 251                         return false;\r
 252                 }\r
 253                 button_zoom = 1;\r
 254                 return true;\r
 255         } else if(strCmd == "-button4") { // zoom\r
 256                 if(ignore_minus_zoom)\r
 257                 {\r
 258                         --ignore_minus_zoom;\r
 259                         return false;\r
 260                 }\r
 261                 button_zoom = 0;\r
 262                 return true;\r
 263         } else if(strCmd == "+button3") { // secondary\r
 264                 button_attack2 = 1;\r
 265                 return false;\r
 266         } else if(strCmd == "-button3") { // secondary\r
 267                 button_attack2 = 0;\r
 268                 return false;\r
 269         } else if(strCmd == "ons_map") {\r
 270                 Cmd_ons_map();\r
 271                 return true;\r
 272         } else if(strCmd == "sbar_columns_set") {\r
 273                 Cmd_Sbar_SetFields(argc);\r
 274                 return true;\r
 275         } else if(strCmd == "sbar_columns_help") {\r
 276                 Cmd_Sbar_Help(argc);\r
 277                 return true;\r
 278         } else if(strCmd == "+showscores") {\r
 279                 sb_showscores = true;\r
 280                 return true;\r
 281         } else if(strCmd == "-showscores") {\r
 282                 sb_showscores = false;\r
 283                 return true;\r
 284         }\r
 285         \r
 286         return false;\r
 287 }\r
 288 \r
 289 float GameCommand(string msg)\r
 290 {\r
 291         float argc;\r
 292         argc = tokenize(msg);\r
 293         string cmd;\r
 294         cmd = argv(0);\r
 295         if(cmd == "mv_download") {\r
 296                 Cmd_MapVote_MapDownload(argc);\r
 297                 return true;\r
 298         }\r
 299         else if(cmd == "settemp") {\r
 300                 cvar_clientsettemp(argv(1), argv(2));\r
 301         }\r
 302         \r
 303         return false;\r
 304 }\r
 305 \r
 306 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 307 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 308 // All keys are in ascii.\r
 309 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 310 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 311 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 312 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 313 {\r
 314         local float bSkipKey;\r
 315         bSkipKey = false;\r
 316         \r
 317         if(menu_visible)\r
 318                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 319                         return TRUE;\r
 320         return bSkipKey;\r
 321 }\r
 322 \r
 323 // END REQUIRED CSQC FUNCTIONS\r
 324 // --------------------------------------------------------------------------\r
 325 \r
 326 // --------------------------------------------------------------------------\r
 327 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 328 void Ent_ReadONS()\r
 329 {\r
 330         entity gps;\r
 331         using_gps = true;\r
 332 \r
 333         self.origin_x = ReadCoord();\r
 334         self.origin_y = ReadCoord();\r
 335         self.angles_y = ReadCoord();\r
 336         self.origin_z = self.angles_x = self.angles_z = 0;\r
 337 \r
 338         for(gps = gps_start; gps; gps = gps.chain)\r
 339         {\r
 340                 if(gps == self)\r
 341                         break;\r
 342         }\r
 343         if(!gps)\r
 344         {\r
 345                 self.chain = gps_start;\r
 346                 gps_start = self;\r
 347         }\r
 348 }\r
 349 \r
 350 void Ent_RemoveONS()\r
 351 {\r
 352         if(gps_start == self)\r
 353                 gps_start = self.chain;\r
 354         else\r
 355         {\r
 356                 local entity ent;\r
 357                 ent = gps_start;\r
 358                         \r
 359                 while(ent.chain != self && ent.chain != world)\r
 360                         ent = ent.chain;\r
 361                 if(ent.chain == self)\r
 362                         ent.chain = self.chain;\r
 363         }\r
 364 }\r
 365 \r
 366 void Ent_Remove();\r
 367 void Ent_ReadPlayerScore()\r
 368 {\r
 369         float i, Team, n;\r
 370         float isNew;\r
 371         entity o;\r
 372 \r
 373         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 374         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 375         isNew = !self.owner; // workaround for DP bug\r
 376         n = ReadByte()-1;\r
 377 \r
 378 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 379         if(!isNew && n != self.sv_entnum)\r
 380         {\r
 381                 print("A CSQC entity changed its owner!\n");\r
 382                 isNew = true;\r
 383                 Ent_Remove();\r
 384                 self.enttype = ENT_CLIENT_SCORES;\r
 385         }\r
 386 #endif\r
 387 \r
 388         self.sv_entnum = n;\r
 389         Team = GetPlayerColor(self.sv_entnum);\r
 390 \r
 391         if not(playerslots[self.sv_entnum])\r
 392                 playerslots[self.sv_entnum] = spawn();\r
 393         o = self.owner = playerslots[self.sv_entnum];\r
 394         o.sv_entnum = self.sv_entnum;\r
 395         o.gotscores = 1;\r
 396         if not(o.sort_prev)\r
 397                 RegisterPlayer(o);\r
 398 \r
 399         SetTeam(o, Team);\r
 400 \r
 401 #if MAX_SCORE <= 3\r
 402         for(i = 0; i < MAX_SCORE; ++i)\r
 403                 o.(scores[i]) = ReadShort();\r
 404 #else\r
 405         float sf;\r
 406 #if MAX_SCORE <= 8\r
 407         sf = ReadByte();\r
 408 #else\r
 409         sf = ReadShort();\r
 410 #endif\r
 411         float p;\r
 412         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 413                 if(sf & p)\r
 414                         o.(scores[i]) = ReadShort();\r
 415 #endif\r
 416 \r
 417         Sbar_UpdatePlayerPos(o);\r
 418 }\r
 419 \r
 420 void Ent_ReadTeamScore()\r
 421 {\r
 422         float i;\r
 423         entity o;\r
 424         \r
 425         self.team = ReadByte();\r
 426         o = self.owner = GetTeam(self.team, true);\r
 427 \r
 428 #if MAX_TEAMSCORE <= 3\r
 429         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 430                 o.(teamscores[i]) = ReadShort();\r
 431 #else\r
 432         float sf;\r
 433 #if MAX_TEAMSCORE <= 8\r
 434         sf = ReadByte();\r
 435 #else\r
 436         sf = ReadShort();\r
 437 #endif\r
 438         float p;\r
 439         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 440                 if(sf & p)\r
 441                         o.(teamscores[i]) = ReadShort();\r
 442 #endif\r
 443 \r
 444         Sbar_UpdateTeamPos(o);\r
 445 }\r
 446 \r
 447 void Ent_Nagger()\r
 448 {\r
 449         float nags;\r
 450         string s;\r
 451 \r
 452         nags = ReadByte();\r
 453 \r
 454         if(nags & 128)\r
 455         {\r
 456                 if(vote_called_vote)\r
 457                         strunzone(vote_called_vote);\r
 458                 vote_called_vote = strzone(ReadString());\r
 459         }\r
 460 \r
 461         ready_waiting = (nags & 1);\r
 462         ready_waiting_for_me = (nags & 2);\r
 463         vote_waiting = (nags & 4);\r
 464         vote_waiting_for_me = (nags & 8);\r
 465 }\r
 466 \r
 467 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 468 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 469 void(float bIsNewEntity) CSQC_Ent_Update =\r
 470 {\r
 471         float msg, t;\r
 472         t = ReadByte();\r
 473 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 474         if(self.enttype)\r
 475                 if(t != self.enttype)\r
 476                 {\r
 477                         print("A CSQC entity changed its type!\n");\r
 478                         Ent_Remove();\r
 479                 }\r
 480 #endif\r
 481         self.enttype = t;\r
 482         if(self.enttype == ENT_CLIENT_ENTCS)\r
 483         {\r
 484                 self.sv_entnum = ReadByte()-1;\r
 485 \r
 486                 for(msg = ReadByte(); msg != ENTCS_MSG_END; msg = ReadByte())\r
 487                 {\r
 488                         switch(msg)\r
 489                         {\r
 490                         case ENTCS_MSG_ONS_GPS: Ent_ReadONS(); break;\r
 491                         case ENTCS_MSG_ONS_REMOVE: Ent_RemoveONS(); break;\r
 492                         default:\r
 493                                 error("unknown ENTCS_MSG type\n");\r
 494                         }\r
 495                 }\r
 496         }\r
 497         else if(self.enttype == ENT_CLIENT_SCORES)\r
 498                 Ent_ReadPlayerScore();\r
 499         else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 500                 Ent_ReadTeamScore();\r
 501         else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 502                 Ent_PointParticles();\r
 503         else if(self.enttype == ENT_CLIENT_RAINSNOW)\r
 504                 Ent_RainOrSnow();\r
 505         else if(self.enttype == ENT_CLIENT_LASER)\r
 506                 Ent_Laser();\r
 507         else if(self.enttype == ENT_CLIENT_NAGGER)\r
 508                 Ent_Nagger();\r
 509         else\r
 510                 error("unknown entity type in CSQC_Ent_Update\n");\r
 511         \r
 512 };\r
 513 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 514 // used when an entity changes its type. For an entity that someone interacts\r
 515 // with others, make sure it can no longer do so.\r
 516 void Ent_Remove()\r
 517 {\r
 518         if(self.enttype == ENT_CLIENT_ENTCS)\r
 519         {\r
 520                 if(using_gps) //gametype == GAME_ONSLAUGHT)\r
 521                 {\r
 522                         if(gps_start == self)\r
 523                                 gps_start = self.chain;\r
 524                         else\r
 525                         {\r
 526                                 local entity ent;\r
 527                                 ent = gps_start;\r
 528                         \r
 529                                 while(ent.chain != self && ent.chain != world)\r
 530                                         ent = ent.chain;\r
 531                                 if(ent.chain == self)\r
 532                                         ent.chain = self.chain;\r
 533                         }\r
 534                 }\r
 535         } else if(self.enttype == ENT_CLIENT_SCORES)\r
 536         {\r
 537                 if(self.owner)\r
 538                 {\r
 539                         SetTeam(self.owner, -1);\r
 540                         if(self.owner.sort_prev)\r
 541                                 RemovePlayer(self.owner);\r
 542                         self.owner.sort_prev = NULL;\r
 543                 }\r
 544         } else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 545         {\r
 546                 /*\r
 547                 if(self.owner)\r
 548                         RemoveTeam(self.owner);\r
 549                 */\r
 550                 // we don't NEED to remove them... they won't display anyway\r
 551                 // plus, svqc never does this anyway\r
 552         } else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 553         {\r
 554                 Ent_PointParticles_Remove();\r
 555         }\r
 556 \r
 557         self.enttype = 0;\r
 558         self.classname = "";\r
 559         self.draw = menu_sub_null;\r
 560         // TODO possibly set more stuff to defaults\r
 561 }\r
 562 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 563 void CSQC_Ent_Remove()\r
 564 {\r
 565         if(self.enttype)\r
 566                 Ent_Remove();\r
 567         remove(self);\r
 568 }\r
 569 \r
 570 void Gamemode_Init()\r
 571 {\r
 572         local string mapinfo, infoline;\r
 573         local float len;\r
 574         local float file;\r
 575 \r
 576         get_mi_min_max();\r
 577         mi_center = (mi_min + mi_max) * 0.5;\r
 578         mi_scale = mi_max - mi_min;\r
 579         minimapname = strzone(strcat("gfx/", mi_shortname, "_mini.tga"));\r
 580         shortmapname = mi_shortname;\r
 581 \r
 582         if(gametype == GAME_ONSLAUGHT) {\r
 583                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 584                 precache_pic(minimapname);\r
 585                 precache_pic("gfx/ons-cp-neutral.tga");\r
 586                 precache_pic("gfx/ons-cp-red.tga");\r
 587                 precache_pic("gfx/ons-cp-blue.tga");\r
 588                 precache_pic("gfx/ons-frame.tga");\r
 589                 precache_pic("gfx/ons-frame-team.tga");\r
 590         } else if(gametype == GAME_KEYHUNT) {\r
 591                 precache_pic("gfx/sb_key_carrying");\r
 592                 precache_pic("gfx/sb_key_carrying_outline");\r
 593         }\r
 594 }\r
 595 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 596 void CSQC_Parse_StuffCmd(string strMessage)\r
 597 {\r
 598         localcmd(strMessage);\r
 599 }\r
 600 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 601 void CSQC_Parse_Print(string strMessage)\r
 602 {\r
 603         print(strMessage);\r
 604 }\r
 605 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  To execute standard behavior, simply execute cprint with the string.\r
 606 void CSQC_Parse_CenterPrint(string strMessage)\r
 607 {\r
 608         cprint(strMessage);\r
 609 }\r
 610 \r
 611 void CSQC_CheckRevision();\r
 612 \r
 613 void Fog_Force()\r
 614 {\r
 615         string s;\r
 616 \r
 617         // TODO somehow thwart prvm_globalset client ...\r
 618 \r
 619         if(forcefog != "")\r
 620                 localcmd(strcat("\nfog ", forcefog, "\nr_fog_exp2 0\nr_drawfog 1\n"));\r
 621 }\r
 622 \r
 623 void Net_ReadFog()\r
 624 {\r
 625         if(forcefog)\r
 626                 strunzone(forcefog);\r
 627         ReadCoord(); // ignore fog interval\r
 628         forcefog = strzone(ReadString());\r
 629 }\r
 630 \r
 631 void Gamemode_Init();\r
 632 void Net_ReadScoresInfo()\r
 633 {\r
 634         float i;\r
 635         gametype = ReadByte();\r
 636         for(i = 0; i < MAX_SCORE; ++i)\r
 637         {\r
 638                 scores_label[i] = strzone(ReadString());\r
 639                 scores_flags[i] = ReadByte();\r
 640         }\r
 641         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 642         {\r
 643                 teamscores_label[i] = strzone(ReadString());\r
 644                 teamscores_flags[i] = ReadByte();\r
 645         }\r
 646         Sbar_InitScores();\r
 647         Gamemode_Init();\r
 648 }\r
 649 \r
 650 void Net_ReadInit()\r
 651 {\r
 652         float i;\r
 653         csqc_revision = ReadShort();\r
 654         maxclients = ReadByte();\r
 655         for(i = 0; i < 24; ++i)\r
 656                 weaponimpulse[i] = ReadByte() - 1;\r
 657         CSQC_CheckRevision();\r
 658 }\r
 659 \r
 660 string Net_ReadPicture()\r
 661 {\r
 662         string img;\r
 663         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 664         {\r
 665                 img = ReadPicture();\r
 666                 print(strcat("Got Picture: ", img, "\n"));\r
 667         } else {\r
 668                 img = ReadString();\r
 669                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 670                 float psize, i;\r
 671                 psize = ReadShort();\r
 672                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 673                 // Because then this could be optimized to first get all 4-byte-groups,\r
 674                 // then the remaining 2, then the remaining 1\r
 675                 for(i = 0; i < psize; ++i)\r
 676                         ReadByte();\r
 677         }\r
 678         return img;\r
 679 }\r
 680 \r
 681 void Net_Config()\r
 682 {\r
 683         string key, value;\r
 684         key = ReadString();\r
 685         value = ReadString();\r
 686         db_put(configdb, strcat("/v/", key), value);\r
 687         db_put(configdb, strcat("/s/", key), "1");\r
 688 }\r
 689 \r
 690 void Net_ReadRace()\r
 691 {\r
 692         float b;\r
 693 \r
 694         b = ReadByte();\r
 695 \r
 696         switch(b)\r
 697         {\r
 698                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 699                         race_checkpoint = ReadByte();\r
 700                         race_time = ReadShort();\r
 701                         race_previousbesttime = ReadShort();\r
 702                         if(race_previousbestname)\r
 703                                 strunzone(race_previousbestname);\r
 704                         race_previousbestname = strzone(ReadString());\r
 705 \r
 706                         race_checkpointtime = time;\r
 707 \r
 708                         if(race_checkpoint == 0)\r
 709                                 race_laptime = time; // valid\r
 710 \r
 711                         break;\r
 712 \r
 713                 case RACE_NET_CHECKPOINT_CLEAR:\r
 714                         race_laptime = 0;\r
 715                         race_checkpointtime = 0;\r
 716                         break;\r
 717 \r
 718                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 719                         race_laptime = ReadCoord();\r
 720                         race_checkpointtime = -99999;\r
 721                         // fall through\r
 722                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 723                         race_nextcheckpoint = ReadByte();\r
 724 \r
 725                         race_nextbesttime = ReadShort();\r
 726                         if(race_nextbestname)\r
 727                                 strunzone(race_nextbestname);\r
 728                         race_nextbestname = strzone(ReadString());\r
 729                         break;\r
 730 \r
 731                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 732                         race_mycheckpoint = ReadByte();\r
 733                         race_mycheckpointtime = time;\r
 734                         race_mycheckpointdelta = ReadShort();\r
 735                         race_mycheckpointlapsdelta = ReadByte();\r
 736                         if(race_mycheckpointlapsdelta >= 128)\r
 737                                 race_mycheckpointlapsdelta -= 256;\r
 738                         if(race_mycheckpointenemy)\r
 739                                 strunzone(race_mycheckpointenemy);\r
 740                         race_mycheckpointenemy = strzone(ReadString());\r
 741                         break;\r
 742 \r
 743                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 744                         race_othercheckpoint = ReadByte();\r
 745                         race_othercheckpointtime = time;\r
 746                         race_othercheckpointdelta = ReadShort();\r
 747                         race_othercheckpointlapsdelta = ReadByte();\r
 748                         if(race_othercheckpointlapsdelta >= 128)\r
 749                                 race_othercheckpointlapsdelta -= 256;\r
 750                         if(race_othercheckpointenemy)\r
 751                                 strunzone(race_othercheckpointenemy);\r
 752                         race_othercheckpointenemy = strzone(ReadString());\r
 753                         break;\r
 754         }\r
 755 }\r
 756 \r
 757 void Net_ReadForceScoreboard()\r
 758 {\r
 759         sb_showscores_force = ReadByte();\r
 760 }\r
 761 \r
 762 void Net_Reset()\r
 763 {\r
 764         float i;\r
 765         race_laptime = 0;\r
 766         race_checkpointtime = 0;\r
 767         for(i = 0; i < 24; ++i)\r
 768                 angles_held_status[i] = 0;\r
 769 }\r
 770 \r
 771 void Net_ReadSpectating()\r
 772 {\r
 773         float newspectatee_status;\r
 774         newspectatee_status = ReadByte();\r
 775         if(newspectatee_status == player_localentnum)\r
 776                 newspectatee_status = -1; // observing\r
 777         if(newspectatee_status != spectatee_status)\r
 778                 Net_Reset();\r
 779         spectatee_status = newspectatee_status;\r
 780 }\r
 781 \r
 782 void Net_ReadZoomNotify()\r
 783 {\r
 784         spectatorbutton_zoom = ReadByte();\r
 785 }\r
 786 \r
 787 void Net_ReadSpawn()\r
 788 {\r
 789         zoomin_effect = 1;\r
 790         current_viewzoom = 0.6;\r
 791 }\r
 792 \r
 793 void Net_ReadWarmupStage()\r
 794 {\r
 795         warmup_stage = ReadByte();\r
 796 }\r
 797 \r
 798 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 799 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 800 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 801 void Net_ReadHoldAngles();\r
 802 float CSQC_Parse_TempEntity()\r
 803 {\r
 804         local float bHandled;\r
 805                 bHandled  = true;\r
 806         // Acquire TE ID\r
 807         local float nTEID;\r
 808                 nTEID = ReadByte();\r
 809 \r
 810                 // NOTE: Could just do return instead of break...\r
 811         switch(nTEID)\r
 812         {\r
 813                 case TE_CSQC_INIT:\r
 814                         Net_ReadInit();\r
 815                         bHandled = true;\r
 816                         break;\r
 817                 case TE_CSQC_MAPVOTE:\r
 818                         Net_Mapvote();\r
 819                         bHandled = true;\r
 820                         break;\r
 821                 case TE_CSQC_CONFIG:\r
 822                         Net_Config();\r
 823                         bHandled = true;\r
 824                         break;\r
 825                 case TE_CSQC_SCORESINFO:\r
 826                         Net_ReadScoresInfo();\r
 827                         bHandled = true;\r
 828                         break;\r
 829                 case TE_CSQC_RACE:\r
 830                         Net_ReadRace();\r
 831                         bHandled = true;\r
 832                         break;\r
 833                 case TE_CSQC_FORCESCOREBOARD:\r
 834                         Net_ReadForceScoreboard();\r
 835                         bHandled = true;\r
 836                         break;\r
 837                 case TE_CSQC_SPECTATING:\r
 838                         Net_ReadSpectating();\r
 839                         bHandled = true;\r
 840                         break;\r
 841                 case 13: // TE_BEAM\r
 842                         Net_GrapplingHook();\r
 843                         bHandled = true;\r
 844                         break;\r
 845                 case TE_CSQC_SPAWN:\r
 846                         Net_ReadSpawn();\r
 847                         bHandled = true;\r
 848                         break;\r
 849                 case TE_CSQC_ZOOMNOTIFY:\r
 850                         Net_ReadZoomNotify();\r
 851                         bHandled = true;\r
 852                         break;\r
 853                 case TE_CSQC_HOLDANGLES:\r
 854                         Net_ReadHoldAngles();\r
 855                         bHandled = true;\r
 856                         break;\r
 857                 case TE_CSQC_WARMUP:\r
 858                         Net_ReadWarmupStage();\r
 859                         bHandled = true;\r
 860                         break;\r
 861                 case TE_CSQC_FOG:\r
 862                         Net_ReadFog();\r
 863                         bHandled = true;\r
 864                         break;\r
 865                 default:\r
 866                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
 867                         bHandled = false;\r
 868                         break;\r
 869         }\r
 870         \r
 871         if(!postinit)\r
 872                 PostInit();\r
 873                 \r
 874         return bHandled;\r
 875 }\r
 876 \r
 877 // COMMIT-TODO: Update if necessare, before committing\r
 878 void CSQC_CheckRevision()\r
 879 {\r
 880         if(csqc_revision == CSQC_REVISION)\r
 881         {\r
 882                 print("^2SVQC and CSQC revisions are compatible.\n");\r
 883         } else if(csqc_revision < CSQC_REVISION) {\r
 884                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
 885         } else if(csqc_revision > CSQC_REVISION) {\r
 886                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
 887                 print("^1Please update to a newer version.\n");\r
 888         }\r
 889 }\r
 890 \r
 891 string getcommandkey(string text, string command)\r
 892 {\r
 893         string keys;\r
 894         float n, j, k, l;\r
 895 \r
 896         if (!sbar_showbinds)\r
 897                 return text;\r
 898 \r
 899         keys = db_get(binddb, command);\r
 900         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 901         {\r
 902                 if (!keys) \r
 903                 {\r
 904                         n = tokenize(findkeysforcommand(command));\r
 905                         for(j = 0; j < n; ++j)\r
 906                         {\r
 907                                 k = stof(argv(j));\r
 908                                 if(k != -1) \r
 909                                 {\r
 910                                         if ("" == keys)\r
 911                                                 keys = keynumtostring(k);\r
 912                                         else\r
 913                                                 keys = strcat(keys, ", ", keynumtostring(k));\r
 914 \r
 915                                         ++l;\r
 916                                         if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;\r
 917                                 }\r
 918                         \r
 919                         }\r
 920                         db_put(binddb, command, keys);\r
 921                 }\r
 922         }\r
 923         \r
 924         if ("" == keys) {\r
 925                 if (sbar_showbinds > 1)\r
 926                         return strcat(text, " (not bound)");\r
 927                 else\r
 928                         return text;\r
 929         }\r
 930         else if (sbar_showbinds > 1)\r
 931                 return strcat(text, " (", keys, ")");\r
 932         else\r
 933                 return keys;\r
 934 }\r