qcsrc/gamec/cl_player.c

   1 $frame die1 die2 draw duck duckwalk duckjump duckidle idle
   2 $frame jump pain1 pain2 shoot taunt run runbackwards
   3 $frame strafeleft straferight dead1 dead2 forwardright
   4 $frame forwardleft backright backleft
   5
   6 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   7 // merged player_run and player_stand to player_anim
   8 // added death animations to player_anim
   9 // can now spawn thrown weapons from anywhere, not just from players
  10 // thrown weapons now fade out after 20 seconds
  11 // created PlayerGib function
  12 // PlayerDie no longer uses hitloc or damage
  13 // PlayerDie now supports dying animations as well as gibbing
  14 // cleaned up PlayerDie a lot
  15 // added CopyBody
  16
  17 void CopyBody(float keepvelocity)
  18 {
  19         local entity oldself;
  20         if (self.effects & EF_NODRAW)
  21                 return;
  22         oldself = self;
  23         self = spawn();
  24         self.angles = oldself.angles;
  25         self.avelocity = oldself.avelocity;
  26         self.classname = "body";
  27         self.damageforcescale = oldself.damageforcescale;
  28         self.effects = oldself.effects;
  29         self.event_damage = oldself.event_damage;
  30         self.frame = oldself.frame;
  31         self.health = oldself.health;
  32         self.model = oldself.model;
  33         self.modelindex = oldself.modelindex;
  34         self.movetype = oldself.movetype;
  35         self.nextthink = oldself.nextthink;
  36         self.skin = oldself.skin;
  37         self.solid = oldself.solid;
  38         self.takedamage = oldself.takedamage;
  39         self.think = oldself.think;
  40         if (keepvelocity == 1)
  41                 self.velocity = oldself.velocity;
  42         //self.weapon = oldself.weapon;
  43         setorigin(self, oldself.origin);
  44         setsize(self, '-16 -16 -24',  '16 16 5');
  45         self = oldself;
  46 }
  47
  48 void player_anim (void)
  49 {
  50         if (self.deadflag != DEAD_NO)
  51         {
  52                 if (time > self.dead_time)
  53                         self.frame = self.dead_frame;
  54                 else
  55                         self.frame = self.die_frame;
  56                 return;
  57         }
  58
  59
  60         if (self.crouch)
  61         {
  62                 if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
  63                         self.frame = $duckwalk;
  64                 else
  65                         self.frame = $duckidle;
  66         }
  67         else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
  68         {
  69                 if (self.movement_x > 0 && self.movement_y == 0)
  70                         self.frame = $run;
  71                 else if (self.movement_x < 0 && self.movement_y == 0)
  72                         self.frame = $runbackwards;
  73                 else if (self.movement_x == 0 && self.movement_y > 0)
  74                         self.frame = $straferight;
  75                 else if (self.movement_x == 0 && self.movement_y < 0)
  76                         self.frame = $strafeleft;
  77                 else if (self.movement_x > 0 && self.movement_y > 0)
  78                         self.frame = $forwardright;
  79                 else if (self.movement_x > 0 && self.movement_y < 0)
  80                         self.frame = $forwardleft;
  81                 else if (self.movement_x < 0 && self.movement_y > 0)
  82                         self.frame = $backright;
  83                 else if (self.movement_x < 0 && self.movement_y < 0)
  84                         self.frame = $backleft;
  85                 else
  86                         self.frame = $run;
  87         }
  88         else if (self.pain_finished > time)
  89                 self.frame = self.pain_frame;
  90         else if (self.attack_finished > time)
  91                 self.frame = $shoot;
  92         else
  93                 self.frame = $idle;
  94
  95         if (!(self.flags & FL_ONGROUND))
  96                 self.frame = $jump;
  97 }
  98 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
  99
 100 void SpawnThrownWeapon (vector org, float w)
 101 {
 102         local entity oldself;
 103
 104         if ((cvar("g_instagib") == 1) | (cvar("g_rocketarena") == 1))
 105                 return;
 106         if (w == IT_LASER)
 107                 return;
 108
 109         oldself = self;
 110         self = spawn();
 111         // this will cause it to be removed later
 112         self.classname = "droppedweapon";
 113
 114         setorigin(self, org);
 115         self.velocity = randomvec() * 100 + '0 0 200';
 116         SUB_SetFade(self, time + 20, 1);
 117
 118         if (w == WEP_UZI)
 119                 weapon_uzi ();
 120         else if (w == WEP_SHOTGUN)
 121                 weapon_shotgun ();
 122         else if (w == WEP_GRENADE_LAUNCHER)
 123                 weapon_grenadelauncher ();
 124         else if (w == WEP_ELECTRO)
 125                 weapon_electro ();
 126         else if (w == WEP_CRYLINK)
 127                 weapon_crylink ();
 128         else if (w == WEP_NEX)
 129                 weapon_nex ();
 130         else if (w == WEP_HAGAR)
 131                 weapon_hagar ();
 132         else if (w == WEP_ROCKET_LAUNCHER)
 133                 weapon_rocketlauncher ();
 134
 135         self = oldself;
 136 }
 137
 138 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 139 {
 140         local float take, save;
 141         te_blood (hitloc, force, damage);
 142         // damage resistance (ignore most of the damage from a bullet or similar)
 143         damage = max(damage - 5, 1);
 144         save = bound(0, damage * 0.6, self.armorvalue);
 145         take = bound(0, damage - save, damage);
 146         self.armorvalue = self.armorvalue - save;
 147         self.health = self.health - take;
 148         self.dmg_save = self.dmg_save + save;
 149         self.dmg_take = self.dmg_take + take;
 150         self.dmg_inflictor = inflictor;
 151         if (self.health <= -50)
 152         {
 153                 // don't use any animations as a gib
 154                 self.frame = 0;
 155                 self.dead_frame = 0;
 156                 self.die_frame = 0;
 157                 // view just above the floor
 158                 self.view_ofs = '0 0 4';
 159
 160                 // make a juicy mess
 161                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 800, 1000);
 162                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 400, 1000);
 163
 164                 // make a meaty mess
 165                 TossGib (self, "models/gibs/eye.md3", self.origin, self.velocity,0);
 166                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin, '0 0 600',0);
 167
 168                 TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity,0);
 169                 TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity,0);
 170                 TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity,0);
 171                 TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity,0);
 172
 173                 // these destory on impact
 174                 TossGib (world, "models/gibs/gib5.md3", self.origin, '-500 0 450',1);
 175                 TossGib (world, "models/gibs/gib6.md3", self.origin, '0 500 450',1);
 176                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 -500 450',1);
 177                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '500 0 450',1);
 178                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity,1);
 179                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 0 450',1);
 180
 181                 sound (trace_ent, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 182         }
 183 }
 184
 185 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 186 {
 187         local float take, save;
 188
 189          te_blood (hitloc, force, damage);
 190         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 191         {
 192                 if (random() > 0.5)
 193                         self.pain_frame = $pain1;
 194                 else
 195                         self.pain_frame = $pain2;
 196                 self.pain_finished = time + 0.5;        //Supajoe
 197         }
 198
 199         save = bound(0, damage * 0.6, self.armorvalue);
 200         take = bound(0, damage - save, damage);
 201
 202         if (save > 10)
 203                 sound (self, CHAN_BODY, "misc/armorimpact.wav", 1, ATTN_NORM);
 204         if (take > 10)
 205                 sound (self, CHAN_BODY, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 206         if (take > 30)
 207                 sound (self, CHAN_BODY, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 208
 209         if (take > 50)
 210                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 211         if (take > 100)
 212                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 213
 214         if (!(self.flags & FL_GODMODE))
 215         {
 216                 self.armorvalue = self.armorvalue - save;
 217                 self.health = self.health - take;
 218         }
 219         self.dmg_save = self.dmg_save + max(save - 10, 0);
 220         self.dmg_take = self.dmg_take + max(take - 10, 0);
 221         self.dmg_inflictor = inflictor;
 222         if (self.health <= 2)
 223         {
 224                 // throw a weapon
 225                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.weapon);
 226                 // print an obituary message
 227                 Obituary (attacker, self, deathtype);
 228                 // make the corpse upright (not tilted)
 229                 self.angles_x = 0;
 230                 self.angles_z = 0;
 231                 // don't spin
 232                 self.avelocity = '0 0 0';
 233                 // no weapon when dead
 234                 self.weaponmodel = "";
 235                 w_clear();
 236                 // view from the floor
 237                 self.view_ofs = '0 0 -8';
 238                 // toss the corpse
 239                 self.movetype = MOVETYPE_TOSS;
 240                 // shootable corpse
 241                 self.solid = SOLID_CORPSE;
 242                 // don't stick to the floor
 243                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 244                 // dying animation
 245                 self.deadflag = DEAD_DYING;
 246                 // when to allow respawn
 247                 self.death_time = time + 0.5;
 248                 // when to switch to the dead_frame
 249                 self.dead_time = time + 2;
 250                 if (random() < 0.5)
 251                 {
 252                         self.die_frame = $die1;
 253                         self.dead_frame = $dead1;
 254                 }
 255                 else
 256                 {
 257                         self.die_frame = $die2;
 258                         self.dead_frame = $dead2;
 259                 }
 260                 // start the animation
 261                 player_anim();
 262                 // set damage function to corpse damage
 263                 self.event_damage = PlayerCorpseDamage;
 264                 // call the corpse damage function just in case it wants to gib
 265                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 266                 // set up to fade out later
 267                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 268         }
 269 }
 270