configure.ac

   1 # -*- mode: shell-script -*-
   2
   3 define([D2X_MAJOR],0)
   4 define([D2X_MINOR],2)
   5 define([D2X_MICRO],6)
   6
   7 AC_INIT([d2x],[D2X_MAJOR.D2X_MINOR.D2X_MICRO],[https://github.com/btb/d2x/issues])
   8 AC_PREREQ([2.52])
   9
  10 AC_CANONICAL_BUILD
  11 AC_CANONICAL_HOST
  12 AC_CANONICAL_TARGET
  13
  14 AM_INIT_AUTOMAKE([subdir-objects])
  15
  16 AC_CONFIG_HEADERS(conf.h)
  17
  18 AC_DEFINE_UNQUOTED(D2XMAJOR,D2X_MAJOR,[d2x major version])
  19 AC_DEFINE_UNQUOTED(D2XMINOR,D2X_MINOR,[d2x minor version])
  20 AC_DEFINE_UNQUOTED(D2XMICRO,D2X_MICRO,[d2x micro version])
  21
  22 AM_MAINTAINER_MODE
  23
  24 #kludge to keep autoconf from adding -g -O2
  25 CFLAGS=" $CFLAGS"
  26
  27 AC_PROG_INSTALL
  28 AC_PROG_MAKE_SET
  29 AC_SEARCH_LIBS([strerror],[cposix])
  30 AC_CHECK_TOOL(CC, gcc, :)
  31 AC_CHECK_TOOL(RANLIB, ranlib, :)
  32 AC_CHECK_TOOL(STRIP, strip, :)
  33 AC_CHECK_TOOL(AR, ar, :)
  34 AC_PROG_CC
  35 AC_PATH_PROGS(NASM, nasm nasmw, no)
  36 AC_C_BIGENDIAN
  37 AC_CHECK_SIZEOF(void *)
  38
  39 case $host_cpu in
  40     sparc)
  41         AC_DEFINE(WORDS_NEED_ALIGNMENT,,[Define if your processor needs data to be word-aligned])
  42     ;;
  43 esac
  44
  45 case $host_os in
  46     cygwin)
  47         AC_MSG_WARN([Cygwin found, setting -mno-cygwin])
  48         CFLAGS="-mno-cygwin $CFLAGS"
  49         MINGW32=yes
  50         ;;
  51     mingw*)
  52         MINGW32=yes
  53         ;;
  54     darwin*)
  55         MACOSX=yes
  56         CFLAGS="-no-cpp-precomp $CFLAGS"
  57         ;;
  58     msdos*)
  59         MSDOS=yes
  60         ;;
  61 esac
  62
  63 AC_CHECK_DECLS(nanosleep,,,[#include <time.h>])
  64 AC_CHECK_TYPES([struct timespec, struct timeval],,,[#include <sys/time.h>])
  65
  66 AM_CONDITIONAL(MINGW32, test x$MINGW32 = xyes)
  67
  68 AM_CONDITIONAL(MACOSX, test x$MACOSX = xyes)
  69
  70 AM_CONDITIONAL(MSDOS, test x$MSDOS = xyes)
  71
  72 dnl Set $prefix and $exec_prefix to $ac_default_prefix if they are not set
  73 test "x$prefix" = "xNONE" && prefix=$ac_default_prefix
  74 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
  75
  76 dnl Set default locations to find data files.
  77 default_sharepath="$datadir/games/$PACKAGE"
  78
  79 CFLAGS="-Wall -Werror -Wno-deprecated-declarations -Wno-int-to-pointer-cast -Wno-pointer-to-int-cast -Wno-unused-value -Wno-address $CFLAGS"
  80 AX_CHECK_COMPILE_FLAG([-Wno-ignored-attributes], [CFLAGS="$CFLAGS -Wno-ignored-attributes"])
  81 AX_CHECK_COMPILE_FLAG([-Wno-unused-but-set-variable], [CFLAGS="$CFLAGS -Wno-unused-but-set-variable"])
  82 AX_CHECK_COMPILE_FLAG([-Wno-address-of-packed-member], [CFLAGS="$CFLAGS -Wno-address-of-packed-member"])
  83 AX_CHECK_COMPILE_FLAG([-Wno-stringop-truncation], [CFLAGS="$CFLAGS -Wno-stringop-truncation"])
  84
  85 dnl Enable editor build?
  86 AC_ARG_ENABLE(editor,
  87     [  --enable-editor         Build editor? (not functional)],,)
  88
  89 dnl Enable macdata build?
  90 AC_ARG_ENABLE(macdata,
  91     [  --enable-macdata        Build for mac datafiles],,)
  92 if test x$enable_macdata = xyes; then
  93     AC_DEFINE(MACDATA,,[Define if you want to build for mac datafiles])
  94     D2X_FEATURES="macdata ${D2X_FEATURES}"
  95 fi
  96 AM_CONDITIONAL(MACDATA, test x$enable_macdata = xyes)
  97
  98 dnl Build with NDEBUG?
  99 AC_ARG_ENABLE(debug,
 100     [  --disable-debug         Take out debug symbols, Asserts, Int3, etc ],,)
 101 if test x$enable_debug = xno; then
 102     AC_DEFINE(NDEBUG,,[Define to disable asserts, int3, etc.])
 103     CFLAGS="-O2 $CFLAGS"
 104 else
 105     CFLAGS="-g $CFLAGS"
 106     D2X_FEATURES="debug ${D2X_FEATURES}"
 107 fi
 108
 109 dnl Build with RELEASE?
 110 AC_ARG_ENABLE(release,
 111     [  --enable-release        Release build.  Removes debug/editor things ],,)
 112 if test x$enable_release = xyes; then
 113     AC_DEFINE(RELEASE,,[Define for a "release" build])
 114     D2X_FEATURES="release ${D2X_FEATURES}"
 115 fi
 116
 117 dnl Build without using sdl-joystick ?
 118 AC_ARG_ENABLE(linuxjoy,
 119     [  --enable-linuxjoy       do not use the SDL Joystick. (eg for MS Sidewinder)],,)
 120 if test x$enable_linuxjoy = xyes; then
 121     AC_DEFINE(USE_LINUX_JOY,,[define to not use the SDL_Joystick routines.])
 122     D2X_FEATURES="linuxjoy ${D2X_FEATURES}"
 123 fi
 124 AM_CONDITIONAL(USE_LINUX_JOY, test x$enable_linuxjoy = xyes)
 125
 126 dnl Build with FAST_FILE_IO?
 127 AC_ARG_ENABLE(fastfileio,
 128     [  --disable-fastfileio    Disable fast file i/o. ],,)
 129 if test x$enable_fastfileio != xno; then
 130     if test x$ac_cv_c_bigendian = xyes; then
 131         AC_MSG_WARN([big-endian cpu detected.  disabling fastfileio])
 132         enable_fastfileio="no";
 133     fi
 134     if test $ac_cv_sizeof_void_p != 4; then
 135         AC_MSG_WARN([pointers not 32 bits.  disabling fastfileio])
 136         enable_fastfileio="no";
 137     fi
 138 fi
 139 if test x$enable_fastfileio != xno; then
 140     AC_DEFINE(FAST_FILE_IO,,[Define for faster i/o on little-endian cpus])
 141     D2X_FEATURES="fastfileio ${D2X_FEATURES}"
 142 fi
 143
 144 AC_ARG_WITH(sharepath,
 145     [[  --with-sharepath=DIR    Use DIR for shared game data (unix only) [DATADIR/games/d2x]]],
 146     sharepath=$withval, sharepath="auto")
 147 if test "x$sharepath" = "xauto" -o "x$sharepath" = "xyes" -o "x$sharepath" = "x"; then
 148     sharepath="$default_sharepath"
 149 fi
 150 AC_SUBST(sharepath)
 151 eval sharepath=$sharepath
 152 eval sharepath=$sharepath
 153 AC_DEFINE_UNQUOTED(SHAREPATH, "$sharepath",[Define this to be the shared game directory root])
 154
 155 TARGETS=
 156
 157 # Test for MSDOS
 158 if test x$MSDOS = xyes; then
 159     TARGETS="d2x$ac_cv_exeext $TARGETS"
 160         if test x$enable_editor = xyes; then
 161                 TARGETS="miner$ac_cv_exeext $TARGETS"
 162         fi
 163 else
 164
 165     CFLAGS="-pipe $CFLAGS"
 166
 167     dnl Check for SDL
 168     AM_PATH_SDL(1.1.0,
 169         :,
 170         AC_MSG_ERROR(SDL not found. Make sure sdl-config is in your PATH, or specify with --with-sdl-prefix)
 171     )
 172
 173     TARGETS="d2x-sdl$ac_cv_exeext $TARGETS"
 174         if test x$enable_editor = xyes; then
 175                 TARGETS="miner-sdl$ac_cv_exeext $TARGETS"
 176         fi
 177
 178     AC_CHECK_HEADERS(netipx/ipx.h)
 179
 180   # Check for SDL_image
 181     AC_CHECK_LIB(SDL_image, IMG_ReadXPMFromArray,
 182         SDLIMAGE_LIBS="-lSDL_image"
 183         AC_DEFINE(SDL_IMAGE,,[Define if you have the SDL_image library]))
 184     AC_SUBST(SDLIMAGE_LIBS)
 185
 186   # Check for SDL_mixer
 187     PKG_CHECK_MODULES(SDLMIXER, SDL_mixer)
 188     AC_SUBST(SDLMIXER_CFLAGS)
 189     AC_SUBST(SDLMIXER_LIBS)
 190
 191   # Check for libpng
 192     have_libpng=no
 193     #PKG_CHECK_MODULES(LIBPNG, libpng,
 194     #    AC_DEFINE(HAVE_LIBPNG,,[Define if you have libpng])
 195     #    have_libpng=yes
 196     #    LIBS="$LIBPNG_LIBS $LIBS",
 197     #    AC_MSG_WARN([libpng not found. disabling png replacement texture support])
 198     #)
 199     AM_CONDITIONAL(USE_LIBPNG, test x$have_libpng = xyes)
 200
 201   # Check for PhysicsFS
 202     PKG_CHECK_MODULES(PHYSFS, physfs, CFLAGS="$CFLAGS -D__EXPORT__=PHYSFS_DECL",
 203     AC_CHECK_HEADERS(physfs.h, , [AC_MSG_ERROR([physfs.h required])])
 204     AC_CHECK_LIB(physfs, PHYSFS_init, PHYSFS_LIBS="-lphysfs",
 205                  [AC_MSG_ERROR([physfs library required])])
 206     )
 207     AC_SUBST(PHYSFS_LIBS)
 208
 209   # Check for OpenGL
 210     AC_ARG_WITH(opengl,
 211         [  --with-opengl           Build OpenGL support ],,)
 212     if test x$with_opengl = xyes; then
 213         TARGETS="d2x-gl$ac_cv_exeext $TARGETS"
 214                 if test x$enable_editor = xyes; then
 215                         TARGETS="miner-gl$ac_cv_exeext $TARGETS"
 216                 fi
 217     fi
 218
 219   # Check for SVGALib
 220     AC_ARG_WITH(svga,
 221         [  --with-svga             Build SVGALib support ],,)
 222     if test x$with_svga = xyes; then
 223         TARGETS="d2x-svga$ac_cv_exeext $TARGETS"
 224                 if test x$enable_editor = xyes; then
 225                         TARGETS="miner-svga$ac_cv_exeext $TARGETS"
 226                 fi
 227     fi
 228     AC_SUBST(SVGA_LIBS)
 229 fi
 230
 231 dnl Check for network
 232 AC_ARG_ENABLE(network,
 233     [  --disable-network       Do not build network/serial support ],,)
 234 if test x$enable_network != xno; then
 235     case $host_os in
 236         cygwin* | mingw* | msdos* | linux*)
 237             enable_native_ipx="yes";
 238            ;;
 239        *)
 240             AC_MSG_WARN([d2x does not support native ipx on this host.  disabling native ipx])
 241             enable_native_ipx="no";
 242             ;;
 243     esac
 244     case $host_os in
 245         cygwin* | mingw* | msdos*)
 246             enable_kalinix="no";
 247             ;;
 248     esac
 249     case $host_os in
 250         *solaris*)
 251             AC_CHECK_LIB(socket, socket, LIBS="${LIBS} -lsocket",
 252                 [AC_MSG_ERROR(socket lib required for net support on solaris not found)])
 253             AC_CHECK_LIB(nsl, inet_addr, LIBS="${LIBS} -lnsl",
 254                 [AC_MSG_ERROR(nsl lib required for net support on solaris not found)])
 255             ;;
 256     esac
 257 fi
 258 AC_ARG_ENABLE(kalinix,
 259     [  --disable-kalinix       Disable the KaliNix driver (unix-only)],,)
 260 if test x$enable_network != xno; then
 261     if test x$enable_native_ipx != xno; then
 262         D2X_FEATURES="ipx ${D2X_FEATURES}"
 263         AC_DEFINE(NATIVE_IPX,,[Define to use the IPX support of the OS])
 264     fi
 265     if test x$enable_kalinix != xno; then
 266         D2X_FEATURES="kalinix ${D2X_FEATURES}"
 267         AC_DEFINE(KALINIX,,[Define to enable use of the KaliNix driver])
 268     fi
 269     AC_DEFINE(NETWORK,,[Define if you want a network build])
 270     D2X_FEATURES="network ${D2X_FEATURES}"
 271 fi
 272 AM_CONDITIONAL(USE_NETWORK, test x$enable_network != xno)
 273 AM_CONDITIONAL(USE_NATIVE_IPX, test x$enable_native_ipx != xno)
 274 AM_CONDITIONAL(USE_KALINIX, test x$enable_kalinix != xno)
 275
 276 dnl Check for assembler
 277 AC_ARG_ENABLE(assembler,
 278     [  --disable-assembler     Do not use assembler optimization ],,)
 279 if test x$enable_assembler != xno; then
 280     if test x$NASM = xno; then
 281         AC_MSG_WARN([nasm not found. disabling assembler])
 282         enable_assembler="no"
 283     else
 284         NASMFLAGS="-i\$(srcdir)/ $NASMFLAGS"
 285         case $host_os in
 286             cygwin* | mingw*)
 287                 NASMFLAGS="-f win32 $NASMFLAGS"
 288                 ;;
 289             msdos*)
 290                 NASMFLAGS="-f coff $NASMFLAGS"
 291                 ;;
 292             linux* | freebsd*)
 293                 NASMFLAGS="-f elf -d__ELF__ $NASMFLAGS"
 294                 ;;
 295             *)
 296                 AC_MSG_WARN([nasm not supported for this OS. disabling assembler])
 297                 enable_assembler="no"
 298                 ;;
 299         esac
 300         case $host_cpu in
 301             x86_64)
 302                 AC_MSG_WARN([nasm not supported for this cpu. disabling assembler])
 303                 enable_assembler="no"
 304                 ;;
 305         esac
 306     fi
 307 fi
 308 if test x$enable_assembler = xno; then
 309     AC_DEFINE(NO_ASM,,[Define if you want an assembler free build])
 310     D2X_FEATURES="no_asm ${D2X_FEATURES}"
 311 fi
 312 AM_CONDITIONAL(USE_ASM, test x$enable_assembler != xno)
 313
 314 AH_BOTTOM([
 315         /* General defines */
 316 #ifndef PACKAGE_STRING
 317 #define PACKAGE_STRING PACKAGE " " VERSION
 318 #endif
 319 #define VERSION_NAME PACKAGE_STRING
 320 #define NMONO 1
 321 #define PIGGY_USE_PAGING 1
 322 #define NEWDEMO 1
 323
 324 #if defined(__APPLE__) && defined(__MACH__)
 325 #define __unix__ /* since we're doing a unix-style compilation... */
 326 #endif
 327         ])
 328
 329 AM_PROG_AS
 330
 331 AC_SUBST(TARGETS)
 332
 333 AC_SUBST(NASMFLAGS)
 334
 335 AC_SUBST(CFLAGS)
 336
 337 AC_CONFIG_FILES([Makefile
 338     debian/changelog
 339     rpm/d2x.spec
 340 ])
 341 AC_OUTPUT
 342
 343 AC_MSG_RESULT([
 344         d2x has been configured successfully.
 345
 346         Targets: $TARGETS
 347         Features: $D2X_FEATURES
 348
 349         Shared game data directory (unix only): $sharepath
 350         ])