configure.ac

   1 # -*- mode: shell-script -*-
   2
   3 define([D2X_MAJOR],0)
   4 define([D2X_MINOR],2)
   5 define([D2X_MICRO],6)
   6
   7 AC_INIT([d2x],[D2X_MAJOR.D2X_MINOR.D2X_MICRO],[https://github.com/btb/d2x/issues])
   8 AC_PREREQ([2.52])
   9
  10 AC_CANONICAL_BUILD
  11 AC_CANONICAL_HOST
  12 AC_CANONICAL_TARGET
  13
  14 AM_INIT_AUTOMAKE([subdir-objects])
  15
  16 AC_CONFIG_HEADERS(conf.h)
  17
  18 AC_DEFINE_UNQUOTED(D2XMAJOR,D2X_MAJOR,[d2x major version])
  19 AC_DEFINE_UNQUOTED(D2XMINOR,D2X_MINOR,[d2x minor version])
  20 AC_DEFINE_UNQUOTED(D2XMICRO,D2X_MICRO,[d2x micro version])
  21
  22 AM_MAINTAINER_MODE
  23
  24 #kludge to keep autoconf from adding -g -O2
  25 CFLAGS=" $CFLAGS"
  26
  27 AC_PROG_INSTALL
  28 AC_PROG_MAKE_SET
  29 AC_SEARCH_LIBS([strerror],[cposix])
  30 AC_CHECK_TOOL(CC, gcc, :)
  31 AC_CHECK_TOOL(RANLIB, ranlib, :)
  32 AC_CHECK_TOOL(STRIP, strip, :)
  33 AC_CHECK_TOOL(AR, ar, :)
  34 AC_PROG_CC
  35 AC_PATH_PROGS(NASM, nasm nasmw, no)
  36 AC_C_BIGENDIAN
  37 AC_CHECK_SIZEOF(void *)
  38
  39 case $host_cpu in
  40     sparc)
  41         AC_DEFINE(WORDS_NEED_ALIGNMENT,,[Define if your processor needs data to be word-aligned])
  42     ;;
  43 esac
  44
  45 case $host_os in
  46     cygwin)
  47         AC_MSG_WARN([Cygwin found, setting -mno-cygwin])
  48         CFLAGS="-mno-cygwin $CFLAGS"
  49         MINGW32=yes
  50         ;;
  51     mingw*)
  52         MINGW32=yes
  53         ;;
  54     darwin*)
  55         MACOSX=yes
  56         CFLAGS="-no-cpp-precomp $CFLAGS"
  57         ;;
  58     msdos*)
  59         MSDOS=yes
  60         ;;
  61 esac
  62
  63 AC_CHECK_DECLS(nanosleep,,,[#include <time.h>])
  64 AC_CHECK_TYPES([struct timespec, struct timeval],,,[#include <sys/time.h>])
  65
  66 AM_CONDITIONAL(MINGW32, test x$MINGW32 = xyes)
  67
  68 AM_CONDITIONAL(MACOSX, test x$MACOSX = xyes)
  69
  70 AM_CONDITIONAL(MSDOS, test x$MSDOS = xyes)
  71
  72 dnl Set $prefix and $exec_prefix to $ac_default_prefix if they are not set
  73 test "x$prefix" = "xNONE" && prefix=$ac_default_prefix
  74 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
  75
  76 dnl Set default locations to find data files.
  77 default_sharepath="$datadir/games/$PACKAGE"
  78
  79 CFLAGS="-Wall -Werror -Wno-deprecated-declarations -Wno-int-to-pointer-cast -Wno-pointer-to-int-cast -Wno-unused-value -Wno-address $CFLAGS"
  80 AX_CHECK_COMPILE_FLAG([-Wno-ignored-attributes], [CFLAGS="$CFLAGS -Wno-ignored-attributes"])
  81 AX_CHECK_COMPILE_FLAG([-Wno-unused-but-set-variable], [CFLAGS="$CFLAGS -Wno-unused-but-set-variable"])
  82 AX_CHECK_COMPILE_FLAG([-Wno-address-of-packed-member], [CFLAGS="$CFLAGS -Wno-address-of-packed-member"])
  83
  84 dnl Enable editor build?
  85 AC_ARG_ENABLE(editor,
  86     [  --enable-editor         Build editor? (not functional)],,)
  87
  88 dnl Enable macdata build?
  89 AC_ARG_ENABLE(macdata,
  90     [  --enable-macdata        Build for mac datafiles],,)
  91 if test x$enable_macdata = xyes; then
  92     AC_DEFINE(MACDATA,,[Define if you want to build for mac datafiles])
  93     D2X_FEATURES="macdata ${D2X_FEATURES}"
  94 fi
  95 AM_CONDITIONAL(MACDATA, test x$enable_macdata = xyes)
  96
  97 dnl Build with NDEBUG?
  98 AC_ARG_ENABLE(debug,
  99     [  --disable-debug         Take out debug symbols, Asserts, Int3, etc ],,)
 100 if test x$enable_debug = xno; then
 101     AC_DEFINE(NDEBUG,,[Define to disable asserts, int3, etc.])
 102     CFLAGS="-O2 $CFLAGS"
 103 else
 104     CFLAGS="-g $CFLAGS"
 105     D2X_FEATURES="debug ${D2X_FEATURES}"
 106 fi
 107
 108 dnl Build with RELEASE?
 109 AC_ARG_ENABLE(release,
 110     [  --enable-release        Release build.  Removes debug/editor things ],,)
 111 if test x$enable_release = xyes; then
 112     AC_DEFINE(RELEASE,,[Define for a "release" build])
 113     D2X_FEATURES="release ${D2X_FEATURES}"
 114 fi
 115
 116 dnl Build without using sdl-joystick ?
 117 AC_ARG_ENABLE(linuxjoy,
 118     [  --enable-linuxjoy       do not use the SDL Joystick. (eg for MS Sidewinder)],,)
 119 if test x$enable_linuxjoy = xyes; then
 120     AC_DEFINE(USE_LINUX_JOY,,[define to not use the SDL_Joystick routines.])
 121     D2X_FEATURES="linuxjoy ${D2X_FEATURES}"
 122 fi
 123 AM_CONDITIONAL(USE_LINUX_JOY, test x$enable_linuxjoy = xyes)
 124
 125 dnl Build with FAST_FILE_IO?
 126 AC_ARG_ENABLE(fastfileio,
 127     [  --disable-fastfileio    Disable fast file i/o. ],,)
 128 if test x$enable_fastfileio != xno; then
 129     if test x$ac_cv_c_bigendian = xyes; then
 130         AC_MSG_WARN([big-endian cpu detected.  disabling fastfileio])
 131         enable_fastfileio="no";
 132     fi
 133     if test $ac_cv_sizeof_void_p != 4; then
 134         AC_MSG_WARN([pointers not 32 bits.  disabling fastfileio])
 135         enable_fastfileio="no";
 136     fi
 137 fi
 138 if test x$enable_fastfileio != xno; then
 139     AC_DEFINE(FAST_FILE_IO,,[Define for faster i/o on little-endian cpus])
 140     D2X_FEATURES="fastfileio ${D2X_FEATURES}"
 141 fi
 142
 143 AC_ARG_WITH(sharepath,
 144     [[  --with-sharepath=DIR    Use DIR for shared game data (unix only) [DATADIR/games/d2x]]],
 145     sharepath=$withval, sharepath="auto")
 146 if test "x$sharepath" = "xauto" -o "x$sharepath" = "xyes" -o "x$sharepath" = "x"; then
 147     sharepath="$default_sharepath"
 148 fi
 149 AC_SUBST(sharepath)
 150 eval sharepath=$sharepath
 151 eval sharepath=$sharepath
 152 AC_DEFINE_UNQUOTED(SHAREPATH, "$sharepath",[Define this to be the shared game directory root])
 153
 154 TARGETS=
 155
 156 # Test for MSDOS
 157 if test x$MSDOS = xyes; then
 158     TARGETS="d2x$ac_cv_exeext $TARGETS"
 159         if test x$enable_editor = xyes; then
 160                 TARGETS="miner$ac_cv_exeext $TARGETS"
 161         fi
 162 else
 163
 164     CFLAGS="-pipe $CFLAGS"
 165
 166     dnl Check for SDL
 167     AM_PATH_SDL(1.1.0,
 168         :,
 169         AC_MSG_ERROR(SDL not found. Make sure sdl-config is in your PATH, or specify with --with-sdl-prefix)
 170     )
 171
 172     TARGETS="d2x-sdl$ac_cv_exeext $TARGETS"
 173         if test x$enable_editor = xyes; then
 174                 TARGETS="miner-sdl$ac_cv_exeext $TARGETS"
 175         fi
 176
 177     AC_CHECK_HEADERS(netipx/ipx.h)
 178
 179   # Check for SDL_image
 180     AC_CHECK_LIB(SDL_image, IMG_ReadXPMFromArray,
 181         SDLIMAGE_LIBS="-lSDL_image"
 182         AC_DEFINE(SDL_IMAGE,,[Define if you have the SDL_image library]))
 183     AC_SUBST(SDLIMAGE_LIBS)
 184
 185   # Check for SDL_mixer
 186     PKG_CHECK_MODULES(SDLMIXER, SDL_mixer)
 187     AC_SUBST(SDLMIXER_CFLAGS)
 188     AC_SUBST(SDLMIXER_LIBS)
 189
 190   # Check for libpng
 191     have_libpng=no
 192     #PKG_CHECK_MODULES(LIBPNG, libpng,
 193     #    AC_DEFINE(HAVE_LIBPNG,,[Define if you have libpng])
 194     #    have_libpng=yes
 195     #    LIBS="$LIBPNG_LIBS $LIBS",
 196     #    AC_MSG_WARN([libpng not found. disabling png replacement texture support])
 197     #)
 198     AM_CONDITIONAL(USE_LIBPNG, test x$have_libpng = xyes)
 199
 200   # Check for PhysicsFS
 201     PKG_CHECK_MODULES(PHYSFS, physfs, CFLAGS="$CFLAGS -D__EXPORT__=PHYSFS_DECL",
 202     AC_CHECK_HEADERS(physfs.h, , [AC_MSG_ERROR([physfs.h required])])
 203     AC_CHECK_LIB(physfs, PHYSFS_init, PHYSFS_LIBS="-lphysfs",
 204                  [AC_MSG_ERROR([physfs library required])])
 205     )
 206     AC_SUBST(PHYSFS_LIBS)
 207
 208   # Check for OpenGL
 209     AC_ARG_WITH(opengl,
 210         [  --with-opengl           Build OpenGL support ],,)
 211     if test x$with_opengl = xyes; then
 212         TARGETS="d2x-gl$ac_cv_exeext $TARGETS"
 213                 if test x$enable_editor = xyes; then
 214                         TARGETS="miner-gl$ac_cv_exeext $TARGETS"
 215                 fi
 216     fi
 217
 218   # Check for SVGALib
 219     AC_ARG_WITH(svga,
 220         [  --with-svga             Build SVGALib support ],,)
 221     if test x$with_svga = xyes; then
 222         TARGETS="d2x-svga$ac_cv_exeext $TARGETS"
 223                 if test x$enable_editor = xyes; then
 224                         TARGETS="miner-svga$ac_cv_exeext $TARGETS"
 225                 fi
 226     fi
 227     AC_SUBST(SVGA_LIBS)
 228 fi
 229
 230 dnl Check for network
 231 AC_ARG_ENABLE(network,
 232     [  --disable-network       Do not build network/serial support ],,)
 233 if test x$enable_network != xno; then
 234     case $host_os in
 235         cygwin* | mingw* | msdos* | linux*)
 236             enable_native_ipx="yes";
 237            ;;
 238        *)
 239             AC_MSG_WARN([d2x does not support native ipx on this host.  disabling native ipx])
 240             enable_native_ipx="no";
 241             ;;
 242     esac
 243     case $host_os in
 244         cygwin* | mingw* | msdos*)
 245             enable_kalinix="no";
 246             ;;
 247     esac
 248     case $host_os in
 249         *solaris*)
 250             AC_CHECK_LIB(socket, socket, LIBS="${LIBS} -lsocket",
 251                 [AC_MSG_ERROR(socket lib required for net support on solaris not found)])
 252             AC_CHECK_LIB(nsl, inet_addr, LIBS="${LIBS} -lnsl",
 253                 [AC_MSG_ERROR(nsl lib required for net support on solaris not found)])
 254             ;;
 255     esac
 256 fi
 257 AC_ARG_ENABLE(kalinix,
 258     [  --disable-kalinix       Disable the KaliNix driver (unix-only)],,)
 259 if test x$enable_network != xno; then
 260     if test x$enable_native_ipx != xno; then
 261         D2X_FEATURES="ipx ${D2X_FEATURES}"
 262         AC_DEFINE(NATIVE_IPX,,[Define to use the IPX support of the OS])
 263     fi
 264     if test x$enable_kalinix != xno; then
 265         D2X_FEATURES="kalinix ${D2X_FEATURES}"
 266         AC_DEFINE(KALINIX,,[Define to enable use of the KaliNix driver])
 267     fi
 268     AC_DEFINE(NETWORK,,[Define if you want a network build])
 269     D2X_FEATURES="network ${D2X_FEATURES}"
 270 fi
 271 AM_CONDITIONAL(USE_NETWORK, test x$enable_network != xno)
 272 AM_CONDITIONAL(USE_NATIVE_IPX, test x$enable_native_ipx != xno)
 273 AM_CONDITIONAL(USE_KALINIX, test x$enable_kalinix != xno)
 274
 275 dnl Check for assembler
 276 AC_ARG_ENABLE(assembler,
 277     [  --disable-assembler     Do not use assembler optimization ],,)
 278 if test x$enable_assembler != xno; then
 279     if test x$NASM = xno; then
 280         AC_MSG_WARN([nasm not found. disabling assembler])
 281         enable_assembler="no"
 282     else
 283         NASMFLAGS="-i\$(srcdir)/ $NASMFLAGS"
 284         case $host_os in
 285             cygwin* | mingw*)
 286                 NASMFLAGS="-f win32 $NASMFLAGS"
 287                 ;;
 288             msdos*)
 289                 NASMFLAGS="-f coff $NASMFLAGS"
 290                 ;;
 291             linux* | freebsd*)
 292                 NASMFLAGS="-f elf -d__ELF__ $NASMFLAGS"
 293                 ;;
 294             *)
 295                 AC_MSG_WARN([nasm not supported for this OS. disabling assembler])
 296                 enable_assembler="no"
 297                 ;;
 298         esac
 299         case $host_cpu in
 300             x86_64)
 301                 AC_MSG_WARN([nasm not supported for this cpu. disabling assembler])
 302                 enable_assembler="no"
 303                 ;;
 304         esac
 305     fi
 306 fi
 307 if test x$enable_assembler = xno; then
 308     AC_DEFINE(NO_ASM,,[Define if you want an assembler free build])
 309     D2X_FEATURES="no_asm ${D2X_FEATURES}"
 310 fi
 311 AM_CONDITIONAL(USE_ASM, test x$enable_assembler != xno)
 312
 313 AH_BOTTOM([
 314         /* General defines */
 315 #ifndef PACKAGE_STRING
 316 #define PACKAGE_STRING PACKAGE " " VERSION
 317 #endif
 318 #define VERSION_NAME PACKAGE_STRING
 319 #define NMONO 1
 320 #define PIGGY_USE_PAGING 1
 321 #define NEWDEMO 1
 322
 323 #if defined(__APPLE__) && defined(__MACH__)
 324 #define __unix__ /* since we're doing a unix-style compilation... */
 325 #endif
 326         ])
 327
 328 AM_PROG_AS
 329
 330 AC_SUBST(TARGETS)
 331
 332 AC_SUBST(NASMFLAGS)
 333
 334 AC_SUBST(CFLAGS)
 335
 336 AC_CONFIG_FILES([Makefile
 337     debian/changelog
 338     rpm/d2x.spec
 339 ])
 340 AC_OUTPUT
 341
 342 AC_MSG_RESULT([
 343         d2x has been configured successfully.
 344
 345         Targets: $TARGETS
 346         Features: $D2X_FEATURES
 347
 348         Shared game data directory (unix only): $sharepath
 349         ])