attic/TeamNexuiz/game/gamec/w_hagar.c

   1 void() hagar_ready_01;\r
   2 void() hagar_fire1_01;\r
   3 void() hagar_deselect_01;\r
   4 void() hagar_select_01;\r
   5 \r
   6 float() hagar_check =\r
   7 {\r
   8         if (self.ammo_rockets >= 1)\r
   9                 return TRUE;\r
  10         return FALSE;\r
  11 };\r
  12 \r
  13 void(float req) w_hagar =\r
  14 {\r
  15         if (req == WR_IDLE)\r
  16                 hagar_ready_01();\r
  17         else if (req == WR_FIRE1 || req == WR_FIRE2)\r
  18                 weapon_prepareattack(hagar_check, hagar_check, hagar_fire1_01, cvar("g_balance_hagar_refire"));\r
  19         else if (req == WR_RAISE)\r
  20                 hagar_select_01();\r
  21         else if (req == WR_UPDATECOUNTS)\r
  22                 self.currentammo = self.ammo_rockets;\r
  23         else if (req == WR_DROP)\r
  24                 hagar_deselect_01();\r
  25         else if (req == WR_SETUP)\r
  26                 weapon_setup(WEP_HAGAR, "w_hagar.zym", IT_ROCKETS);\r
  27         else if (req == WR_CHECKAMMO)\r
  28                 weapon_hasammo = hagar_check();\r
  29 };\r
  30 \r
  31 void W_Hagar_Explode (void)\r
  32 {\r
  33         vector  org2;\r
  34         float b;\r
  35         org2 = findbetterlocation (self.origin);\r
  36         effect (org2, "models/sprites/hagarexplosion.spr32", 0, 20, 30);\r
  37         b = crandom();\r
  38         if (b<-0.7)\r
  39                 sound (self, CHAN_BODY, "weapons/hagexp1.wav", 1, ATTN_NORM);\r
  40         else if (b<0.4)\r
  41                 sound (self, CHAN_BODY, "weapons/hagexp2.wav", 1, ATTN_NORM);\r
  42         else if (b<1)\r
  43                 sound (self, CHAN_BODY, "weapons/hagexp3.wav", 1, ATTN_NORM);\r
  44 \r
  45         self.event_damage = SUB_Null;\r
  46         RadiusDamage (self, self.owner, cvar("g_balance_hagar_damage"), cvar("g_balance_hagar_edgedamage"), cvar("g_balance_hagar_radius"), world, cvar("g_balance_hagar_force"), WEP_HAGAR);\r
  47 \r
  48         remove (self);\r
  49 }\r
  50 \r
  51 void W_Hagar_Touch (void)\r
  52 {\r
  53         if (other == self.owner)\r
  54                 return;\r
  55         else if (pointcontents (self.origin) == CONTENT_SKY)\r
  56         {\r
  57                 remove (self);\r
  58                 return;\r
  59         }\r
  60 \r
  61         W_Hagar_Explode ();\r
  62 }\r
  63 \r
  64 void W_Hagar_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)\r
  65 {\r
  66         self.health = self.health - damage;\r
  67         if (self.health <= 0)\r
  68                 W_Hagar_Explode();\r
  69 }\r
  70 \r
  71 void W_Hagar_Attack (void)\r
  72 {\r
  73         local entity missile;\r
  74         local vector org;\r
  75 \r
  76         sound (self, CHAN_WEAPON, "weapons/hagar_fire.wav", 1, ATTN_NORM);\r
  77         self.ammo_rockets = self.ammo_rockets - 1;\r
  78         self.punchangle_x = -2;\r
  79         org = self.origin + self.view_ofs + v_forward * 25 + v_right * 5 + v_up * -8;\r
  80 \r
  81         missile = spawn ();\r
  82         missile.owner = self;\r
  83         missile.classname = "missile";\r
  84         missile.touch = W_Hagar_Touch;\r
  85         missile.think = W_Hagar_Explode;\r
  86         missile.nextthink = time + 10;\r
  87         missile.solid = SOLID_BBOX;\r
  88         missile.scale = 0.4; // BUG: the model is too big\r
  89         setorigin (missile, org);\r
  90         setmodel (missile, "models/hagarmissile.mdl");\r
  91         setsize (missile, '0 0 0', '0 0 0');\r
  92         //missile.takedamage = DAMAGE_YES;\r
  93         //missile.damageforcescale = 4;\r
  94         //missile.health = 10;\r
  95         //missile.event_damage = W_Hagar_Damage;\r
  96         missile.effects = EF_LOWPRECISION;\r
  97 \r
  98         if (self.button3)\r
  99         {\r
 100                 missile.movetype = MOVETYPE_TOSS;\r
 101                 missile.velocity = v_forward * cvar("g_balance_hagar_speed2") + v_up * cvar("g_balance_hagar_speed2_up");\r
 102                 missile.avelocity = '100 10 10';\r
 103         }\r
 104         else\r
 105         {\r
 106                 missile.movetype = MOVETYPE_FLY;\r
 107                 missile.velocity = (v_forward + v_right * crandom() * 0.035 + v_up * crandom() * 0.015) * cvar("g_balance_hagar_speed");\r
 108         }\r
 109 \r
 110         missile.angles = vectoangles (missile.velocity);\r
 111 }\r
 112 \r
 113 // weapon frames\r
 114 void()  hagar_ready_01 =        {weapon_thinkf(WFRAME_IDLE, 0.1, hagar_ready_01); self.weaponentity.state = WS_READY;};\r
 115 void()  hagar_select_01 =       {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');};\r
 116 void()  hagar_deselect_01 =     {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);};\r
 117 void()  hagar_fire1_01 =\r
 118 {\r
 119         weapon_doattack(hagar_check, hagar_check, W_Hagar_Attack);\r
 120         weapon_thinkf(WFRAME_FIRE1, 0.15, hagar_ready_01);\r
 121 };\r
 122 \r