clean stuff up, getting ready for 0.2.0 release
[btb/d2x.git] / configure.ac
1 # -*- mode: shell-script -*-
2
3 define([D2X_MAJOR],0)
4 define([D2X_MINOR],2)
5 define([D2X_MICRO],0)
6
7 AC_INIT(d2x,[D2X_MAJOR.D2X_MINOR.D2X_MICRO],[descent-source@warpcore.org])
8 AC_PREREQ(2.52)
9
10 AC_CANONICAL_BUILD
11 AC_CANONICAL_HOST
12 AC_CANONICAL_TARGET
13
14 AM_INIT_AUTOMAKE([1.6])
15
16 AM_CONFIG_HEADER(conf.h)
17
18 AC_DEFINE_UNQUOTED(D2XMAJOR,D2X_MAJOR,[d2x major version])
19 AC_DEFINE_UNQUOTED(D2XMINOR,D2X_MINOR,[d2x minor version])
20 AC_DEFINE_UNQUOTED(D2XMICRO,D2X_MICRO,[d2x micro version])
21
22 AM_MAINTAINER_MODE
23
24 #kludge to keep autoconf from adding -g -O2
25 CFLAGS=" $CFLAGS"
26
27 AC_PROG_INSTALL
28 AC_PROG_MAKE_SET
29 AC_ISC_POSIX
30 AC_CHECK_TOOL(CC, gcc, :)
31 AC_CHECK_TOOL(RANLIB, ranlib, :)
32 AC_CHECK_TOOL(STRIP, strip, :)
33 AC_CHECK_TOOL(AR, ar, :)
34 AC_PROG_CC
35 AC_PROG_CXX
36 AC_STDC_HEADERS
37 AC_PATH_PROGS(NASM, nasm nasmw, no)
38 AC_C_BIGENDIAN
39
40 case $host_cpu in
41         sparc)
42                 AC_DEFINE(WORDS_NEED_ALIGNMENT,,[Define if your processor needs data to be word-aligned])
43         ;;
44 esac
45
46 case $host_os in
47     cygwin)
48         AC_MSG_WARN([Cygwin found, setting -mno-cygwin])
49         CFLAGS="-mno-cygwin $CFLAGS"
50         MINGW32=yes
51         ;;
52     mingw*)
53         MINGW32=yes
54         ;;
55     darwin*)
56         MACOSX=yes
57         ;;
58     msdos*)
59         MSDOS=yes
60         ;;
61 esac
62
63 AM_CONDITIONAL(MINGW32, test x$MINGW32 = xyes)
64 if test x$MINGW32 = xyes; then
65     GL_LIBS="opengl32 glu32"
66 elif test x$MACOSX = xyes; then
67     GL_LIBS=""
68 else
69     GL_LIBS="GL GLU"
70 fi
71
72 if test x$MACOSX = xyes; then
73     AC_DEFINE(__MACOSX__,,[Define if building on MAC OS X])
74 fi
75 AM_CONDITIONAL(MACOSX, test x$MACOSX = xyes)
76
77 dnl Set $prefix and $exec_prefix to $ac_default_prefix if they are not set
78 test "x$prefix" = "xNONE" && prefix=$ac_default_prefix
79 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
80
81 dnl Set default locations to find data files.
82 default_sharepath="$datadir/games/$PACKAGE"
83
84 CFLAGS="-Wall $CFLAGS"
85
86 dnl Enable editor build?
87 AC_ARG_ENABLE(editor,
88     [  --enable-editor         Build editor? (not functional)],,)
89 if test x$enable_editor = xyes; then
90     AC_DEFINE(EDITOR,,[Define if you want to build the editor])
91     D2X_MAIN_SUBDIRS=editor
92 fi
93 AM_CONDITIONAL(EDITOR, test x$enable_editor = xyes)
94
95 dnl Enable macdata build?
96 AC_ARG_ENABLE(macdata,
97     [  --enable-macdata        Build for mac datafiles],,)
98 if test x$enable_macdata = xyes; then
99     AC_DEFINE(MACDATA,,[Define if you want to build for mac datafiles])
100     D2X_FEATURES="macdata ${D2X_FEATURES}"
101 fi
102 AM_CONDITIONAL(MACDATA, test x$enable_macdata = xyes)
103
104 dnl Build with NDEBUG?
105 AC_ARG_ENABLE(debug,
106     [  --disable-debug         Take out debug symbols, Asserts, Int3, etc ],,)
107 if test x$enable_debug = xno; then
108     AC_DEFINE(NDEBUG,,[Define to disable asserts, int3, etc.])
109     CFLAGS="-O2 $CFLAGS"
110 else
111     CFLAGS="-g $CFLAGS"
112     D2X_FEATURES="debug ${D2X_FEATURES}"
113 fi
114
115 dnl Build with RELEASE?
116 AC_ARG_ENABLE(release,
117     [  --enable-release        Release build.  Removes debug/editor things ],,)
118 if test x$enable_release = xyes; then
119     AC_DEFINE(RELEASE,,[Define for a "release" build])
120     D2X_FEATURES="release ${D2X_FEATURES}"
121 fi
122
123 dnl Build without using sdl-joystick ?
124 AC_ARG_ENABLE(linuxjoy,
125     [  --enable-linuxjoy       do not use the SDL Joystick. (eg for MS Sidewinder)],,)
126 if test x$enable_linuxjoy = xyes; then
127     AC_DEFINE(USE_LINUX_JOY,,[define to not use the SDL_Joystick routines.])
128 fi
129 AM_CONDITIONAL(USE_LINUX_JOY, test x$enable_linuxjoy = xyes)
130
131 dnl Build with FAST_FILE_IO?
132 AC_ARG_ENABLE(fastfileio,
133     [  --disable-fastfileio    Disable fast file i/o. ],,)
134 if test x$enable_fastfileio != xno; then
135         if test x$ac_cv_c_bigendian = xyes; then
136                 AC_MSG_WARN([big-endian cpu detected.  disabling fastfileio])
137                 enable_fastfileio="no";
138         fi
139 fi
140 if test x$enable_fastfileio != xno; then
141     AC_DEFINE(FAST_FILE_IO,,[Define for faster i/o on little-endian cpus])
142     D2X_FEATURES="fastfileio ${D2X_FEATURES}"
143 fi
144
145 AC_ARG_WITH(sharepath,
146     [[  --with-sharepath=DIR    Use DIR for shared game data (unix only) [DATADIR/games/d2x]]],
147     sharepath=$withval, sharepath="auto")
148 if test "x$sharepath" = "xauto" -o "x$sharepath" = "xyes" -o "x$sharepath" = "x"; then
149     sharepath="$default_sharepath"
150 fi
151 AC_SUBST(sharepath)
152 eval sharepath=$sharepath
153 AC_DEFINE_UNQUOTED(SHAREPATH, "$sharepath",[Define this to be the shared game directory root])
154
155 # Test for MSDOS
156 if test x$MSDOS = xyes; then
157     CFLAGS="-I \$(top_srcdir)/arch/dos/include $CFLAGS"
158     TARGETS=d2x
159     D2X_ARCH_SUBDIRS=dos
160 else
161
162     CFLAGS="-pipe $CFLAGS"
163
164     dnl Check for SDL
165     AM_PATH_SDL(1.1.0,
166         :,
167         AC_MSG_ERROR(SDL not found. Make sure sdl-config is in your PATH, or specify with --with-sdl-prefix)
168     )
169     CFLAGS="$SDL_CFLAGS $CFLAGS"
170     LIBS="$SDL_LIBS $LIBS"
171
172     TARGETS=d2x-sdl
173     D2X_ARCH_SUBDIRS=sdl
174
175     AC_CHECK_HEADERS(netipx/ipx.h)
176
177   # Check for OpenGL
178     AC_ARG_WITH(opengl,
179         [  --with-opengl           Build OpenGL support ],,)
180     if test x$with_opengl = xyes; then
181         for lib in $GL_LIBS; do
182             AC_CHECK_LIB($lib, main,
183                 OGL_LIBS="${OGL_LIBS} -l$lib",
184                 [AC_MSG_ERROR([$lib not found, --with-opengl cannot be used])
185                     opengl=false],
186                 ${OGL_LIBS}
187             )
188         done
189         AC_DEFINE(OGL,,[Define if you want an OpenGL build])
190         TARGETS=d2x-gl
191         D2X_ARCH_SUBDIRS="ogl ${D2X_ARCH_SUBDIRS}"
192     fi
193     AC_SUBST(OGL_LIBS)
194     AM_CONDITIONAL(USE_OPENGL, test x$with_opengl = xyes)
195
196   # Check for GGI
197     AC_ARG_WITH(ggi,
198         [  --with-ggi              Build GGI support ],,)
199     if test x$with_ggi = xyes; then
200         AC_CHECK_LIB(ggi, ggiInit,
201             GGI_LIBS="-lggi",
202             [AC_MSG_ERROR([GGI not found, GGI version cannot be built]); ggi=false])
203         AC_CHECK_LIB(gii, giiInit,
204             GGI_LIBS="${GGI_LIBS} -lgii",
205             [AC_MSG_ERROR([GII not found, GGI version cannot be built]); ggi=false])
206         AC_DEFINE(GGI,,[Define if you want a GGI build])
207         TARGETS=d2x-ggi
208         D2X_ARCH_SUBDIRS="ggi ${D2X_ARCH_SUBDIRS}"
209     fi
210     AC_SUBST(GGI_LIBS)
211     AM_CONDITIONAL(USE_GGI, test x$with_ggi = xyes)
212
213   # Check for SVGALib
214     AC_ARG_WITH(svga,
215         [  --with-svga             Build SVGALib support ],,)
216     if test x$with_svga = xyes; then
217         AC_CHECK_LIB(vga,vga_getmousetype,
218             SVGA_LIBS="-lvga",
219             [AC_MSG_ERROR([vga not found, SVGALib cannot be built])
220                 svga=false],
221         )
222         AC_CHECK_LIB(vgagl,gl_getcontext,
223             SVGA_LIBS="${SVGA_LIBS} -lvgagl",
224             [AC_MSG_ERROR([vgagl not found, SVGALib cannot be built])
225                 svga=false],
226             -lvga)
227         AC_DEFINE(SVGA,,[Define if you want an SVGALib build])
228         TARGETS=d2x-svga
229         D2X_ARCH_SUBDIRS="svgalib ${D2X_ARCH_SUBDIRS}"
230     fi
231     AC_SUBST(SVGA_LIBS)
232     AM_CONDITIONAL(USE_SVGALIB, test x$with_svga = xyes)
233
234     if test x$MINGW32 = xyes; then
235         D2X_ARCH_SUBDIRS="win32 ${D2X_ARCH_SUBDIRS}"
236     else
237         CFLAGS="-I \$(top_srcdir)/arch/linux/include $CFLAGS"
238         D2X_ARCH_SUBDIRS="linux ${D2X_ARCH_SUBDIRS}"
239     fi
240 fi
241
242 dnl Check for network
243 AC_ARG_ENABLE(network,
244     [  --disable-network       Do not build network/serial support ],,)
245 if test x$enable_network != xno; then
246         if test x$MACOSX = xyes; then
247                 AC_MSG_WARN([OS X detected.  disabling network])
248                 enable_network="no";
249         fi
250         if test x$MINGW32 = xyes; then
251                 AC_MSG_WARN([MINGW detected.  disabling network])
252                 enable_network="no";
253         fi
254 fi
255 if test x$enable_network != xno; then
256     AC_DEFINE(NETWORK,,[Define if you want a network build])
257     D2X_FEATURES="network ${D2X_FEATURES}"
258 fi
259 AM_CONDITIONAL(USE_NETWORK, test x$enable_network != xno)
260
261 dnl Check for assembler
262 AC_ARG_ENABLE(assembler,
263     [  --disable-assembler     Do not use assembler optimization ],,)
264 if test x$enable_assembler != xno; then
265     if test x$NASM = xno; then
266         AC_MSG_WARN([nasm not found. disabling assembler])
267         enable_assembler="no"
268     else
269         NASMFLAGS="-i\$(srcdir)/ $NASMFLAGS"
270         case $host_os in
271             cygwin* | mingw*)
272                 NASMFLAGS="-f win32 $NASMFLAGS"
273                 ;;
274             msdos*)
275                 NASMFLAGS="-f coff $NASMFLAGS"
276                 ;;
277             linux*)
278                 NASMFLAGS="-f elf -d__linux__ $NASMFLAGS"
279                 ;;
280             *)
281                 AC_MSG_WARN([nasm not supported for this OS. disabling assembler])
282                 enable_assembler="no"
283                 ;;
284         esac
285     fi
286 fi
287 if test x$enable_assembler = xno; then
288     AC_DEFINE(NO_ASM,,[Define if you want an assembler free build])
289     D2X_FEATURES="no_asm ${D2X_FEATURES}"
290 fi
291 AM_CONDITIONAL(USE_ASM, test x$enable_assembler != xno)
292
293 AH_BOTTOM([
294         /* General defines */
295 #define VERSION_NAME PACKAGE_STRING
296 #define NMONO 1
297 #define PIGGY_USE_PAGING 1
298 #define NEWDEMO 1
299
300 #ifdef __MACOSX__
301 #define __unix__
302 #endif
303
304 #ifdef __unix__
305 # ifdef GGI
306 #  define GII_INPUT 1
307 #  define GGI_VIDEO 1
308 # else
309 #  ifdef SVGA
310 #   define SVGALIB_INPUT 1
311 #   define SVGALIB_VIDEO 1
312 #  else
313 #   define SDL_INPUT 1
314 #   ifdef OGL
315 #    define SDL_GL_VIDEO 1
316 #   else
317 #    define SDL_VIDEO 1
318 #   endif
319 #  endif
320 # endif
321 #endif
322
323 #ifdef __MINGW32__
324 # define SDL_INPUT 1
325 # ifdef OGL
326 #  define SDL_GL_VIDEO 1
327 # else
328 #  define SDL_VIDEO 1
329 # endif
330 #endif
331         ])
332
333 AM_PROG_AS
334
335 AC_SUBST(D2X_ARCH_SUBDIRS)
336
337 AC_SUBST(D2X_MAIN_SUBDIRS)
338
339 AC_SUBST(TARGETS)
340
341 AC_SUBST(NASMFLAGS)
342
343 AC_SUBST(CFLAGS)
344
345 AC_OUTPUT(
346     Makefile
347     2d/Makefile
348     3d/Makefile
349     arch/Makefile
350     arch/dos/Makefile
351     arch/ggi/Makefile
352     arch/linux/Makefile
353     arch/ogl/Makefile
354     arch/sdl/Makefile
355     arch/svgalib/Makefile
356     arch/win32/Makefile
357     cfile/Makefile
358     iff/Makefile
359     libmve/Makefile
360     main/Makefile
361     main/editor/Makefile
362     maths/Makefile
363     mem/Makefile
364     misc/Makefile
365     texmap/Makefile
366     utilities/Makefile
367     debian/changelog
368     rpm/d2x.spec
369 )
370
371 AC_MSG_RESULT([
372         d2x has been configured successfully.
373
374         Platform(s): $D2X_ARCH_SUBDIRS
375         Features   : $D2X_FEATURES $D2X_MAIN_SUBDIRS
376
377         Shared game data directory (unix only): $sharepath
378         ])