qcsrc/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8 }
   9
  10 /*
  11 =============
  12 SelectSpawnPoint
  13
  14 Finds a point to respawn
  15 =============
  16 */
  17 entity SelectSpawnPoint (void)
  18 {
  19         local entity spot, thing;
  20         local float pcount;
  21
  22         spot = find (world, classname, "testplayerstart");
  23         if (spot)
  24                 return spot;
  25
  26         spot = lastspawn;
  27         while (1)
  28         {
  29                 spot = find(spot, classname, "info_player_deathmatch");
  30                 if (spot != world)
  31                 {
  32                         if (spot == lastspawn)
  33                                 return lastspawn;
  34                         pcount = 0;
  35                         thing = findradius(spot.origin, 70);
  36                         while(thing)
  37                         {
  38                                 if (thing.classname == "player")
  39                                         pcount = pcount + 1;
  40                                 thing = thing.chain;
  41                         }
  42                         if (pcount == 0)
  43                         {
  44                                 lastspawn = spot;
  45                                 return spot;
  46                         }
  47                 }
  48         }
  49
  50         spot = find (world, classname, "info_player_start");
  51         if (!spot)
  52                 error ("PutClientInServer: no info_player_start on level");
  53
  54         return spot;
  55 }
  56
  57
  58 /*
  59 =============
  60 PutClientInServer
  61
  62 Called when a client spawns in the server
  63 =============
  64 */
  65 void PutClientInServer (void)
  66 {
  67         entity  spot;
  68         float mdlrandom;
  69
  70         spot = SelectSpawnPoint ();
  71
  72         self.classname = "player";
  73         self.movetype = MOVETYPE_WALK;
  74         self.solid = SOLID_SLIDEBOX;
  75         self.flags = FL_CLIENT;
  76         self.takedamage = DAMAGE_YES;
  77         self.effects = 0;
  78         self.health = cvar("g_balance_health");
  79         self.damageforcescale = 2;
  80         self.death_time = 0;
  81         self.dead_time = 0;
  82         self.dead_frame = 0;
  83         self.die_frame = 0;
  84         self.alpha = 0;
  85         self.scale = 0;
  86         self.fade_time = 0;
  87         self.pain_frame = 0;
  88         self.pain_finished = 0;
  89         self.strength_finished = 0;
  90         self.invincible_finished = 0;
  91         //self.speed_finished = 0;
  92         //self.slowmo_finished = 0;
  93         // players have no think function
  94         self.think = nullfunction;
  95         self.nextthink = 0;
  96
  97         self.deadflag = DEAD_NO;
  98
  99         self.angles = spot.angles;
 100         self.fixangle = TRUE; // turn this way immediately
 101         self.velocity = '0 0 0';
 102         self.avelocity = '0 0 0';
 103         self.punchangle = '0 0 0';
 104         self.punchvector = '0 0 0';
 105
 106         self.viewzoom = 0.6;
 107
 108         // Savage: Insufficient check for invalid playermodels
 109         if(strlen(self.playermodel) < 15) self.playermodel = "models/player/marine.zym";
 110
 111         setmodel (self, self.playermodel);
 112         self.skin = stof(self.playerskin);
 113         self.crouch = FALSE;
 114         self.view_ofs = PL_VIEW_OFS;
 115         setsize (self, PL_MIN, PL_MAX);
 116         setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 117         // don't reset back to last position, even if new position is stuck in solid
 118         self.oldorigin = self.origin;
 119
 120 //      self.items = IT_LASER | IT_UZI| IT_SHOTGUN | IT_GRENADE_LAUNCHER | IT_ELECTRO | IT_CRYLINK | IT_NEX | IT_HAGAR | IT_ROCKET_LAUNCHER;
 121 //      self.weapon = IT_UZI;
 122
 123         if (cvar("g_instagib") == 1)
 124         {
 125                 self.items = IT_NEX;
 126                 self.switchweapon = WEP_NEX;
 127                 self.ammo_shells = 0;
 128                 self.ammo_nails = 0;
 129                 self.ammo_rockets = 0;
 130                 self.ammo_cells = 999;
 131         }
 132         else if (cvar("g_rocketarena") == 1)
 133         {
 134                 self.items = IT_ROCKET_LAUNCHER;
 135                 self.switchweapon = WEP_ROCKET_LAUNCHER;
 136                 self.ammo_shells = 0;
 137                 self.ammo_nails = 0;
 138                 self.ammo_rockets = 999;
 139                 self.ammo_cells = 0;
 140         }
 141         else
 142         {
 143                 self.items = IT_LASER | IT_SHOTGUN;
 144                 self.switchweapon = WEP_SHOTGUN;
 145                 self.ammo_shells = 50;
 146                 self.ammo_nails = 0;
 147                 self.ammo_rockets = 0;
 148                 self.ammo_cells = 0;
 149         }
 150
 151         if (cvar("g_fullbrightplayers") == 1)
 152                 self.effects = EF_FULLBRIGHT;
 153
 154         self.event_damage = PlayerDamage;
 155
 156         self.statdraintime = time + 5;
 157         self.button0 = self.button1 = self.button2 = self.button3 = 0;
 158
 159         /*
 160         W_UpdateWeapon();
 161         W_UpdateAmmo();
 162         */
 163         CL_SpawnWeaponentity();
 164
 165         //stuffcmd(self, "chase_active 0");
 166 }
 167
 168 /*
 169 =============
 170 SetNewParms
 171 =============
 172 */
 173 void SetNewParms (void)
 174 {
 175
 176 }
 177
 178 /*
 179 =============
 180 SetChangeParms
 181 =============
 182 */
 183 void SetChangeParms (void)
 184 {
 185
 186 }
 187
 188 /*
 189 =============
 190 ClientKill
 191
 192 Called when a client types 'kill' in the console
 193 =============
 194 */
 195 void ClientKill (void)
 196 {
 197         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 198 }
 199
 200 /*
 201 =============
 202 ClientConnect
 203
 204 Called when a client connects to the server
 205 =============
 206 */
 207 void ClientConnect (void)
 208 {
 209         ClientInRankings();
 210         bprint ("^4",self.netname);
 211         bprint (" connected\n");
 212         stuffcmd(self, "exec maps/");
 213         stuffcmd(self, mapname);
 214         stuffcmd(self, ".cfg\n");
 215 }
 216
 217 /*
 218 =============
 219 ClientDisconnect
 220
 221 Called when a client disconnects from the server
 222 =============
 223 */
 224 void ClientDisconnect (void)
 225 {
 226         ClientDisconnected();
 227         bprint ("^4",self.netname);
 228         bprint (" disconnected\n");
 229 }
 230
 231 .entity chatbubbleentity;
 232 .float buttonchat;
 233 void() ChatBubbleThink =
 234 {
 235         self.nextthink = time;
 236         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 237         {
 238                 remove(self);
 239                 return;
 240         }
 241         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 242         if (self.owner.buttonchat)
 243                 self.effects = 0;
 244         else
 245                 self.effects = EF_NODRAW;
 246 };
 247
 248 void() UpdateChatBubble =
 249 {
 250         if (!self.modelindex)
 251                 return;
 252         // spawn a chatbubble entity if needed
 253         if (!self.chatbubbleentity)
 254         {
 255                 self.chatbubbleentity = spawn();
 256                 self.chatbubbleentity.owner = self;
 257                 self.chatbubbleentity.think = ChatBubbleThink;
 258                 self.chatbubbleentity.nextthink = time;
 259                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 260                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 261                 self.chatbubbleentity.effects = EF_NODRAW;
 262         }
 263 }
 264
 265 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 266 // added to the model skins
 267 void() UpdateColorModHack =
 268 {
 269         local float c;
 270         c = self.clientcolors & 15;
 271         // LordHavoc: only bothering to support white, green, red, yellow, blue
 272              if (teamplay == 0) self.colormod = '0 0 0';
 273         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 274         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 275         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 276         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 277         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 278         else self.colormod = '1 1 1';
 279 };
 280
 281 /*
 282 =============
 283 PlayerJump
 284
 285 When you press the jump key
 286 =============
 287 */
 288 void PlayerJump (void)
 289 {
 290         if (self.waterlevel >= 2)
 291         {
 292                 if (self.watertype == CONTENT_WATER)
 293                         self.velocity_z = 200;
 294                 else if (self.watertype == CONTENT_SLIME)
 295                         self.velocity_z = 80;
 296                 else
 297                         self.velocity_z = 50;
 298
 299                 return;
 300         }
 301
 302
 303         if (!(self.flags & FL_ONGROUND))
 304                 return;
 305
 306         if (!(self.flags & FL_JUMPRELEASED))
 307                 return;
 308
 309         self.velocity_z = self.velocity_z + cvar("g_balance_jumpheight");
 310
 311         self.flags = self.flags - FL_ONGROUND;
 312         self.flags = self.flags - FL_JUMPRELEASED;
 313 }
 314
 315 void() WaterMove =
 316 {
 317         if (self.movetype == MOVETYPE_NOCLIP)
 318                 return;
 319         if (self.health < 0)
 320                 return;
 321
 322         if (self.waterlevel != 3)
 323         {
 324                 self.air_finished = time + 12;
 325                 self.dmg = 2;
 326         }
 327         else if (self.air_finished < time)
 328         {       // drown!
 329                 if (self.pain_finished < time)
 330                 {
 331                         Damage (self, world, world, 5, DEATH_DROWN, self.origin, '0 0 0');
 332                         self.pain_finished = time + 0.5;
 333                 }
 334         }
 335
 336         if (!self.waterlevel)
 337         {
 338                 if (self.flags & FL_INWATER)
 339                 {
 340                         // play leave water sound
 341                         self.flags = self.flags - FL_INWATER;
 342                 }
 343                 return;
 344         }
 345
 346         if (self.watertype == CONTENT_LAVA)
 347         {       // do damage
 348                 if (self.dmgtime < time)
 349                 {
 350                         self.dmgtime = time + 0.1;
 351                         Damage (self, world, world, 3 * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
 352                 }
 353         }
 354         else if (self.watertype == CONTENT_SLIME)
 355         {       // do damage
 356                 if (self.dmgtime < time)
 357                 {
 358                         self.dmgtime = time + 0.1;
 359                         Damage (self, world, world, 1 * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
 360                 }
 361         }
 362
 363         if ( !(self.flags & FL_INWATER) )
 364         {
 365
 366                 //if (self.watertype == CONTENT_LAVA)
 367                 //      sound (self, CHAN_BODY, "player/inlava.wav", 1, ATTN_NORM);
 368                 //if (self.watertype == CONTENT_WATER)
 369                 //      sound (self, CHAN_BODY, "player/inh2o.wav", 1, ATTN_NORM);
 370                 //if (self.watertype == CONTENT_SLIME)
 371                 //      sound (self, CHAN_BODY, "player/slimbrn2.wav", 1, ATTN_NORM);
 372
 373                 self.flags = self.flags + FL_INWATER;
 374                 self.dmgtime = 0;
 375         }
 376 };
 377
 378 void() CheckWaterJump =
 379 {
 380         local vector start, end;
 381
 382 // check for a jump-out-of-water
 383         makevectors (self.angles);
 384         start = self.origin;
 385         start_z = start_z + 8;
 386         v_forward_z = 0;
 387         normalize(v_forward);
 388         end = start + v_forward*24;
 389         traceline (start, end, TRUE, self);
 390         if (trace_fraction < 1)
 391         {       // solid at waist
 392                 start_z = start_z + self.maxs_z - 8;
 393                 end = start + v_forward*24;
 394                 self.movedir = trace_plane_normal * -50;
 395                 traceline (start, end, TRUE, self);
 396                 if (trace_fraction == 1)
 397                 {       // open at eye level
 398                         self.flags = self.flags | FL_WATERJUMP;
 399                         self.velocity_z = 225;
 400                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 401                         self.teleport_time = time + 2;  // safety net
 402                         return;
 403                 }
 404         }
 405 };
 406
 407
 408 void respawn(void)
 409 {
 410         CopyBody(1);
 411         PutClientInServer();
 412 }
 413
 414 void player_powerups (void)
 415 {
 416         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 417         if (self.items & IT_STRENGTH)
 418         {
 419                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 420                 if (time > self.strength_finished)
 421                 {
 422                         self.items = self.items - (self.items & IT_STRENGTH);
 423                         sprint(self, "^3Strength has worn off\n");
 424                 }
 425         }
 426         else
 427         {
 428                 if (time < self.strength_finished)
 429                 {
 430                         self.items = self.items | IT_STRENGTH;
 431                         sprint(self, "^3Strength infuses your weapons with devestating power\n");
 432                 }
 433         }
 434         if (self.items & IT_INVINCIBLE)
 435         {
 436                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
 437                 if (time > self.invincible_finished)
 438                 {
 439                         self.items = self.items - (self.items & IT_INVINCIBLE);
 440                         sprint(self, "^3Invincible has worn off\n");
 441                 }
 442         }
 443         else
 444         {
 445                 if (time < self.invincible_finished)
 446                 {
 447                         self.items = self.items | IT_INVINCIBLE;
 448                         sprint(self, "^3Invincible shielding surrounds you\n");
 449                 }
 450         }
 451 }
 452
 453 void player_regen (void)
 454 {
 455         if (self.health >= 100 || time > self.pain_finished)
 456                 self.health = bound(0, self.health + (100 - self.health) * cvar("g_balance_healthregen") * frametime, 1000);
 457         if (self.armorvalue > 100)
 458                 self.armorvalue = bound(100, self.armorvalue + (100 - self.armorvalue) * cvar("g_balance_armorrott") * frametime, 1000);
 459 }
 460
 461 /*
 462 =============
 463 PlayerPreThink
 464
 465 Called every frame for each client before the physics are run
 466 =============
 467 */
 468 .float attack_finished;
 469 void PlayerPreThink (void)
 470 {
 471         local vector m1, m2;
 472
 473         if (BotPreFrame())
 474                 return;
 475
 476         CheckRules();
 477
 478         if (intermission_running)
 479         {
 480                 IntermissionThink ();   // otherwise a button could be missed between
 481                 return;                                 // the think tics
 482         }
 483
 484         if (self.deadflag != DEAD_NO)
 485         {
 486                 player_anim();
 487                 weapon_freeze();
 488                 if (self.deadflag == DEAD_DYING)
 489                 {
 490                         if (time > self.dead_time)
 491                                 self.deadflag = DEAD_DEAD;
 492                 }
 493                 else if (self.deadflag == DEAD_DEAD)
 494                 {
 495                         if (!self.button0 && !self.button2 && !self.button3)
 496                                 self.deadflag = DEAD_RESPAWNABLE;
 497                 }
 498                 else if (self.deadflag == DEAD_RESPAWNABLE)
 499                 {
 500                         if (self.button0 || self.button2 || self.button3  || self.button4)
 501                                 respawn();
 502                 }
 503                 return;
 504         }
 505
 506         if (self.button5)
 507         {
 508                 if (!self.crouch)
 509                 {
 510                         self.crouch = TRUE;
 511                         self.view_ofs = PL_CROUCH_VIEW_OFS;
 512                         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
 513                 }
 514         }
 515         else
 516         {
 517                 if (self.crouch)
 518                 {
 519                         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
 520                         if (!trace_startsolid)
 521                         {
 522                                 self.crouch = FALSE;
 523                                 self.view_ofs = PL_VIEW_OFS;
 524                                 setsize (self, PL_MIN, PL_MAX);
 525                         }
 526                 }
 527         }
 528
 529         if (self.playermodel != self.model)
 530         {
 531                 m1 = self.mins;
 532                 m2 = self.maxs;
 533                 setmodel (self, self.playermodel);
 534                 setsize (self, m1, m2);
 535         }
 536
 537         if (self.skin != stof(self.playerskin))
 538                 self.skin = stof(self.playerskin);
 539
 540         W_WeaponFrame();
 541
 542         if (self.button4)
 543         {
 544                 if (self.viewzoom > 0.4)
 545                         self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
 546         }
 547         else if (self.viewzoom < 1.0)
 548                 self.viewzoom = min (1.0, self.viewzoom + frametime);
 549
 550
 551         if (self.button2)
 552                 PlayerJump ();
 553         else
 554                 self.flags = self.flags | FL_JUMPRELEASED;
 555
 556
 557         player_powerups();
 558         player_regen();
 559         player_anim();
 560
 561         self.angles_y=self.v_angle_y + 90;   // temp
 562
 563         WaterMove ();
 564         if (self.waterlevel == 2)
 565                 CheckWaterJump ();
 566
 567         //if (TetrisPreFrame()) return;
 568 }
 569
 570 /*
 571 =============
 572 PlayerPostThink
 573
 574 Called every frame for each client after the physics are run
 575 =============
 576 */
 577 void PlayerPostThink (void)
 578 {
 579         float soundrandom;
 580         if (BotPostFrame())
 581                 return;
 582         CheckRules();
 583         UpdateChatBubble();
 584         UpdateColorModHack();
 585         if (self.deadflag == DEAD_NO)
 586         if (self.impulse)
 587                 ImpulseCommands ();
 588         if (intermission_running)
 589                 return;         // intermission or finale
 590
 591         // VorteX: landing on floor, landing damage etc.
 592         // LordHavoc: removed 'big fall' death code that VorteX added
 593         if (self.flags & FL_ONGROUND)
 594         {
 595                 if (self.jump_flag < -100 && !self.watertype == CONTENT_WATER) // HitGround
 596                 {
 597                         soundrandom = random() * 4;
 598                         if (soundrandom < 1)
 599                                 sound (self, CHAN_BODY, "misc/hitground1.wav", 1, ATTN_NORM);
 600                         else if (soundrandom < 2)
 601                                 sound (self, CHAN_BODY, "misc/hitground2.wav", 1, ATTN_NORM);
 602                         else if (soundrandom < 3)
 603                                 sound (self, CHAN_BODY, "misc/hitground3.wav", 1, ATTN_NORM);
 604                         else if (soundrandom < 4)
 605                                 sound (self, CHAN_BODY, "misc/hitground4.wav", 1, ATTN_NORM);
 606                         if (self.jump_flag < -650) // landing damage
 607                         {
 608                                 local float dm;
 609                                 dm = bound(0, 0.1*(fabs(self.jump_flag) - 600), 5);
 610                                 Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
 611                         }
 612                         self.jump_flag = 0;
 613                 }
 614         }
 615         else
 616                 self.jump_flag = self.velocity_z;
 617
 618         //if (TetrisPostFrame()) return;
 619 }