qcsrc/gamec/t_items.c

   1 void Item_ClearRespawnEffect (void) {
   2         self.effects = 0;
   3 }
   4
   5 void Item_Respawn (void)
   6 {
   7         self.model = self.mdl;          // restore original model
   8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   9         sound (self, CHAN_VOICE, "misc/itemrespawn.wav", 1, ATTN_NORM); // play respawn sound
  10         setorigin (self, self.origin);
  11
  12         // Savage: Add simple Respawn effect and make sure it gets removed
  13         if(self.effects == 0) {
  14                 self.effects = EF_STARDUST;
  15                 self.think = Item_ClearRespawnEffect;
  16                 self.nextthink = time + 0.1;
  17         }
  18 }
  19
  20 void Item_Touch (void)
  21 {
  22
  23         local entity oldself;
  24         local float     _switchweapon;
  25
  26         if (other.classname != "player")
  27                 return;
  28         if (other.deadflag)
  29                 return;
  30         if (self.solid != SOLID_TRIGGER)
  31                 return;
  32         // Savage: Remove the respawn effect if still present
  33         if(self.effects == EF_STARDUST)
  34                 self.effects = 0;
  35
  36         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  37
  38         // if the player is using their best weapon before items are given, they
  39         // probably want to switch to an even better weapon after items are given
  40         _switchweapon = other.switchweapon == w_getbestweapon(other);
  41
  42         if (self.ammo_shells)
  43                 other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
  44         if (self.ammo_nails)
  45                 other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
  46         if (self.ammo_rockets)
  47                 other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
  48         if (self.ammo_cells)
  49                 other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
  50
  51         if (self.items & IT_UZI)                                W_GiveWeapon (other, IT_UZI, "Machine gun");
  52         if (self.items & IT_SHOTGUN)                    W_GiveWeapon (other, IT_SHOTGUN, "Shotgun");
  53         if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, "Mortar");
  54         if (self.items & IT_ELECTRO)                    W_GiveWeapon (other, IT_ELECTRO, "Electro");
  55         if (self.items & IT_NEX)                                W_GiveWeapon (other, IT_NEX, "Nex");
  56         if (self.items & IT_HAGAR)                              W_GiveWeapon (other, IT_HAGAR, "Hagar");
  57         if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, "Rocket Launcher");
  58         if (self.items & IT_CRYLINK)                    W_GiveWeapon (other, IT_CRYLINK, "Crylink");
  59
  60         if (self.strength_finished)
  61                 other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  62         if (self.invincible_finished)
  63                 other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
  64         //if (self.speed_finished)
  65         //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
  66         //if (self.slowmo_finished)
  67         //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
  68
  69         if (self.max_health)
  70                 other.health = other.health + self.max_health;
  71         if (self.armorvalue)
  72                 other.armorvalue = other.armorvalue + self.armorvalue;
  73
  74         oldself = self;
  75         self = other;
  76
  77         if (_switchweapon)
  78                 self.switchweapon = w_getbestweapon(self);
  79
  80         //W_UpdateWeapon ();
  81         //W_UpdateAmmo ();
  82         weapon_action(self.weapon, WR_UPDATECOUNTS);
  83
  84         self = oldself;
  85
  86         if (self.classname == "droppedweapon")
  87                 remove (self);
  88         else
  89         {
  90                 self.solid = SOLID_NOT;
  91                 self.model = string_null;
  92                 self.nextthink = time + self.respawntime;
  93                 self.think = Item_Respawn;
  94                 setorigin (self, self.origin);
  95         }
  96 }
  97
  98 // Savage: used for item garbage-collection
  99 // TODO: perhaps nice special effect?
 100 void RemoveItem(void) = {
 101         remove(self);
 102 }
 103
 104
 105 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags)
 106 {
 107         if ((cvar("g_instagib") == 1) | (cvar("g_rocketarena") == 1))
 108         {
 109                 remove (self);
 110                 return;
 111         }
 112         self.mdl = itemmodel;
 113         self.noise = pickupsound;
 114         // let mappers override respawntime
 115         if (!self.respawntime)
 116                 self.respawntime = defaultrespawntime;
 117         self.netname = itemname;
 118         self.items = itemid;
 119         self.flags = FL_ITEM | itemflags;
 120         setmodel (self, self.mdl);
 121         if (itemflags & FL_WEAPON)
 122         {
 123                 setorigin (self, self.origin + '0 0 22');
 124                 setsize (self, '-12 -12 -12', '12 12 12');
 125         }
 126         else
 127         {
 128                 setorigin (self, self.origin + '0 0 15');
 129         //      setsize (self, '-8 -8 -5', '8 8 8');
 130         }
 131         self.movetype = MOVETYPE_TOSS;
 132         self.solid = SOLID_TRIGGER;
 133         self.touch = Item_Touch;
 134
 135         if (itemflags & FL_POWERUP)
 136                 self.effects = self.effects | EF_ADDITIVE;
 137
 138         // Savage: remove thrown items after a certain period of time ("garbage collection")
 139         if (self.classname == "droppedweapon")
 140         {
 141                 self.think = RemoveItem;
 142                 self.nextthink = time + 60;
 143         }
 144
 145         if (cvar("g_fullbrightitems"))
 146                 self.effects = self.effects | EF_FULLBRIGHT;
 147
 148 }
 149
 150 void weapon_uzi (void) {self.ammo_nails = 120;StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.wav", 15, "Uzi", IT_UZI, FL_WEAPON);}
 151 void weapon_shotgun (void) {self.ammo_shells = 15;StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.wav", 15, "Shotgun", IT_SHOTGUN, FL_WEAPON);}
 152 void weapon_grenadelauncher (void) {self.ammo_rockets = 15;StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.wav", 15, "Grenade Launcher", IT_GRENADE_LAUNCHER, FL_WEAPON);}
 153 void weapon_electro (void) {self.ammo_cells = 25;StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.wav", 15, "Electro", IT_ELECTRO, FL_WEAPON);}
 154 void weapon_crylink (void) {self.ammo_cells = 25;StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.wav", 15, "Crylink", IT_CRYLINK, FL_WEAPON);}
 155 void weapon_nex (void) {self.ammo_cells = 25;StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.wav", 15, "Nex Gun", IT_NEX, FL_WEAPON);}
 156 void weapon_hagar (void) {self.ammo_rockets = 15;StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.wav", 15, "Hagar", IT_HAGAR, FL_WEAPON);}
 157 void weapon_rocketlauncher (void) {self.ammo_rockets = 15;StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.wav", 15, "Rocket Launcher", IT_ROCKET_LAUNCHER, FL_WEAPON);}
 158
 159 void item_rockets (void) {self.ammo_rockets = 15;StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", 15, "rockets", IT_ROCKETS, 0);}
 160 void item_bullets (void) {self.ammo_nails = 120;StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", 15, "bullets", IT_NAILS, 0);}
 161 void item_cells (void) {self.ammo_cells = 25;StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", 15, "cells", IT_CELLS, 0);}
 162 void item_shells (void) {self.ammo_shells = 15;StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", 15, "shells", IT_SHELLS, 0);}
 163
 164 void item_armor1 (void) {self.armorvalue = 5;StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", 0, 0);}
 165 void item_armor25 (void) {self.armorvalue = 100;StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", 0, 0);}
 166 void item_health1 (void) {self.max_health = 5;StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", 15, "5 Health", 0, 0);}
 167 void item_health25 (void) {self.max_health = 25;StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", 15, "25 Health", 0, 0);}
 168 void item_health100 (void) {self.max_health = 100;StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", 30, "100 Health", 0, 0);}
 169
 170 void item_strength (void) {self.strength_finished = 30;StartItem ("models/items/g_strength.md3", "misc/powerup.wav", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP);}
 171 void item_invincible (void) {self.invincible_finished = 30;StartItem ("models/items/g_invincible.md3", "misc/powerup.wav", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP);}
 172 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP);}
 173 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP);}
 174
 175 void misc_models (void)
 176 {
 177         precache_model (self.model);
 178         setmodel (self, self.model);
 179         setsize (self, self.mins, self.maxs);
 180 }
 181
 182