data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         self.event_damage = SUB_Null;
   7         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
   8
   9         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  10         {
  11                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  12                 {
  13                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  14                         ATTACK_FINISHED(self.owner) = time;
  15                         self.owner.switchweapon = w_getbestweapon(self.owner);
  16                 }
  17                 if(g_laserguided_missile)
  18                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  19         }
  20         remove (self);
  21 }
  22
  23 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  24 {
  25         entity head, selected;
  26         vector dir;
  27         float dist, maxdist,// bestdist,
  28                 dot,// bestdot,
  29                 points, bestpoints;
  30         //bestdist = 9999;
  31         //bestdot = -2;
  32         bestpoints = 0;
  33         maxdist = 800;
  34         selected = world;
  35
  36         makevectors(e.angles);
  37
  38         head = find(world, classname, "laser_target");
  39         while(head)
  40         {
  41                 points = 0;
  42                 dir = normalize(head.origin - self.origin);
  43                 dot = dir * v_forward;
  44                 dist = vlen(head.origin - self.origin);
  45                 if(dist > maxdist)
  46                         dist = maxdist;
  47
  48                 // gain points for being in front
  49                 points = points + ((dot+1)*0.5) * 500
  50                         * (1 + crandom()*dot_variance);
  51                 // gain points for being close away
  52                 points = points + (1 - dist/maxdist) * 1000
  53                         * (1 + crandom()*dot_variance);
  54
  55                 traceline(e.origin, head.origin, TRUE, self);
  56                 if(trace_fraction < 1)
  57                 {
  58                         points = 0;
  59                 }
  60
  61                 if(points > bestpoints)//random() > 0.5)//
  62                 {
  63                         bestpoints = points;
  64                         selected = head;
  65                 }
  66
  67                 head = find(head, classname, "laser_target");
  68         }
  69
  70         //bprint(selected.owner.netname);
  71         //bprint("\n");
  72         return selected;
  73 }
  74
  75 void W_Rocket_RemoteExplode()
  76 {
  77         if(self.owner.deadflag == DEAD_NO)
  78         {
  79                 if((self.spawnshieldtime >= 0)
  80                         ? (time >= self.spawnshieldtime) // timer
  81                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  82                 )
  83                 {
  84                         other = world;
  85                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  86                         W_Rocket_Explode ();
  87                 }
  88                 else
  89                 {
  90                 }
  91         }
  92 }
  93
  94 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
  95 {
  96         if(thisdir * goaldir > maxturn_cos)
  97                 return goaldir;
  98         float f, m2;
  99         vector v;
 100         // solve:
 101         //   g = normalize(thisdir + goaldir * X)
 102         //   thisdir * g = maxturn
 103         //
 104         //   gg = thisdir + goaldir * X
 105         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 106         //
 107         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 108         f = thisdir * goaldir;
 109         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 110         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 111         m2 = maxturn_cos * maxturn_cos;
 112         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 113         return normalize(thisdir + goaldir * v_y); // the larger solution!
 114 }
 115
 116 void W_Rocket_Think (void)
 117 {
 118         entity e;
 119         vector desireddir, olddir, newdir, desiredorigin, goal;
 120         float turnrate, velspeed;
 121         self.nextthink = time;
 122         if (time > self.cnt)
 123         {
 124                 other = world;
 125                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 126                 W_Rocket_Explode ();
 127                 return;
 128         }
 129
 130         if(g_laserguided_missile)
 131         {
 132                 // accelerate
 133                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 134                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 135                 if (velspeed > 0)
 136                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 137         }
 138         else
 139         {
 140                 // accelerate
 141                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 142                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 143                 if (velspeed > 0)
 144                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 145         }
 146
 147         // laser guided, or remote detonation
 148         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 149         {
 150                 if(g_laserguided_missile)
 151                 {
 152                         if(self.rl_detonate_later)
 153                                 W_Rocket_RemoteExplode();
 154
 155                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 156                         {
 157                                 if(self.owner.laser_on)
 158                                 {
 159                                         if(self.attack_finished_single < time)
 160                                         {
 161                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 162                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 163                                         }
 164
 165                                         if(!self.enemy)
 166                                                 self.enemy = self.owner.weaponentity.lasertarget;
 167                                 }
 168                                 else self.enemy = world;
 169                         }
 170                         else // don't allow stealing: always target my owner's laser (if it exists)
 171                                 self.enemy = self.owner.weaponentity.lasertarget;
 172
 173                         if(self.enemy != world)
 174                         {
 175                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 176                                 velspeed = vlen(self.velocity);
 177                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 178                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 179                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 180                                 olddir = normalize(self.velocity);                                      // get my current direction
 181                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 182                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 183                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 184
 185                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 186                         }
 187                 }
 188                 else
 189                 {
 190                         if(!self.rl_release && !self.owner.rl_release && cvar("g_balance_rocketlauncher_guiderate"))
 191                         {
 192                                 velspeed = vlen(self.velocity);
 193
 194                                 makevectors(self.owner.v_angle);
 195                                 desireddir = v_forward;
 196                                 desiredorigin = self.owner.origin + self.owner.view_ofs;
 197                                 olddir = normalize(self.velocity);
 198
 199                                 // now it gets tricky... we want to move like some curve to approximate the target direction
 200                                 // but we are limiting the rate at which we can turn!
 201                                 goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 202                                 newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * frametime * PI / 180));
 203
 204                                 self.velocity = newdir * velspeed;
 205                         }
 206                         else
 207                                 self.rl_release = 1;
 208
 209                         if(self.rl_detonate_later)
 210                                 W_Rocket_RemoteExplode();
 211                 }
 212         }
 213
 214         if(self.csqcprojectile_clientanimate == 0)
 215                 UpdateCSQCProjectile(self);
 216 }
 217
 218 void W_Rocket_Touch (void)
 219 {
 220         if(self.owner && self.owner.lastrocket == self)
 221                 self.owner.lastrocket = world;
 222         PROJECTILE_TOUCH;
 223         W_Rocket_Explode ();
 224 }
 225
 226 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 227 {
 228         self.health = self.health - damage;
 229         self.angles = vectoangles(self.velocity);
 230         if (self.health <= 0)
 231                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 232 }
 233
 234 void W_Rocket_Attack (void)
 235 {
 236         local entity missile;
 237         local entity flash;
 238
 239         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 240                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 241
 242         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav");
 243         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 244
 245         missile = spawn ();
 246         missile.owner = self;
 247         self.lastrocket = missile;
 248         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 249                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 250         else
 251                 missile.spawnshieldtime = -1;
 252         missile.classname = "rocket";
 253         missile.bot_dodge = TRUE;
 254         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 255
 256         missile.takedamage = DAMAGE_YES;
 257         missile.damageforcescale = 4;
 258         missile.health = cvar("g_balance_rocketlauncher_health");
 259         missile.event_damage = W_Rocket_Damage;
 260
 261         missile.movetype = MOVETYPE_FLY;
 262         missile.solid = SOLID_BBOX;
 263         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 264         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 265
 266         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 267         if(g_laserguided_missile && self.laser_on)
 268                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 269         else
 270                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 271         W_SetupProjectileVelocity(missile);
 272         missile.angles = vectoangles (missile.velocity);
 273
 274         missile.touch = W_Rocket_Touch;
 275         missile.think = W_Rocket_Think;
 276         missile.nextthink = time;
 277         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 278         missile.flags = FL_PROJECTILE;
 279
 280         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 281
 282         // muzzle flash for 1st person view
 283         flash = spawn ();
 284         setmodel (flash, "models/flash.md3"); // precision set below
 285         SUB_SetFade (flash, time, 0.1);
 286         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 287         W_AttachToShotorg(flash, '5 0 0');
 288
 289         // common properties
 290 }
 291
 292 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 293
 294 float w_rlauncher(float req)
 295 {
 296         entity rock;
 297         float rockfound;
 298         if (req == WR_AIM)
 299         {
 300                 // aim and decide to fire if appropriate
 301                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 302                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 303                 {
 304                         // decide whether to detonate rockets
 305                         local entity missile, targetlist, targ;
 306                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 307                         local float selfdamage, teamdamage, enemydamage;
 308                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 309                         coredamage = cvar("g_balance_rocketlauncher_damage");
 310                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 311                         recipricoledgeradius = 1 / edgeradius;
 312                         selfdamage = 0;
 313                         teamdamage = 0;
 314                         enemydamage = 0;
 315                         targetlist = findchainfloat(bot_attack, TRUE);
 316                         missile = find(world, classname, "rocket");
 317                         while (missile)
 318                         {
 319                                 if (missile.owner != self)
 320                                 {
 321                                         missile = find(missile, classname, "rocket");
 322                                         continue;
 323                                 }
 324                                 targ = targetlist;
 325                                 while (targ)
 326                                 {
 327                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 328                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 329                                         // count potential damage according to type of target
 330                                         if (targ == self)
 331                                                 selfdamage = selfdamage + d;
 332                                         else if (targ.team == self.team && teams_matter)
 333                                                 teamdamage = teamdamage + d;
 334                                         else if (bot_shouldattack(targ))
 335                                                 enemydamage = enemydamage + d;
 336                                         targ = targ.chain;
 337                                 }
 338                                 missile = find(missile, classname, "rocket");
 339                         }
 340                         local float desirabledamage;
 341                         desirabledamage = enemydamage;
 342                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 343                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 344                         if (self.team && teamplay != 1)
 345                                 desirabledamage = desirabledamage - teamdamage;
 346
 347                         missile = find(world, classname, "rocket");
 348                         while (missile)
 349                         {
 350                                 if (missile.owner != self)
 351                                 {
 352                                         missile = find(missile, classname, "rocket");
 353                                         continue;
 354                                 }
 355                                 makevectors(missile.v_angle);
 356                                 targ = targetlist;
 357                                 if (skill > 9) // normal players only do this for the target they are tracking
 358                                 {
 359                                         targ = targetlist;
 360                                         while (targ)
 361                                         {
 362                                                 if (
 363                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 364                                                         && desirabledamage > 0.1*coredamage
 365                                                 )self.BUTTON_ATCK2 = TRUE;
 366                                                 targ = targ.chain;
 367                                         }
 368                                 }else{
 369                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 370                                         //As the distance gets larger, a correct detonation gets near imposible
 371                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 372                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 373                                                 if(self.enemy.classname == "player")
 374                                                         if(desirabledamage >= 0.1*coredamage)
 375                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 376                                                                         self.BUTTON_ATCK2 = TRUE;
 377                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 378                                 }
 379
 380                                 missile = find(missile, classname, "rocket");
 381                         }
 382                         // if we would be doing at X percent of the core damage, detonate it
 383                         // but don't fire a new shot at the same time!
 384                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 385                                 self.BUTTON_ATCK2 = TRUE;
 386                         if ((skill > 6.5) && (selfdamage > self.health))
 387                                 self.BUTTON_ATCK2 = FALSE;
 388                         //if(self.BUTTON_ATCK2 == TRUE)
 389                         //      dprint(ftos(desirabledamage),"\n");
 390                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 391                 }
 392         }
 393         else if (req == WR_THINK)
 394         {
 395                 if(g_laserguided_missile)
 396                 {
 397                         if (self.BUTTON_ATCK && self.rl_release)
 398                         {
 399                                 rockfound = 0;
 400                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 401                                 {
 402                                         if(!rock.rl_detonate_later)
 403                                         {
 404                                                 rock.rl_detonate_later = TRUE;
 405                                                 rockfound = 1;
 406                                         }
 407                                 }
 408                                 if(rockfound)
 409                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 410                                 else
 411                                 {
 412                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 413                                         {
 414                                                 W_Rocket_Attack();
 415                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 416                                         }
 417                                 }
 418                                 self.rl_release = 0;
 419                         }
 420                         if (!self.BUTTON_ATCK)
 421                                 self.rl_release = 1;
 422                         if (self.BUTTON_ATCK2)
 423                         if(self.exteriorweaponentity.attack_finished_single < time)
 424                         {
 425                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 426                                 self.laser_on = !self.laser_on;
 427                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 428                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 429                         }
 430                 }
 431                 else
 432                 {
 433                         if (self.BUTTON_ATCK && self.rl_release)
 434                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 435                         {
 436                                 W_Rocket_Attack();
 437                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 438                                 self.rl_release = 0;
 439                         }
 440                         if (!self.BUTTON_ATCK)
 441                                 self.rl_release = 1;
 442                         if (self.BUTTON_ATCK2)
 443                         {
 444                                 rockfound = 0;
 445                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 446                                 {
 447                                         if(!rock.rl_detonate_later)
 448                                         {
 449                                                 rock.rl_detonate_later = TRUE;
 450                                                 rockfound = 1;
 451                                         }
 452                                 }
 453                                 if(rockfound)
 454                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 455                         }
 456                 }
 457         }
 458         else if (req == WR_PRECACHE)
 459         {
 460                 precache_model ("models/flash.md3");
 461                 precache_model ("models/weapons/g_rl.md3");
 462                 precache_model ("models/weapons/v_rl.md3");
 463                 precache_model ("models/weapons/h_rl.dpm");
 464                 precache_sound ("weapons/rocket_det.wav");
 465                 precache_sound ("weapons/rocket_fire.wav");
 466                 if (g_laserguided_missile)
 467                 {
 468                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 469                         precache_sound ("weapons/rocket_mode.wav");
 470                 }
 471         }
 472         else if (req == WR_SETUP)
 473         {
 474                 weapon_setup(WEP_ROCKET_LAUNCHER);
 475                 self.rl_release = 1;
 476         }
 477         else if (req == WR_CHECKAMMO1)
 478         {
 479                 // don't switch while guiding a missile
 480                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 481                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 482                         return FALSE;
 483         }
 484         else if (req == WR_CHECKAMMO2)
 485                 return FALSE;
 486         else if (req == WR_SUICIDEMESSAGE)
 487                 w_deathtypestring = "exploded";
 488         else if (req == WR_KILLMESSAGE)
 489         {
 490                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 491                         w_deathtypestring = "got too close to #'s rocket";
 492                 else if(w_deathtype & HITTYPE_SPLASH)
 493                         w_deathtypestring = "almost dodged #'s rocket";
 494                 else
 495                         w_deathtypestring = "ate #'s rocket";
 496         }
 497         return TRUE;
 498 };