qcsrc/gamec/w_grenadelauncher.c

   1 void() glauncher_ready_01;
   2 void() glauncher_fire1_01;
   3 void() glauncher_fire2_01;
   4 void() glauncher_deselect_01;
   5 void() glauncher_select_01;
   6
   7 float() glauncher_check =
   8 {
   9         if (self.ammo_rockets >= 3)
  10                 return TRUE;
  11         return FALSE;
  12 };
  13
  14 void(float req) w_glauncher =
  15 {
  16         if (req == WR_IDLE)
  17                 glauncher_ready_01();
  18         else if (req == WR_FIRE1)
  19                 weapon_prepareattack(glauncher_check, glauncher_check, glauncher_fire1_01, cvar("g_balance_grenadelauncher_refire"));
  20         else if (req == WR_FIRE2)
  21                 weapon_prepareattack(glauncher_check, glauncher_check, glauncher_fire2_01, cvar("g_balance_grenadelauncher_refire"));
  22         else if (req == WR_RAISE)
  23                 glauncher_select_01();
  24         else if (req == WR_UPDATECOUNTS)
  25                 self.currentammo = self.ammo_rockets;
  26         else if (req == WR_DROP)
  27                 glauncher_deselect_01();
  28         else if (req == WR_SETUP)
  29                 weapon_setup(WEP_GRENADE_LAUNCHER, "w_gl.zym", IT_ROCKETS);
  30         else if (req == WR_CHECKAMMO)
  31                 weapon_hasammo = glauncher_check();
  32 };
  33
  34 void W_Grenade_Explode (void)
  35 {
  36         ImpactEffect (self, IT_GRENADE_LAUNCHER);
  37
  38         self.event_damage = nullfunction;
  39         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_damage"), cvar("g_balance_grenadelauncher_edgedamage"), cvar("g_balance_grenadelauncher_radius"), world, cvar("g_balance_grenadelauncher_force"), IT_GRENADE_LAUNCHER);
  40
  41         remove (self);
  42 }
  43
  44 void W_Grenade_Touch (void)
  45 {
  46         if (other.classname == "player" || other.classname == "corpse")
  47                 W_Grenade_Explode ();
  48         else
  49         sound (self, CHAN_BODY, "weapons/grenade_bounce.wav", 1, ATTN_NORM);
  50 }
  51
  52 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  53 {
  54         self.health = self.health - damage;
  55         if (self.health <= 0)
  56                 W_Grenade_Explode();
  57 }
  58
  59 void W_Grenade_Attack (void)
  60 {
  61         makevectors(self.v_angle);
  62         sound (self, CHAN_WEAPON, "weapons/grenade_fire.wav", 1, ATTN_NORM);
  63         self.punchangle_x = -4;
  64
  65         entity gren;
  66
  67         gren = spawn ();
  68         gren.owner = self;
  69         gren.classname = "grenade";
  70         gren.movetype = MOVETYPE_BOUNCE;
  71         gren.solid = SOLID_BBOX;
  72         setmodel(gren, "models/grenademodel.md3");
  73         setsize(gren, '-6 -6 -3', '6 6 3');
  74         setorigin(gren, self.origin + self.view_ofs + v_forward * 15 + v_right * 5 + v_up * -12);
  75         gren.health = 1;
  76         gren.takedamage = DAMAGE_YES;
  77         gren.velocity = v_forward * cvar("g_balance_grenadelauncher_speed") + v_up * cvar("g_balance_grenadelauncher_speed_up");
  78         gren.avelocity_x = random () * -500 - 500;
  79         setsize (gren, gren.mins, gren.maxs);
  80         gren.angles = vectoangles (gren.velocity);
  81         gren.touch = W_Grenade_Explode;
  82         gren.think = W_Grenade_Explode;
  83         gren.nextthink = time + 30;
  84         self.ammo_rockets = self.ammo_rockets - 3;
  85 }
  86
  87 void W_Grenade_Attack2 (void)
  88 {
  89
  90         entity  gren;
  91         makevectors(self.v_angle);
  92         sound (self, CHAN_WEAPON, "weapons/grenade_fire.wav", 1, ATTN_NORM);
  93         self.punchangle_x = -4;
  94
  95         gren = spawn ();
  96         gren.owner = self;
  97         gren.classname = "grenade";
  98
  99         gren.movetype = MOVETYPE_BOUNCE;
 100         gren.solid = SOLID_BBOX;
 101
 102         gren.takedamage = DAMAGE_YES;
 103         gren.damageforcescale = 4;
 104         gren.health = 10;
 105         gren.event_damage = W_Grenade_Damage;
 106
 107         setmodel (gren, "models/grenademodel.md3");
 108         setsize (gren, '-6 -6 -3', '6 6 3');
 109
 110         setorigin (gren, self.origin + self.view_ofs + v_forward * 15 + v_right * 5 + v_up * -12);
 111
 112         gren.velocity = v_forward * cvar("g_balance_grenadelauncher_speed2") + v_up * cvar("g_balance_grenadelauncher_speed2_up");
 113         gren.angles = vectoangles (gren.velocity);
 114         gren.avelocity = '100 150 100';
 115
 116         gren.touch = W_Grenade_Explode;
 117         //gren.think = W_Grenade_FuseExplode;
 118         //gren.nextthink = time + 5;
 119
 120         self.ammo_rockets = self.ammo_rockets - 3;
 121 }
 122
 123 // weapon frames
 124
 125 void()  glauncher_ready_01 =    {weapon_thinkf(WFRAME_IDLE, 0.1, glauncher_ready_01); self.weaponentity.state = WS_READY;};
 126 void()  glauncher_select_01 =   {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');};
 127 void()  glauncher_deselect_01 = {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);};
 128 void()  glauncher_fire1_01 =
 129 {
 130         weapon_doattack(glauncher_check, glauncher_check, W_Grenade_Attack);
 131         weapon_thinkf(WFRAME_FIRE1, 0.3, glauncher_ready_01);
 132 };
 133 void()  glauncher_fire2_01 =
 134 {
 135         weapon_doattack(glauncher_check, glauncher_check, W_Grenade_Attack2);
 136         weapon_thinkf(WFRAME_FIRE2, 0.8, glauncher_ready_01);
 137 };