configure.ac

   1 # -*- mode: shell-script -*-
   2
   3 define([D2X_MAJOR],0)
   4 define([D2X_MINOR],2)
   5 define([D2X_MICRO],6)
   6
   7 AC_INIT(d2x,[D2X_MAJOR.D2X_MINOR.D2X_MICRO],[descent-source@warpcore.org])
   8 AC_PREREQ(2.52)
   9
  10 AC_CANONICAL_BUILD
  11 AC_CANONICAL_HOST
  12 AC_CANONICAL_TARGET
  13
  14 AC_EXEEXT
  15 AC_OBJEXT
  16
  17 AM_INIT_AUTOMAKE([subdir-objects])
  18
  19 AM_CONFIG_HEADER(conf.h)
  20
  21 AC_DEFINE_UNQUOTED(D2XMAJOR,D2X_MAJOR,[d2x major version])
  22 AC_DEFINE_UNQUOTED(D2XMINOR,D2X_MINOR,[d2x minor version])
  23 AC_DEFINE_UNQUOTED(D2XMICRO,D2X_MICRO,[d2x micro version])
  24
  25 AM_MAINTAINER_MODE
  26
  27 #kludge to keep autoconf from adding -g -O2
  28 CFLAGS=" $CFLAGS"
  29
  30 AC_PROG_INSTALL
  31 AC_PROG_MAKE_SET
  32 AC_ISC_POSIX
  33 AC_CHECK_TOOL(CC, gcc, :)
  34 AC_CHECK_TOOL(RANLIB, ranlib, :)
  35 AC_CHECK_TOOL(STRIP, strip, :)
  36 AC_CHECK_TOOL(AR, ar, :)
  37 AC_PROG_CC
  38 AC_PROG_CXX
  39 AC_STDC_HEADERS
  40 AC_PATH_PROGS(NASM, nasm nasmw, no)
  41 AC_C_BIGENDIAN
  42 AC_CHECK_SIZEOF(void *)
  43
  44 case $host_cpu in
  45     sparc)
  46         AC_DEFINE(WORDS_NEED_ALIGNMENT,,[Define if your processor needs data to be word-aligned])
  47     ;;
  48 esac
  49
  50 case $host_os in
  51     cygwin)
  52         AC_MSG_WARN([Cygwin found, setting -mno-cygwin])
  53         CFLAGS="-mno-cygwin $CFLAGS"
  54         MINGW32=yes
  55         ;;
  56     mingw*)
  57         MINGW32=yes
  58         ;;
  59     darwin*)
  60         MACOSX=yes
  61         CFLAGS="-no-cpp-precomp $CFLAGS"
  62         ;;
  63     msdos*)
  64         MSDOS=yes
  65         ;;
  66 esac
  67
  68 AC_CHECK_DECLS(nanosleep,,,[#include <time.h>])
  69 AC_CHECK_TYPES([struct timespec, struct timeval],,,[#include <sys/time.h>])
  70
  71 AM_CONDITIONAL(MINGW32, test x$MINGW32 = xyes)
  72
  73 AM_CONDITIONAL(MACOSX, test x$MACOSX = xyes)
  74
  75 AM_CONDITIONAL(MSDOS, test x$MSDOS = xyes)
  76
  77 dnl Set $prefix and $exec_prefix to $ac_default_prefix if they are not set
  78 test "x$prefix" = "xNONE" && prefix=$ac_default_prefix
  79 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
  80
  81 dnl Set default locations to find data files.
  82 default_sharepath="$datadir/games/$PACKAGE"
  83
  84 CFLAGS="-Wall -Werror -Wno-ignored-attributes -Wno-deprecated-declarations -Wno-int-to-pointer-cast $CFLAGS"
  85
  86 dnl Enable editor build?
  87 AC_ARG_ENABLE(editor,
  88     [  --enable-editor         Build editor? (not functional)],,)
  89 if test x$enable_editor = xyes; then
  90     AC_DEFINE(EDITOR,,[Define if you want to build the editor])
  91     D2X_FEATURES="editor $D2X_FEATURES"
  92 fi
  93 AM_CONDITIONAL(USE_EDITOR, test x$enable_editor = xyes)
  94
  95 dnl Enable macdata build?
  96 AC_ARG_ENABLE(macdata,
  97     [  --enable-macdata        Build for mac datafiles],,)
  98 if test x$enable_macdata = xyes; then
  99     AC_DEFINE(MACDATA,,[Define if you want to build for mac datafiles])
 100     D2X_FEATURES="macdata ${D2X_FEATURES}"
 101 fi
 102 AM_CONDITIONAL(MACDATA, test x$enable_macdata = xyes)
 103
 104 dnl Build with NDEBUG?
 105 AC_ARG_ENABLE(debug,
 106     [  --disable-debug         Take out debug symbols, Asserts, Int3, etc ],,)
 107 if test x$enable_debug = xno; then
 108     AC_DEFINE(NDEBUG,,[Define to disable asserts, int3, etc.])
 109     CFLAGS="-O2 $CFLAGS"
 110 else
 111     CFLAGS="-g $CFLAGS"
 112     D2X_FEATURES="debug ${D2X_FEATURES}"
 113 fi
 114
 115 dnl Build with RELEASE?
 116 AC_ARG_ENABLE(release,
 117     [  --enable-release        Release build.  Removes debug/editor things ],,)
 118 if test x$enable_release = xyes; then
 119     AC_DEFINE(RELEASE,,[Define for a "release" build])
 120     D2X_FEATURES="release ${D2X_FEATURES}"
 121 fi
 122
 123 dnl Build without using sdl-joystick ?
 124 AC_ARG_ENABLE(linuxjoy,
 125     [  --enable-linuxjoy       do not use the SDL Joystick. (eg for MS Sidewinder)],,)
 126 if test x$enable_linuxjoy = xyes; then
 127     AC_DEFINE(USE_LINUX_JOY,,[define to not use the SDL_Joystick routines.])
 128     D2X_FEATURES="linuxjoy ${D2X_FEATURES}"
 129 fi
 130 AM_CONDITIONAL(USE_LINUX_JOY, test x$enable_linuxjoy = xyes)
 131
 132 dnl Build with FAST_FILE_IO?
 133 AC_ARG_ENABLE(fastfileio,
 134     [  --disable-fastfileio    Disable fast file i/o. ],,)
 135 if test x$enable_fastfileio != xno; then
 136     if test x$ac_cv_c_bigendian = xyes; then
 137         AC_MSG_WARN([big-endian cpu detected.  disabling fastfileio])
 138         enable_fastfileio="no";
 139     fi
 140     if test $ac_cv_sizeof_void_p != 4; then
 141         AC_MSG_WARN([pointers not 32 bits.  disabling fastfileio])
 142         enable_fastfileio="no";
 143     fi
 144 fi
 145 if test x$enable_fastfileio != xno; then
 146     AC_DEFINE(FAST_FILE_IO,,[Define for faster i/o on little-endian cpus])
 147     D2X_FEATURES="fastfileio ${D2X_FEATURES}"
 148 fi
 149
 150 AC_ARG_WITH(sharepath,
 151     [[  --with-sharepath=DIR    Use DIR for shared game data (unix only) [DATADIR/games/d2x]]],
 152     sharepath=$withval, sharepath="auto")
 153 if test "x$sharepath" = "xauto" -o "x$sharepath" = "xyes" -o "x$sharepath" = "x"; then
 154     sharepath="$default_sharepath"
 155 fi
 156 AC_SUBST(sharepath)
 157 eval sharepath=$sharepath
 158 eval sharepath=$sharepath
 159 AC_DEFINE_UNQUOTED(SHAREPATH, "$sharepath",[Define this to be the shared game directory root])
 160
 161 TARGETS=
 162
 163 # Test for MSDOS
 164 if test x$MSDOS = xyes; then
 165     TARGETS="d2x $TARGETS"
 166 else
 167
 168     CFLAGS="-pipe $CFLAGS"
 169
 170     dnl Check for SDL
 171     AM_PATH_SDL(1.1.0,
 172         :,
 173         AC_MSG_ERROR(SDL not found. Make sure sdl-config is in your PATH, or specify with --with-sdl-prefix)
 174     )
 175
 176     TARGETS="d2x-sdl $TARGETS"
 177
 178     AC_CHECK_HEADERS(netipx/ipx.h)
 179
 180   # Check for SDL_image
 181     AC_CHECK_LIB(SDL_image, IMG_ReadXPMFromArray,
 182         SDLIMAGE_LIBS="-lSDL_image"
 183         AC_DEFINE(SDL_IMAGE,,[Define if you have the SDL_image library]))
 184     AC_SUBST(SDLIMAGE_LIBS)
 185
 186   # Check for libpng
 187     have_libpng=no
 188     #PKG_CHECK_MODULES(LIBPNG, libpng,
 189     #    AC_DEFINE(HAVE_LIBPNG,,[Define if you have libpng])
 190     #    have_libpng=yes
 191     #    LIBS="$LIBPNG_LIBS $LIBS",
 192     #    AC_MSG_WARN([libpng not found. disabling png replacement texture support])
 193     #)
 194     AM_CONDITIONAL(USE_LIBPNG, test x$have_libpng = xyes)
 195
 196   # Check for PhysicsFS
 197     AC_CHECK_HEADERS(physfs.h, , [AC_MSG_ERROR([physfs.h required])])
 198     AC_CHECK_LIB(physfs, PHYSFS_init, PHYSFS_LIBS="-lphysfs",
 199                  [AC_MSG_ERROR([physfs library required])])
 200     AC_SUBST(PHYSFS_LIBS)
 201
 202   # Check for OpenGL
 203     AC_ARG_WITH(opengl,
 204         [  --with-opengl           Build OpenGL support ],,)
 205     if test x$with_opengl = xyes; then
 206         TARGETS="d2x-gl $TARGETS"
 207     fi
 208
 209   # Check for SVGALib
 210     AC_ARG_WITH(svga,
 211         [  --with-svga             Build SVGALib support ],,)
 212     if test x$with_svga = xyes; then
 213         TARGETS="d2x-svga $TARGETS"
 214     fi
 215     AC_SUBST(SVGA_LIBS)
 216     AM_CONDITIONAL(USE_SVGALIB, test x$with_svga = xyes)
 217 fi
 218
 219 dnl Check for network
 220 AC_ARG_ENABLE(network,
 221     [  --disable-network       Do not build network/serial support ],,)
 222 if test x$enable_network != xno; then
 223     case $host_os in
 224         cygwin* | mingw* | msdos* | linux*)
 225             enable_native_ipx="yes";
 226            ;;
 227        *)
 228             AC_MSG_WARN([d2x does not support native ipx on this host.  disabling native ipx])
 229             enable_native_ipx="no";
 230             ;;
 231     esac
 232     case $host_os in
 233         cygwin* | mingw* | msdos*)
 234             enable_kalinix="no";
 235             ;;
 236     esac
 237     case $host_os in
 238         *solaris*)
 239             AC_CHECK_LIB(socket, socket, LIBS="${LIBS} -lsocket",
 240                 [AC_MSG_ERROR(socket lib required for net support on solaris not found)])
 241             AC_CHECK_LIB(nsl, inet_addr, LIBS="${LIBS} -lnsl",
 242                 [AC_MSG_ERROR(nsl lib required for net support on solaris not found)])
 243             ;;
 244     esac
 245 fi
 246 AC_ARG_ENABLE(kalinix,
 247     [  --disable-kalinix       Disable the KaliNix driver (unix-only)],,)
 248 if test x$enable_network != xno; then
 249     if test x$enable_native_ipx != xno; then
 250         D2X_FEATURES="ipx ${D2X_FEATURES}"
 251         AC_DEFINE(NATIVE_IPX,,[Define to use the IPX support of the OS])
 252     fi
 253     if test x$enable_kalinix != xno; then
 254         D2X_FEATURES="kalinix ${D2X_FEATURES}"
 255         AC_DEFINE(KALINIX,,[Define to enable use of the KaliNix driver])
 256     fi
 257     AC_DEFINE(NETWORK,,[Define if you want a network build])
 258     D2X_FEATURES="network ${D2X_FEATURES}"
 259 fi
 260 AM_CONDITIONAL(USE_NETWORK, test x$enable_network != xno)
 261 AM_CONDITIONAL(USE_NATIVE_IPX, test x$enable_native_ipx != xno)
 262 AM_CONDITIONAL(USE_KALINIX, test x$enable_kalinix != xno)
 263
 264 dnl Check for assembler
 265 AC_ARG_ENABLE(assembler,
 266     [  --disable-assembler     Do not use assembler optimization ],,)
 267 if test x$enable_assembler != xno; then
 268     if test x$NASM = xno; then
 269         AC_MSG_WARN([nasm not found. disabling assembler])
 270         enable_assembler="no"
 271     else
 272         NASMFLAGS="-i\$(srcdir)/ $NASMFLAGS"
 273         case $host_os in
 274             cygwin* | mingw*)
 275                 NASMFLAGS="-f win32 $NASMFLAGS"
 276                 ;;
 277             msdos*)
 278                 NASMFLAGS="-f coff $NASMFLAGS"
 279                 ;;
 280             linux* | freebsd*)
 281                 NASMFLAGS="-f elf -d__ELF__ $NASMFLAGS"
 282                 ;;
 283             *)
 284                 AC_MSG_WARN([nasm not supported for this OS. disabling assembler])
 285                 enable_assembler="no"
 286                 ;;
 287         esac
 288         case $host_cpu in
 289             x86_64)
 290                 AC_MSG_WARN([nasm not supported for this cpu. disabling assembler])
 291                 enable_assembler="no"
 292                 ;;
 293         esac
 294     fi
 295 fi
 296 if test x$enable_assembler = xno; then
 297     AC_DEFINE(NO_ASM,,[Define if you want an assembler free build])
 298     D2X_FEATURES="no_asm ${D2X_FEATURES}"
 299 fi
 300 AM_CONDITIONAL(USE_ASM, test x$enable_assembler != xno)
 301
 302 AH_BOTTOM([
 303         /* General defines */
 304 #ifndef PACKAGE_STRING
 305 #define PACKAGE_STRING PACKAGE " " VERSION
 306 #endif
 307 #define VERSION_NAME PACKAGE_STRING
 308 #define NMONO 1
 309 #define PIGGY_USE_PAGING 1
 310 #define NEWDEMO 1
 311
 312 #if defined(__APPLE__) && defined(__MACH__)
 313 #define __unix__ /* since we're doing a unix-style compilation... */
 314 #endif
 315
 316 #ifdef __unix__
 317 #  ifdef SVGA
 318 #   define SVGALIB_INPUT 1
 319 #   define SVGALIB_VIDEO 1
 320 #  else
 321 #   define SDL_INPUT 1
 322 #   ifdef OGL
 323 #    define SDL_GL_VIDEO 1
 324 #   else
 325 #    define SDL_VIDEO 1
 326 #   endif
 327 #  endif
 328 #endif
 329
 330 #ifdef _WIN32
 331 # define SDL_INPUT 1
 332 # ifdef OGL
 333 #  define SDL_GL_VIDEO 1
 334 # else
 335 #  define SDL_VIDEO 1
 336 # endif
 337 #endif
 338         ])
 339
 340 TARGETS="$TARGETS$ac_cv_exeext"
 341
 342 AM_PROG_AS
 343
 344 AC_SUBST(TARGETS)
 345
 346 AC_SUBST(NASMFLAGS)
 347
 348 AC_SUBST(CFLAGS)
 349
 350 AC_OUTPUT(
 351     Makefile
 352     debian/changelog
 353     rpm/d2x.spec
 354 )
 355
 356 AC_MSG_RESULT([
 357         d2x has been configured successfully.
 358
 359         Targets: $TARGETS
 360         Features: $D2X_FEATURES
 361
 362         Shared game data directory (unix only): $sharepath
 363         ])