qcsrc/player.qc

   1 $frame die1 die2 draw duck duckwalk duckjump duckidle idle
   2 $frame jump pain1 pain2 shoot taunt run runbackwards
   3 $frame strafeleft straferight dead1 dead2 forwardright
   4 $frame forwardleft backright backleft
   5
   6 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   7 // merged player_run and player_stand to player_anim
   8 // added death animations to player_anim
   9 // can now spawn thrown weapons from anywhere, not just from players
  10 // thrown weapons now fade out after 20 seconds
  11 // created PlayerGib function
  12 // PlayerDie no longer uses hitloc or damage
  13 // PlayerDie now supports dying animations as well as gibbing
  14 // cleaned up PlayerDie a lot
  15 // added CopyBody
  16
  17 void CopyBody()
  18 {
  19         local entity oldself;
  20         oldself = self;
  21         self = spawn();
  22         self.angles = oldself.angles;
  23         self.avelocity = oldself.avelocity;
  24         self.classname = "body";
  25         self.damageforcescale = oldself.damageforcescale;
  26         self.effects = oldself.effects;
  27         self.event_damage = oldself.event_damage;
  28         self.frame = oldself.frame;
  29         self.health = oldself.health;
  30         self.model = oldself.model;
  31         self.modelindex = oldself.modelindex;
  32         self.movetype = oldself.movetype;
  33         self.nextthink = oldself.nextthink;
  34         self.norespawn = TRUE;
  35         self.skin = oldself.skin;
  36         self.solid = oldself.solid;
  37         self.takedamage = oldself.takedamage;
  38         self.think = oldself.think;
  39         self.velocity = oldself.velocity;
  40         self.weapon = oldself.weapon;
  41         setorigin(self, oldself.origin);
  42         setsize(self, '-16 -16 -24',  '16 16 5');
  43         self = oldself;
  44 }
  45
  46 void player_anim (void)
  47 {
  48         if (self.deadflag != DEAD_NO)
  49         {
  50                 if (time > self.dead_time)
  51                         self.frame = self.dead_frame;
  52                 else
  53                         self.frame = self.die_frame;
  54                 //SUB_SetFade (self, time + 12 + random () * 4);
  55                 return;
  56         }
  57
  58         if (self.crouch)
  59         {
  60                 // don't duck if moving
  61                 if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
  62                         self.frame = $duckwalk;
  63                 else
  64                         self.frame = $duckidle;
  65         }
  66         else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
  67         {
  68                 if (self.movement_x > 0 && self.movement_y == 0)
  69                         self.frame = $run;
  70                 else if (self.movement_x < 0 && self.movement_y == 0)
  71                         self.frame = $runbackwards;
  72                 else if (self.movement_x == 0 && self.movement_y > 0)
  73                         self.frame = $straferight;
  74                 else if (self.movement_x == 0 && self.movement_y < 0)
  75                         self.frame = $strafeleft;
  76                 else if (self.movement_x > 0 && self.movement_y > 0)
  77                         self.frame = $forwardright;
  78                 else if (self.movement_x > 0 && self.movement_y < 0)
  79                         self.frame = $forwardleft;
  80                 else if (self.movement_x < 0 && self.movement_y > 0)
  81                         self.frame = $backright;
  82                 else if (self.movement_x < 0 && self.movement_y < 0)
  83                         self.frame = $backleft;
  84                 else
  85                         self.frame = $run;
  86         }
  87         else if (self.pain_finished > time)
  88                 self.frame = self.pain_frame;
  89         else if (self.attack_finished > time)
  90                 self.frame = $shoot;
  91         else
  92                 self.frame = $idle;
  93 }
  94 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
  95
  96 void SpawnThrownWeapon (vector org, float w)
  97 {
  98         local entity oldself;
  99
 100         if (w == IT_LASER)
 101                 return;
 102
 103         oldself = self;
 104         self = spawn();
 105
 106         setorigin(self, org);
 107         self.velocity = randomvec() * 100 + '0 0 200';
 108         self.norespawn = 1;
 109         //SUB_SetFade(self, time + 20);
 110
 111         if (w == IT_UZI)
 112                 weapon_uzi ();
 113         else if (w == IT_SHOTGUN)
 114                 weapon_shotgun ();
 115         else if (w == IT_GRENADE_LAUNCHER)
 116                 weapon_grenadelauncher ();
 117         else if (w == IT_ELECTRO)
 118                 weapon_electro ();
 119         else if (w == IT_CRYLINK)
 120                 weapon_crylink ();
 121         else if (w == IT_NEX)
 122                 weapon_nex ();
 123         else if (w == IT_HAGAR)
 124                 weapon_hagar ();
 125         else //if (w == IT_ROCKET_LAUNCHER)
 126                 weapon_rocketlauncher ();
 127
 128         self = oldself;
 129 }
 130
 131 void PlayerCorpseDamage (vector hitloc, float damage, entity inflictor, entity attacker, float deathtype)
 132 {
 133         te_blood (hitloc, '0 0 20', damage);
 134         // damage resistance (ignore most of the damage from a bullet or similar)
 135         damage = max(damage - 5, 1);
 136         self.health = self.health - damage;
 137         self.dmg_take = self.dmg_take + damage;
 138         self.dmg_inflictor = inflictor;
 139         if (self.health <= -50)
 140         {
 141                 // don't use any animations as a gib
 142                 self.frame = 0;
 143                 self.dead_frame = 0;
 144                 self.die_frame = 0;
 145                 // view just above the floor
 146                 self.view_ofs = '0 0 4';
 147                 // make a juicy mess
 148                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 500, 2000);
 149                 // make a meaty mess
 150                 TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity);
 151                 TossGib (world, "models/gibs/gib2.mdl", self.origin, self.velocity);
 152                 TossGib (world, "models/gibs/gib3.mdl", self.origin, self.velocity);
 153                 TossGib (world, "models/gibs/gib4.mdl", self.origin, self.velocity);
 154                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin, self.velocity);
 155                 TossGib (self, "models/gibs/eye.md3", self.origin, self.velocity);
 156                 sound (trace_ent, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 157         }
 158 }
 159
 160 void PlayerDamage (vector hitloc, float damage, entity inflictor, entity attacker, float deathtype)
 161 {
 162         te_blood (hitloc, '0 0 20', damage);
 163         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 164         {
 165                 if (random() > 0.5)
 166                         self.pain_frame = $pain1;
 167                 else
 168                         self.pain_frame = $pain2;
 169                 self.pain_finished = time + 0.5;        //Supajoe
 170         }
 171         self.health = self.health - damage;
 172         self.dmg_take = self.dmg_take + damage;
 173         self.dmg_inflictor = inflictor;
 174         if (self.health <= 0)
 175         {
 176                 // print an obituary message
 177                 Obituary (attacker, self, deathtype);
 178                 // make the corpse upright (not tilted)
 179                 self.angles_x = 0;
 180                 self.angles_z = 0;
 181                 // don't spin
 182                 self.avelocity = '0 0 0';
 183                 // no weapon when dead
 184                 self.weaponmodel = "";
 185                 // view from the floor
 186                 self.view_ofs = '0 0 -8';
 187                 // toss the corpse
 188                 self.movetype = MOVETYPE_TOSS;
 189                 // shootable corpse
 190                 self.solid = SOLID_CORPSE;
 191                 // don't stick to the floor
 192                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 193                 // dying animation
 194                 self.deadflag = DEAD_DYING;
 195                 // when to allow respawn
 196                 self.death_time = time + 2;
 197                 // when to switch to the dead_frame
 198                 self.dead_time = time + 2;
 199                 if (random() < 0.5)
 200                 {
 201                         self.die_frame = $die1;
 202                         self.dead_frame = $dead1;
 203                 }
 204                 else
 205                 {
 206                         self.die_frame = $die2;
 207                         self.dead_frame = $dead2;
 208                 }
 209                 // start the animation
 210                 player_anim();
 211                 // throw a weapon
 212                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.weapon);
 213                 // set damage function to corpse damage
 214                 self.event_damage = PlayerCorpseDamage;
 215                 // call the corpse damage function just in case it wants to gib
 216                 self.event_damage(hitloc, 0, inflictor, attacker, deathtype);
 217         }
 218 }
 219