data/qcsrc/server/w_tuba.qc

   1 #define TUBA_NOTE(n) strcat("weapons/tuba_note", ftos(n), ".wav")
   2 .float tuba_notecount;
   3
   4 float Tuba_GetNote(entity pl, float hittype)
   5 {
   6         float note;
   7         float movestate;
   8         movestate = 5;
   9         if(pl.movement_x < 0) movestate -= 3;
  10         if(pl.movement_x > 0) movestate += 3;
  11         if(pl.movement_y < 0) movestate -= 1;
  12         if(pl.movement_y > 0) movestate += 1;
  13         switch(movestate)
  14         {
  15         // layout: originally I wanted
  16         //   eb e  e#=f
  17         //   B  c  d
  18         //   Gb G  G#
  19         // but then you only use forward and right key. So to make things more
  20         // interesting, I swapped B with e#. Har har har...
  21         //   eb e  B
  22         // f=e# c  d
  23         //   Gb G  G#
  24                 case 1: note = -6; break; // Gb
  25                 case 2: note = -5; break; // G
  26                 case 3: note = -4; break; // G#
  27                 case 4: note = +5; break; // e#
  28                 case 5: note =  0; break; // c
  29                 case 6: note = +2; break; // d
  30                 case 7: note = +3; break; // eb
  31                 case 8: note = +4; break; // e
  32                 case 9: note = -1; break; // B
  33         }
  34         if(pl.BUTTON_CROUCH)
  35                 note -= 12;
  36         if(hittype & HITTYPE_SECONDARY)
  37                 note += 7;
  38
  39         // we support two kinds of tubas, those tuned in Eb and those tuned in C
  40         // kind of tuba currently is player slot number, or team number if in
  41         // teamplay
  42         // that way, holes in the range of notes are "plugged"
  43         if(teams_matter)
  44         {
  45                 if(pl.team == COLOR_TEAM2 || pl.team == COLOR_TEAM4)
  46                         note += 3;
  47         }
  48         else
  49         {
  50                 if(mod(num_for_edict(pl), 2) == 0)
  51                         note += 3;
  52         }
  53
  54         // total range of notes:
  55         //                       0
  56         //                 ***  ** ****
  57         //                        ***  ** ****
  58         //     ***  ** ****
  59         //            ***  ** ****
  60         //     ***  ********************* ****
  61         //     -18.........................+12
  62         //        ***  ********************* ****
  63         //     -18............................+15
  64         return note;
  65 }
  66
  67 void W_Tuba_Attack(float hittype)
  68 {
  69         W_SetupShot(self, FALSE, 2, "");
  70         self.tuba_notecount = !self.tuba_notecount;
  71         if(self.tuba_notecount)
  72                 sound(self, CHAN_WEAPON, TUBA_NOTE(Tuba_GetNote(self, hittype)), VOL_BASE, cvar("g_balance_tuba_attenuation"));
  73         else
  74                 sound(self, CHAN_WEAPON2, TUBA_NOTE(Tuba_GetNote(self, hittype)), VOL_BASE, cvar("g_balance_tuba_attenuation"));
  75         RadiusDamage(self, self, cvar("g_balance_tuba_damage"), cvar("g_balance_tuba_edgedamage"), cvar("g_balance_tuba_radius"), world, cvar("g_balance_tuba_force"), hittype | WEP_TUBA, world);
  76 }
  77
  78 void spawnfunc_weapon_tuba (void)
  79 {
  80         error("The tuba does not work yet. Forget it.");
  81         weapon_defaultspawnfunc(WEP_TUBA);
  82 }
  83
  84 float w_tuba(float req)
  85 {
  86         if (req == WR_AIM)
  87         {
  88                 // bots cannot play the Tuba yet
  89                 // I think they should start with the recorder first
  90         }
  91         else if (req == WR_THINK)
  92         {
  93                 if (self.BUTTON_ATCK)
  94                 if (weapon_prepareattack(0, cvar("g_balance_tuba_refire")))
  95                 {
  96                         W_Tuba_Attack(0);
  97                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_tuba_animtime"), w_ready);
  98                 }
  99                 if (self.BUTTON_ATCK2)
 100                 if (weapon_prepareattack(1, cvar("g_balance_tuba_refire")))
 101                 {
 102                         W_Tuba_Attack(HITTYPE_SECONDARY);
 103                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_tuba_animtime"), w_ready);
 104                 }
 105         }
 106         else if (req == WR_PRECACHE)
 107         {
 108                 precache_model ("models/weapons/g_tuba.md3");
 109                 precache_model ("models/weapons/v_tuba.md3");
 110                 precache_model ("models/weapons/h_tuba.dpm");
 111
 112                 float i;
 113                 for(i = -18; i <= +15; ++i)
 114                         precache_sound(TUBA_NOTE(i));
 115         }
 116         else if (req == WR_SETUP)
 117                 weapon_setup(WEP_TUBA);
 118         else if (req == WR_CHECKAMMO1)
 119                 return TRUE; // TODO use fuel?
 120         else if (req == WR_CHECKAMMO2)
 121                 return TRUE; // TODO use fuel?
 122         else if (req == WR_SUICIDEMESSAGE)
 123         {
 124                 w_deathtypestring = "hurt his own ears with the @!#%'n Tuba";
 125         }
 126         else if (req == WR_KILLMESSAGE)
 127         {
 128                 w_deathtypestring = "died of #'s great playing on the @!#%'n Tuba";
 129         }
 130         return TRUE;
 131 };