qcsrc/gamec/cl_player.c

   1 $frame die1 die2 draw duck duckwalk duckjump duckidle idle
   2 $frame jump pain1 pain2 shoot taunt run runbackwards
   3 $frame strafeleft straferight dead1 dead2 forwardright
   4 $frame forwardleft backright backleft
   5
   6 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   7 // merged player_run and player_stand to player_anim
   8 // added death animations to player_anim
   9 // can now spawn thrown weapons from anywhere, not just from players
  10 // thrown weapons now fade out after 20 seconds
  11 // created PlayerGib function
  12 // PlayerDie no longer uses hitloc or damage
  13 // PlayerDie now supports dying animations as well as gibbing
  14 // cleaned up PlayerDie a lot
  15 // added CopyBody
  16
  17 void CopyBody(float keepvelocity)
  18 {
  19         local entity oldself;
  20         if (self.effects & EF_NODRAW)
  21                 return;
  22         oldself = self;
  23         self = spawn();
  24         self.angles = oldself.angles;
  25         self.avelocity = oldself.avelocity;
  26         self.classname = "body";
  27         self.damageforcescale = oldself.damageforcescale;
  28         self.effects = oldself.effects;
  29         self.event_damage = oldself.event_damage;
  30         self.frame = oldself.frame;
  31         self.health = oldself.health;
  32         self.model = oldself.model;
  33         self.modelindex = oldself.modelindex;
  34         self.movetype = oldself.movetype;
  35         self.nextthink = oldself.nextthink;
  36         self.skin = oldself.skin;
  37         self.solid = oldself.solid;
  38         self.takedamage = oldself.takedamage;
  39         self.think = oldself.think;
  40         if (keepvelocity == 1)
  41                 self.velocity = oldself.velocity;
  42         self.fade_time = oldself.fade_time;
  43         self.fade_rate = oldself.fade_rate;
  44         //self.weapon = oldself.weapon;
  45         setorigin(self, oldself.origin);
  46         setsize(self, oldself.mins, oldself.maxs);//'-16 -16 -24',  '16 16 5');
  47         self.oldorigin = oldself.origin;
  48         self = oldself;
  49 }
  50
  51 void player_anim (void)
  52 {
  53         if (self.deadflag != DEAD_NO)
  54         {
  55                 if (time > self.dead_time)
  56                 {
  57                         if (self.maxs_z > 5)
  58                                 setsize(self, '-16 -16 -24', '16 16 5');
  59                         self.frame = self.dead_frame;
  60                 }
  61                 else
  62                         self.frame = self.die_frame;
  63                 return;
  64         }
  65
  66
  67         if (self.crouch)
  68         {
  69                 if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
  70                         self.frame = $duckwalk;
  71                 else
  72                         self.frame = $duckidle;
  73         }
  74         else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
  75         {
  76                 if (self.movement_x > 0 && self.movement_y == 0)
  77                         self.frame = $run;
  78                 else if (self.movement_x < 0 && self.movement_y == 0)
  79                         self.frame = $runbackwards;
  80                 else if (self.movement_x == 0 && self.movement_y > 0)
  81                         self.frame = $straferight;
  82                 else if (self.movement_x == 0 && self.movement_y < 0)
  83                         self.frame = $strafeleft;
  84                 else if (self.movement_x > 0 && self.movement_y > 0)
  85                         self.frame = $forwardright;
  86                 else if (self.movement_x > 0 && self.movement_y < 0)
  87                         self.frame = $forwardleft;
  88                 else if (self.movement_x < 0 && self.movement_y > 0)
  89                         self.frame = $backright;
  90                 else if (self.movement_x < 0 && self.movement_y < 0)
  91                         self.frame = $backleft;
  92                 else
  93                         self.frame = $run;
  94         }
  95         else if (self.pain_finished > time)
  96                 self.frame = self.pain_frame;
  97         else if (self.attack_finished > time)
  98                 self.frame = $shoot;
  99         else
 100                 self.frame = $idle;
 101
 102         if (!(self.flags & FL_ONGROUND))
 103                 self.frame = $jump;
 104 }
 105 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 106
 107 void SpawnThrownWeapon (vector org, float w)
 108 {
 109         local entity oldself;
 110
 111         if ((cvar("g_instagib") == 1) | (cvar("g_rocketarena") == 1))
 112                 return;
 113         if (w == IT_LASER)
 114                 return;
 115
 116         oldself = self;
 117         self = spawn();
 118         // this will cause it to be removed later
 119         self.classname = "droppedweapon";
 120
 121         setorigin(self, org);
 122         self.velocity = randomvec() * 100 + '0 0 200';
 123         SUB_SetFade(self, time + 20, 1);
 124
 125         if (w == WEP_UZI)
 126                 weapon_uzi ();
 127         else if (w == WEP_SHOTGUN)
 128                 weapon_shotgun ();
 129         else if (w == WEP_GRENADE_LAUNCHER)
 130                 weapon_grenadelauncher ();
 131         else if (w == WEP_ELECTRO)
 132                 weapon_electro ();
 133         else if (w == WEP_CRYLINK)
 134                 weapon_crylink ();
 135         else if (w == WEP_NEX)
 136                 weapon_nex ();
 137         else if (w == WEP_HAGAR)
 138                 weapon_hagar ();
 139         else if (w == WEP_ROCKET_LAUNCHER)
 140                 weapon_rocketlauncher ();
 141
 142         self = oldself;
 143 }
 144
 145 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 146 {
 147         local float take, save;
 148         te_blood (hitloc, force, damage);
 149         // damage resistance (ignore most of the damage from a bullet or similar)
 150         damage = max(damage - 5, 1);
 151         save = bound(0, damage * 0.6, self.armorvalue);
 152         take = bound(0, damage - save, damage);
 153         self.armorvalue = self.armorvalue - save;
 154         self.health = self.health - take;
 155         self.dmg_save = self.dmg_save + save;
 156         self.dmg_take = self.dmg_take + take;
 157         self.dmg_inflictor = inflictor;
 158         if (self.health <= -50)
 159         {
 160                 // don't use any animations as a gib
 161                 self.frame = 0;
 162                 self.dead_frame = 0;
 163                 self.die_frame = 0;
 164                 // view just above the floor
 165                 self.view_ofs = '0 0 4';
 166
 167                 // make a juicy mess
 168                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 800, 1000);
 169                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 400, 1000);
 170
 171                 // make a meaty mess
 172                 TossGib (self, "models/gibs/eye.md3", self.origin, self.velocity,0);
 173                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin, '0 0 600',0);
 174
 175                 TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity,0);
 176                 TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity,0);
 177                 TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity,0);
 178                 TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity,0);
 179
 180                 // these destory on impact
 181                 TossGib (world, "models/gibs/gib5.md3", self.origin, '-500 0 450',1);
 182                 TossGib (world, "models/gibs/gib6.md3", self.origin, '0 500 450',1);
 183                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 -500 450',1);
 184                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '500 0 450',1);
 185                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity,1);
 186                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 0 450',1);
 187
 188                 sound (trace_ent, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 189         }
 190 }
 191
 192 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 193 {
 194         local float take, save;
 195
 196          te_blood (hitloc, force, damage);
 197         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 198         {
 199                 if (random() > 0.5)
 200                         self.pain_frame = $pain1;
 201                 else
 202                         self.pain_frame = $pain2;
 203                 self.pain_finished = time + 0.5;        //Supajoe
 204         }
 205
 206         save = bound(0, damage * 0.6, self.armorvalue);
 207         take = bound(0, damage - save, damage);
 208
 209         if (save > 10)
 210                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 211         if (take > 10)
 212                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 213         if (take > 30)
 214                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 215
 216         if (take > 50)
 217                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 218         if (take > 100)
 219                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 220
 221         if (!(self.flags & FL_GODMODE))
 222         {
 223                 self.armorvalue = self.armorvalue - save;
 224                 self.health = self.health - take;
 225         }
 226         self.dmg_save = self.dmg_save + max(save - 10, 0);
 227         self.dmg_take = self.dmg_take + max(take - 10, 0);
 228         self.dmg_inflictor = inflictor;
 229         if (self.health <= 2)
 230         {
 231                 // throw a weapon
 232                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.weapon);
 233                 // print an obituary message
 234                 Obituary (attacker, self, deathtype);
 235                 // make the corpse upright (not tilted)
 236                 self.angles_x = 0;
 237                 self.angles_z = 0;
 238                 // don't spin
 239                 self.avelocity = '0 0 0';
 240                 // no weapon when dead
 241                 self.weaponmodel = "";
 242                 w_clear();
 243                 // view from the floor
 244                 self.view_ofs = '0 0 -8';
 245                 // toss the corpse
 246                 self.movetype = MOVETYPE_TOSS;
 247                 // shootable corpse
 248                 self.solid = SOLID_CORPSE;
 249                 // don't stick to the floor
 250                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 251                 // dying animation
 252                 self.deadflag = DEAD_DYING;
 253                 // when to allow respawn
 254                 self.death_time = time + 0.5;
 255                 // when to switch to the dead_frame
 256                 self.dead_time = time + 2;
 257                 if (random() < 0.5)
 258                 {
 259                         self.die_frame = $die1;
 260                         self.dead_frame = $dead1;
 261                 }
 262                 else
 263                 {
 264                         self.die_frame = $die2;
 265                         self.dead_frame = $dead2;
 266                 }
 267                 // start the animation
 268                 player_anim();
 269                 // set damage function to corpse damage
 270                 self.event_damage = PlayerCorpseDamage;
 271                 // call the corpse damage function just in case it wants to gib
 272                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 273                 // set up to fade out later
 274                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 275         }
 276 }
 277