qcsrc/gamec/t_items.c

   1
   2 void Item_Respawn (void)
   3 {
   4         self.model = self.mdl;          // restore original model
   5         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   6         sound (self, CHAN_VOICE, "misc/itemrespawn.wav", 1, ATTN_NORM); // play respawn sound
   7         setorigin (self, self.origin);
   8 }
   9
  10 void Item_Touch (void)
  11 {
  12         local entity oldself;
  13         local float     _switchweapon;
  14
  15         if (self.solid != SOLID_TRIGGER)
  16                 return;
  17
  18         if (other.classname != "player" && other.classname != "bot")
  19                 return;
  20         if (other.health <= 0)
  21                 return;
  22
  23         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  24
  25         // if the player is using their best weapon before items are given, they
  26         // probably want to switch to an even better weapon after items are given
  27         _switchweapon = other.switchweapon == w_getbestweapon(other);
  28
  29         if (self.ammo_shells){
  30                 other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
  31         }
  32         if (self.ammo_nails)
  33                 other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
  34         if (self.ammo_rockets)
  35                 other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
  36         if (self.ammo_cells)
  37                 other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
  38
  39         if (self.items & IT_UZI)                                W_GiveWeapon (other, IT_UZI, "Machine gun");
  40         if (self.items & IT_SHOTGUN)                    W_GiveWeapon (other, IT_SHOTGUN, "Shotgun");
  41         if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, "Mortar");
  42         if (self.items & IT_ELECTRO)                    W_GiveWeapon (other, IT_ELECTRO, "Electro");
  43         if (self.items & IT_NEX)                                W_GiveWeapon (other, IT_NEX, "Nex");
  44         if (self.items & IT_HAGAR)                              W_GiveWeapon (other, IT_HAGAR, "Hagar");
  45         if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, "Rocket Launcher");
  46         if (self.items & IT_CRYLINK)                    W_GiveWeapon (other, IT_CRYLINK, "Crylink");
  47
  48         if (self.strength_finished)
  49                 other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  50         if (self.invincible_finished)
  51                 other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
  52         //if (self.speed_finished)
  53         //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
  54         //if (self.slowmo_finished)
  55         //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
  56
  57         if (self.max_health)
  58                 other.health = other.health + self.max_health;
  59         if (self.armorvalue)
  60                 other.armorvalue = other.armorvalue + self.armorvalue;
  61
  62         oldself = self;
  63         self = other;
  64
  65         if (_switchweapon)
  66                 self.switchweapon = w_getbestweapon(self);
  67
  68         //W_UpdateWeapon ();
  69         //W_UpdateAmmo ();
  70         weapon_action(self.weapon, WR_UPDATECOUNTS);
  71
  72         self = oldself;
  73
  74         if (self.norespawn)
  75                 remove (self);
  76         else
  77         {
  78                 self.solid = SOLID_NOT;
  79                 self.model = string_null;
  80                 self.nextthink = time + self.respawntime;
  81                 self.think = Item_Respawn;
  82                 setorigin (self, self.origin);
  83         }
  84 }
  85
  86 // Savage: used for item garbage-collection
  87 // TODO: perhaps nice special effect?
  88 void RemoveItem(void) = {
  89         remove(self);
  90 }
  91
  92
  93 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags)
  94 {
  95         if ((cvar("g_instagib") == 1) | (cvar("g_rocketarena") == 1))
  96         {
  97                 remove (self);
  98                 return;
  99         }
 100         self.mdl = itemmodel;
 101         self.noise = pickupsound;
 102         // let mappers override respawntime
 103         if (!self.respawntime)
 104                 self.respawntime = defaultrespawntime;
 105         self.netname = itemname;
 106         self.items = itemid;
 107         self.flags = FL_ITEM | itemflags;
 108         setmodel (self, self.mdl);
 109         if (itemflags & FL_WEAPON)
 110         {
 111                 setorigin (self, self.origin + '0 0 22');
 112                 setsize (self, '-12 -12 -12', '12 12 12');
 113         }
 114         else
 115         {
 116                 setorigin (self, self.origin + '0 0 15');
 117         //      setsize (self, '-8 -8 -5', '8 8 8');
 118         }
 119         self.movetype = MOVETYPE_TOSS;
 120         self.solid = SOLID_TRIGGER;
 121         self.touch = Item_Touch;
 122
 123         if (itemflags & FL_POWERUP)
 124         {
 125                 self.effects = self.effects | EF_ADDITIVE;
 126         }
 127
 128         // Savage: remove thrown items after a certain period of time ("garbage collection")
 129         if(self.norespawn) {
 130                 self.think = RemoveItem;
 131                 self.nextthink = time + 60;
 132         }
 133
 134 }
 135
 136 void weapon_uzi (void) {self.ammo_nails = 30;StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.wav", 15, "Uzi", IT_UZI, FL_WEAPON);}
 137 void weapon_shotgun (void) {self.ammo_shells = 15;StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.wav", 15, "Shotgun", IT_SHOTGUN, FL_WEAPON);}
 138 void weapon_grenadelauncher (void) {self.ammo_rockets = 15;StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.wav", 15, "Grenade Launcher", IT_GRENADE_LAUNCHER, FL_WEAPON);}
 139 void weapon_electro (void) {self.ammo_cells = 25;StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.wav", 15, "Electro", IT_ELECTRO, FL_WEAPON);}
 140 void weapon_crylink (void) {self.ammo_cells = 25;StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.wav", 15, "Crylink", IT_CRYLINK, FL_WEAPON);}
 141 void weapon_nex (void) {self.ammo_cells = 25;StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.wav", 15, "Nex Gun", IT_NEX, FL_WEAPON);}
 142 void weapon_hagar (void) {self.ammo_rockets = 15;StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.wav", 15, "Hagar", IT_HAGAR, FL_WEAPON);}
 143 void weapon_rocketlauncher (void) {self.ammo_rockets = 15;StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.wav", 15, "Rocket Launcher", IT_ROCKET_LAUNCHER, FL_WEAPON);}
 144
 145 void item_rockets (void) {self.ammo_rockets = 15;StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", 15, "rockets", IT_ROCKETS, 0);}
 146 void item_bullets (void) {self.ammo_nails = 30;StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", 15, "bullets", IT_NAILS, 0);}
 147 void item_cells (void) {self.ammo_cells = 25;StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", 15, "cells", IT_CELLS, 0);}
 148 void item_shells (void) {self.ammo_shells = 15;StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", 15, "shells", IT_SHELLS, 0);}
 149
 150 void item_armor1 (void) {self.armorvalue = 5;StartItem ("models/items/g_a1.md3", "misc/itempickup.wav", 15, "Armor Shard", 0, 0);}
 151 void item_armor25 (void) {self.armorvalue = 100;StartItem ("models/items/g_a25.md3", "misc/itempickup.wav", 30, "Armor", 0, 0);}
 152 void item_health1 (void) {self.max_health = 5;StartItem ("models/items/g_h1.md3", "misc/itempickup.wav", 15, "5 Health", 0, 0);}
 153 void item_health25 (void) {self.max_health = 25;StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", 15, "25 Health", 0, 0);}
 154 void item_health100 (void) {self.max_health = 100;StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", 30, "100 Health", 0, 0);}
 155
 156 void item_strength (void) {self.strength_finished = 30;StartItem ("models/items/g_strength.md3", "misc/powerup.wav", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP);}
 157 void item_invincible (void) {self.invincible_finished = 30;StartItem ("models/items/g_invincible.md3", "misc/powerup.wav", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP);}
 158 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP);}
 159 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP);}
 160
 161 void misc_models (void)
 162 {
 163         precache_model (self.model);
 164         setmodel (self, self.model);
 165         setsize (self, self.mins, self.maxs);
 166 }
 167
 168