qcsrc/gamec/cl_player.c

   1 $frame die1 die2 draw duck duckwalk duckjump duckidle idle
   2 $frame jump pain1 pain2 shoot taunt run runbackwards
   3 $frame strafeleft straferight dead1 dead2 forwardright
   4 $frame forwardleft backright backleft
   5
   6 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   7 // merged player_run and player_stand to player_anim
   8 // added death animations to player_anim
   9 // can now spawn thrown weapons from anywhere, not just from players
  10 // thrown weapons now fade out after 20 seconds
  11 // created PlayerGib function
  12 // PlayerDie no longer uses hitloc or damage
  13 // PlayerDie now supports dying animations as well as gibbing
  14 // cleaned up PlayerDie a lot
  15 // added CopyBody
  16
  17 .entity pusher;
  18 .float pushltime;
  19
  20 void CopyBody(float keepvelocity)
  21 {
  22         local entity oldself;
  23         if (self.effects & EF_NODRAW)
  24                 return;
  25         oldself = self;
  26         self = spawn();
  27         self.iscreature = oldself.iscreature;
  28         self.angles = oldself.angles;
  29         self.avelocity = oldself.avelocity;
  30         self.classname = "body";
  31         self.damageforcescale = oldself.damageforcescale;
  32         self.effects = oldself.effects;
  33         self.event_damage = oldself.event_damage;
  34         self.frame = oldself.frame;
  35         self.health = oldself.health;
  36         self.armorvalue = oldself.armorvalue;
  37         self.armortype = oldself.armortype;
  38         self.model = oldself.model;
  39         self.modelindex = oldself.modelindex;
  40         self.movetype = oldself.movetype;
  41         self.nextthink = oldself.nextthink;
  42         self.skin = oldself.skin;
  43         self.solid = oldself.solid;
  44         self.takedamage = oldself.takedamage;
  45         self.think = oldself.think;
  46         if (keepvelocity == 1)
  47                 self.velocity = oldself.velocity;
  48         self.oldvelocity = self.velocity;
  49         self.fade_time = oldself.fade_time;
  50         self.fade_rate = oldself.fade_rate;
  51         //self.weapon = oldself.weapon;
  52         setorigin(self, oldself.origin);
  53         setsize(self, oldself.mins, oldself.maxs);//'-16 -16 -24',  '16 16 5');
  54         self.oldorigin = oldself.origin;
  55         self = oldself;
  56 }
  57
  58 void player_anim (void)
  59 {
  60         if (self.deadflag != DEAD_NO)
  61         {
  62                 if (time > self.dead_time)
  63                 {
  64                         if (self.maxs_z > 5)
  65                                 setsize(self, '-16 -16 -24', '16 16 5');
  66                         self.frame = self.dead_frame;
  67                 }
  68                 else
  69                         self.frame = self.die_frame;
  70                 return;
  71         }
  72
  73
  74         if (self.crouch)
  75         {
  76                 if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
  77                         self.frame = $duckwalk;
  78                 else
  79                         self.frame = $duckidle;
  80         }
  81         else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
  82         {
  83                 if (self.movement_x > 0 && self.movement_y == 0)
  84                         self.frame = $run;
  85                 else if (self.movement_x < 0 && self.movement_y == 0)
  86                         self.frame = $runbackwards;
  87                 else if (self.movement_x == 0 && self.movement_y > 0)
  88                         self.frame = $straferight;
  89                 else if (self.movement_x == 0 && self.movement_y < 0)
  90                         self.frame = $strafeleft;
  91                 else if (self.movement_x > 0 && self.movement_y > 0)
  92                         self.frame = $forwardright;
  93                 else if (self.movement_x > 0 && self.movement_y < 0)
  94                         self.frame = $forwardleft;
  95                 else if (self.movement_x < 0 && self.movement_y > 0)
  96                         self.frame = $backright;
  97                 else if (self.movement_x < 0 && self.movement_y < 0)
  98                         self.frame = $backleft;
  99                 else
 100                         self.frame = $run;
 101         }
 102         else if (self.pain_finished > time)
 103                 self.frame = self.pain_frame;
 104         else if (self.attack_finished > time)
 105                 self.frame = $shoot;
 106         else
 107                 self.frame = $idle;
 108
 109         if (!(self.flags & FL_ONGROUND))
 110                 self.frame = $jump;
 111 }
 112 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 113
 114 void SpawnThrownWeapon (vector org, float w)
 115 {
 116         local entity oldself;
 117
 118         if ((cvar("g_instagib") == 1) || (cvar("g_rocketarena") == 1))
 119                 return;
 120         if (w == IT_LASER)
 121                 return;
 122
 123         oldself = self;
 124         self = spawn();
 125         // this will cause it to be removed later
 126         self.classname = "droppedweapon";
 127
 128         setorigin(self, org);
 129         self.velocity = randomvec() * 100 + '0 0 200';
 130         SUB_SetFade(self, time + 20, 1);
 131
 132         if (w == WEP_UZI)
 133                 weapon_uzi ();
 134         else if (w == WEP_SHOTGUN)
 135                 weapon_shotgun ();
 136         else if (w == WEP_GRENADE_LAUNCHER)
 137                 weapon_grenadelauncher ();
 138         else if (w == WEP_ELECTRO)
 139                 weapon_electro ();
 140         else if (w == WEP_CRYLINK)
 141                 weapon_crylink ();
 142         else if (w == WEP_NEX)
 143                 weapon_nex ();
 144         else if (w == WEP_HAGAR)
 145                 weapon_hagar ();
 146         else if (w == WEP_ROCKET_LAUNCHER)
 147                 weapon_rocketlauncher ();
 148
 149         // making absolutely sure...
 150         self.classname = "droppedweapon";
 151
 152         self = oldself;
 153 }
 154
 155 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 156 {
 157         local float take, save;
 158         te_blood (hitloc, force, damage);
 159         // damage resistance (ignore most of the damage from a bullet or similar)
 160         damage = max(damage - 5, 1);
 161
 162         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 163         take = bound(0, damage - save, damage);
 164
 165         if (save > 10)
 166                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 167         else if (take > 30)
 168                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 169         else if (take > 10)
 170                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 171
 172         if (take > 50)
 173                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 174         if (take > 100)
 175                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 176
 177         if (!(self.flags & FL_GODMODE))
 178         {
 179                 self.armorvalue = self.armorvalue - save;
 180                 self.health = self.health - take;
 181                 // pause regeneration for 5 seconds
 182                 self.pauseregen_finished = max(self.pauseregen_finished, time + 5);
 183         }
 184         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 185         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 186         self.dmg_inflictor = inflictor;
 187
 188         if (self.health <= -50)
 189         {
 190                 // don't use any animations as a gib
 191                 self.frame = 0;
 192                 self.dead_frame = 0;
 193                 self.die_frame = 0;
 194                 // view just above the floor
 195                 self.view_ofs = '0 0 4';
 196
 197                 // make a juicy mess
 198                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 800, 1000);
 199                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 400, 1000);
 200
 201                 // make a meaty mess
 202                 TossGib (self, "models/gibs/eye.md3", self.origin, self.velocity,0);
 203                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin, '0 0 600',0);
 204
 205                 TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity,0);
 206                 TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity,0);
 207                 TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity,0);
 208                 TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity,0);
 209
 210                 // these destory on impact
 211                 TossGib (world, "models/gibs/gib5.md3", self.origin, '-500 0 450',1);
 212                 TossGib (world, "models/gibs/gib6.md3", self.origin, '0 500 450',1);
 213                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 -500 450',1);
 214                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '500 0 450',1);
 215                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity,1);
 216                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 0 450',1);
 217
 218                 sound (trace_ent, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 219         }
 220 }
 221
 222 void DropAllRunes(entity pl);
 223
 224
 225 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 226 {
 227         local float take, save;
 228
 229         te_blood (hitloc, force, damage);
 230         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 231         {
 232                 if (random() > 0.5)
 233                         self.pain_frame = $pain1;
 234                 else
 235                         self.pain_frame = $pain2;
 236                 self.pain_finished = time + 0.5;        //Supajoe
 237         }
 238
 239         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 240         take = bound(0, damage - save, damage);
 241
 242         if (save > 10)
 243                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 244         else if (take > 30)
 245                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 246         else if (take > 10)
 247                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 248
 249         if (take > 50)
 250                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 251         if (take > 100)
 252                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 253
 254         if (!(self.flags & FL_GODMODE))
 255         {
 256                 self.armorvalue = self.armorvalue - save;
 257                 self.health = self.health - take;
 258                 // pause regeneration for 5 seconds
 259                 self.pauseregen_finished = max(self.pauseregen_finished, time + 5);
 260         }
 261         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 262         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 263         self.dmg_inflictor = inflictor;
 264
 265         if(attacker == self)
 266         {
 267                 // don't reset pushltime for self damage as it may be an attempt to
 268                 // escape a lava pit or similar
 269                 //self.pushltime = 0;
 270         }
 271         else if(attacker.classname == "player" || attacker.classname == "gib")
 272         {
 273                 self.pusher = attacker;
 274                 self.pushltime = time + cvar("g_maxpushtime");
 275         }
 276         else if(time < self.pushltime)
 277         {
 278                 attacker = self.pusher;
 279                 self.pushltime = max(self.pushltime, time + 0.6);
 280         }
 281         else
 282                 self.pushltime = 0;
 283
 284         if (self.health <= 2)
 285         {
 286                 DropAllRunes(self);
 287
 288                 // throw a weapon
 289                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.weapon);
 290                 // print an obituary message
 291                 Obituary (attacker, self, deathtype);
 292                 // make the corpse upright (not tilted)
 293                 self.angles_x = 0;
 294                 self.angles_z = 0;
 295                 // don't spin
 296                 self.avelocity = '0 0 0';
 297                 // no weapon when dead
 298                 self.weaponmodel = "";
 299                 w_clear();
 300                 // view from the floor
 301                 self.view_ofs = '0 0 -8';
 302                 // toss the corpse
 303                 self.movetype = MOVETYPE_TOSS;
 304                 // shootable corpse
 305                 self.solid = SOLID_CORPSE;
 306                 // don't stick to the floor
 307                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 308                 // dying animation
 309                 self.deadflag = DEAD_DYING;
 310                 // when to allow respawn
 311                 self.death_time = time + 0.5;
 312                 // when to switch to the dead_frame
 313                 self.dead_time = time + 2;
 314                 if (random() < 0.5)
 315                 {
 316                         self.die_frame = $die1;
 317                         self.dead_frame = $dead1;
 318                 }
 319                 else
 320                 {
 321                         self.die_frame = $die2;
 322                         self.dead_frame = $dead2;
 323                 }
 324                 // start the animation
 325                 player_anim();
 326                 // set damage function to corpse damage
 327                 self.event_damage = PlayerCorpseDamage;
 328                 // call the corpse damage function just in case it wants to gib
 329                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 330                 // set up to fade out later
 331                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 332         }
 333 }
 334