data/qcsrc/server/w_uzi.qc

   1 .float uzi_bulletcounter;
   2 void W_Uzi_Attack (void)
   3 {
   4         local entity flash, flash2;
   5
   6         if (cvar("g_use_ammunition"))
   7         {
   8                 if (self.uzi_bulletcounter == 1)
   9                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_first_ammo");
  10                 else
  11                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_sustained_ammo");
  12         }
  13         W_SetupShot (self, '15 5.5 -8', TRUE, 0, "weapons/uzi_fire.ogg");
  14         if (!cvar("g_norecoil"))
  15         {
  16                 self.punchangle_x = random () - 0.5;
  17                 self.punchangle_y = random () - 0.5;
  18         }
  19
  20         // this attack_finished just enforces a cooldown at the end of a burst
  21         self.attack_finished = time + cvar("g_balance_uzi_first_refire");
  22
  23         if (self.uzi_bulletcounter == 1)
  24                 fireBullet (w_shotorg, w_shotdir, cvar("g_balance_uzi_first_spread"), cvar("g_balance_uzi_first_damage"), IT_UZI, TRUE);
  25         else
  26                 fireBullet (w_shotorg, w_shotdir, cvar("g_balance_uzi_sustained_spread"), cvar("g_balance_uzi_sustained_damage"), IT_UZI, (self.uzi_bulletcounter & 3) == 0);
  27
  28         // muzzle flash for 1st person view
  29         flash = spawn();
  30         setorigin(flash, '53 5 -1');
  31         setmodel(flash, "models/uziflash.md3"); flash.effects = EF_LOWPRECISION;
  32         setattachment(flash, self.weaponentity, "bone01");
  33         flash.viewmodelforclient = self;
  34         flash.scale = 1.2;
  35         SUB_SetFade(flash, time, 0.2);
  36
  37         // muzzle flash for 3rd person view
  38         flash2 = spawn();
  39         setorigin(flash2, '51 1 8');
  40         setmodel(flash2, "models/uziflash.md3"); flash2.effects = EF_LOWPRECISION;
  41         setattachment(flash2, self.exteriorweaponentity, "");
  42         SUB_SetFade(flash2, time, 0.2);
  43
  44         // common properties
  45         flash.angles_z = flash2.angles_z = flash.v_angle_z + random() * 180;
  46         flash.alpha = flash2.alpha = 0.5;
  47         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  48
  49         // casing code
  50         if (cvar("g_casings") >= 2)
  51                 SpawnCasing (w_shotorg + v_forward * 10, ((random () * 50 + 50) * v_right) - ((random () * 25 + 25) * v_forward) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3);
  52 }
  53
  54 // weapon frames
  55 void()  uzi_fire1_02 =
  56 {
  57         if(self.weapon != self.switchweapon) // abort immediately if switching
  58         {
  59                 w_ready();
  60                 return;
  61         }
  62         if (self.button0)
  63         {
  64                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
  65                 {
  66                         self.switchweapon = w_getbestweapon(self);
  67                         if (self.switchweapon != self.weapon)
  68                                 self.cnt = self.weapon;
  69                         w_ready();
  70                         return;
  71                 }
  72                 self.attack_finished = time + cvar("g_balance_uzi_refire");
  73                 self.uzi_bulletcounter = self.uzi_bulletcounter + 1;
  74                 W_Uzi_Attack();
  75                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
  76         }
  77         else
  78                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
  79 };
  80
  81 float(float req) w_uzi =
  82 {
  83         if (req == WR_AIM)
  84                 self.button0 = bot_aim(1000000, 0, 0.001, FALSE);
  85         else if (req == WR_THINK)
  86         {
  87                 if (self.button0)
  88                 if (weapon_prepareattack(0, cvar("g_balance_uzi_refire")))
  89                 {
  90                         self.uzi_bulletcounter = 1;
  91                         W_Uzi_Attack();
  92                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
  93                 }
  94                 if (self.button3)
  95                 if (weapon_prepareattack(1, cvar("g_balance_uzi_refire")))
  96                 {
  97                         self.uzi_bulletcounter = 1;
  98                         W_Uzi_Attack();
  99                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
 100                 }
 101         }
 102         else if (req == WR_SETUP)
 103                 weapon_setup(WEP_UZI, "uzi", IT_NAILS);
 104         else if (req == WR_CHECKAMMO1)
 105                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 106         else if (req == WR_CHECKAMMO2)
 107                 return self.ammo_nails >= cvar("g_balance_uzi_sustained_ammo");
 108         return TRUE;
 109 };