configure.ac

   1 AC_PREREQ([2.54])
   2 AC_INIT([openbox], [3.5.0-rc1], [http://bugzilla.icculus.org])
   3 AM_INIT_AUTOMAKE
   4 AC_CONFIG_SRCDIR([openbox/openbox.c])
   5
   6 OB_VERSION=$PACKAGE_VERSION
   7 AC_SUBST(OB_VERSION)
   8
   9 dnl Making releases:
  10 dnl   RR_MICRO_VERSION += 1;
  11 dnl   RR_INTERFACE_AGE += 1;
  12 dnl   R_BINARY_AGE += 1;
  13 dnl if any functions have been added, set RR_INTERFACE_AGE to 0.
  14 dnl if backwards compatibility has been broken,
  15 dnl set RR_BINARY_AGE and RR_INTERFACE_AGE to 0.
  16 dnl
  17 dnl if MAJOR or MINOR version changes, be sure to change AC_INIT above to match
  18 dnl
  19 RR_MAJOR_VERSION=3
  20 RR_MINOR_VERSION=5
  21 RR_MICRO_VERSION=27
  22 RR_INTERFACE_AGE=0
  23 RR_BINARY_AGE=0
  24 RR_VERSION=$RR_MAJOR_VERSION.$RR_MINOR_VERSION
  25
  26 OBT_MAJOR_VERSION=3
  27 OBT_MINOR_VERSION=5
  28 OBT_MICRO_VERSION=0
  29 OBT_INTERFACE_AGE=0
  30 OBT_BINARY_AGE=0
  31 OBT_VERSION=$OBT_MAJOR_VERSION.$OBT_MINOR_VERSION
  32
  33 AC_SUBST(RR_MAJOR_VERSION)
  34 AC_SUBST(RR_MINOR_VERSION)
  35 AC_SUBST(RR_MICRO_VERSION)
  36 AC_SUBST(RR_INTERFACE_AGE)
  37 AC_SUBST(RR_BINARY_AGE)
  38 AC_SUBST(RR_VERSION)
  39 AC_SUBST(OBT_MAJOR_VERSION)
  40 AC_SUBST(OBT_MINOR_VERSION)
  41 AC_SUBST(OBT_MICRO_VERSION)
  42 AC_SUBST(OBT_INTERFACE_AGE)
  43 AC_SUBST(OBT_BINARY_AGE)
  44 AC_SUBST(OBT_VERSION)
  45
  46 dnl Libtool versioning
  47 RR_RELEASE=$RR_MAJOR_VERSION.$RR_MINOR_VERSION
  48 RR_CURRENT=`expr $RR_MICRO_VERSION - $RR_INTERFACE_AGE`
  49 RR_REVISION=$RR_INTERFACE_AGE
  50 RR_AGE=`expr $RR_BINARY_AGE - $RR_INTERFACE_AGE`
  51 RR_CURRENT_MINUS_AGE=`expr $RR_CURRENT - $RR_AGE`
  52
  53 OBT_RELEASE=$OBT_MAJOR_VERSION.$OBT_MINOR_VERSION
  54 OBT_CURRENT=`expr $OBT_MICRO_VERSION - $OBT_INTERFACE_AGE`
  55 OBT_REVISION=$OBT_INTERFACE_AGE
  56 OBT_AGE=`expr $OBT_BINARY_AGE - $OBT_INTERFACE_AGE`
  57 OBT_CURRENT_MINUS_AGE=`expr $OBT_CURRENT - $OBT_AGE`
  58
  59 AC_SUBST(RR_RELEASE)
  60 AC_SUBST(RR_CURRENT)
  61 AC_SUBST(RR_REVISION)
  62 AC_SUBST(RR_AGE)
  63 AC_SUBST(RR_CURRENT_MINUS_AGE)
  64 AC_SUBST(OBT_RELEASE)
  65 AC_SUBST(OBT_CURRENT)
  66 AC_SUBST(OBT_REVISION)
  67 AC_SUBST(OBT_AGE)
  68 AC_SUBST(OBT_CURRENT_MINUS_AGE)
  69
  70 AC_PREFIX_DEFAULT([/usr/local])
  71 test "$prefix" = "NONE" && prefix=$ac_default_prefix
  72
  73 dnl Determine build target
  74 OB_DEBUG
  75 dnl Pick compiler specific/build target flags, and set $CVS
  76 AM_PROG_CC_C_O
  77 OB_COMPILER_FLAGS
  78 AC_C_CONST
  79 AC_C_INLINE
  80
  81 AC_PROG_LIBTOOL
  82 AC_SUBST(LIBTOOL_DEPS)
  83 LIBTOOL="$LIBTOOL --silent"
  84
  85 AC_PROG_INSTALL
  86
  87 AM_GNU_GETTEXT_VERSION(0.15)
  88 AM_GNU_GETTEXT([external])
  89
  90 AC_CHECK_HEADERS(ctype.h fcntl.h locale.h signal.h string.h stdio.h stdlib.h)
  91 AC_CHECK_HEADERS(unistd.h sys/stat.h sys/select.h sys/socket.h sys/time.h)
  92 AC_CHECK_HEADERS(sys/wait.h)
  93 # AC_HEADER_TIME
  94 # AC_TYPE_SIGNAL
  95
  96 AC_PATH_PROG([SED], [sed], [no])
  97 if test "$SED" = "no"; then
  98   AC_MSG_ERROR([The program "sed" is not available. This program is required to build Openbox.])
  99 fi
 100
 101 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.14.0])
 102 AC_SUBST(GLIB_CFLAGS)
 103 AC_SUBST(GLIB_LIBS)
 104
 105 PKG_CHECK_MODULES(PANGO, [pango >= 1.8.0 pangoxft >= 1.8.0])
 106 AC_SUBST(PANGO_CFLAGS)
 107 AC_SUBST(PANGO_LIBS)
 108
 109 PKG_CHECK_MODULES(CAIRO, [cairo-xlib])
 110 AC_SUBST(CAIRO_CFLAGS)
 111 AC_SUBST(CAIRO_LIBS)
 112
 113 PKG_CHECK_MODULES(XML, [libxml-2.0 >= 2.6.0])
 114 AC_SUBST(XML_CFLAGS)
 115 AC_SUBST(XML_LIBS)
 116
 117 AC_ARG_ENABLE(startup-notification,
 118   AC_HELP_STRING(
 119     [--disable-startup-notification],
 120     [disable the startup notification library. [[default=enabled]]]
 121   ),
 122   [enable_sn=$enableval],
 123   [enable_sn=yes]
 124 )
 125
 126 if test "$enable_sn" = yes; then
 127 PKG_CHECK_MODULES(LIBSN, [libstartup-notification-1.0 >= 0.8],
 128   [
 129     AC_DEFINE(USE_LIBSN, [1], [Use startup-notification])
 130     AC_SUBST(LIBSN_CFLAGS)
 131     AC_SUBST(LIBSN_LIBS)
 132     sn_found=yes
 133   ],
 134   [
 135     sn_found=no
 136   ]
 137 )
 138 else
 139   sn_found=no
 140 fi
 141
 142 AC_ARG_ENABLE(xcursor,
 143   AC_HELP_STRING(
 144     [--disable-xcursor],
 145     [disable use of the X Cursor library. [[default=enabled]]]
 146   ),
 147   [enable_xcursor=$enableval],
 148   [enable_xcursor=yes]
 149 )
 150
 151 if test "$enable_xcursor" = yes; then
 152 PKG_CHECK_MODULES(XCURSOR, [xcursor],
 153   [
 154     AC_DEFINE(USE_XCURSOR, [1], [Use X Cursor library])
 155     AC_SUBST(XCURSOR_CFLAGS)
 156     AC_SUBST(XCURSOR_LIBS)
 157     xcursor_found=yes
 158   ],
 159   [
 160     xcursor_found=no
 161   ]
 162 )
 163 else
 164   xcursor_found=no
 165 fi
 166
 167 AC_ARG_ENABLE(imlib2,
 168   AC_HELP_STRING(
 169     [--disable-imlib2],
 170     [disable use of Imlib2 image library for loading icons. [[default=enabled]]]
 171   ),
 172   [enable_imlib2=$enableeval],
 173   [enable_imlib2=yes]
 174 )
 175
 176 if test "$enable_imlib2" = yes; then
 177 PKG_CHECK_MODULES(IMLIB2, [imlib2],
 178   [
 179     AC_DEFINE(USE_IMLIB2, [1], [Use Imlib2 image library])
 180     AC_SUBST(IMLIB2_CFLAGS)
 181     AC_SUBST(IMLIB2_LIBS)
 182     # export it for the pkg-config file
 183     PKG_CONFIG_IMLIB=imlib2
 184     AC_SUBST(PKG_CONFIG_IMLIB)
 185     imlib2_found=yes
 186   ],
 187   [
 188     imlib2_found=no
 189   ]
 190 )
 191 else
 192   imlib2_found=no
 193 fi
 194
 195 AM_CONDITIONAL(USE_IMLIB2, [test $imlib2_found = yes])
 196
 197 dnl Check for session management
 198 X11_SM
 199
 200 #EFENCE_LIBS=-lefence
 201 EFENCE_LIBS=""
 202 AC_SUBST(EFENCE_LIBS)
 203
 204 dnl Check for X11 extensions
 205 X11_EXT_XKB
 206 X11_EXT_XRANDR
 207 X11_EXT_SHAPE
 208 X11_EXT_XINERAMA
 209 X11_EXT_SYNC
 210
 211 AC_CONFIG_FILES([
 212   Makefile
 213   m4/Makefile
 214   po/Makefile.in
 215   obrender/obrender-3.5.pc
 216   obt/obt-3.5.pc
 217   obrender/version.h
 218   obt/version.h
 219   version.h
 220 ])
 221 AC_CONFIG_COMMANDS([doc],
 222                    [test -d doc || mkdir doc])
 223 AC_CONFIG_COMMANDS([data],
 224                    [test -d data || mkdir data])
 225 AC_CONFIG_COMMANDS([data/xsession],
 226                    [test -d data/xsession || mkdir data/xsession])
 227 AC_OUTPUT
 228
 229 AC_MSG_RESULT
 230 AC_MSG_RESULT([Compiling with these options:
 231                Startup Notification... $sn_found
 232                X Cursor Library... $xcursor_found
 233                Session Management... $SM
 234                Imlib2 library... $imlib2_found
 235                ])
 236 AC_MSG_RESULT([configure complete, now type "make"])