qcsrc/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8 }
   9
  10 /*
  11 =============
  12 SelectSpawnPoint
  13
  14 Finds a point to respawn
  15 =============
  16 */
  17 entity SelectSpawnPoint (void)
  18 {
  19         local entity spot, thing;
  20         local float pcount;
  21
  22         spot = find (world, classname, "testplayerstart");
  23         if (spot)
  24                 return spot;
  25
  26         spot = lastspawn;
  27         while (1)
  28         {
  29                 spot = find(spot, classname, "info_player_deathmatch");
  30                 if (spot != world)
  31                 {
  32                         if (spot == lastspawn)
  33                                 return lastspawn;
  34                         pcount = 0;
  35                         thing = findradius(spot.origin, 70);
  36                         while(thing)
  37                         {
  38                                 if (thing.classname == "player")
  39                                         pcount = pcount + 1;
  40                                 thing = thing.chain;
  41                         }
  42                         if (pcount == 0)
  43                         {
  44                                 lastspawn = spot;
  45                                 return spot;
  46                         }
  47                 }
  48         }
  49
  50         spot = find (world, classname, "info_player_start");
  51         if (!spot)
  52                 error ("PutClientInServer: no info_player_start on level");
  53
  54         return spot;
  55 }
  56
  57 /*
  58 =============
  59 CheckPlayerModel
  60
  61 Checks if the argument string can be a valid playermodel.
  62 Returns a valid one in doubt.
  63 =============
  64 */
  65 string CheckPlayerModel(string playermodel) {
  66         if( substring(playermodel,0,14) != "models/player/") playermodel = "models/player/marine.zym";
  67
  68         /* Possible Fixme: Check if server can open the model?
  69            This would kill custom models, however. */
  70
  71         return playermodel;
  72 }
  73
  74
  75 /*
  76 =============
  77 PutClientInServer
  78
  79 Called when a client spawns in the server
  80 =============
  81 */
  82 void PutClientInServer (void)
  83 {
  84         entity  spot;
  85
  86         spot = SelectSpawnPoint ();
  87
  88         self.classname = "player";
  89         self.movetype = MOVETYPE_WALK;
  90         self.solid = SOLID_SLIDEBOX;
  91         self.flags = FL_CLIENT;
  92         self.takedamage = DAMAGE_YES;
  93         self.effects = 0;
  94         self.health = cvar("g_balance_health_start");
  95         self.armorvalue = cvar("g_balance_armor_start");
  96         self.damageforcescale = 2;
  97         self.death_time = 0;
  98         self.dead_time = 0;
  99         self.dead_frame = 0;
 100         self.die_frame = 0;
 101         self.alpha = 0;
 102         self.scale = 0;
 103         self.fade_time = 0;
 104         self.pain_frame = 0;
 105         self.pain_finished = 0;
 106         self.strength_finished = 0;
 107         self.invincible_finished = 0;
 108         //self.speed_finished = 0;
 109         //self.slowmo_finished = 0;
 110         // players have no think function
 111         self.think = SUB_Null;
 112         self.nextthink = 0;
 113
 114         self.deadflag = DEAD_NO;
 115
 116         self.angles = spot.angles;
 117         self.fixangle = TRUE; // turn this way immediately
 118         self.velocity = '0 0 0';
 119         self.avelocity = '0 0 0';
 120         self.punchangle = '0 0 0';
 121         self.punchvector = '0 0 0';
 122
 123         self.viewzoom = 0.6;
 124
 125
 126         self.playermodel = CheckPlayerModel(self.playermodel);
 127
 128         precache_model (self.playermodel);
 129         setmodel (self, self.playermodel);
 130         self.skin = stof(self.playerskin);
 131         self.crouch = FALSE;
 132         self.view_ofs = PL_VIEW_OFS;
 133         setsize (self, PL_MIN, PL_MAX);
 134         setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 135         // don't reset back to last position, even if new position is stuck in solid
 136         self.oldorigin = self.origin;
 137
 138 //      self.items = IT_LASER | IT_UZI| IT_SHOTGUN | IT_GRENADE_LAUNCHER | IT_ELECTRO | IT_CRYLINK | IT_NEX | IT_HAGAR | IT_ROCKET_LAUNCHER;
 139 //      self.weapon = IT_UZI;
 140
 141         if (cvar("g_instagib") == 1)
 142         {
 143                 self.items = IT_NEX;
 144                 self.switchweapon = WEP_NEX;
 145                 self.ammo_shells = 0;
 146                 self.ammo_nails = 0;
 147                 self.ammo_rockets = 0;
 148                 self.ammo_cells = 999;
 149         }
 150         else if (cvar("g_rocketarena") == 1)
 151         {
 152                 self.items = IT_ROCKET_LAUNCHER;
 153                 self.switchweapon = WEP_ROCKET_LAUNCHER;
 154                 self.ammo_shells = 0;
 155                 self.ammo_nails = 0;
 156                 self.ammo_rockets = 999;
 157                 self.ammo_cells = 0;
 158         }
 159         else
 160         {
 161                 self.items = IT_LASER | IT_SHOTGUN;
 162                 self.switchweapon = WEP_SHOTGUN;
 163                 self.ammo_shells = 50;
 164                 self.ammo_nails = 0;
 165                 self.ammo_rockets = 0;
 166                 self.ammo_cells = 0;
 167         }
 168
 169         if (cvar("g_fullbrightplayers") == 1)
 170                 self.effects = EF_FULLBRIGHT;
 171
 172         self.event_damage = PlayerDamage;
 173
 174         self.statdraintime = time + 5;
 175         self.button0 = self.button1 = self.button2 = self.button3 = 0;
 176
 177         /*
 178         W_UpdateWeapon();
 179         W_UpdateAmmo();
 180         */
 181         CL_SpawnWeaponentity();
 182
 183         //stuffcmd(self, "chase_active 0");
 184 }
 185
 186 /*
 187 =============
 188 SetNewParms
 189 =============
 190 */
 191 void SetNewParms (void)
 192 {
 193
 194 }
 195
 196 /*
 197 =============
 198 SetChangeParms
 199 =============
 200 */
 201 void SetChangeParms (void)
 202 {
 203
 204 }
 205
 206 /*
 207 =============
 208 ClientKill
 209
 210 Called when a client types 'kill' in the console
 211 =============
 212 */
 213 void ClientKill (void)
 214 {
 215         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 216 }
 217
 218 /*
 219 =============
 220 ClientConnect
 221
 222 Called when a client connects to the server
 223 =============
 224 */
 225 void ClientConnect (void)
 226 {
 227         ClientInRankings();
 228         bprint ("^4",self.netname);
 229         bprint (" connected\n");
 230         stuffcmd(self, "exec maps/");
 231         stuffcmd(self, mapname);
 232         stuffcmd(self, ".cfg\n");
 233 }
 234
 235 /*
 236 =============
 237 ClientDisconnect
 238
 239 Called when a client disconnects from the server
 240 =============
 241 */
 242 void ClientDisconnect (void)
 243 {
 244         ClientDisconnected();
 245         bprint ("^4",self.netname);
 246         bprint (" disconnected\n");
 247 }
 248
 249 .entity chatbubbleentity;
 250 .float buttonchat;
 251 void() ChatBubbleThink =
 252 {
 253         self.nextthink = time;
 254         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 255         {
 256                 remove(self);
 257                 return;
 258         }
 259         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 260         if (self.owner.buttonchat)
 261                 self.effects = 0;
 262         else
 263                 self.effects = EF_NODRAW;
 264 };
 265
 266 void() UpdateChatBubble =
 267 {
 268         if (!self.modelindex)
 269                 return;
 270         // spawn a chatbubble entity if needed
 271         if (!self.chatbubbleentity)
 272         {
 273                 self.chatbubbleentity = spawn();
 274                 self.chatbubbleentity.owner = self;
 275                 self.chatbubbleentity.think = ChatBubbleThink;
 276                 self.chatbubbleentity.nextthink = time;
 277                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 278                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 279                 self.chatbubbleentity.effects = EF_NODRAW;
 280         }
 281 }
 282
 283 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 284 // added to the model skins
 285 void() UpdateColorModHack =
 286 {
 287         local float c;
 288         c = self.clientcolors & 15;
 289         // LordHavoc: only bothering to support white, green, red, yellow, blue
 290              if (teamplay == 0) self.colormod = '0 0 0';
 291         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 292         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 293         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 294         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 295         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 296         else self.colormod = '1 1 1';
 297 };
 298
 299 /*
 300 =============
 301 PlayerJump
 302
 303 When you press the jump key
 304 =============
 305 */
 306 void PlayerJump (void)
 307 {
 308         if (self.waterlevel >= 2)
 309         {
 310                 if (self.watertype == CONTENT_WATER)
 311                         self.velocity_z = 200;
 312                 else if (self.watertype == CONTENT_SLIME)
 313                         self.velocity_z = 80;
 314                 else
 315                         self.velocity_z = 50;
 316
 317                 return;
 318         }
 319
 320
 321         if (!(self.flags & FL_ONGROUND))
 322                 return;
 323
 324         if (!(self.flags & FL_JUMPRELEASED))
 325                 return;
 326
 327         self.velocity_z = self.velocity_z + cvar("g_balance_jumpheight");
 328
 329         self.flags = self.flags - FL_ONGROUND;
 330         self.flags = self.flags - FL_JUMPRELEASED;
 331 }
 332
 333 .float watersound_finished;
 334 void() WaterMove =
 335 {
 336         if (self.movetype == MOVETYPE_NOCLIP)
 337                 return;
 338         if (self.health < 0)
 339                 return;
 340
 341         if (self.waterlevel != 3)
 342         {
 343                 self.air_finished = time + 12;
 344                 self.dmg = 2;
 345         }
 346         else if (self.air_finished < time)
 347         {       // drown!
 348                 if (self.pain_finished < time)
 349                 {
 350                         Damage (self, world, world, 5, DEATH_DROWN, self.origin, '0 0 0');
 351                         self.pain_finished = time + 0.5;
 352                 }
 353         }
 354
 355         if (!self.waterlevel)
 356         {
 357                 if (self.flags & FL_INWATER)
 358                 {
 359                         // play leave water sound
 360                         self.flags = self.flags - FL_INWATER;
 361                 }
 362                 return;
 363         }
 364
 365         if (self.watersound_finished < time)
 366         {
 367                 self.watersound_finished = time + 0.5;
 368                 if (self.watertype == CONTENT_LAVA)
 369                         sound (self, CHAN_BODY, "player/lava.wav", 1, ATTN_NORM);
 370                 if (self.watertype == CONTENT_SLIME)
 371                         sound (self, CHAN_BODY, "player/slime.wav", 1, ATTN_NORM);
 372                 //if (self.watertype == CONTENT_WATER)
 373                 //      sound (self, CHAN_BODY, "player/water.wav", 1, ATTN_NORM);
 374         }
 375
 376         if (self.watertype == CONTENT_LAVA)
 377         {       // do damage
 378                 if (self.dmgtime < time)
 379                 {
 380                         self.dmgtime = time + 0.1;
 381                         Damage (self, world, world, 3 * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
 382                 }
 383         }
 384         else if (self.watertype == CONTENT_SLIME)
 385         {       // do damage
 386                 if (self.dmgtime < time)
 387                 {
 388                         self.dmgtime = time + 0.1;
 389                         Damage (self, world, world, 1 * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
 390                 }
 391         }
 392
 393         if ( !(self.flags & FL_INWATER) )
 394         {
 395
 396                 //if (self.watertype == CONTENT_LAVA)
 397                 //      sound (self, CHAN_BODY, "player/inlava.wav", 1, ATTN_NORM);
 398                 //if (self.watertype == CONTENT_WATER)
 399                 //      sound (self, CHAN_BODY, "player/inh2o.wav", 1, ATTN_NORM);
 400                 //if (self.watertype == CONTENT_SLIME)
 401                 //      sound (self, CHAN_BODY, "player/slimbrn2.wav", 1, ATTN_NORM);
 402
 403                 self.flags = self.flags + FL_INWATER;
 404                 self.dmgtime = 0;
 405         }
 406 };
 407
 408 void() CheckWaterJump =
 409 {
 410         local vector start, end;
 411
 412 // check for a jump-out-of-water
 413         makevectors (self.angles);
 414         start = self.origin;
 415         start_z = start_z + 8;
 416         v_forward_z = 0;
 417         normalize(v_forward);
 418         end = start + v_forward*24;
 419         traceline (start, end, TRUE, self);
 420         if (trace_fraction < 1)
 421         {       // solid at waist
 422                 start_z = start_z + self.maxs_z - 8;
 423                 end = start + v_forward*24;
 424                 self.movedir = trace_plane_normal * -50;
 425                 traceline (start, end, TRUE, self);
 426                 if (trace_fraction == 1)
 427                 {       // open at eye level
 428                         self.flags = self.flags | FL_WATERJUMP;
 429                         self.velocity_z = 225;
 430                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 431                         self.teleport_time = time + 2;  // safety net
 432                         return;
 433                 }
 434         }
 435 };
 436
 437
 438 void respawn(void)
 439 {
 440         CopyBody(1);
 441         PutClientInServer();
 442 }
 443
 444 void player_powerups (void)
 445 {
 446         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 447         if (self.items & IT_STRENGTH)
 448         {
 449                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 450                 if (time > self.strength_finished)
 451                 {
 452                         self.items = self.items - (self.items & IT_STRENGTH);
 453                         sprint(self, "^3Strength has worn off\n");
 454                 }
 455         }
 456         else
 457         {
 458                 if (time < self.strength_finished)
 459                 {
 460                         self.items = self.items | IT_STRENGTH;
 461                         sprint(self, "^3Strength infuses your weapons with devestating power\n");
 462                 }
 463         }
 464         if (self.items & IT_INVINCIBLE)
 465         {
 466                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
 467                 if (time > self.invincible_finished)
 468                 {
 469                         self.items = self.items - (self.items & IT_INVINCIBLE);
 470                         sprint(self, "^3Shield has worn off\n");
 471                 }
 472         }
 473         else
 474         {
 475                 if (time < self.invincible_finished)
 476                 {
 477                         self.items = self.items | IT_INVINCIBLE;
 478                         sprint(self, "^3Shield surrounds you\n");
 479                 }
 480         }
 481 }
 482
 483 void player_regen (void)
 484 {
 485         local float maxh;
 486         local float maxa;
 487         maxh = cvar("g_balance_health_stable");
 488         maxa = cvar("g_balance_armor_stable");
 489         if (self.health > maxh)
 490                 self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
 491         else if (time > self.pain_finished)
 492                 self.health = bound(0, self.health + (maxh- self.health) * cvar("g_balance_health_regen") * frametime, 1000);
 493         if (self.armorvalue > maxa)
 494                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 495         else if (time > self.pain_finished)
 496                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime, 1000);
 497 }
 498
 499 /*
 500 =============
 501 PlayerPreThink
 502
 503 Called every frame for each client before the physics are run
 504 =============
 505 */
 506 .float attack_finished;
 507 void PlayerPreThink (void)
 508 {
 509         local vector m1, m2;
 510
 511         if (BotPreFrame())
 512                 return;
 513
 514         CheckRules_Player();
 515
 516         if (intermission_running)
 517         {
 518                 IntermissionThink ();   // otherwise a button could be missed between
 519                 return;                                 // the think tics
 520         }
 521
 522         if (self.deadflag != DEAD_NO)
 523         {
 524                 player_anim();
 525                 weapon_freeze();
 526                 if (self.deadflag == DEAD_DYING)
 527                 {
 528                         if (time > self.dead_time)
 529                                 self.deadflag = DEAD_DEAD;
 530                 }
 531                 else if (self.deadflag == DEAD_DEAD)
 532                 {
 533                         if (!self.button0 && !self.button2 && !self.button3)
 534                                 self.deadflag = DEAD_RESPAWNABLE;
 535                 }
 536                 else if (self.deadflag == DEAD_RESPAWNABLE)
 537                 {
 538                         if (self.button0 || self.button2 || self.button3  || self.button4)
 539                                 respawn();
 540                 }
 541                 return;
 542         }
 543
 544         if (self.button5)
 545         {
 546                 if (!self.crouch)
 547                 {
 548                         self.crouch = TRUE;
 549                         self.view_ofs = PL_CROUCH_VIEW_OFS;
 550                         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
 551                 }
 552         }
 553         else
 554         {
 555                 if (self.crouch)
 556                 {
 557                         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
 558                         if (!trace_startsolid)
 559                         {
 560                                 self.crouch = FALSE;
 561                                 self.view_ofs = PL_VIEW_OFS;
 562                                 setsize (self, PL_MIN, PL_MAX);
 563                         }
 564                 }
 565         }
 566
 567         if (self.playermodel != self.model)
 568         {
 569                 self.playermodel = CheckPlayerModel(self.playermodel);
 570                 m1 = self.mins;
 571                 m2 = self.maxs;
 572                 precache_model (self.playermodel);
 573                 setmodel (self, self.playermodel);
 574                 setsize (self, m1, m2);
 575         }
 576
 577         if (self.skin != stof(self.playerskin))
 578                 self.skin = stof(self.playerskin);
 579
 580         W_WeaponFrame();
 581
 582         if (self.button4)
 583         {
 584                 if (self.viewzoom > 0.4)
 585                         self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
 586         }
 587         else if (self.viewzoom < 1.0)
 588                 self.viewzoom = min (1.0, self.viewzoom + frametime);
 589
 590
 591         if (self.button2)
 592                 PlayerJump ();
 593         else
 594                 self.flags = self.flags | FL_JUMPRELEASED;
 595
 596
 597         player_powerups();
 598         player_regen();
 599         player_anim();
 600
 601         self.angles_y=self.v_angle_y + 90;   // temp
 602
 603         WaterMove ();
 604         if (self.waterlevel == 2)
 605                 CheckWaterJump ();
 606
 607         //if (TetrisPreFrame()) return;
 608 }
 609
 610 /*
 611 =============
 612 PlayerPostThink
 613
 614 Called every frame for each client after the physics are run
 615 =============
 616 */
 617 void PlayerPostThink (void)
 618 {
 619         float soundrandom;
 620         if (BotPostFrame())
 621                 return;
 622         CheckRules_Player();
 623         UpdateChatBubble();
 624         UpdateColorModHack();
 625         if (self.deadflag == DEAD_NO)
 626         if (self.impulse)
 627                 ImpulseCommands ();
 628         if (intermission_running)
 629                 return;         // intermission or finale
 630
 631         // VorteX: landing on floor, landing damage etc.
 632         // LordHavoc: removed 'big fall' death code that VorteX added
 633         if (self.flags & FL_ONGROUND)
 634         {
 635                 if (self.jump_flag < -100 && !self.watertype == CONTENT_WATER) // HitGround
 636                 {
 637                         soundrandom = random() * 4;
 638                         if (soundrandom < 1)
 639                                 sound (self, CHAN_BODY, "misc/hitground1.wav", 1, ATTN_NORM);
 640                         else if (soundrandom < 2)
 641                                 sound (self, CHAN_BODY, "misc/hitground2.wav", 1, ATTN_NORM);
 642                         else if (soundrandom < 3)
 643                                 sound (self, CHAN_BODY, "misc/hitground3.wav", 1, ATTN_NORM);
 644                         else if (soundrandom < 4)
 645                                 sound (self, CHAN_BODY, "misc/hitground4.wav", 1, ATTN_NORM);
 646                         if (self.jump_flag < -650) // landing damage
 647                         {
 648                                 local float dm;
 649                                 dm = bound(0, 0.1*(fabs(self.jump_flag) - 600), 5);
 650                                 Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
 651                         }
 652                         self.jump_flag = 0;
 653                 }
 654         }
 655         else
 656                 self.jump_flag = self.velocity_z;
 657
 658         //if (TetrisPostFrame()) return;
 659 }