configure.ac

   1 # -*- mode: shell-script -*-
   2
   3 define([D2X_MAJOR],0)
   4 define([D2X_MINOR],1)
   5 define([D2X_MICRO],4)
   6
   7 AC_INIT(d2x,[D2X_MAJOR.D2X_MINOR.D2X_MICRO],[descent-source@warpcore.org])
   8 AC_PREREQ(2.52)
   9
  10 AC_CANONICAL_BUILD
  11 AC_CANONICAL_HOST
  12 AC_CANONICAL_TARGET
  13
  14 AM_INIT_AUTOMAKE([1.6])
  15
  16 AM_CONFIG_HEADER(conf.h)
  17
  18 AC_DEFINE_UNQUOTED(D2XMAJOR,D2X_MAJOR,[d2x major version])
  19 AC_DEFINE_UNQUOTED(D2XMINOR,D2X_MINOR,[d2x minor version])
  20 AC_DEFINE_UNQUOTED(D2XMICRO,D2X_MICRO,[d2x micro version])
  21
  22 AM_MAINTAINER_MODE
  23
  24 #kludge to keep autoconf from adding -g -O2
  25 CFLAGS=" $CFLAGS"
  26
  27 AC_PROG_INSTALL
  28 AC_PROG_MAKE_SET
  29 AC_ISC_POSIX
  30 AC_CHECK_TOOL(CC, gcc, :)
  31 AC_CHECK_TOOL(RANLIB, ranlib, :)
  32 AC_CHECK_TOOL(STRIP, strip, :)
  33 AC_CHECK_TOOL(AR, ar, :)
  34 AC_PROG_CC
  35 AC_PROG_CXX
  36 AC_STDC_HEADERS
  37 AC_PATH_PROGS(NASM, nasm nasmw, no)
  38 AC_C_BIGENDIAN
  39
  40 case $host_os in
  41     cygwin)
  42         AC_MSG_WARN([Cygwin found, setting -mno-cygwin])
  43         CFLAGS="-mno-cygwin $CFLAGS"
  44         MINGW32=yes
  45         ;;
  46     mingw*)
  47         MINGW32=yes
  48         ;;
  49     darwin*)
  50         MACOSX=yes
  51         ;;
  52     msdos*)
  53         MSDOS=yes
  54         ;;
  55 esac
  56
  57 AM_CONDITIONAL(MINGW32, test x$MINGW32 = xyes)
  58 if test x$MINGW32 = xyes; then
  59     GL_LIBS="opengl32 glu32"
  60 elif test x$MACOSX = xyes; then
  61     GL_LIBS=""
  62 else
  63     GL_LIBS="GL GLU"
  64 fi
  65
  66 if test x$MACOSX = xyes; then
  67     AC_DEFINE(__MACOSX__,,[Define if building on MAC OS X])
  68 fi
  69 AM_CONDITIONAL(MACOSX, test x$MACOSX = xyes)
  70
  71 dnl Set $prefix and $exec_prefix to $ac_default_prefix if they are not set
  72 test "x$prefix" = "xNONE" && prefix=$ac_default_prefix
  73 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
  74
  75 dnl Set default locations to find data files.
  76 eval foo="$datadir"
  77 default_sharepath="$foo/games/$PACKAGE"
  78
  79 CFLAGS="-Wall $CFLAGS"
  80
  81 dnl Enable editor build?
  82 AC_ARG_ENABLE(editor,
  83     [  --enable-editor         Build editor? (not functional)],,)
  84 if test x$enable_editor = xyes; then
  85     AC_DEFINE(EDITOR,,[Define if you want to build the editor])
  86     D2X_MAIN_SUBDIRS=editor
  87 fi
  88 AM_CONDITIONAL(EDITOR, test x$enable_editor = xyes)
  89
  90 dnl Enable shareware build?
  91 AC_ARG_ENABLE(shareware,
  92     [  --enable-shareware      Build for demo datafiles (not functional)],,)
  93 if test x$enable_shareware = xyes; then
  94     AC_DEFINE(SHAREWARE,,[Define if you want to build the demo version])
  95     D2X_FEATURES="shareware ${D2X_FEATURES}"
  96 fi
  97 AM_CONDITIONAL(SHAREWARE, test x$enable_shareware = xyes)
  98
  99 dnl Build with NDEBUG?
 100 AC_ARG_ENABLE(debug,
 101     [  --disable-debug         Take out debug symbols, Asserts, Int3, etc ],,)
 102 if test x$enable_debug = xno; then
 103     AC_DEFINE(NDEBUG,,[Define to disable asserts, int3, etc.])
 104     CFLAGS="-O2 $CFLAGS"
 105 else
 106     CFLAGS="-g $CFLAGS"
 107     D2X_FEATURES="debug ${D2X_FEATURES}"
 108 fi
 109
 110 dnl Build with RELEASE?
 111 AC_ARG_ENABLE(release,
 112     [  --enable-release        Release build.  Removes debug/editor things ],,)
 113 if test x$enable_release = xyes; then
 114     AC_DEFINE(RELEASE,,[Define for a "release" build])
 115     D2X_FEATURES="release ${D2X_FEATURES}"
 116 fi
 117
 118 dnl Build with FAST_FILE_IO?
 119 AC_ARG_ENABLE(fastfileio,
 120     [  --enable-fastfileio     Fast file i/o build.  little-endian only ],,)
 121 if test x$enable_fastfileio = xyes; then
 122     AC_DEFINE(FAST_FILE_IO,,[Define for a faster file i/o on little-endian machines])
 123     D2X_FEATURES="fastfileio ${D2X_FEATURES}"
 124 fi
 125
 126 AC_ARG_WITH(sharepath,
 127     [[  --with-sharepath=DIR    Use DIR for shared game data (unix only) [DATADIR/games/d2x]]],
 128     sharepath=$withval, sharepath="auto")
 129 if test "x$sharepath" = "xauto" -o "x$sharepath" = "xyes" -o "x$sharepath" = "x"; then
 130     sharepath="$default_sharepath"
 131 fi
 132 AC_DEFINE_UNQUOTED(SHAREPATH, "$sharepath",[Define this to be the shared game directory root])
 133
 134 # Test for MSDOS
 135 if test x$MSDOS = xyes; then
 136     CFLAGS="-I \$(top_srcdir)/arch/dos/include $CFLAGS"
 137     TARGETS=d2x
 138     D2X_ARCH_SUBDIRS=dos
 139 else
 140
 141     CFLAGS="-pipe $CFLAGS"
 142
 143     dnl Check for SDL
 144     AM_PATH_SDL(1.1.0,
 145         :,
 146         AC_MSG_ERROR(SDL not found. Make sure sdl-config is in your PATH, or specify with --with-sdl-prefix)
 147     )
 148     CFLAGS="$SDL_CFLAGS $CFLAGS"
 149     LIBS="$SDL_LIBS $LIBS"
 150
 151     TARGETS=d2x-sdl
 152     D2X_ARCH_SUBDIRS=sdl
 153
 154     AC_CHECK_HEADERS(netipx/ipx.h)
 155
 156   # Check for OpenGL
 157     AC_ARG_WITH(opengl,
 158         [  --with-opengl           Build OpenGL support ],,)
 159     if test x$with_opengl = xyes; then
 160         for lib in $GL_LIBS; do
 161             AC_CHECK_LIB($lib, main,
 162                 OGL_LIBS="${OGL_LIBS} -l$lib",
 163                 [AC_MSG_ERROR([$lib not found, --with-opengl cannot be used])
 164                     opengl=false],
 165                 ${OGL_LIBS}
 166             )
 167         done
 168         AC_DEFINE(OGL,,[Define if you want an OpenGL build])
 169         TARGETS=d2x-gl
 170         D2X_ARCH_SUBDIRS="ogl ${D2X_ARCH_SUBDIRS}"
 171     fi
 172     AC_SUBST(OGL_LIBS)
 173     AM_CONDITIONAL(USE_OPENGL, test x$with_opengl = xyes)
 174
 175   # Check for GGI
 176     AC_ARG_WITH(ggi,
 177         [  --with-ggi              Build GGI support ],,)
 178     if test x$with_ggi = xyes; then
 179         AC_CHECK_LIB(ggi, ggiInit,
 180             GGI_LIBS="-lggi",
 181             [AC_MSG_ERROR([GGI not found, GGI version cannot be built]); ggi=false])
 182         AC_CHECK_LIB(gii, giiInit,
 183             GGI_LIBS="${GGI_LIBS} -lgii",
 184             [AC_MSG_ERROR([GII not found, GGI version cannot be built]); ggi=false])
 185         AC_DEFINE(GGI,,[Define if you want a GGI build])
 186         TARGETS=d2x-ggi
 187         D2X_ARCH_SUBDIRS="ggi ${D2X_ARCH_SUBDIRS}"
 188     fi
 189     AC_SUBST(GGI_LIBS)
 190     AM_CONDITIONAL(USE_GGI, test x$with_ggi = xyes)
 191
 192   # Check for SVGALib
 193     AC_ARG_WITH(svga,
 194         [  --with-svga             Build SVGALib support ],,)
 195     if test x$with_svga = xyes; then
 196         AC_CHECK_LIB(vga,vga_getmousetype,
 197             SVGA_LIBS="-lvga",
 198             [AC_MSG_ERROR([vga not found, SVGALib cannot be built])
 199                 svga=false],
 200         )
 201         AC_CHECK_LIB(vgagl,gl_getcontext,
 202             SVGA_LIBS="${SVGA_LIBS} -lvgagl",
 203             [AC_MSG_ERROR([vgagl not found, SVGALib cannot be built])
 204                 svga=false],
 205             -lvga)
 206         AC_DEFINE(SVGA,,[Define if you want an SVGALib build])
 207         TARGETS=d2x-svga
 208         D2X_ARCH_SUBDIRS="svgalib ${D2X_ARCH_SUBDIRS}"
 209     fi
 210     AC_SUBST(SVGA_LIBS)
 211     AM_CONDITIONAL(USE_SVGALIB, test x$with_svga = xyes)
 212
 213     if test x$MINGW32 = xyes; then
 214         D2X_ARCH_SUBDIRS="win32 ${D2X_ARCH_SUBDIRS}"
 215     else
 216         CFLAGS="-I \$(top_srcdir)/arch/linux/include $CFLAGS"
 217         D2X_ARCH_SUBDIRS="linux ${D2X_ARCH_SUBDIRS}"
 218     fi
 219 fi
 220
 221 dnl Check for network
 222 AC_ARG_ENABLE(network,
 223     [  --disable-network       Do not build network/serial support ],,)
 224 if test x$enable_network != xno; then
 225     AC_DEFINE(NETWORK,,[Define if you want a network build])
 226     D2X_FEATURES="network ${D2X_FEATURES}"
 227 fi
 228 AM_CONDITIONAL(USE_NETWORK, test x$enable_network != xno)
 229
 230 dnl Check for assembler
 231 AC_ARG_ENABLE(assembler,
 232     [  --disable-assembler     Do not use assembler optimization ],,)
 233 if test x$enable_assembler != xno; then
 234     if test x$NASM = xno; then
 235         AC_MSG_WARN([nasm not found. disabling assembler])
 236         enable_assembler="no"
 237     else
 238         NASMFLAGS="-i\$(srcdir)/ $NASMFLAGS"
 239         case $host_os in
 240             cygwin*)
 241                 NASMFLAGS="-f win32 $NASMFLAGS"
 242                 ;;
 243             msdos*)
 244                 NASMFLAGS="-f coff $NASMFLAGS"
 245                 ;;
 246             linux*)
 247                 NASMFLAGS="-f elf -d__linux__ $NASMFLAGS"
 248                 ;;
 249             *)
 250                 AC_MSG_WARN([nasm not supported for this OS. disabling assembler])
 251                 enable_assembler="no"
 252                 ;;
 253         esac
 254     fi
 255 fi
 256 if test x$enable_assembler = xno; then
 257     AC_DEFINE(NO_ASM,,[Define if you want an assembler free build])
 258     D2X_FEATURES="no_asm ${D2X_FEATURES}"
 259 fi
 260 AM_CONDITIONAL(USE_ASM, test x$enable_assembler != xno)
 261
 262 AH_BOTTOM([
 263         /* General defines */
 264 #define NMONO 1
 265 #define PIGGY_USE_PAGING 1
 266 #define NEWDEMO 1
 267
 268 #ifdef __MACOSX__
 269 #define __unix__
 270 #endif
 271
 272 #ifdef __unix__
 273 # ifdef GGI
 274 #  define GII_INPUT 1
 275 #  define GGI_VIDEO 1
 276 # else
 277 #  ifdef SVGA
 278 #   define SVGALIB_INPUT 1
 279 #   define SVGALIB_VIDEO 1
 280 #  else
 281 #   define SDL_INPUT 1
 282 #   ifdef OGL
 283 #    define SDL_GL_VIDEO 1
 284 #   else
 285 #    define SDL_VIDEO 1
 286 #   endif
 287 #  endif
 288 # endif
 289 #endif
 290
 291 #ifdef __MINGW32__
 292 # define SDL_INPUT 1
 293 # ifdef OGL
 294 #  define SDL_GL_VIDEO 1
 295 # else
 296 #  define SDL_VIDEO 1
 297 # endif
 298 #endif
 299         ])
 300
 301 AM_PROG_AS
 302
 303 AC_SUBST(D2X_ARCH_SUBDIRS)
 304
 305 AC_SUBST(D2X_MAIN_SUBDIRS)
 306
 307 AC_SUBST(TARGETS)
 308
 309 AC_SUBST(NASMFLAGS)
 310
 311 AC_SUBST(CFLAGS)
 312
 313 AC_OUTPUT(
 314     Makefile
 315     2d/Makefile
 316     3d/Makefile
 317     arch/Makefile
 318     arch/dos/Makefile
 319     arch/ggi/Makefile
 320     arch/linux/Makefile
 321     arch/ogl/Makefile
 322     arch/sdl/Makefile
 323     arch/svgalib/Makefile
 324     arch/win32/Makefile
 325     cfile/Makefile
 326     iff/Makefile
 327     main/Makefile
 328     main/editor/Makefile
 329     maths/Makefile
 330     mem/Makefile
 331     misc/Makefile
 332     texmap/Makefile
 333     utility/Makefile
 334     debian/changelog
 335     rpm/d2x.spec
 336 )
 337
 338 AC_MSG_RESULT([
 339         d2x has been configured successfully.
 340
 341         Platform(s): $D2X_ARCH_SUBDIRS
 342         Features   : $D2X_FEATURES $D2X_MAIN_SUBDIRS
 343
 344         Shared game data directory (unix only): $sharepath
 345         ])