configure.ac

   1 AC_PREREQ([2.54])
   2 AC_INIT([openbox], [2.90.0cvs], [http://bugzilla.icculus.org])
   3 AM_INIT_AUTOMAKE
   4 AC_CONFIG_SRCDIR([kernel/openbox.c])
   5
   6 AC_PREFIX_DEFAULT([/usr/local])
   7 test "$prefix" = "NONE" && prefix=$ac_default_prefix
   8
   9 AC_PATH_PROG([SED], [sed])
  10 test "$SED" || AC_MSG_ERROR([sed not found])
  11
  12 # Determine build target
  13 OB_DEBUG
  14 # Pick compiler specific/build target flags, and set $CVS
  15 OB_COMPILER_FLAGS
  16 AC_C_CONST
  17 AC_C_INLINE
  18
  19 if test "$CVS" = "yes"; then
  20     AC_PATH_PROG([FLEX], [flex])
  21     test "$FLEX" || AC_MSG_ERROR([flex not found])
  22
  23     AC_PATH_PROG([BISON], [bison])
  24     test "BISON" || AC_MSG_ERROR([bison not found])
  25 fi
  26
  27 AC_DISABLE_STATIC
  28 AC_LIBTOOL_DLOPEN
  29 AC_PROG_LIBTOOL
  30 AC_SUBST(LIBTOOL_DEPS)
  31 LIBTOOL="$LIBTOOL --silent"
  32
  33 AC_PROG_INSTALL
  34
  35 ALL_LINGUAS=""
  36 AM_GNU_GETTEXT_VERSION(0.11.5)
  37 AM_GNU_GETTEXT([external])
  38
  39 AC_CHECK_HEADERS(ctype.h fcntl.h locale.h signal.h string.h stdio.h stdlib.h)
  40 AC_CHECK_HEADERS(unistd.h sys/stat.h sys/select.h sys/time.h sys/wait.h)
  41 # AC_HEADER_TIME
  42 # AC_TYPE_SIGNAL
  43
  44 PKG_CHECK_MODULES([GLIB], [glib-2.0])
  45 AC_SUBST(GLIB_CFLAGS)
  46 AC_SUBST(GLIB_LIBS)
  47
  48 PKG_CHECK_MODULES([GMODULE], [gmodule-2.0])
  49 AC_SUBST(GMODULE_CFLAGS)
  50 AC_SUBST(GMODULE_LIBS)
  51
  52 PKG_CHECK_MODULES(FC, [fontconfig])
  53 AC_SUBST(FC_CFLAGS)
  54 AC_SUBST(FC_LIBS)
  55
  56 ## XXX REMOVE ME PLS XXX ##
  57 PKG_CHECK_MODULES(XFT, [xft])
  58 AC_SUBST(XFT_CFLAGS)
  59 AC_SUBST(XFT_LIBS)
  60 ## XXX REMOVE ME PLS XXX ##
  61
  62 PKG_CHECK_MODULES(XML, [libxml-2.0])
  63 AC_SUBST(XML_CFLAGS)
  64 AC_SUBST(XML_LIBS)
  65
  66 PKG_CHECK_MODULES(LIBSN, [libstartup-notification-1.0],
  67   [
  68     AC_DEFINE(USE_LIBSN)
  69     AC_SUBST(LIBSN_CFLAGS)
  70     AC_SUBST(LIBSN_LIBS)
  71   ],
  72   [
  73     no_such_luck=yes
  74   ]
  75 )
  76
  77 PKG_CHECK_MODULES(GTK, [gtk+-2.0],
  78   [
  79     AC_SUBST(GTK_CFLAGS)
  80     AC_SUBST(GTK_LIBS)
  81     use_gtk="yes"
  82
  83     PKG_CHECK_MODULES(GLADE, [libglade-2.0],
  84       [
  85         AC_SUBST(GLADE_CFLAGS)
  86         AC_SUBST(GLADE_LIBS)
  87         use_glade="yes"
  88       ],
  89       [
  90         use_glade="no"
  91         AC_MSG_WARN([disabling build of the configuration tool])
  92       ]
  93     )
  94   ],
  95   [
  96     use_gtk="no"
  97     AC_MSG_WARN([disabling build of the configuration tool])
  98   ]
  99 )
 100 AM_CONDITIONAL(OBCONF, [test "$use_gtk" = "yes" && test "$use_glade" = "yes"])
 101
 102 # Check for X11 extensions
 103 X11_EXT_XKB
 104 X11_EXT_XRANDR
 105 X11_EXT_VIDMODE
 106 X11_EXT_SHAPE
 107 X11_EXT_XINERAMA
 108
 109 GL_DEVEL
 110
 111 AC_CONFIG_FILES([Makefile
 112                  po/Makefile.in
 113                  themes/Makefile
 114                  data/Makefile
 115                  glft/Makefile
 116                  render2/Makefile
 117                  parser/Makefile
 118                  kernel/Makefile
 119                  plugins/Makefile
 120                  plugins/resistance/Makefile
 121                  plugins/placement/Makefile
 122                  plugins/mouse/Makefile
 123                  plugins/keyboard/Makefile
 124                  plugins/menu/Makefile
 125                  tools/Makefile
 126                  tools/obconf/Makefile])
 127 AC_OUTPUT
 128
 129 AC_MSG_RESULT
 130 if test "$DEBUG" = "yes"; then
 131   AC_MSG_RESULT([Creating a DEBUG build.])
 132 else
 133   AC_MSG_RESULT([Creating a RELEASE build.])
 134 fi
 135 AC_MSG_RESULT
 136 AC_MSG_RESULT([configure complete, now type \"make\"])